lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "translator-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87
  88
  89 #define YYERROR_VERBOSE 1
  90
  91 My_lily_parser* my_lily_parser;
  92 #define YYPARSE_PARAM my_lily_parser
  93 #define YYLEX_PARAM my_lily_parser
  94 #define THIS\
  95         ((My_lily_parser *) my_lily_parser)
  96
  97 #define yyerror THIS->parser_error
  98
  99 /*
 100   Add symbols to the  TAGS field of a music object.
 101 */
 102
 103 void
 104 tag_music (Music*m,  SCM tag, Input ip)
 105 {
 106         SCM tags = m->get_mus_property ("tags");
 107         if (gh_symbol_p (tag))
 108                 tags = scm_cons (tag, tags);
 109         else if (gh_list_p (tag))
 110                 tags = gh_append2 (tag, tags);
 111         else
 112                 ip.warning (_("Tag must be symbol or list of symbols."));
 113
 114         m->set_mus_property ("tags", tags);
 115 }
 116
 117
 118
 119 bool
 120 regular_identifier_b (SCM id)
 121 {
 122   String str = ly_scm2string (id);
 123   char const *s = str.to_str0 () ;
 124
 125   bool v = true;
 126   while (*s && v)
 127    {
 128         v = v && isalpha (*s);
 129         s++;
 130    }
 131   return v;
 132 }
 133
 134 SCM
 135 make_simple_markup (SCM a)
 136 {
 137         static SCM simple;
 138         if (!simple)
 139         simple = scm_c_eval_string ("simple-markup");
 140
 141         return scm_list_n (simple, a, SCM_UNDEFINED);
 142 }
 143
 144
 145 bool
 146 is_duration_b (int t)
 147 {
 148   return t && t == 1 << intlog2 (t);
 149 }
 150
 151 void
 152 set_music_properties (Music *p, SCM a)
 153 {
 154   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 155         {
 156         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 157         }
 158 }
 159
 160 SCM
 161 make_chord_step (int step, int alter)
 162 {
 163         if (step == 7)
 164                 alter += FLAT;
 165
 166         while(step < 0)
 167                 step += 7;
 168         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 169         return m.smobbed_copy ();
 170 }
 171
 172
 173 SCM
 174 make_chord (SCM pitch, SCM dur, SCM modification_list)
 175 {
 176         static SCM chord_ctor;
 177         if (!chord_ctor)
 178                 chord_ctor= scm_c_eval_string ("construct-chord");
 179         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 180         scm_gc_protect_object (ch);
 181         return ch;
 182 }
 183
 184 /*
 185   Todo: actually also use apply iso. call too ...
 186 */
 187 bool
 188 ly_input_procedure_p (SCM x)
 189 {
 190         return gh_procedure_p (x)
 191                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 192 }
 193
 194 Music*
 195 set_property_music (SCM sym, SCM value)
 196 {
 197         Music * p = MY_MAKE_MUSIC("PropertySet");
 198         p->set_mus_property ("symbol", sym);
 199         p->set_mus_property ("value", value);
 200         return p;
 201 }
 202
 203 %}
 204
 205 /* We use SCMs to do strings, because it saves us the trouble of
 206 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 207 of the parse stack onto the heap. */
 208
 209
 210 %union {
 211         String * string;
 212     Music *music;
 213     Score *score;
 214     Music_output_def * outputdef;
 215     SCM scm;
 216     int i;
 217 }
 218 %{
 219
 220 int
 221 yylex (YYSTYPE *s,  void * v)
 222 {
 223         My_lily_parser   *pars = (My_lily_parser*) v;
 224         My_lily_lexer * lex = pars->lexer_;
 225
 226         lex->lexval = (void*) s;
 227         lex->prepare_for_next_token();
 228         return lex->yylex ();
 229 }
 230
 231
 232 %}
 233
 234 %pure_parser
 235
 236
 237 %token ACCEPTS
 238 %token ADDLYRICS
 239 %token ALIAS
 240 %token ALTERNATIVE
 241 %token APPLY
 242 %token APPLYCONTEXT
 243 %token APPLYOUTPUT
 244 %token AUTOCHANGE
 245 %token BAR
 246 %token BREATHE
 247 %token CHORDMODIFIERS
 248 %token CHORDS
 249 %token LESSLESS
 250 %token MOREMORE
 251 %token CLEF
 252 %token COMMANDSPANREQUEST
 253 %token CONSISTS
 254 %token CONSISTSEND
 255 %token CONTEXT
 256 %token DEFAULT
 257 %token DENIES
 258 %token DESCRIPTION
 259 %token EXTENDER
 260 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 261 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 262 %token GRACE
 263 %token ACCIACCATURA
 264 %token APPOGGIATURA
 265 %token GROBDESCRIPTIONS
 266 %token HEADER
 267 %token HYPHEN
 268 %token INVALID
 269 %token KEY
 270 %token LYRICS
 271 %token MARK
 272 %token MIDI
 273 %token MULTI_MEASURE_REST
 274 %token NAME
 275 %token NEWCONTEXT
 276 %token NOTES
 277 %token OCTAVE
 278 %token ONCE
 279 %token OVERRIDE SET REVERT
 280 %token PAPER
 281 %token PARTCOMBINE
 282 %token PARTIAL
 283 %token PITCHNAMES
 284 %token PROPERTY
 285 %token RELATIVE
 286 %token REMOVE
 287 %token REPEAT
 288 %token REST
 289 %token SCM_T
 290 %token SCORE
 291 %token SEQUENTIAL
 292 %token SIMULTANEOUS
 293 %token SKIP
 294 %token SPANREQUEST
 295 %token TAG
 296 %token TEMPO
 297 %token TIMES
 298 %token TIME_T
 299 %token TRANSLATOR
 300 %token TRANSPOSE
 301 %token TYPE
 302 %token UNSET
 303
 304
 305 /* escaped */
 306 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 307 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 308 %token E_BACKSLASH
 309 %token <i> E_UNSIGNED
 310 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 311 %token FIGURE_SPACE
 312
 313 %type <i>       exclamations questions dots optional_rest
 314 %type <i>        bass_mod
 315 %type <scm>     grace_head
 316 %type <scm>     lyric_element
 317 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 318 %token <i>      DIGIT
 319 %token <scm>    NOTENAME_PITCH
 320 %token <scm>    TONICNAME_PITCH
 321 %token <scm>    CHORDMODIFIER_PITCH
 322 %token <scm>    DURATION_IDENTIFIER
 323 %token <scm>    FRACTION
 324 %token <id>     IDENTIFIER
 325 %token <scm>    CHORDNAMES
 326
 327 %token <scm> CHORD_MODIFIER
 328
 329 %token <scm>    SCORE_IDENTIFIER
 330 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 331 %token <scm>    NUMBER_IDENTIFIER
 332 %token <scm>    EVENT_IDENTIFIER
 333 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 334 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 335 %token <scm>    RESTNAME
 336 %token <scm>    STRING
 337 %token <scm>    SCM_T
 338 %token <i>      UNSIGNED
 339 %token <scm>   REAL
 340
 341 %token MARKUP
 342 %token <scm> MARKUP_HEAD_MARKUP0
 343 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 344 %token <scm> MARKUP_HEAD_SCM0
 345 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0_SCM1
 347 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 349
 350 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 351 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 352
 353 %type <outputdef> output_def
 354 %type <scm>     lilypond_header lilypond_header_body
 355 %type <music>   open_event close_event
 356 %type <i>       sub_quotes sup_quotes
 357 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 358 %type <music>   Repeated_music
 359 %type <scm>     Alternative_music
 360 %type <i>       tremolo_type
 361 %type <i>       bare_int  bare_unsigned
 362 %type <i>       script_dir
 363 %type <scm>     identifier_init
 364
 365 %type <music> note_chord_element chord_body chord_body_element
 366 %type <scm>  chord_body_elements
 367 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 368
 369 %type <scm>   post_events
 370 %type <music> gen_text_def direction_less_event direction_reqd_event
 371 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 372 %type <scm>    steno_tonic_pitch
 373 %type <scm>     duration_length fraction
 374
 375 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 376
 377 %type <scm>  embedded_scm scalar
 378 %type <music>   Music Sequential_music Simultaneous_music
 379 %type <music>   relative_music re_rhythmed_music part_combined_music
 380 %type <music>   property_def translator_change  simple_property_def
 381 %type <scm> Music_list
 382 %type <outputdef>  music_output_def_body
 383 %type <music> shorthand_command_req
 384 %type <music>   post_event tagged_post_event
 385 %type <music> command_req verbose_command_req
 386 %type <music>   extender_req
 387 %type <music> hyphen_req
 388 %type <music> string_number_event
 389 %type <scm>     string bare_number number_expression number_term number_factor
 390 %type <score>   score_block score_body
 391
 392 %type <scm>     translator_spec_block translator_spec_body
 393 %type <music>   tempo_event
 394 %type <scm> notenames_body notenames_block chordmodifiers_block
 395 %type <scm>     script_abbreviation
 396
 397
 398
 399 %left '-' '+'
 400
 401 /* We don't assign precedence to / and *, because we might need varied
 402 prec levels in different prods */
 403
 404 %left UNARY_MINUS
 405
 406 %%
 407
 408 lilypond:       /* empty */
 409         | lilypond toplevel_expression {}
 410         | lilypond assignment  { }
 411         | lilypond error {
 412                 THIS->error_level_  = 1;
 413         }
 414         | lilypond INVALID      {
 415                 THIS->error_level_  = 1;
 416         }
 417         ;
 418
 419 toplevel_expression:
 420         notenames_block                 {
 421                 THIS->lexer_->pitchname_tab_ =  $1;
 422         }
 423         | chordmodifiers_block                  {
 424                 THIS->lexer_->chordmodifier_tab_  = $1;
 425         }
 426         | lilypond_header {
 427                 THIS->input_file_->header_ = $1;
 428         }
 429         | score_block {
 430                 Score * sc = $1;
 431
 432                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 433
 434                 Path p = split_path (THIS->output_basename_);
 435                 int *c =  &THIS->input_file_->score_count_;
 436                 if (*c)
 437                         {
 438                         p.base += "-" + to_string (*c);
 439                         }
 440
 441                 (*c)++;
 442                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 443
 444                 for (int i=0; i < sc->defs_.size (); i++)
 445                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 446
 447                 if (sc->defs_.empty ())
 448                 {
 449                    Music_output_def *id =
 450                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 451                                 ("$defaultpaper"));
 452
 453                    id = id ? id->clone () : new Paper_def;
 454
 455                    default_rendering (sc->music_, id->self_scm(), head, outname);
 456
 457                    scm_gc_unprotect_object (id->self_scm ());
 458                 }
 459                 scm_gc_unprotect_object (sc->self_scm());
 460         }
 461         | output_def {
 462                 if (dynamic_cast<Paper_def*> ($1))
 463                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 464                 else if (dynamic_cast<Midi_def*> ($1))
 465                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 466         }
 467         ;
 468
 469 embedded_scm:
 470         SCM_T
 471         | SCM_IDENTIFIER
 472         ;
 473
 474
 475 chordmodifiers_block:
 476         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 477         ;
 478
 479 notenames_block:
 480         PITCHNAMES notenames_body   {  $$ = $2; }
 481         ;
 482
 483 notenames_body:
 484         embedded_scm    {
 485           int i = scm_ilength ($1);
 486
 487           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 488           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 489                 SCM pt = ly_cdar (s);
 490                 scm_hashq_set_x (tab, ly_caar (s), pt);
 491           }
 492           $$ = tab;
 493         }
 494         ;
 495
 496 lilypond_header_body:
 497         {
 498                 $$ = ly_make_anonymous_module ();
 499                 THIS->lexer_->add_scope ($$);
 500         }
 501         | lilypond_header_body assignment  {
 502
 503         }
 504         ;
 505
 506 lilypond_header:
 507         HEADER '{' lilypond_header_body '}'     {
 508                 $$ = THIS->lexer_-> remove_scope();
 509         }
 510         ;
 511
 512
 513 /*
 514         DECLARATIONS
 515 */
 516 assignment:
 517         STRING {
 518                 THIS->push_spot ();
 519         }
 520         /* cont */ '=' identifier_init  {
 521
 522         /*
 523                 Should find generic way of associating input with objects.
 524         */
 525                 Input ip = THIS->pop_spot ();
 526
 527                 if (! regular_identifier_b ($1))
 528                 {
 529                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 530                 }
 531
 532                 THIS->lexer_->set_identifier ($1, $4);
 533
 534 /*
 535  TODO: devise standard for protection in parser.
 536
 537   The parser stack lives on the C-stack, which means that
 538 all objects can be unprotected as soon as they're here.
 539
 540 */
 541         }
 542         | embedded_scm { }
 543         ;
 544
 545
 546
 547 identifier_init:
 548         score_block {
 549                 $$ = $1->self_scm ();
 550                 scm_gc_unprotect_object ($$);
 551         }
 552         | full_markup {
 553                 $$ = $1;
 554         }
 555         | output_def {
 556                 $$ = $1->self_scm ();
 557                 scm_gc_unprotect_object ($$);
 558         }
 559         | translator_spec_block {
 560                 $$ = $1;
 561         }
 562         | Music  {
 563                 $$ = $1->self_scm ();
 564                 scm_gc_unprotect_object ($$);
 565         }
 566         | post_event {
 567                 $$ = $1->self_scm ();
 568                 scm_gc_unprotect_object ($$);
 569         }
 570         | number_expression {
 571                 $$ = $1;
 572         }
 573         | string {
 574                 $$ = $1;
 575         }
 576         | embedded_scm  {
 577                 $$ = $1;
 578         }
 579         ;
 580
 581 translator_spec_block:
 582         TRANSLATOR '{' translator_spec_body '}'
 583                 {
 584                 $$ = $3;
 585         }
 586         ;
 587
 588 translator_spec_body:
 589         /**/ {
 590                 $$ = Translator_def::make_scm ();
 591                 unsmob_translator_def ($$)->set_spot (THIS->here_input ());
 592         }
 593         | TRANSLATOR_IDENTIFIER {
 594                 $$ = $1;
 595                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 596         }
 597         | translator_spec_body TYPE STRING      {
 598                 unsmob_translator_def ($$)->translator_group_type_ = $3;
 599         }
 600         | translator_spec_body DESCRIPTION string  {
 601                 unsmob_translator_def ($$)->description_ = $3;
 602         }
 603         | translator_spec_body STRING '=' embedded_scm                  {
 604                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 605         }
 606         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 607                 unsmob_translator_def ($$)
 608                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 609         }
 610         | translator_spec_body STRING SET embedded_scm '=' embedded_scm {
 611                 unsmob_translator_def ($$)
 612                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 613         }
 614         | translator_spec_body STRING REVERT embedded_scm  {
 615           unsmob_translator_def ($$)->add_pop_property (
 616                 scm_string_to_symbol ($2), $4);
 617         }
 618         | translator_spec_body NAME STRING  {
 619                 unsmob_translator_def ($$)->type_name_ = scm_string_to_symbol ($3);
 620         }
 621         | translator_spec_body CONSISTS STRING  {
 622                 unsmob_translator_def ($$)->add_element ($3);
 623         }
 624         | translator_spec_body ALIAS STRING  {
 625                 Translator_def*td = unsmob_translator_def ($$);
 626                 td->type_aliases_ = scm_cons (scm_string_to_symbol ($3), td->type_aliases_);
 627         }
 628         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 629                 Translator_def*td = unsmob_translator_def($$);
 630                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 631                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 632                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 633         }
 634         | translator_spec_body CONSISTSEND STRING  {
 635                 unsmob_translator_def ($$)->add_last_element ( $3);
 636         }
 637         | translator_spec_body ACCEPTS STRING  {
 638                 unsmob_translator_def ($$)->set_acceptor (scm_string_to_symbol ($3), true);
 639         }
 640         | translator_spec_body DENIES STRING  {
 641                 unsmob_translator_def ($$)->set_acceptor (scm_string_to_symbol ($3), false);
 642         }
 643         | translator_spec_body REMOVE STRING  {
 644                 unsmob_translator_def ($$)->remove_element ($3);
 645         }
 646         ;
 647
 648 /*
 649         SCORE
 650 */
 651 score_block:
 652         SCORE {
 653                 THIS->push_spot ();
 654         }
 655         /*cont*/ '{' score_body '}'     {
 656                 THIS->pop_spot ();
 657                 $$ = $4;
 658
 659         }
 660         ;
 661
 662 score_body:
 663         Music   {
 664                 $$ = new Score;
 665
 666                 $$->set_spot (THIS->here_input ());
 667                 SCM m = $1->self_scm ();
 668                 scm_gc_unprotect_object (m);
 669
 670                 /*
 671                         guh.
 672                 */
 673                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 674                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 675                         m = gh_call1 (gh_car (check_funcs), m);
 676                 $$->music_ = m;
 677
 678         }
 679         | SCORE_IDENTIFIER {
 680                 $$ = unsmob_score ($1);
 681                 $$->set_spot (THIS->here_input ());
 682         }
 683         | score_body lilypond_header    {
 684                 $$->header_ = $2;
 685         }
 686         | score_body output_def {
 687                 $$->defs_.push ($2);
 688         }
 689         | score_body error {
 690
 691         }
 692         ;
 693
 694
 695 /*
 696         MIDI
 697 */
 698 output_def:
 699         music_output_def_body '}' {
 700                 $$ = $1;
 701                 THIS-> lexer_-> remove_scope ();
 702         }
 703         ;
 704
 705 music_output_def_body:
 706         MIDI '{'    {
 707                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 708
 709
 710                 Midi_def* p =0;
 711                 if (id)
 712                         p = dynamic_cast<Midi_def*> (id->clone ());
 713                 else
 714                         p = new Midi_def;
 715
 716                 $$ = p;
 717                 THIS->lexer_->add_scope (p->scope_);
 718         }
 719         | PAPER '{'     {
 720                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 721                   Paper_def *p = 0;
 722                 if (id)
 723                         p = dynamic_cast<Paper_def*> (id->clone ());
 724                 else
 725                         p = new Paper_def;
 726
 727                 THIS->lexer_->add_scope (p->scope_);
 728                 $$ = p;
 729         }
 730         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 731                 Music_output_def * o =  unsmob_music_output_def ($3);
 732                 $$ =o;
 733
 734                 THIS->lexer_->add_scope (o->scope_);
 735         }
 736         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 737                 Music_output_def * o =  unsmob_music_output_def ($3);
 738                 $$ = o;
 739
 740                 THIS->lexer_->add_scope (o->scope_);
 741         }
 742         | music_output_def_body assignment  {
 743
 744         }
 745         | music_output_def_body translator_spec_block   {
 746                 $$->assign_translator ($2);
 747         }
 748         | music_output_def_body tempo_event  {
 749                 /*
 750                         junk this ? there already is tempo stuff in
 751                         music.
 752                 */
 753                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 754                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 755                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 756                 if (md)
 757                         md->set_tempo (d->get_length (), m);
 758         }
 759         | music_output_def_body error {
 760
 761         }
 762         ;
 763
 764 tempo_event:
 765         TEMPO steno_duration '=' bare_unsigned  {
 766                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 767                 $$->set_mus_property ("tempo-unit", $2);
 768                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 769         }
 770         ;
 771
 772 /*
 773 The representation of a  list is the
 774
 775   (LIST . LAST-CONS)
 776
 777  to have  efficient append.
 778 */
 779 Music_list:
 780         /* empty */ {
 781                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 782         }
 783         | Music_list Music {
 784                 SCM s = $$;
 785                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 786                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 787                 if (gh_pair_p (ly_cdr (s)))
 788                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 789                 else
 790                         gh_set_car_x (s, c); /* set first cons */
 791                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 792         }
 793         | Music_list error {
 794         }
 795         ;
 796
 797
 798 Music:
 799         Simple_music
 800         | Composite_music
 801         ;
 802
 803 Alternative_music:
 804         /* empty */ {
 805                 $$ = SCM_EOL;
 806         }
 807         | ALTERNATIVE '{' Music_list '}' {
 808                 $$ = $3;
 809         }
 810         ;
 811
 812 Repeated_music:
 813         REPEAT string bare_unsigned Music Alternative_music
 814         {
 815                 Music *beg = $4;
 816                 int times = $3;
 817                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 818                 if (times < scm_ilength (alts)) {
 819                   unsmob_music (gh_car (alts))
 820                     ->origin ()->warning (
 821                     _("More alternatives than repeats.  Junking excess alternatives."));
 822                   alts = ly_truncate_list (times, alts);
 823                 }
 824
 825
 826                 static SCM proc;
 827                 if (!proc)
 828                         proc = scm_c_eval_string ("make-repeated-music");
 829
 830                 SCM mus = scm_call_1 (proc, $2);
 831                 scm_gc_protect_object (mus); // UGH.
 832                 Music *r =unsmob_music (mus);
 833                 if (beg)
 834                         {
 835                         r-> set_mus_property ("element", beg->self_scm ());
 836                         scm_gc_unprotect_object (beg->self_scm ());
 837                         }
 838                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 839
 840                 r-> set_mus_property ("elements",alts);
 841                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 842                         /*
 843                         we can not get durations and other stuff correct down the line, so we have to
 844                         add to the duration log here.
 845                         */
 846                         static SCM func;
 847
 848                         if (!func)
 849                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 850
 851                         int dots = ($3 % 3) ? 0 : 1;
 852                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 853
 854                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 855
 856                         if (seq) {
 857                                 int list_len =scm_ilength (seq->music_list ());
 858                                 if (list_len != 2)
 859                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 860                                 shift -= 1;
 861                                 r->compress (Moment (Rational (1,list_len)));
 862                                 }
 863                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 864
 865                 }
 866                 r->set_spot (*$4->origin ());
 867
 868                 $$ = r;
 869         }
 870         ;
 871
 872 Sequential_music:
 873         SEQUENTIAL '{' Music_list '}'           {
 874                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 875                 $$->set_mus_property ("elements", ly_car ($3));
 876                 $$->set_spot(THIS->here_input());
 877         }
 878         | '{' Music_list '}'            {
 879                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 880                 $$->set_mus_property ("elements", ly_car ($2));
 881                 $$->set_spot(THIS->here_input());
 882         }
 883         ;
 884
 885 Simultaneous_music:
 886         SIMULTANEOUS '{' Music_list '}'{
 887                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 888                 $$->set_mus_property ("elements", ly_car ($3));
 889                 $$->set_spot(THIS->here_input());
 890
 891         }
 892         | simul_open Music_list simul_close     {
 893                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 894                 $$->set_mus_property ("elements", ly_car ($2));
 895                 $$->set_spot(THIS->here_input());
 896         }
 897         ;
 898
 899 Simple_music:
 900         event_chord             { $$ = $1; }
 901         | APPLYOUTPUT embedded_scm {
 902                 if (!ly_input_procedure_p ($2))
 903                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 904                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 905                 $$->set_mus_property ("procedure", $2);
 906                 $$->set_spot (THIS->here_input());
 907         }
 908         | APPLYCONTEXT embedded_scm {
 909                 if (!ly_input_procedure_p ($2))
 910                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 911                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 912                 $$->set_mus_property ("procedure", $2);
 913                 $$->set_spot (THIS->here_input());
 914         }
 915         | MUSIC_IDENTIFIER {
 916                 $$ = unsmob_music ($1);
 917         }
 918         | property_def
 919         | translator_change
 920         ;
 921
 922
 923 grace_head:
 924         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 925         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 926         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 927         ;
 928
 929
 930 Composite_music:
 931         CONTEXT STRING Music    {
 932                 Music*csm =MY_MAKE_MUSIC("ContextSpeccedMusic");
 933
 934                 csm->set_mus_property ("element", $3->self_scm ());
 935                 scm_gc_unprotect_object ($3->self_scm ());
 936
 937                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
 938                 csm->set_mus_property ("context-id", scm_makfrom0str (""));
 939
 940                 $$ = csm;
 941         }
 942         | AUTOCHANGE STRING Music       {
 943         Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 944                 chm->set_mus_property ("element", $3->self_scm ());
 945                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 946
 947                 scm_gc_unprotect_object ($3->self_scm ());
 948                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 949
 950                 $$ = chm;
 951                 chm->set_spot (*$3->origin ());
 952         }
 953         | grace_head Music {
 954 #if 1
 955         /*
 956                 The other version is for easier debugging  of
 957                 Sequential_music_iterator in combination with grace notes.
 958         */
 959
 960 /*
 961
 962 TODO: should distinguish between both grace types in the
 963 basic music objects too, since the meaning is different.
 964
 965 */
 966
 967                 String start_str = "start" + ly_scm2string ($1) + "Music";
 968                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 969
 970                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 971                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 972
 973                 Music *startm = unsmob_music (start);
 974                 Music *stopm = unsmob_music (stop);
 975
 976                 SCM ms = SCM_EOL;
 977                 if (stopm) {
 978                         stopm = stopm->clone ();
 979                         ms = scm_cons (stopm->self_scm (), ms);
 980                         scm_gc_unprotect_object (stopm->self_scm ());
 981                 }
 982                 ms = scm_cons ($2->self_scm (), ms);
 983                 scm_gc_unprotect_object ($2->self_scm());
 984                 if (startm) {
 985                         startm = startm->clone ();
 986                         ms = scm_cons (startm->self_scm () , ms);
 987                         scm_gc_unprotect_object (startm->self_scm ());
 988                 }
 989
 990
 991                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 992                 seq->set_mus_property ("elements", ms);
 993
 994
 995                 $$ = MY_MAKE_MUSIC("GraceMusic");
 996                 $$->set_mus_property ("element", seq->self_scm ());
 997                 scm_gc_unprotect_object (seq->self_scm ());
 998 #else
 999                 $$ = MY_MAKE_MUSIC("GraceMusic");
1000                 $$->set_mus_property ("element", $2->self_scm ());
1001                 scm_gc_unprotect_object ($2->self_scm ());
1002 #endif
1003         }
1004         | CONTEXT string '=' string Music {
1005                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1006
1007                 csm->set_mus_property ("element", $5->self_scm ());
1008                 scm_gc_unprotect_object ($5->self_scm ());
1009
1010                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
1011                 csm->set_mus_property ("context-id", $4);
1012
1013                 $$ = csm;
1014         }
1015         | NEWCONTEXT string Music {
1016                 static int new_context_count;
1017
1018                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1019
1020                 csm->set_mus_property ("element", $3->self_scm ());
1021                 scm_gc_unprotect_object ($3->self_scm ());
1022
1023                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
1024
1025                 char s[1024];
1026                 snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
1027
1028                 SCM new_id = scm_makfrom0str (s);
1029                 csm->set_mus_property ("context-id", new_id);
1030                 $$ = csm;
1031         }
1032         | TIMES {
1033                 THIS->push_spot ();
1034         }
1035         /* CONTINUED */
1036                 fraction Music
1037
1038         {
1039                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
1040                 Music *mp = $4;
1041
1042                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
1043                 $$->set_spot (THIS->pop_spot ());
1044
1045                 $$->set_mus_property ("element", mp->self_scm ());
1046                 scm_gc_unprotect_object (mp->self_scm ());
1047                 $$->set_mus_property ("numerator", gh_int2scm (n));
1048                 $$->set_mus_property ("denominator", gh_int2scm (d));
1049                 $$->compress (Moment (Rational (n,d)));
1050
1051         }
1052         | Repeated_music                { $$ = $1; }
1053         | Simultaneous_music            { $$ = $1; }
1054         | Sequential_music              { $$ = $1; }
1055         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1056                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1057                 Music *p = $4;
1058                 Pitch from = *unsmob_pitch ($2);
1059                 Pitch to = *unsmob_pitch ($3);
1060
1061                 p->transpose (interval (from, to));
1062                 $$->set_mus_property ("element", p->self_scm ());
1063                 scm_gc_unprotect_object (p->self_scm ());
1064         }
1065         | APPLY embedded_scm Music  {
1066                 if (!ly_input_procedure_p ($2))
1067                         {
1068                         THIS->parser_error (_ ("\\apply takes function argument"));
1069                         $$ = $3;
1070                         }
1071                 else
1072                         {
1073                         SCM ret = gh_call1 ($2, $3->self_scm ());
1074                         Music *m = unsmob_music (ret);
1075                         if (!m) {
1076                                 THIS->parser_error ("\\apply must return a Music");
1077                                 m = MY_MAKE_MUSIC("Music");
1078                                 }
1079                         $$ = m;
1080                         }
1081         }
1082         | NOTES
1083                 { THIS->lexer_->push_note_state (); }
1084         Music
1085                 { $$ = $3;
1086                   THIS->lexer_->pop_state ();
1087                 }
1088         | FIGURES
1089                 { THIS->lexer_->push_figuredbass_state (); }
1090         Music
1091                 {
1092                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1093                   chm->set_mus_property ("element", $3->self_scm ());
1094                   $$ = chm;
1095                   scm_gc_unprotect_object ($3->self_scm());
1096
1097                   THIS->lexer_->pop_state ();
1098         }
1099         | CHORDS
1100                 { THIS->lexer_->push_chord_state (); }
1101         Music
1102                 {
1103                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1104                   chm->set_mus_property ("element", $3->self_scm ());
1105                   scm_gc_unprotect_object ($3->self_scm());
1106                   $$ = chm;
1107
1108                   THIS->lexer_->pop_state ();
1109         }
1110         | LYRICS
1111                 { THIS->lexer_->push_lyric_state (); }
1112         Music
1113                 {
1114                   $$ = $3;
1115                   THIS->lexer_->pop_state ();
1116         }
1117         | relative_music        { $$ = $1; }
1118         | re_rhythmed_music     { $$ = $1; }
1119         | part_combined_music   { $$ = $1; }
1120         | TAG embedded_scm Music {
1121                 tag_music ($3, $2, THIS->here_input ());
1122                 $$ = $3;
1123         }
1124         ;
1125
1126 relative_music:
1127         RELATIVE absolute_pitch Music {
1128                 Music * p = $3;
1129                 Pitch pit = *unsmob_pitch ($2);
1130                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1131
1132                 $$->set_mus_property ("element", p->self_scm ());
1133                 scm_gc_unprotect_object (p->self_scm ());
1134
1135
1136                 Pitch retpitch = p->to_relative_octave (pit);
1137                 if (lily_1_8_relative)
1138                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1139         }
1140         ;
1141
1142 re_rhythmed_music:
1143         ADDLYRICS Music Music {
1144         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1145           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1146           scm_gc_unprotect_object ($3->self_scm ());
1147           scm_gc_unprotect_object ($2->self_scm ());
1148           $$ = l;
1149         }
1150         ;
1151
1152 part_combined_music:
1153         PARTCOMBINE STRING Music Music {
1154                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1155                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1156                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1157
1158                 scm_gc_unprotect_object ($3->self_scm ());
1159                 scm_gc_unprotect_object ($4->self_scm ());
1160
1161                 $$ = p;
1162         }
1163         ;
1164
1165 translator_change:
1166         TRANSLATOR STRING '=' STRING  {
1167                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1168                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1169                 t-> set_mus_property ("change-to-id", $4);
1170
1171                 $$ = t;
1172                 $$->set_spot (THIS->here_input ());
1173         }
1174         ;
1175
1176 property_def:
1177         simple_property_def
1178         | ONCE simple_property_def {
1179                 $$ = $2;
1180                 SCM e = $2->get_mus_property ("element");
1181                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1182         }
1183         ;
1184
1185 simple_property_def:
1186         PROPERTY STRING '.' STRING '='  scalar {
1187                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1188                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1189
1190                 csm->set_mus_property ("element", t->self_scm ());
1191                 scm_gc_unprotect_object (t->self_scm ());
1192
1193                 $$ = csm;
1194                 $$->set_spot (THIS->here_input ());
1195
1196                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1197         }
1198         | PROPERTY STRING '.' STRING UNSET {
1199
1200                 Music *t = MY_MAKE_MUSIC("PropertyUnset");
1201                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1202
1203                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1204                 csm->set_mus_property ("element", t->self_scm ());
1205                 scm_gc_unprotect_object (t->self_scm ());
1206
1207                 $$ = csm;
1208                 $$->set_spot (THIS->here_input ());
1209
1210                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1211         }
1212         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1213                 bool autobeam
1214                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1215                 bool itc = internal_type_checking_global_b;
1216                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1217                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1218                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1219                 if (autobeam)
1220                         internal_type_checking_global_b = false;
1221                 t->set_mus_property ("grob-property", $6);
1222                 if (autobeam)
1223                         internal_type_checking_global_b = itc;
1224                 t->set_mus_property ("grob-value", $8);
1225
1226                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1227                 csm->set_mus_property ("element", t->self_scm ());
1228                 scm_gc_unprotect_object (t->self_scm ());
1229                 $$ = csm;
1230                 $$->set_spot (THIS->here_input ());
1231
1232                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1233         }
1234         | PROPERTY STRING '.' STRING OVERRIDE
1235                 embedded_scm '=' embedded_scm
1236         {
1237                 /*
1238                         UGH UGH UGH UGH.
1239                 */
1240                 bool autobeam
1241                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1242                 bool itc = internal_type_checking_global_b;
1243
1244                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1245                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1246                 if (autobeam)
1247                         internal_type_checking_global_b = false;
1248                 t->set_mus_property ("grob-property", $6);
1249                 t->set_mus_property ("grob-value", $8);
1250                 if (autobeam)
1251                         internal_type_checking_global_b = itc;
1252
1253                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1254                 csm->set_mus_property ("element", t->self_scm ());
1255                 scm_gc_unprotect_object (t->self_scm ());
1256
1257                 $$ = csm;
1258                 $$->set_spot (THIS->here_input ());
1259
1260                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1261
1262         }
1263         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1264                 Music *t = MY_MAKE_MUSIC("RevertProperty");
1265                 bool autobeam
1266                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1267                 bool itc = internal_type_checking_global_b;
1268
1269                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1270                 if (autobeam)
1271                         internal_type_checking_global_b = false;
1272                 t->set_mus_property ("grob-property", $6);
1273                 if (autobeam)
1274                         internal_type_checking_global_b = itc;
1275
1276                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1277                 csm->set_mus_property ("element", t->self_scm ());
1278                 scm_gc_unprotect_object (t->self_scm ());
1279
1280                 $$ = csm;
1281                 $$->set_spot (THIS->here_input ());
1282
1283                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1284         }
1285         ;
1286
1287
1288 scalar:
1289         string          { $$ = $1; }
1290         | bare_int      { $$ = gh_int2scm ($1); }
1291         | embedded_scm  { $$ = $1; }
1292         | full_markup {  $$ = $1; }
1293         | DIGIT { $$ = gh_int2scm ($1); }
1294         ;
1295
1296
1297
1298 /*
1299 This is a trick:
1300
1301 Adding pre_events to the simple_element
1302 makes the choice between
1303
1304   string:  STRING
1305
1306 and
1307
1308   simple_element: STRING
1309
1310 a single shift/reduction conflict.
1311
1312 nevertheless, this is not very clean, and we should find a different
1313 solution.
1314
1315 */
1316 pre_events: {
1317                 THIS->push_spot ();
1318         }
1319         ;
1320
1321 event_chord:
1322         pre_events simple_element post_events   {
1323                 SCM elts = $2-> get_mus_property ("elements");
1324
1325                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1326
1327                 $2->set_mus_property ("elements", elts);
1328                 $$ = $2;
1329         }
1330         | command_element
1331         | note_chord_element
1332         ;
1333
1334
1335 note_chord_element:
1336         chord_body optional_notemode_duration post_events
1337         {
1338                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1339                 SCM es = $1->get_mus_property ("elements");
1340                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1341
1342                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1343                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1344                 es = gh_append2 (es, postevs);
1345
1346                 $1-> set_mus_property ("elements", es);
1347                 $$ = $1;
1348         }
1349         ;
1350
1351 chord_open: '<'
1352         ;
1353
1354 chord_close: '>'
1355         ;
1356
1357 simul_open: LESSLESS
1358         ;
1359
1360 simul_close: MOREMORE
1361         ;
1362
1363 chord_body:
1364         chord_open chord_body_elements chord_close
1365         {
1366                 $$ = MY_MAKE_MUSIC("EventChord");
1367                 $$->set_mus_property ("elements",
1368                         scm_reverse_x ($2, SCM_EOL));
1369         }
1370         ;
1371
1372 chord_body_elements:
1373         /* empty */             { $$ = SCM_EOL; }
1374         | chord_body_elements chord_body_element {
1375                 $$ = gh_cons ($2->self_scm(), $1);
1376                 scm_gc_unprotect_object ($2->self_scm());
1377         }
1378         ;
1379
1380 chord_body_element:
1381         pitch exclamations questions post_events
1382         {
1383                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1384                 n->set_mus_property ("pitch", $1);
1385                 if ($3 % 2)
1386                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1387                 if ($2 % 2 || $3 % 2)
1388                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1389
1390                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1391                 n->set_mus_property ("articulations", arts);
1392
1393                 $$ = n;
1394         }
1395         ;
1396
1397 command_element:
1398         command_req {
1399                 $$ = MY_MAKE_MUSIC("EventChord");
1400                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1401                 scm_gc_unprotect_object ($1->self_scm());
1402
1403                 $$-> set_spot (THIS->here_input ());
1404                 $1-> set_spot (THIS->here_input ());
1405         }
1406         | OCTAVE { THIS->push_spot (); }
1407           pitch {
1408                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1409                 $$ = l;
1410                 $$->set_spot (THIS->pop_spot ());
1411                 $$->set_mus_property ("pitch", $3);
1412         }
1413         | E_LEFTSQUARE {
1414                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1415                 l->set_mus_property ("span-direction", gh_int2scm (START));
1416                 l->set_spot (THIS->here_input ());
1417
1418                 $$ = MY_MAKE_MUSIC("EventChord");
1419                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1420                 scm_gc_unprotect_object (l->self_scm());
1421                 $$->set_spot (THIS->here_input ());
1422         }
1423         | E_RIGHTSQUARE {
1424                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1425                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1426                 l->set_spot (THIS->here_input ());
1427
1428                 $$ = MY_MAKE_MUSIC("EventChord");
1429                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1430                 $$->set_spot (THIS->here_input ());
1431                 scm_gc_unprotect_object (l->self_scm());
1432         }
1433         | E_BACKSLASH {
1434                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1435                 $$->set_spot (THIS->here_input ());
1436         }
1437         | '|'      {
1438
1439                 $$ = MY_MAKE_MUSIC("BarCheck");
1440                 $$->set_spot (THIS->here_input ());
1441         }
1442         | BAR STRING                    {
1443                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1444
1445                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1446                 csm->set_mus_property ("element", t->self_scm ());
1447                 scm_gc_unprotect_object (t->self_scm ());
1448
1449                 $$ = csm;
1450                 $$->set_spot (THIS->here_input ());
1451
1452                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1453         }
1454         | PARTIAL duration_length       {
1455                 Moment m = - unsmob_duration ($2)->get_length ();
1456                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1457
1458                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1459                 sp->set_mus_property ("element", p->self_scm ());
1460                 scm_gc_unprotect_object (p->self_scm ());
1461
1462                 $$ =sp ;
1463                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1464         }
1465         | CLEF STRING  {
1466                 static SCM proc ;
1467                 if (!proc)
1468                         proc = scm_c_eval_string ("make-clef-set");
1469
1470                 SCM result = scm_call_1 (proc, $2);
1471                 scm_gc_protect_object (result);
1472                 $$ = unsmob_music (result);
1473         }
1474         | TIME_T fraction  {
1475                 static SCM proc;
1476                 if (!proc)
1477                         proc = scm_c_eval_string ("make-time-signature-set");
1478
1479                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1480                 scm_gc_protect_object (result);
1481                 $$ = unsmob_music (result);
1482         }
1483         ;
1484
1485 command_req:
1486         shorthand_command_req   { $$ = $1; }
1487         | verbose_command_req   { $$ = $1; }
1488         ;
1489
1490 shorthand_command_req:
1491         extender_req {
1492                 $$ = $1;
1493         }
1494         | hyphen_req {
1495                 $$ = $1;
1496         }
1497         | BREATHE {
1498                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1499         }
1500         | E_TILDE {
1501                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1502         }
1503         ;
1504
1505 verbose_command_req:
1506         MARK DEFAULT  {
1507                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1508                 $$ = m;
1509         }
1510         | MARK scalar {
1511                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1512                 m->set_mus_property ("label", $2);
1513                 $$ = m;
1514         }
1515         | SKIP duration_length {
1516                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1517                 skip->set_mus_property ("duration", $2);
1518
1519                 $$ = skip;
1520         }
1521         | tempo_event {
1522                 $$ = $1;
1523         }
1524         | KEY DEFAULT {
1525                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1526                 $$ = key;
1527         }
1528         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1529
1530                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1531                 if (scm_ilength ($3) > 0)
1532                 {
1533                         key->set_mus_property ("pitch-alist", $3);
1534                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1535                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1536                 } else {
1537                         THIS->parser_error (_("Second argument must be pitch list."));
1538                 }
1539
1540                 $$ = key;
1541         }
1542         ;
1543
1544 post_events:
1545         /* empty */ {
1546                 $$ = SCM_EOL;
1547         }
1548         | post_events post_event {
1549                 $2->set_spot (THIS->here_input ());
1550                 $$ = gh_cons ($2->self_scm(), $$);
1551                 scm_gc_unprotect_object ($2->self_scm());
1552         }
1553         | post_events tagged_post_event {
1554                 $2 -> set_spot (THIS->here_input ());
1555                 $$ = scm_cons ($2->self_scm(), $$);
1556                 scm_gc_unprotect_object ($2->self_scm());
1557         }
1558         ;
1559
1560
1561 tagged_post_event:
1562         '-' TAG embedded_scm post_event {
1563                 tag_music ($4, $3, THIS->here_input ());
1564                 $$ = $4;
1565         }
1566         ;
1567
1568 post_event:
1569         direction_less_event {
1570                 $$ = $1;
1571         }
1572         | script_dir direction_reqd_event {
1573                 if ($1)
1574                         $2->set_mus_property ("direction", gh_int2scm ($1));
1575                 $$ = $2;
1576         }
1577         | script_dir direction_less_event {
1578                 if ($1)
1579                         $2->set_mus_property ("direction", gh_int2scm ($1));
1580                 $$ = $2;
1581         }
1582         | string_number_event
1583         ;
1584
1585 string_number_event:
1586         E_UNSIGNED {
1587                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1588                 s->set_mus_property ("string-number",  gh_int2scm($1));
1589                 s->set_spot (THIS->here_input ());
1590                 $$ = s;
1591         }
1592         ;
1593
1594
1595 direction_less_event:
1596         '['  {
1597
1598
1599 /*
1600
1601 TODO: should take all these defs out of the parser, adn make use
1602 configurable, i.e.
1603
1604
1605 (set-articulation '~ "trill")
1606
1607 */
1608                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1609                 m->set_spot (THIS->here_input());
1610                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1611                 $$ = m;
1612         }
1613         | ']'  {
1614                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1615                 m->set_spot (THIS->here_input());
1616                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1617                 $$ = m;
1618         }
1619         | '~' {
1620                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1621                 m->set_spot (THIS->here_input());
1622                 $$ = m;
1623         }
1624         | close_event {
1625                 $$ = $1;
1626                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (START));
1627         }
1628         | open_event {
1629                 $$ = $1;
1630                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (STOP));
1631         }
1632         | EVENT_IDENTIFIER      {
1633                 $$ = unsmob_music ($1);
1634         }
1635         | tremolo_type  {
1636                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1637                a->set_spot (THIS->here_input ());
1638                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1639                $$ = a;
1640         }
1641         ;
1642
1643 direction_reqd_event:
1644         gen_text_def {
1645                 $$ = $1;
1646         }
1647         | script_abbreviation {
1648                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1649                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1650                 if (gh_string_p (s))
1651                         a->set_mus_property ("articulation-type", s);
1652                 else THIS->parser_error (_ ("Expecting string as script definition"));
1653                 $$ = a;
1654         }
1655         ;
1656
1657 sup_quotes:
1658         '\'' {
1659                 $$ = 1;
1660         }
1661         | sup_quotes '\'' {
1662                 $$ ++;
1663         }
1664         ;
1665
1666 sub_quotes:
1667         ',' {
1668                 $$ = 1;
1669         }
1670         | sub_quotes ',' {
1671                 $$ ++ ;
1672         }
1673         ;
1674
1675 steno_pitch:
1676         NOTENAME_PITCH  {
1677                 $$ = $1;
1678         }
1679         | NOTENAME_PITCH sup_quotes     {
1680                 Pitch p = *unsmob_pitch ($1);
1681                 p = p.transposed (Pitch ($2,0,0));
1682                 $$ = p.smobbed_copy ();
1683         }
1684         | NOTENAME_PITCH sub_quotes      {
1685                 Pitch p =* unsmob_pitch ($1);
1686                 p = p.transposed (Pitch (-$2,0,0));
1687                 $$ = p.smobbed_copy ();
1688         }
1689         ;
1690
1691 /*
1692 ugh. duplication
1693 */
1694
1695 steno_tonic_pitch:
1696         TONICNAME_PITCH {
1697                 $$ = $1;
1698         }
1699         | TONICNAME_PITCH sup_quotes    {
1700                 Pitch p = *unsmob_pitch ($1);
1701                 p = p.transposed (Pitch ($2,0,0));
1702                 $$ = p.smobbed_copy ();
1703         }
1704         | TONICNAME_PITCH sub_quotes     {
1705                 Pitch p =* unsmob_pitch ($1);
1706
1707                 p = p.transposed (Pitch (-$2,0,0));
1708                 $$ = p.smobbed_copy ();
1709         }
1710         ;
1711
1712 pitch:
1713         steno_pitch {
1714                 $$ = $1;
1715         }
1716         ;
1717
1718 pitch_also_in_chords:
1719         pitch
1720         | steno_tonic_pitch
1721         ;
1722
1723
1724
1725
1726
1727 extender_req:
1728         EXTENDER {
1729                 if (!THIS->lexer_->lyric_state_b ())
1730                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1731                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1732         }
1733         ;
1734
1735 hyphen_req:
1736         HYPHEN {
1737                 if (!THIS->lexer_->lyric_state_b ())
1738                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1739                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1740         }
1741         ;
1742
1743 close_event:
1744         '('     {
1745                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1746                 $$ = s;
1747                 s->set_spot (THIS->here_input());
1748         }
1749         | E_OPEN        {
1750                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1751                 $$ = s;
1752                 s->set_spot (THIS->here_input());
1753         }
1754         | E_SMALLER {
1755                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1756                 $$ = s;
1757                 s->set_spot (THIS->here_input());
1758         }
1759         | E_BIGGER {
1760                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1761                 $$ = s;
1762                 s->set_spot (THIS->here_input());
1763         }
1764         ;
1765
1766
1767 open_event:
1768         E_EXCLAMATION   {
1769                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1770                 s->set_spot (THIS->here_input());
1771
1772                 $$ = s;
1773         }
1774         | ')'   {
1775                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1776                 $$ = s;
1777                 s->set_spot (THIS->here_input());
1778
1779         }
1780         | E_CLOSE       {
1781                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1782                 $$ = s;
1783                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1784                 s->set_spot (THIS->here_input());
1785         }
1786         ;
1787
1788 gen_text_def:
1789         full_markup {
1790                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1791                 t->set_mus_property ("text", $1);
1792                 t->set_spot (THIS->here_input ());
1793                 $$ = t;
1794         }
1795         | string {
1796                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1797                 t->set_mus_property ("text", make_simple_markup ($1));
1798                 t->set_spot (THIS->here_input ());
1799                 $$ = t;
1800
1801         }
1802         | DIGIT {
1803                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1804                 t->set_mus_property ("digit",  gh_int2scm ($1));
1805                 t->set_spot (THIS->here_input ());
1806                 $$ = t;
1807         }
1808         ;
1809
1810 script_abbreviation:
1811         '^'             {
1812                 $$ = scm_makfrom0str ("Hat");
1813         }
1814         | '+'           {
1815                 $$ = scm_makfrom0str ("Plus");
1816         }
1817         | '-'           {
1818                 $$ = scm_makfrom0str ("Dash");
1819         }
1820         | '|'           {
1821                 $$ = scm_makfrom0str ("Bar");
1822         }
1823         | '>'           {
1824                 $$ = scm_makfrom0str ("Larger");
1825         }
1826         | '.'           {
1827                 $$ = scm_makfrom0str ("Dot");
1828         }
1829         | '_' {
1830                 $$ = scm_makfrom0str ("Underscore");
1831         }
1832         ;
1833
1834 script_dir:
1835         '_'     { $$ = DOWN; }
1836         | '^'   { $$ = UP; }
1837         | '-'   { $$ = CENTER; }
1838         ;
1839
1840
1841 absolute_pitch:
1842         steno_pitch     {
1843                 $$ = $1;
1844         }
1845         ;
1846
1847 duration_length:
1848         multiplied_duration {
1849                 $$ = $1;
1850         }
1851         ;
1852
1853 optional_notemode_duration:
1854         {
1855                 Duration dd = THIS->default_duration_;
1856                 $$ = dd.smobbed_copy ();
1857
1858                 THIS->beam_check ($$);
1859         }
1860         | multiplied_duration   {
1861                 $$ = $1;
1862                 THIS->default_duration_ = *unsmob_duration ($$);
1863
1864                 THIS->beam_check ($$);
1865         }
1866         ;
1867
1868 steno_duration:
1869         bare_unsigned dots              {
1870                 int l = 0;
1871                 if (!is_duration_b ($1))
1872                         THIS->parser_error (_f ("not a duration: %d", $1));
1873                 else
1874                         l =  intlog2 ($1);
1875
1876                 $$ = Duration (l, $2).smobbed_copy ();
1877         }
1878         | DURATION_IDENTIFIER dots      {
1879                 Duration *d =unsmob_duration ($1);
1880                 Duration k (d->duration_log (),d->dot_count () + $2);
1881
1882                 *d = k;
1883                 $$ = $1;
1884         }
1885         ;
1886
1887
1888
1889
1890 multiplied_duration:
1891         steno_duration {
1892                 $$ = $1;
1893         }
1894         | multiplied_duration '*' bare_unsigned {
1895                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1896         }
1897         | multiplied_duration '*' FRACTION {
1898                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1899
1900                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1901         }
1902         ;
1903
1904 fraction:
1905         FRACTION { $$ = $1; }
1906         | UNSIGNED '/' UNSIGNED {
1907                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1908         }
1909         ;
1910
1911 dots:
1912         /* empty */     {
1913                 $$ = 0;
1914         }
1915         | dots '.' {
1916                 $$ ++;
1917         }
1918         ;
1919
1920
1921 tremolo_type:
1922         ':'     {
1923                 $$ =0;
1924         }
1925         | ':' bare_unsigned {
1926                 if (!is_duration_b ($2))
1927                         THIS->parser_error (_f ("not a duration: %d", $2));
1928                 $$ = $2;
1929         }
1930         ;
1931
1932
1933
1934 /*****************************************************************
1935                 BASS FIGURES
1936 *****************************************************************/
1937 bass_number:
1938         DIGIT   {
1939                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1940         }
1941         | UNSIGNED {
1942                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1943         }
1944         | STRING { $$ =  $1; }
1945         ;
1946
1947 bass_mod:
1948         '-'     { $$ = -2; }
1949         | '+'   { $$ = 2; }
1950         | '!'   { $$ = 0; }
1951         ;
1952
1953 bass_figure:
1954         FIGURE_SPACE {
1955                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1956                 $$ = bfr->self_scm();
1957                 scm_gc_unprotect_object ($$);
1958         }
1959         | bass_number  {
1960                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1961                 $$ = bfr->self_scm();
1962
1963                 bfr->set_mus_property ("figure", $1);
1964
1965                 scm_gc_unprotect_object ($$);
1966         }
1967         | bass_figure bass_mod {
1968                 Music *m = unsmob_music ($1);
1969                 if ($2) {
1970                         SCM salter =m->get_mus_property ("alteration");
1971                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1972                         m->set_mus_property ("alteration",
1973                                 gh_int2scm (alter + $2));
1974                 } else {
1975                         m->set_mus_property ("alteration", gh_int2scm (0));
1976                 }
1977         }
1978         ;
1979
1980 br_bass_figure:
1981         '[' bass_figure {
1982                 $$ = $2;
1983                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1984         }
1985         | bass_figure   {
1986                 $$ = $1;
1987         }
1988         | br_bass_figure ']' {
1989                 $$ = $1;
1990                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1991         }
1992         ;
1993
1994 figure_list:
1995         /**/            {
1996                 $$ = SCM_EOL;
1997         }
1998         | figure_list br_bass_figure {
1999                 $$ = scm_cons ($2, $1);
2000         }
2001         ;
2002
2003 figure_spec:
2004         FIGURE_OPEN figure_list FIGURE_CLOSE {
2005                 Music * m = MY_MAKE_MUSIC("EventChord");
2006                 $2 = scm_reverse_x ($2, SCM_EOL);
2007                 m->set_mus_property ("elements",  $2);
2008                 $$ = m->self_scm ();
2009         }
2010         ;
2011
2012
2013 optional_rest:
2014         /**/   { $$ = 0; }
2015         | REST { $$ = 1; }
2016         ;
2017
2018 simple_element:
2019         pitch exclamations questions optional_notemode_duration optional_rest {
2020
2021                 Input i = THIS->pop_spot ();
2022                 if (!THIS->lexer_->note_state_b ())
2023                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2024
2025                 Music *n = 0;
2026                 if ($5)
2027                         n =  MY_MAKE_MUSIC("RestEvent");
2028                 else
2029                         n =  MY_MAKE_MUSIC("NoteEvent");
2030
2031                 n->set_mus_property ("pitch", $1);
2032                 n->set_mus_property ("duration", $4);
2033
2034
2035                 if ($3 % 2)
2036                         n->set_mus_property ("cautionary", SCM_BOOL_T);
2037                 if ($2 % 2 || $3 % 2)
2038                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
2039
2040                 Music *v = MY_MAKE_MUSIC("EventChord");
2041                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
2042                 scm_gc_unprotect_object (n->self_scm());
2043
2044                 v->set_spot (i);
2045                 n->set_spot (i);
2046                 $$ = v;
2047         }
2048         | figure_spec optional_notemode_duration {
2049                 Music * m = unsmob_music ($1);
2050                 Input i = THIS->pop_spot ();
2051                 m->set_spot (i);
2052                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2053                 {
2054                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
2055                 }
2056                 $$ = m;
2057         }
2058         | RESTNAME optional_notemode_duration           {
2059
2060                 Input i = THIS->pop_spot ();
2061                 Music * ev = 0;
2062                 if (ly_scm2string ($1) =="s") {
2063                         /* Space */
2064                         ev = MY_MAKE_MUSIC("SkipEvent");
2065                   }
2066                 else {
2067                         ev = MY_MAKE_MUSIC("RestEvent");
2068
2069                     }
2070                 ev->set_mus_property ("duration" ,$2);
2071                 ev->set_spot (i);
2072                 Music * velt = MY_MAKE_MUSIC("EventChord");
2073                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2074                 velt->set_spot (i);
2075
2076                 $$ = velt;
2077         }
2078         | MULTI_MEASURE_REST optional_notemode_duration         {
2079                 THIS->pop_spot ();
2080
2081                 static SCM proc ;
2082                 if (!proc)
2083                         proc = scm_c_eval_string ("make-multi-measure-rest");
2084
2085                 SCM mus = scm_call_2 (proc, $2,
2086                         make_input (THIS->here_input()));
2087                 scm_gc_protect_object (mus);
2088                 $$ = unsmob_music (mus);
2089         }
2090
2091         | lyric_element optional_notemode_duration      {
2092                 Input i = THIS->pop_spot ();
2093                 if (!THIS->lexer_->lyric_state_b ())
2094                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2095
2096                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2097                 lreq->set_mus_property ("text", $1);
2098                 lreq->set_mus_property ("duration",$2);
2099                 lreq->set_spot (i);
2100                 Music * velt = MY_MAKE_MUSIC("EventChord");
2101                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2102
2103                 $$= velt;
2104         }
2105         | new_chord {
2106                 THIS->pop_spot ();
2107
2108                 if (!THIS->lexer_->chord_state_b ())
2109                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2110                 $$ = unsmob_music ($1);
2111         }
2112         ;
2113
2114 lyric_element:
2115         full_markup { $$ = $1; }
2116         | STRING {  $$ = $1 ; }
2117         ;
2118
2119 new_chord:
2120         steno_tonic_pitch optional_notemode_duration   {
2121                 $$ = make_chord ($1, $2, SCM_EOL);
2122         }
2123         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2124                 SCM its = scm_reverse_x ($4, SCM_EOL);
2125                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2126         }
2127         ;
2128
2129 chord_items:
2130         /**/ {
2131                 $$ = SCM_EOL;
2132         }
2133         | chord_items chord_item {
2134                 $$ = gh_cons ($2, $$);
2135         }
2136         ;
2137
2138 chord_separator:
2139         CHORD_COLON {
2140                 $$ = ly_symbol2scm ("chord-colon");
2141         }
2142         | CHORD_CARET {
2143                 $$ = ly_symbol2scm ("chord-caret");
2144         }
2145         | CHORD_SLASH steno_tonic_pitch {
2146                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2147         }
2148         | CHORD_BASS steno_tonic_pitch {
2149                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2150         }
2151         ;
2152
2153 chord_item:
2154         chord_separator {
2155                 $$ = $1;
2156         }
2157         | step_numbers {
2158                 $$ = scm_reverse_x ($1, SCM_EOL);
2159         }
2160         | CHORD_MODIFIER  {
2161                 $$ = $1;
2162         }
2163         ;
2164
2165 step_numbers:
2166         step_number { $$ = gh_cons ($1, SCM_EOL); }
2167         | step_numbers '.' step_number {
2168                 $$ = gh_cons ($3, $$);
2169         }
2170         ;
2171
2172 step_number:
2173         bare_unsigned {
2174                 $$ = make_chord_step ($1, 0);
2175         }
2176         | bare_unsigned '+' {
2177                 $$ = make_chord_step ($1, SHARP);
2178         }
2179         | bare_unsigned CHORD_MINUS {
2180                 $$ = make_chord_step ($1, FLAT);
2181         }
2182         ;
2183
2184 /*
2185         UTILITIES
2186
2187 TODO: should deprecate in favor of Scheme?
2188
2189  */
2190 number_expression:
2191         number_expression '+' number_term {
2192                 $$ = scm_sum ($1, $3);
2193         }
2194         | number_expression '-' number_term {
2195                 $$ = scm_difference ($1, $3);
2196         }
2197         | number_term
2198         ;
2199
2200 number_term:
2201         number_factor {
2202                 $$ = $1;
2203         }
2204         | number_factor '*' number_factor {
2205                 $$ = scm_product ($1, $3);
2206         }
2207         | number_factor '/' number_factor {
2208                 $$ = scm_divide ($1, $3);
2209         }
2210         ;
2211
2212 number_factor:
2213         '-'  number_factor { /* %prec UNARY_MINUS */
2214                 $$ = scm_difference ($2, SCM_UNDEFINED);
2215         }
2216         | bare_number
2217         ;
2218
2219
2220 bare_number:
2221         UNSIGNED        {
2222                 $$ = gh_int2scm ($1);
2223         }
2224         | REAL          {
2225                 $$ = $1;
2226         }
2227         | NUMBER_IDENTIFIER             {
2228                 $$ = $1;
2229         }
2230         | REAL NUMBER_IDENTIFIER        {
2231                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2232         }
2233         | UNSIGNED NUMBER_IDENTIFIER    {
2234                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2235         }
2236         ;
2237
2238
2239 bare_unsigned:
2240         UNSIGNED {
2241                         $$ = $1;
2242         }
2243         | DIGIT {
2244                 $$ = $1;
2245         }
2246         ;
2247
2248 bare_int:
2249         bare_number {
2250                 if (scm_integer_p ($1) == SCM_BOOL_T)
2251                 {
2252                         int k = gh_scm2int ($1);
2253                         $$ = k;
2254                 } else
2255                 {
2256                         THIS->parser_error (_ ("need integer number arg"));
2257                         $$ = 0;
2258                 }
2259         }
2260         | '-' bare_int {
2261                 $$ = -$2;
2262         }
2263         ;
2264
2265
2266 string:
2267         STRING          {
2268                 $$ = $1;
2269         }
2270         | STRING_IDENTIFIER     {
2271                 $$ = $1;
2272         }
2273         | string '+' string {
2274                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2275         }
2276         ;
2277
2278
2279 exclamations:
2280                 { $$ = 0; }
2281         | exclamations '!'      { $$ ++; }
2282         ;
2283
2284 questions:
2285                 { $$ = 0; }
2286         | questions '?' { $$ ++; }
2287         ;
2288
2289
2290
2291 full_markup:
2292         MARKUP_IDENTIFIER {
2293                 $$ = $1;
2294         }
2295         | MARKUP
2296                 { THIS->lexer_->push_markup_state (); }
2297         markup
2298                 { $$ = $3;
2299                   THIS->lexer_->pop_state ();
2300                 }
2301         ;
2302
2303
2304 /*
2305 This should be done more dynamically if possible.
2306 */
2307 markup:
2308         STRING {
2309                 $$ = make_simple_markup ($1);
2310         }
2311         | MARKUP_HEAD_MARKUP0 markup {
2312                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2313         }
2314         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2315                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2316         }
2317         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2318                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2319         }
2320         | markup_line {
2321                 $$ = $1;
2322         }
2323         | MARKUP_HEAD_LIST0 markup_list {
2324                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2325         }
2326         | MARKUP_HEAD_SCM0 embedded_scm {
2327                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2328         }
2329         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2330                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2331         }
2332         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2333                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2334         }
2335         | MARKUP_IDENTIFIER {
2336                 $$ = $1;
2337         }
2338
2339         ;
2340
2341 markup_list:
2342         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2343         ;
2344
2345 markup_line:
2346         '{' markup_list_body '}' {
2347                 static SCM line ;
2348                 if (!line)
2349                         line = scm_c_eval_string ("line-markup");
2350
2351                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2352         }
2353         ;
2354
2355 markup_list_body:
2356         /**/ {  $$ = SCM_EOL; }
2357         | markup_list_body markup {
2358                 $$ = gh_cons ($2, $1) ;
2359         }
2360         ;
2361
2362
2363 %%
2364
2365 void
2366 My_lily_parser::set_yydebug (bool )
2367 {
2368 #if 0
2369         yydebug = 1;
2370 #endif
2371 }
2372
2373 extern My_lily_parser * current_parser;
2374
2375 void
2376 My_lily_parser::do_yyparse ()
2377 {
2378         current_parser = this;;
2379         yyparse ((void*)this);
2380 }
2381
2382
2383 /*
2384 Should make this optional?    It will also complain when you do
2385
2386         [s4]
2387
2388 which is entirely legitimate.
2389
2390 Or we can scrap it. Barchecks should detect wrong durations, and
2391 skipTypesetting speeds it up a lot.
2392 */
2393
2394 void
2395 My_lily_parser::beam_check (SCM dur)
2396 {
2397   Duration *d = unsmob_duration (dur);
2398   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2399     {
2400       Music * m = unsmob_music (last_beam_start_);
2401       m->origin ()->warning (_("Suspect duration found following this beam"));
2402     }
2403   last_beam_start_ = SCM_EOL;
2404 }
2405
2406
2407
2408
2409 /*
2410
2411 It is a little strange to have this function in this file, but
2412 otherwise, we have to import music classes into the lexer.
2413
2414 */
2415 int
2416 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2417 {
2418         if (gh_string_p (sid)) {
2419                 *destination = sid;
2420                 return STRING_IDENTIFIER;
2421         } else if (gh_number_p (sid)) {
2422                 *destination = sid;
2423                 return NUMBER_IDENTIFIER;
2424         } else if (unsmob_translator_def (sid)) {
2425                 *destination = unsmob_translator_def (sid)->clone_scm();
2426                 return TRANSLATOR_IDENTIFIER;
2427         } else if (unsmob_score (sid)) {
2428                 Score *sc =  new Score (*unsmob_score (sid));
2429                 *destination =sc->self_scm ();
2430                 return SCORE_IDENTIFIER;
2431         } else if (Music * mus =unsmob_music (sid)) {
2432                 *destination = unsmob_music (sid)->clone ()->self_scm();
2433                 unsmob_music (*destination)->
2434                         set_mus_property ("origin", make_input (last_input_));
2435                 return dynamic_cast<Event*> (mus)
2436                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2437         } else if (unsmob_duration (sid)) {
2438                 *destination = unsmob_duration (sid)->smobbed_copy();
2439                 return DURATION_IDENTIFIER;
2440         } else if (unsmob_music_output_def (sid)) {
2441                 Music_output_def *p = unsmob_music_output_def (sid);
2442                 p = p->clone ();
2443
2444                 *destination = p->self_scm();
2445                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2446         } else if (Text_item::markup_p (sid)) {
2447                 *destination = sid;
2448                 return MARKUP_IDENTIFIER;
2449         }
2450
2451         return -1;
2452 }