lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Two shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 2.  \repeat
  23         \repeat .. \alternative
  24
  25
  26     \repeat { \repeat .. \alternative }
  27
  28 or
  29
  30     \repeat { \repeat } \alternative
  31
  32 )
  33
  34 --hwn
  35
  36  */
  37
  38 /*
  39
  40 TODO:
  41
  42 * The rules for who is protecting what are very shady. Uniformise
  43   this.
  44
  45 * There are too many lexical modes?
  46
  47 */
  48
  49 #include <ctype.h>
  50 #include <stdlib.h>
  51
  52
  53
  54 #include "translator-def.hh"
  55 #include "lily-guile.hh"
  56 #include "misc.hh"
  57 #include "my-lily-lexer.hh"
  58 #include "paper-def.hh"
  59 #include "midi-def.hh"
  60 #include "main.hh"
  61 #include "file-path.hh"
  62 #include "warn.hh"
  63 #include "dimensions.hh"
  64 #include "my-lily-parser.hh"
  65 #include "score.hh"
  66 #include "input-file-results.hh"
  67 #include "input.hh"
  68 #include "lilypond-input-version.hh"
  69 #include "scm-hash.hh"
  70 #include "auto-change-iterator.hh"
  71 #include "ly-modules.hh"
  72 #include "music-sequence.hh"
  73 #include "input-smob.hh"
  74 #include "event.hh"
  75 #include "text-item.hh"
  76 #include "music-list.hh"
  77
  78
  79 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  80
  81
  82
  83 #define YYERROR_VERBOSE 1
  84
  85 My_lily_parser* my_lily_parser;
  86 #define YYPARSE_PARAM my_lily_parser
  87 #define YYLEX_PARAM my_lily_parser
  88 #define THIS\
  89         ((My_lily_parser *) my_lily_parser)
  90
  91 #define yyerror THIS->parser_error
  92
  93
  94
  95
  96
  97 bool
  98 regular_identifier_b (SCM id)
  99 {
 100   String str = ly_scm2string (id);
 101   char const *s = str.to_str0 () ;
 102
 103   bool v = true;
 104   while (*s && v)
 105    {
 106         v = v && isalpha (*s);
 107         s++;
 108    }
 109   return v;
 110 }
 111
 112 SCM
 113 make_simple_markup (SCM a)
 114 {
 115         static SCM simple;
 116         if (!simple)
 117         simple = scm_c_eval_string ("simple-markup");
 118
 119         return scm_list_n (simple, a, SCM_UNDEFINED);
 120 }
 121
 122
 123 bool
 124 is_duration_b (int t)
 125 {
 126   return t && t == 1 << intlog2 (t);
 127 }
 128
 129 void
 130 set_music_properties (Music *p, SCM a)
 131 {
 132   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 133         {
 134         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 135         }
 136 }
 137
 138 SCM
 139 make_chord_step (int step, int alter)
 140 {
 141         if (step == 7)
 142                 alter--;
 143
 144         /* ugh: fucks up above 13 */
 145         Pitch m(step > 7 ? 1 : 0,(step - 1) % 7, alter);
 146         return m.smobbed_copy ();
 147 }
 148
 149
 150 SCM
 151 make_chord (SCM pitch, SCM dur, SCM modification_list)
 152 {
 153         static SCM chord_ctor;
 154         if (!chord_ctor)
 155                 chord_ctor= scm_c_eval_string ("construct-chord");
 156         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 157         scm_gc_protect_object (ch);
 158         return ch;
 159 }
 160
 161 /*
 162   Todo: actually also use apply iso. call too ...
 163 */
 164 bool
 165 ly_input_procedure_p (SCM x)
 166 {
 167         return gh_procedure_p (x)
 168                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 169 }
 170
 171 Music*
 172 set_property_music (SCM sym, SCM value)
 173 {
 174         Music * p = MY_MAKE_MUSIC("PropertySet");
 175         p->set_mus_property ("symbol", sym);
 176         p->set_mus_property ("value", value);
 177         return p;
 178 }
 179
 180 %}
 181
 182 /* We use SCMs to do strings, because it saves us the trouble of
 183 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 184 of the parse stack onto the heap. */
 185
 186
 187 %union {
 188         String * string;
 189     Music *music;
 190     Score *score;
 191     Music_output_def * outputdef;
 192     SCM scm;
 193     int i;
 194 }
 195 %{
 196
 197 int
 198 yylex (YYSTYPE *s,  void * v)
 199 {
 200         My_lily_parser   *pars = (My_lily_parser*) v;
 201         My_lily_lexer * lex = pars->lexer_;
 202
 203         lex->lexval = (void*) s;
 204         lex->prepare_for_next_token();
 205         return lex->yylex ();
 206 }
 207
 208
 209 %}
 210
 211 %pure_parser
 212
 213 /* tokens which are not keywords */
 214 %token AUTOCHANGE
 215 %token ALIAS
 216 %token APPLYCONTEXT
 217 %token APPLYOUTPUT
 218 %token APPLY
 219 %token ACCEPTS
 220 %token ALTERNATIVE
 221 %token BAR
 222 %token BREATHE
 223 %token CHORDMODIFIERS
 224 %token CHORDS
 225 %token CLEF
 226 %token CONSISTS
 227 %token DURATION
 228 %token SEQUENTIAL
 229 %token GROBDESCRIPTIONS
 230 %token SIMULTANEOUS
 231 %token CONSISTSEND
 232 %token DENIES
 233 %token DESCRIPTION
 234 %token EXTENDER
 235 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 236 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 237 %token GRACE
 238 %token HEADER
 239 %token HYPHEN
 240 %token INVALID
 241 %token KEY
 242 %token LYRICS
 243 %token MARK
 244 %token MULTI_MEASURE_REST
 245 %token MIDI
 246 %token PITCH
 247 %token DEFAULT
 248 %token NAME
 249 %token PITCHNAMES
 250 %token NOTES
 251 %token ONCE
 252 %token PAPER
 253 %token PARTIAL
 254 %token PROPERTY
 255 %token OVERRIDE SET REVERT
 256 %token RELATIVE
 257 %token REMOVE
 258 %token REPEAT
 259 %token ADDLYRICS
 260 %token PARTCOMBINE
 261 %token SCM_T
 262 %token SCORE
 263 %token SKIP
 264 %token SPANREQUEST
 265 %token COMMANDSPANREQUEST
 266 %token TEMPO
 267 %token OUTPUTPROPERTY
 268 %token TIME_T
 269 %token TIMES
 270 %token TRANSLATOR
 271 %token TRANSPOSE
 272 %token TYPE
 273 %token UNSET
 274 %token CONTEXT
 275 %token REST
 276
 277 %token CHORD_OPEN
 278 %token CHORD_CLOSE
 279
 280
 281 /* escaped */
 282 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 283 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 284 %token E_BACKSLASH
 285 %token <i> E_UNSIGNED
 286 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 287 %token FIGURE_SPACE
 288
 289 %type <i>       exclamations questions dots optional_rest
 290 %type <i>        bass_mod
 291 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 292 %token <i>      DIGIT
 293 %token <scm>    NOTENAME_PITCH
 294 %token <scm>    TONICNAME_PITCH
 295 %token <scm>    CHORDMODIFIER_PITCH
 296 %token <scm>    DURATION_IDENTIFIER
 297 %token <scm>    FRACTION
 298 %token <id>     IDENTIFIER
 299 %token <scm>    CHORDNAMES
 300
 301 %token <scm> CHORD_MODIFIER
 302
 303 %token <scm>    SCORE_IDENTIFIER
 304 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 305 %token <scm>    NUMBER_IDENTIFIER
 306 %token <scm>    EVENT_IDENTIFIER
 307 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 308 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 309 %token <scm>    RESTNAME
 310 %token <scm>    STRING
 311 %token <scm>    SCM_T
 312 %token <i>      UNSIGNED
 313 %token <scm>   REAL
 314
 315 %token MARKUP
 316 %token <scm> MARKUP_HEAD_MARKUP0
 317 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 318 %token <scm> MARKUP_HEAD_SCM0
 319 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 320 %token <scm> MARKUP_HEAD_SCM0_SCM1
 321 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 322 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 323
 324 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 325 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 326
 327 %type <outputdef> output_def
 328 %type <scm>     lilypond_header lilypond_header_body
 329 %type <music>   open_event_parens close_event_parens open_event close_event
 330 %type <music> event_with_dir event_that_take_dir verbose_event
 331 %type <i>       sub_quotes sup_quotes
 332 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 333 %type <music>   Repeated_music
 334 %type <scm>     Alternative_music
 335 %type <i>       tremolo_type
 336 %type <i>       bare_int  bare_unsigned
 337 %type <i>       script_dir
 338 %type <scm>     identifier_init
 339
 340 %type <music> note_chord_element chord_body chord_body_element
 341 %type <scm>  chord_body_elements
 342 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 343 %type <scm>  verbose_duration
 344
 345 %type <scm>  pre_events post_events
 346 %type <music> gen_text_def
 347 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 348 %type <scm>   explicit_pitch steno_tonic_pitch
 349
 350 /* %type <scm>  chord_additions chord_subtractions chord_notes chord_step */
 351 /* %type <music>        chord */
 352 /* %type <scm>  chord_note chord_inversion chord_bass */
 353 %type <scm>     duration_length fraction
 354
 355 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 356
 357 %type <scm>  embedded_scm scalar
 358 %type <music>   Music Sequential_music Simultaneous_music
 359 %type <music>   relative_music re_rhythmed_music part_combined_music
 360 %type <music>   property_def translator_change  simple_property_def
 361 %type <scm> Music_list
 362 %type <outputdef>  music_output_def_body
 363 %type <music> shorthand_command_req
 364 %type <music>   post_event
 365 %type <music> command_req verbose_command_req
 366 %type <music>   extender_req
 367 %type <music> hyphen_req
 368 %type <music> string_event
 369 %type <scm>     string bare_number number_expression number_term number_factor
 370 %type <score>   score_block score_body
 371
 372 %type <scm>     translator_spec_block translator_spec_body
 373 %type <music>   tempo_event
 374 %type <scm> notenames_body notenames_block chordmodifiers_block
 375 %type <scm>     script_abbreviation
 376
 377
 378
 379 %left '-' '+'
 380
 381 /* We don't assign precedence to / and *, because we might need varied
 382 prec levels in different prods */
 383
 384 %left UNARY_MINUS
 385
 386 %%
 387
 388 lilypond:       /* empty */
 389         | lilypond toplevel_expression {}
 390         | lilypond assignment  { }
 391         | lilypond error {
 392                 THIS->error_level_  = 1;
 393         }
 394         | lilypond INVALID      {
 395                 THIS->error_level_  = 1;
 396         }
 397         ;
 398
 399 toplevel_expression:
 400         notenames_block                 {
 401                 THIS->lexer_->pitchname_tab_ =  $1;
 402         }
 403         | chordmodifiers_block                  {
 404                 THIS->lexer_->chordmodifier_tab_  = $1;
 405         }
 406         | lilypond_header {
 407                 THIS->input_file_->header_ = $1;
 408         }
 409         | score_block {
 410                 THIS->input_file_->scores_.push ($1);
 411         }
 412         | output_def {
 413                 if (dynamic_cast<Paper_def*> ($1))
 414                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 415                 else if (dynamic_cast<Midi_def*> ($1))
 416                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 417         }
 418         ;
 419
 420 embedded_scm:
 421         SCM_T
 422         | SCM_IDENTIFIER
 423         ;
 424
 425
 426 chordmodifiers_block:
 427         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 428         ;
 429
 430 notenames_block:
 431         PITCHNAMES notenames_body   {  $$ = $2; }
 432         ;
 433
 434 notenames_body:
 435         embedded_scm    {
 436           int i = scm_ilength ($1);
 437
 438           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 439           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 440                 SCM pt = ly_cdar (s);
 441                 scm_hashq_set_x (tab, ly_caar (s), pt);
 442           }
 443           $$ = tab;
 444         }
 445         ;
 446
 447 lilypond_header_body:
 448         {
 449                 $$ = ly_make_anonymous_module ();
 450                 THIS->lexer_->add_scope ($$);
 451         }
 452         | lilypond_header_body assignment  {
 453
 454         }
 455         ;
 456
 457 lilypond_header:
 458         HEADER '{' lilypond_header_body '}'     {
 459                 $$ = THIS->lexer_-> remove_scope();
 460         }
 461         ;
 462
 463
 464 /*
 465         DECLARATIONS
 466 */
 467 assignment:
 468         STRING {
 469                 THIS->push_spot ();
 470         }
 471         /* cont */ '=' identifier_init  {
 472
 473         /*
 474                 Should find generic way of associating input with objects.
 475         */
 476                 Input ip = THIS->pop_spot ();
 477
 478                 if (! regular_identifier_b ($1))
 479                 {
 480                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 481                 }
 482
 483                 THIS->lexer_->set_identifier ($1, $4);
 484
 485 /*
 486  TODO: devise standard for protection in parser.
 487
 488   The parser stack lives on the C-stack, which means that
 489 all objects can be unprotected as soon as they're here.
 490
 491 */
 492         }
 493         | embedded_scm { }
 494         ;
 495
 496
 497
 498 identifier_init:
 499         score_block {
 500                 $$ = $1->self_scm ();
 501                 scm_gc_unprotect_object ($$);
 502         }
 503         | full_markup {
 504                 $$ = $1;
 505         }
 506         | output_def {
 507                 $$ = $1->self_scm ();
 508                 scm_gc_unprotect_object ($$);
 509         }
 510         | translator_spec_block {
 511                 $$ = $1;
 512         }
 513         | Music  {
 514                 $$ = $1->self_scm ();
 515                 scm_gc_unprotect_object ($$);
 516         }
 517         | post_event {
 518                 $$ = $1->self_scm ();
 519                 scm_gc_unprotect_object ($$);
 520         }
 521         | verbose_duration {
 522                 $$ = $1;
 523         }
 524         | number_expression {
 525                 $$ = $1;
 526         }
 527         | string {
 528                 $$ = $1;
 529         }
 530         | embedded_scm  {
 531                 $$ = $1;
 532         }
 533         ;
 534
 535 translator_spec_block:
 536         TRANSLATOR '{' translator_spec_body '}'
 537                 {
 538                 $$ = $3;
 539         }
 540         ;
 541
 542 translator_spec_body:
 543         TRANSLATOR_IDENTIFIER   {
 544                 $$ = $1;
 545                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 546         }
 547         | TYPE STRING   {
 548                 $$ = Translator_def::make_scm ();
 549                 Translator_def*td =  unsmob_translator_def ($$);
 550                 td->translator_group_type_ = $2;
 551                 td->set_spot (THIS->here_input ());
 552         }
 553         | translator_spec_body DESCRIPTION string  {
 554                 unsmob_translator_def ($$)->description_ = $3;
 555         }
 556         | translator_spec_body STRING '=' embedded_scm                  {
 557                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 558         }
 559         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 560                 unsmob_translator_def ($$)
 561                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 562         }
 563         | translator_spec_body STRING SET embedded_scm '=' embedded_scm {
 564                 unsmob_translator_def ($$)
 565                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 566         }
 567         | translator_spec_body STRING REVERT embedded_scm  {
 568           unsmob_translator_def ($$)->add_pop_property (
 569                 scm_string_to_symbol ($2), $4);
 570         }
 571         | translator_spec_body NAME STRING  {
 572                 unsmob_translator_def ($$)->type_name_ = $3;
 573         }
 574         | translator_spec_body CONSISTS STRING  {
 575                 unsmob_translator_def ($$)->add_element ($3);
 576         }
 577         | translator_spec_body ALIAS STRING  {
 578                 Translator_def*td = unsmob_translator_def ($$);
 579                 td->type_aliases_ = scm_cons ($3, td->type_aliases_);
 580         }
 581         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 582                 Translator_def*td = unsmob_translator_def($$);
 583                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 584                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 585                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 586         }
 587         | translator_spec_body CONSISTSEND STRING  {
 588                 unsmob_translator_def ($$)->add_last_element ( $3);
 589         }
 590         | translator_spec_body ACCEPTS STRING  {
 591                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 592         }
 593         | translator_spec_body DENIES STRING  {
 594                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 595         }
 596         | translator_spec_body REMOVE STRING  {
 597                 unsmob_translator_def ($$)->remove_element ($3);
 598         }
 599         ;
 600
 601 /*
 602         SCORE
 603 */
 604 score_block:
 605         SCORE {
 606                 THIS->push_spot ();
 607         }
 608         /*cont*/ '{' score_body '}'     {
 609                 THIS->pop_spot ();
 610                 $$ = $4;
 611                 if (!$$->defs_.size ())
 612                 {
 613                   Music_output_def *id =
 614                         unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 615                   $$->add_output (id ? id->clone () :  new Paper_def );
 616                 }
 617         }
 618         ;
 619
 620 score_body:
 621         Music   {
 622                 $$ = new Score;
 623
 624                 $$->set_spot (THIS->here_input ());
 625                 SCM m = $1->self_scm ();
 626                 scm_gc_unprotect_object (m);
 627
 628                 /*
 629                         guh.
 630                 */
 631                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 632                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 633                         m = gh_call1 (gh_car (check_funcs), m);
 634                 $$->music_ = m;
 635
 636         }
 637         | SCORE_IDENTIFIER {
 638                 $$ = unsmob_score ($1);
 639                 $$->set_spot (THIS->here_input ());
 640         }
 641         | score_body lilypond_header    {
 642                 $$->header_ = $2;
 643         }
 644         | score_body output_def {
 645                 $$->add_output ($2);
 646         }
 647         | score_body error {
 648
 649         }
 650         ;
 651
 652
 653 /*
 654         MIDI
 655 */
 656 output_def:
 657         music_output_def_body '}' {
 658                 $$ = $1;
 659                 THIS-> lexer_-> remove_scope ();
 660         }
 661         ;
 662
 663 music_output_def_body:
 664         MIDI '{'    {
 665                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 666
 667
 668                 Midi_def* p =0;
 669                 if (id)
 670                         p = dynamic_cast<Midi_def*> (id->clone ());
 671                 else
 672                         p = new Midi_def;
 673
 674                 $$ = p;
 675                 THIS->lexer_->add_scope (p->scope_);
 676         }
 677         | PAPER '{'     {
 678                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 679                   Paper_def *p = 0;
 680                 if (id)
 681                         p = dynamic_cast<Paper_def*> (id->clone ());
 682                 else
 683                         p = new Paper_def;
 684
 685                 THIS->lexer_->add_scope (p->scope_);
 686                 $$ = p;
 687         }
 688         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 689                 Music_output_def * o =  unsmob_music_output_def ($3);
 690                 $$ =o;
 691
 692                 THIS->lexer_->add_scope (o->scope_);
 693         }
 694         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 695                 Music_output_def * o =  unsmob_music_output_def ($3);
 696                 $$ = o;
 697
 698                 THIS->lexer_->add_scope (o->scope_);
 699         }
 700         | music_output_def_body assignment  {
 701
 702         }
 703         | music_output_def_body translator_spec_block   {
 704                 $$->assign_translator ($2);
 705         }
 706         | music_output_def_body tempo_event  {
 707                 /*
 708                         junk this ? there already is tempo stuff in
 709                         music.
 710                 */
 711                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 712                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 713                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 714                 if (md)
 715                         md->set_tempo (d->get_length (), m);
 716         }
 717         | music_output_def_body error {
 718
 719         }
 720         ;
 721
 722 tempo_event:
 723         TEMPO steno_duration '=' bare_unsigned  {
 724                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 725                 $$->set_mus_property ("tempo-unit", $2);
 726                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 727         }
 728         ;
 729
 730 /*
 731 The representation of a  list is the
 732
 733   (LIST . LAST-CONS)
 734
 735  to have  efficient append.
 736 */
 737 Music_list:
 738         /* empty */ {
 739                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 740         }
 741         | Music_list Music {
 742                 SCM s = $$;
 743                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 744                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 745                 if (gh_pair_p (ly_cdr (s)))
 746                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 747                 else
 748                         gh_set_car_x (s, c); /* set first cons */
 749                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 750         }
 751         | Music_list error {
 752         }
 753         ;
 754
 755
 756 Music:
 757         Simple_music
 758         | Composite_music
 759         ;
 760
 761 Alternative_music:
 762         /* empty */ {
 763                 $$ = SCM_EOL;
 764         }
 765         | ALTERNATIVE '{' Music_list '}' {
 766                 $$ = $3;
 767         }
 768         ;
 769
 770 Repeated_music:
 771         REPEAT string bare_unsigned Music Alternative_music
 772         {
 773                 Music *beg = $4;
 774                 int times = $3;
 775                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 776                 if (times < scm_ilength (alts)) {
 777                   unsmob_music (gh_car (alts))
 778                     ->origin ()->warning (
 779                     _("More alternatives than repeats.  Junking excess alternatives."));
 780                   alts = ly_truncate_list (times, alts);
 781                 }
 782
 783
 784                 static SCM proc;
 785                 if (!proc)
 786                         proc = scm_c_eval_string ("make-repeated-music");
 787
 788                 SCM mus = scm_call_1 (proc, $2);
 789                 scm_gc_protect_object (mus); // UGH.
 790                 Music *r =unsmob_music (mus);
 791                 if (beg)
 792                         {
 793                         r-> set_mus_property ("element", beg->self_scm ());
 794                         scm_gc_unprotect_object (beg->self_scm ());
 795                         }
 796                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 797
 798                 r-> set_mus_property ("elements",alts);
 799                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 800                         /*
 801                         we can not get durations and other stuff correct down the line, so we have to
 802                         add to the duration log here.
 803                         */
 804                         static SCM func;
 805
 806                         if (!func)
 807                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 808
 809                         int dots = ($3 % 3) ? 0 : 1;
 810                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 811
 812                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 813
 814                         if (seq) {
 815                                 int list_len =scm_ilength (seq->music_list ());
 816                                 if (list_len != 2)
 817                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 818                                 shift -= 1;
 819                                 r->compress (Moment (Rational (1,list_len)));
 820                                 }
 821                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 822
 823                 }
 824                 r->set_spot (*$4->origin ());
 825
 826                 $$ = r;
 827         }
 828         ;
 829
 830 Sequential_music:
 831         SEQUENTIAL '{' Music_list '}'           {
 832                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 833                 $$->set_mus_property ("elements", ly_car ($3));
 834                 $$->set_spot(THIS->here_input());
 835         }
 836         | '{' Music_list '}'            {
 837                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 838                 $$->set_mus_property ("elements", ly_car ($2));
 839                 $$->set_spot(THIS->here_input());
 840         }
 841         ;
 842
 843 Simultaneous_music:
 844         SIMULTANEOUS '{' Music_list '}'{
 845                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 846                 $$->set_mus_property ("elements", ly_car ($3));
 847                 $$->set_spot(THIS->here_input());
 848
 849         }
 850         | '<' Music_list '>'    {
 851                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 852                 $$->set_mus_property ("elements", ly_car ($2));
 853                 $$->set_spot(THIS->here_input());
 854         }
 855         ;
 856
 857 Simple_music:
 858         event_chord             { $$ = $1; }
 859         | APPLYOUTPUT embedded_scm {
 860                 if (!ly_input_procedure_p ($2))
 861                         THIS->parser_error (_ ("\applycontext takes function argument"));
 862                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 863                 $$->set_mus_property ("procedure", $2);
 864                 $$->set_spot (THIS->here_input());
 865         }
 866         | APPLYCONTEXT embedded_scm {
 867                 if (!ly_input_procedure_p ($2))
 868                         THIS->parser_error (_ ("\applycontext takes function argument"));
 869                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 870                 $$->set_mus_property ("procedure", $2);
 871                 $$->set_spot (THIS->here_input());
 872         }
 873         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 874                 SCM pred = $2;
 875                 if (!gh_symbol_p ($3))
 876                 {
 877                         THIS->parser_error (_ ("Second argument must be a symbol"));
 878                 }
 879                 /* Should check # args */
 880                 if (!gh_procedure_p (pred))
 881                 {
 882                         THIS->parser_error (_ ("First argument must be a procedure taking one argument"));
 883                 }
 884
 885                 Music*m = MY_MAKE_MUSIC("OutputPropertySetMusic");
 886                 m->set_mus_property ("predicate", pred);
 887                 m->set_mus_property ("grob-property", $3);
 888                 m->set_mus_property ("grob-value",  $5);
 889
 890                 $$ = m;
 891         }
 892         | MUSIC_IDENTIFIER {
 893                 $$ = unsmob_music ($1);
 894         }
 895         | property_def
 896         | translator_change
 897         ;
 898
 899
 900 Composite_music:
 901         CONTEXT STRING Music    {
 902                 Music*csm =MY_MAKE_MUSIC("ContextSpeccedMusic");
 903
 904                 csm->set_mus_property ("element", $3->self_scm ());
 905                 scm_gc_unprotect_object ($3->self_scm ());
 906
 907                 csm->set_mus_property ("context-type",$2);
 908                 csm->set_mus_property ("context-id", scm_makfrom0str (""));
 909
 910                 $$ = csm;
 911         }
 912         | AUTOCHANGE STRING Music       {
 913         Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 914                 chm->set_mus_property ("element", $3->self_scm ());
 915                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 916
 917                 scm_gc_unprotect_object ($3->self_scm ());
 918                 chm->set_mus_property ("what", $2);
 919
 920                 $$ = chm;
 921                 chm->set_spot (*$3->origin ());
 922         }
 923         | GRACE Music {
 924 #if 1
 925         /*
 926                 The other version is for easier debugging  of
 927                 Sequential_music_iterator in combination with grace notes.
 928         */
 929
 930                 SCM start = THIS->lexer_->lookup_identifier ("startGraceMusic");
 931                 SCM stop = THIS->lexer_->lookup_identifier ("stopGraceMusic");
 932                 Music *startm = unsmob_music (start);
 933                 Music *stopm = unsmob_music (stop);
 934
 935                 SCM ms = SCM_EOL;
 936                 if (stopm) {
 937                         stopm = stopm->clone ();
 938                         ms = scm_cons (stopm->self_scm (), ms);
 939                         scm_gc_unprotect_object (stopm->self_scm ());
 940                 }
 941                 ms = scm_cons ($2->self_scm (), ms);
 942                 scm_gc_unprotect_object ($2->self_scm());
 943                 if (startm) {
 944                         startm = startm->clone ();
 945                         ms = scm_cons (startm->self_scm () , ms);
 946                         scm_gc_unprotect_object (startm->self_scm ());
 947                 }
 948
 949
 950                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 951                 seq->set_mus_property ("elements", ms);
 952
 953
 954                 $$ = MY_MAKE_MUSIC("GraceMusic");
 955                 $$->set_mus_property ("element", seq->self_scm ());
 956                 scm_gc_unprotect_object (seq->self_scm ());
 957 #else
 958                 $$ = MY_MAKE_MUSIC("GraceMusic");
 959                 $$->set_mus_property ("element", $2->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961 #endif
 962         }
 963         | CONTEXT string '=' string Music {
 964                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
 965
 966                 csm->set_mus_property ("element", $5->self_scm ());
 967                 scm_gc_unprotect_object ($5->self_scm ());
 968
 969                 csm->set_mus_property ("context-type", $2);
 970                 csm->set_mus_property ("context-id", $4);
 971
 972                 $$ = csm;
 973         }
 974         | TIMES {
 975                 THIS->push_spot ();
 976         }
 977         /* CONTINUED */
 978                 fraction Music
 979
 980         {
 981                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 982                 Music *mp = $4;
 983         $$= MY_MAKE_MUSIC("TimeScaledMusic");
 984                 $$->set_spot (THIS->pop_spot ());
 985
 986
 987                 $$->set_mus_property ("element", mp->self_scm ());
 988                 scm_gc_unprotect_object (mp->self_scm ());
 989                 $$->set_mus_property ("numerator", gh_int2scm (n));
 990                 $$->set_mus_property ("denominator", gh_int2scm (d));
 991                 $$->compress (Moment (Rational (n,d)));
 992
 993         }
 994         | Repeated_music                { $$ = $1; }
 995         | Simultaneous_music            { $$ = $1; }
 996         | Sequential_music              { $$ = $1; }
 997         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 998                 $$ = MY_MAKE_MUSIC("TransposedMusic");
 999                 Music *p = $4;
1000                 Pitch from = *unsmob_pitch ($2);
1001                 Pitch to = *unsmob_pitch ($3);
1002
1003                 p->transpose (interval (from, to));
1004                 $$->set_mus_property ("element", p->self_scm ());
1005                 scm_gc_unprotect_object (p->self_scm ());
1006         }
1007         | APPLY embedded_scm Music  {
1008                 if (!ly_input_procedure_p ($2))
1009                         THIS->parser_error (_ ("\apply takes function argument"));
1010
1011                 SCM ret = gh_call1 ($2, $3->self_scm ());
1012                 Music *m = unsmob_music (ret);
1013                 if (!m) {
1014                         THIS->parser_error ("\\apply must return a Music");
1015                         m = MY_MAKE_MUSIC("Music");
1016                         }
1017                 $$ = m;
1018         }
1019         | NOTES
1020                 { THIS->lexer_->push_note_state (); }
1021         Music
1022                 { $$ = $3;
1023                   THIS->lexer_->pop_state ();
1024                 }
1025         | FIGURES
1026                 { THIS->lexer_->push_figuredbass_state (); }
1027         Music
1028                 {
1029                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1030                   chm->set_mus_property ("element", $3->self_scm ());
1031                   $$ = chm;
1032                   scm_gc_unprotect_object ($3->self_scm());
1033
1034                   THIS->lexer_->pop_state ();
1035         }
1036         | CHORDS
1037                 { THIS->lexer_->push_chord_state (); }
1038         Music
1039                 {
1040                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1041                   chm->set_mus_property ("element", $3->self_scm ());
1042                   scm_gc_unprotect_object ($3->self_scm());
1043                   $$ = chm;
1044
1045                   THIS->lexer_->pop_state ();
1046         }
1047         | LYRICS
1048                 { THIS->lexer_->push_lyric_state (); }
1049         Music
1050                 {
1051                   $$ = $3;
1052                   THIS->lexer_->pop_state ();
1053         }
1054         | relative_music        { $$ = $1; }
1055         | re_rhythmed_music     { $$ = $1; }
1056         | part_combined_music   { $$ = $1; }
1057         ;
1058
1059 relative_music:
1060         RELATIVE absolute_pitch Music {
1061                 Music * p = $3;
1062                 Pitch pit = *unsmob_pitch ($2);
1063                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1064
1065                 $$->set_mus_property ("element", p->self_scm ());
1066                 scm_gc_unprotect_object (p->self_scm ());
1067
1068
1069                 $$->set_mus_property ("last-pitch", p->to_relative_octave (pit).smobbed_copy ());
1070
1071         }
1072         ;
1073
1074 re_rhythmed_music:
1075         ADDLYRICS Music Music {
1076         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1077           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1078           scm_gc_unprotect_object ($3->self_scm ());
1079           scm_gc_unprotect_object ($2->self_scm ());
1080           $$ = l;
1081         }
1082         ;
1083
1084 part_combined_music:
1085         PARTCOMBINE STRING Music Music {
1086         Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1087                 p->set_mus_property ("what", $2);
1088                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1089
1090                 scm_gc_unprotect_object ($3->self_scm ());
1091                 scm_gc_unprotect_object ($4->self_scm ());
1092
1093                 $$ = p;
1094         }
1095         ;
1096
1097 translator_change:
1098         TRANSLATOR STRING '=' STRING  {
1099                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1100                 t-> set_mus_property ("change-to-type", $2);
1101                 t-> set_mus_property ("change-to-id", $4);
1102
1103                 $$ = t;
1104                 $$->set_spot (THIS->here_input ());
1105         }
1106         ;
1107
1108 property_def:
1109         simple_property_def
1110         | ONCE simple_property_def {
1111                 $$ = $2;
1112                 SCM e = $2->get_mus_property ("element");
1113                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1114         }
1115         ;
1116
1117 simple_property_def:
1118         PROPERTY STRING '.' STRING '='  scalar {
1119                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1120                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1121
1122                 csm->set_mus_property ("element", t->self_scm ());
1123                 scm_gc_unprotect_object (t->self_scm ());
1124
1125                 $$ = csm;
1126                 $$->set_spot (THIS->here_input ());
1127
1128                 csm-> set_mus_property ("context-type", $2);
1129         }
1130         | PROPERTY STRING '.' STRING UNSET {
1131
1132                 Music *t = MY_MAKE_MUSIC("PropertyUnset");
1133                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1134
1135                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1136                 csm->set_mus_property ("element", t->self_scm ());
1137                 scm_gc_unprotect_object (t->self_scm ());
1138
1139                 $$ = csm;
1140                 $$->set_spot (THIS->here_input ());
1141
1142                 csm-> set_mus_property ("context-type", $2);
1143         }
1144         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1145                 bool autobeam
1146                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1147                 bool itc = internal_type_checking_global_b;
1148                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1149                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1150                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1151                 if (autobeam)
1152                         internal_type_checking_global_b = false;
1153                 t->set_mus_property ("grob-property", $6);
1154                 if (autobeam)
1155                         internal_type_checking_global_b = itc;
1156                 t->set_mus_property ("grob-value", $8);
1157
1158                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1159                 csm->set_mus_property ("element", t->self_scm ());
1160                 scm_gc_unprotect_object (t->self_scm ());
1161                 $$ = csm;
1162                 $$->set_spot (THIS->here_input ());
1163
1164                 csm-> set_mus_property ("context-type", $2);
1165         }
1166         | PROPERTY STRING '.' STRING OVERRIDE
1167                 embedded_scm '=' embedded_scm
1168         {
1169                 /*
1170                         UGH UGH UGH UGH.
1171                 */
1172                 bool autobeam
1173                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1174                 bool itc = internal_type_checking_global_b;
1175
1176                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1177                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1178                 if (autobeam)
1179                         internal_type_checking_global_b = false;
1180                 t->set_mus_property ("grob-property", $6);
1181                 t->set_mus_property ("grob-value", $8);
1182                 if (autobeam)
1183                         internal_type_checking_global_b = itc;
1184
1185                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1186                 csm->set_mus_property ("element", t->self_scm ());
1187                 scm_gc_unprotect_object (t->self_scm ());
1188
1189                 $$ = csm;
1190                 $$->set_spot (THIS->here_input ());
1191
1192                 csm-> set_mus_property ("context-type", $2);
1193
1194         }
1195         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1196                 Music *t = MY_MAKE_MUSIC("RevertProperty");
1197                 bool autobeam
1198                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1199                 bool itc = internal_type_checking_global_b;
1200
1201                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1202                 if (autobeam)
1203                         internal_type_checking_global_b = false;
1204                 t->set_mus_property ("grob-property", $6);
1205                 if (autobeam)
1206                         internal_type_checking_global_b = itc;
1207
1208                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1209                 csm->set_mus_property ("element", t->self_scm ());
1210                 scm_gc_unprotect_object (t->self_scm ());
1211
1212                 $$ = csm;
1213                 $$->set_spot (THIS->here_input ());
1214
1215                 csm-> set_mus_property ("context-type", $2);
1216         }
1217         ;
1218
1219
1220 scalar:
1221         string          { $$ = $1; }
1222         | bare_int      { $$ = gh_int2scm ($1); }
1223         | embedded_scm  { $$ = $1; }
1224         | full_markup {  $$ = $1; }
1225         | DIGIT { $$ = gh_int2scm ($1); }
1226         ;
1227
1228
1229 event_chord:
1230         pre_events {
1231                 THIS->push_spot ();
1232         } /*cont */ simple_element post_events  {
1233                 SCM elts = $3-> get_mus_property ("elements");
1234
1235                 elts = gh_append3 (elts, scm_reverse_x ($1, SCM_EOL),
1236                                    scm_reverse_x ($4, SCM_EOL));
1237
1238                 $3-> set_mus_property ("elements", elts);
1239                 $$ = $3;
1240         }
1241         | command_element
1242         | note_chord_element
1243         ;
1244
1245
1246 note_chord_element:
1247         chord_body optional_notemode_duration post_events
1248         {
1249                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1250                 SCM es = $1->get_mus_property ("elements");
1251                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1252
1253                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1254                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1255                 es = gh_append2 (es, postevs);
1256
1257                 $1-> set_mus_property ("elements", es);
1258                 $$ = $1;
1259         }
1260         ;
1261
1262 chord_body:
1263         CHORD_OPEN chord_body_elements CHORD_CLOSE
1264         {
1265                 $$ = MY_MAKE_MUSIC("EventChord");
1266                 $$->set_mus_property ("elements",
1267                         scm_reverse_x ($2, SCM_EOL));
1268         }
1269         ;
1270
1271 chord_body_elements:
1272         /* empty */             { $$ = SCM_EOL; }
1273         | chord_body_elements chord_body_element {
1274                 $$ = gh_cons ($2->self_scm(), $1);
1275                 scm_gc_unprotect_object ($2->self_scm());
1276         }
1277         ;
1278
1279 chord_body_element:
1280         pitch exclamations questions post_events
1281         {
1282                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1283                 n->set_mus_property ("pitch", $1);
1284                 if ($3 % 2)
1285                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1286                 if ($2 % 2 || $3 % 2)
1287                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1288
1289                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1290                 n->set_mus_property ("articulations", arts);
1291
1292                 $$ = n;
1293         }
1294         ;
1295
1296 command_element:
1297         command_req {
1298                 $$ = MY_MAKE_MUSIC("EventChord");
1299                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1300           scm_gc_unprotect_object ($1->self_scm());
1301
1302                 $$-> set_spot (THIS->here_input ());
1303                 $1-> set_spot (THIS->here_input ());
1304         }
1305         | E_LEFTSQUARE {
1306                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1307                 l->set_mus_property ("span-direction", gh_int2scm (START));
1308                 l->set_spot (THIS->here_input ());
1309
1310                 $$ = MY_MAKE_MUSIC("EventChord");
1311                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1312                 scm_gc_unprotect_object (l->self_scm());
1313                 $$->set_spot (THIS->here_input ());
1314         }
1315         | E_RIGHTSQUARE {
1316                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1317                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1318                 l->set_spot (THIS->here_input ());
1319
1320                 $$ = MY_MAKE_MUSIC("EventChord");
1321                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1322                 $$->set_spot (THIS->here_input ());
1323                 scm_gc_unprotect_object (l->self_scm());
1324         }
1325         | E_BACKSLASH {
1326                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1327                 $$->set_spot (THIS->here_input ());
1328         }
1329         | '|'      {
1330
1331                 $$ = MY_MAKE_MUSIC("BarCheck");
1332                 $$->set_spot (THIS->here_input ());
1333         }
1334         | BAR STRING                    {
1335                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1336
1337                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1338                 csm->set_mus_property ("element", t->self_scm ());
1339                 scm_gc_unprotect_object (t->self_scm ());
1340
1341                 $$ = csm;
1342                 $$->set_spot (THIS->here_input ());
1343
1344                 csm->set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1345         }
1346         | PARTIAL duration_length       {
1347                 Moment m = - unsmob_duration ($2)->get_length ();
1348                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1349
1350                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1351                 sp->set_mus_property ("element", p->self_scm ());
1352                 scm_gc_unprotect_object (p->self_scm ());
1353
1354                 $$ =sp ;
1355                 sp-> set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1356         }
1357         | CLEF STRING  {
1358                 static SCM proc ;
1359                 if (!proc)
1360                         proc = scm_c_eval_string ("make-clef-set");
1361
1362                 SCM result = scm_call_1 (proc, $2);
1363                 scm_gc_protect_object (result);
1364                 $$ = unsmob_music (result);
1365         }
1366         | TIME_T fraction  {
1367                 static SCM proc;
1368                 if (!proc)
1369                         proc = scm_c_eval_string ("make-time-signature-set");
1370
1371                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1372                 scm_gc_protect_object (result);
1373                 $$ = unsmob_music (result);
1374         }
1375         ;
1376
1377 command_req:
1378         shorthand_command_req   { $$ = $1; }
1379         | verbose_command_req   { $$ = $1; }
1380         ;
1381
1382 shorthand_command_req:
1383         extender_req {
1384                 $$ = $1;
1385         }
1386         | hyphen_req {
1387                 $$ = $1;
1388         }
1389         | '~'   {
1390                 $$ = MY_MAKE_MUSIC("TieEvent");
1391         }
1392         | '['           {
1393                 Music *b= MY_MAKE_MUSIC("BeamEvent");
1394                 b->set_mus_property ("span-direction", gh_int2scm (START));
1395                 $$ = b;
1396
1397                 THIS->last_beam_start_ = b->self_scm ();
1398         }
1399         | ']'           {
1400                 Music *b= MY_MAKE_MUSIC("BeamEvent");
1401                 b->set_mus_property ("span-direction", gh_int2scm (STOP));
1402                 $$ = b;
1403         }
1404         | BREATHE {
1405                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1406         }
1407         | E_TILDE {
1408                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1409         }
1410         ;
1411
1412 verbose_command_req:
1413         MARK DEFAULT  {
1414                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1415                 $$ = m;
1416         }
1417         | MARK scalar {
1418                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1419                 m->set_mus_property ("label", $2);
1420                 $$ = m;
1421         }
1422         | SKIP duration_length {
1423                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1424                 skip->set_mus_property ("duration", $2);
1425
1426                 $$ = skip;
1427         }
1428         | tempo_event {
1429                 $$ = $1;
1430         }
1431         | KEY DEFAULT {
1432                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1433                 $$ = key;
1434         }
1435         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1436                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1437
1438                 key->set_mus_property ("pitch-alist", $3);
1439                 key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1440                 ((Music*)key)->transpose (* unsmob_pitch ($2));
1441
1442                 $$ = key;
1443         }
1444         ;
1445
1446 post_events:
1447         /* empty */ {
1448                 $$ = SCM_EOL;
1449         }
1450         | post_events post_event {
1451                 $2->set_spot (THIS->here_input ());
1452                 $$ = gh_cons ($2->self_scm(), $$);
1453                 scm_gc_unprotect_object ($2->self_scm());
1454         }
1455         ;
1456
1457 post_event:
1458         verbose_event
1459         | event_with_dir
1460         | close_event
1461         | string_event
1462         ;
1463
1464 string_event:
1465         E_UNSIGNED {
1466                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1467                 s->set_mus_property ("string-number",  gh_int2scm($1));
1468                 s->set_spot (THIS->here_input ());
1469                 $$ = s;
1470         }
1471         ;
1472
1473
1474 event_that_take_dir:
1475         gen_text_def
1476         | verbose_event
1477         | close_event
1478         | open_event
1479         | '['  {
1480                 Music * m = MY_MAKE_MUSIC ("NewBeamEvent");
1481                 m->set_spot (THIS->here_input());
1482                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1483                 $$ = m;
1484         }
1485         | ']'  {
1486                 Music * m = MY_MAKE_MUSIC ("NewBeamEvent");
1487                 m->set_spot (THIS->here_input());
1488                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1489                 $$ = m;
1490         }
1491         | '~' {
1492                 Music * m = MY_MAKE_MUSIC ("NewTieEvent");
1493                 m->set_spot (THIS->here_input());
1494                 $$ = m;
1495         }
1496         | script_abbreviation {
1497                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1498                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1499                 if (gh_string_p (s))
1500                         a->set_mus_property ("articulation-type", s);
1501                 else THIS->parser_error (_ ("Expecting string as script definition"));
1502                 $$ = a;
1503         }
1504         ;
1505
1506 event_with_dir:
1507         script_dir event_that_take_dir  {
1508                 $2->set_mus_property ("direction", gh_int2scm ($1));
1509                 $$ = $2;
1510         }
1511         ;
1512
1513 verbose_event:
1514         EVENT_IDENTIFIER        {
1515                 $$ = unsmob_music ($1);
1516         }
1517         | tremolo_type  {
1518                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1519                a->set_spot (THIS->here_input ());
1520                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1521                $$ = a;
1522         }
1523         ;
1524
1525 sup_quotes:
1526         '\'' {
1527                 $$ = 1;
1528         }
1529         | sup_quotes '\'' {
1530                 $$ ++;
1531         }
1532         ;
1533
1534 sub_quotes:
1535         ',' {
1536                 $$ = 1;
1537         }
1538         | sub_quotes ',' {
1539                 $$ ++ ;
1540         }
1541         ;
1542
1543 steno_pitch:
1544         NOTENAME_PITCH  {
1545                 $$ = $1;
1546         }
1547         | NOTENAME_PITCH sup_quotes     {
1548                 Pitch p = *unsmob_pitch ($1);
1549                 p = p.transposed (Pitch ($2,0,0));
1550                 $$ = p.smobbed_copy ();
1551         }
1552         | NOTENAME_PITCH sub_quotes      {
1553                 Pitch p =* unsmob_pitch ($1);
1554                 p = p.transposed (Pitch (-$2,0,0));
1555                 $$ = p.smobbed_copy ();
1556         }
1557         ;
1558
1559 /*
1560 ugh. duplication
1561 */
1562
1563 steno_tonic_pitch:
1564         TONICNAME_PITCH {
1565                 $$ = $1;
1566         }
1567         | TONICNAME_PITCH sup_quotes    {
1568                 Pitch p = *unsmob_pitch ($1);
1569                 p = p.transposed (Pitch ($2,0,0));
1570                 $$ = p.smobbed_copy ();
1571         }
1572         | TONICNAME_PITCH sub_quotes     {
1573                 Pitch p =* unsmob_pitch ($1);
1574
1575                 p = p.transposed (Pitch (-$2,0,0));
1576                 $$ = p.smobbed_copy ();
1577         }
1578         ;
1579
1580 pitch:
1581         steno_pitch {
1582                 $$ = $1;
1583         }
1584         | explicit_pitch {
1585                 $$ = $1;
1586         }
1587         ;
1588
1589 pitch_also_in_chords:
1590         pitch
1591         | steno_tonic_pitch
1592         ;
1593
1594 explicit_pitch:
1595         PITCH embedded_scm {
1596                 $$ = $2;
1597                 if (!unsmob_pitch ($2)) {
1598                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1599                          $$ = Pitch ().smobbed_copy ();
1600                 }
1601         }
1602         ;
1603
1604 verbose_duration:
1605         DURATION embedded_scm   {
1606                 $$ = $2;
1607                 if (!unsmob_duration ($2))
1608                 {
1609                         THIS->parser_error (_ ("Must have duration object"));
1610                         $$ = Duration ().smobbed_copy ();
1611                 }
1612         }
1613         ;
1614
1615 extender_req:
1616         EXTENDER {
1617                 if (!THIS->lexer_->lyric_state_b ())
1618                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1619                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1620         }
1621         ;
1622
1623 hyphen_req:
1624         HYPHEN {
1625                 if (!THIS->lexer_->lyric_state_b ())
1626                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1627                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1628         }
1629         ;
1630
1631 close_event:
1632         close_event_parens {
1633                 $$ = $1;
1634                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (START))
1635 ;
1636         }
1637         ;
1638
1639 close_event_parens:
1640         '('     {
1641                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1642                 $$ = s;
1643                 s->set_spot (THIS->here_input());
1644         }
1645         | E_OPEN        {
1646                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1647                 $$ = s;
1648                 s->set_spot (THIS->here_input());
1649         }
1650         | E_SMALLER {
1651                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1652                 $$ = s;
1653                 s->set_spot (THIS->here_input());
1654         }
1655         | E_BIGGER {
1656                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1657                 $$ = s;
1658                 s->set_spot (THIS->here_input());
1659         }
1660         ;
1661
1662
1663 open_event:
1664         open_event_parens {
1665                 $$ = $1;
1666                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (STOP))
1667 ;
1668         }
1669         ;
1670
1671 open_event_parens:
1672         E_EXCLAMATION   {
1673                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1674                 s->set_spot (THIS->here_input());
1675
1676                 $$ = s;
1677         }
1678         | ')'   {
1679                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1680                 $$ = s;
1681                 s->set_spot (THIS->here_input());
1682
1683         }
1684         | E_CLOSE       {
1685                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1686                 $$ = s;
1687                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1688                 s->set_spot (THIS->here_input());
1689         }
1690         ;
1691
1692 gen_text_def:
1693         embedded_scm {
1694                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1695                 t->set_mus_property ("text", $1);
1696                 t->set_spot (THIS->here_input ());
1697                 $$ = t;
1698         }
1699         | full_markup {
1700                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1701                 t->set_mus_property ("text", $1);
1702                 t->set_spot (THIS->here_input ());
1703                 $$ = t;
1704         }
1705         | string {
1706                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1707                 t->set_mus_property ("text", make_simple_markup ($1));
1708                 t->set_spot (THIS->here_input ());
1709                 $$ = t;
1710
1711         }
1712         | DIGIT {
1713                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1714                 t->set_mus_property ("digit",  gh_int2scm ($1));
1715                 t->set_spot (THIS->here_input ());
1716                 $$ = t;
1717         }
1718         ;
1719
1720 script_abbreviation:
1721         '^'             {
1722                 $$ = scm_makfrom0str ("Hat");
1723         }
1724         | '+'           {
1725                 $$ = scm_makfrom0str ("Plus");
1726         }
1727         | '-'           {
1728                 $$ = scm_makfrom0str ("Dash");
1729         }
1730         | '|'           {
1731                 $$ = scm_makfrom0str ("Bar");
1732         }
1733         | '>'           {
1734                 $$ = scm_makfrom0str ("Larger");
1735         }
1736         | '.'           {
1737                 $$ = scm_makfrom0str ("Dot");
1738         }
1739         | '_' {
1740                 $$ = scm_makfrom0str ("Underscore");
1741         }
1742         ;
1743
1744 script_dir:
1745         '_'     { $$ = DOWN; }
1746         | '^'   { $$ = UP; }
1747         | '-'   { $$ = CENTER; }
1748         ;
1749
1750 pre_events:
1751         /* empty */ {
1752                 $$ = SCM_EOL;
1753         }
1754         | pre_events open_event {
1755                 $$ = gh_cons ($2->self_scm(), $$);
1756                 scm_gc_unprotect_object ($2->self_scm());
1757         }
1758         ;
1759
1760 absolute_pitch:
1761         steno_pitch     {
1762                 $$ = $1;
1763         }
1764         ;
1765
1766 duration_length:
1767         multiplied_duration {
1768                 $$ = $1;
1769         }
1770         | verbose_duration {
1771                 $$ = $1;
1772         }
1773         ;
1774
1775 optional_notemode_duration:
1776         {
1777                 Duration dd = THIS->default_duration_;
1778                 $$ = dd.smobbed_copy ();
1779
1780                 THIS->beam_check ($$);
1781         }
1782         | multiplied_duration   {
1783                 $$ = $1;
1784                 THIS->default_duration_ = *unsmob_duration ($$);
1785
1786                 THIS->beam_check ($$);
1787         }
1788         | verbose_duration {
1789                 $$ = $1;
1790                 THIS->default_duration_ = *unsmob_duration ($$);
1791         }
1792         ;
1793
1794 steno_duration:
1795         bare_unsigned dots              {
1796                 int l = 0;
1797                 if (!is_duration_b ($1))
1798                         THIS->parser_error (_f ("not a duration: %d", $1));
1799                 else
1800                         l =  intlog2 ($1);
1801
1802                 $$ = Duration (l, $2).smobbed_copy ();
1803         }
1804         | DURATION_IDENTIFIER dots      {
1805                 Duration *d =unsmob_duration ($1);
1806                 Duration k (d->duration_log (),d->dot_count () + $2);
1807
1808                 *d = k;
1809                 $$ = $1;
1810         }
1811         ;
1812
1813
1814
1815
1816 multiplied_duration:
1817         steno_duration {
1818                 $$ = $1;
1819         }
1820         | multiplied_duration '*' bare_unsigned {
1821                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1822         }
1823         | multiplied_duration '*' FRACTION {
1824                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1825
1826                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1827         }
1828         ;
1829
1830 fraction:
1831         FRACTION { $$ = $1; }
1832         | UNSIGNED '/' UNSIGNED {
1833                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1834         }
1835         ;
1836
1837 dots:
1838         /* empty */     {
1839                 $$ = 0;
1840         }
1841         | dots '.' {
1842                 $$ ++;
1843         }
1844         ;
1845
1846
1847 tremolo_type:
1848         ':'     {
1849                 $$ =0;
1850         }
1851         | ':' bare_unsigned {
1852                 if (!is_duration_b ($2))
1853                         THIS->parser_error (_f ("not a duration: %d", $2));
1854                 $$ = $2;
1855         }
1856         ;
1857
1858
1859
1860 /*****************************************************************
1861                 BASS FIGURES
1862 *****************************************************************/
1863 bass_number:
1864         DIGIT   {
1865                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1866         }
1867         | UNSIGNED {
1868                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1869         }
1870         | STRING { $$ =  $1 }
1871         ;
1872
1873 bass_mod:
1874         '-'     { $$ = -1; }
1875         | '+'   { $$ = 1; }
1876         | '!'   { $$ = 0; }
1877         ;
1878
1879 bass_figure:
1880         FIGURE_SPACE {
1881                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1882                 $$ = bfr->self_scm();
1883                 scm_gc_unprotect_object ($$);
1884         }
1885         | bass_number  {
1886                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1887                 $$ = bfr->self_scm();
1888
1889                 bfr->set_mus_property ("figure", $1);
1890
1891                 scm_gc_unprotect_object ($$);
1892         }
1893         | bass_figure bass_mod {
1894                 Music *m = unsmob_music ($1);
1895                 if ($2) {
1896                         SCM salter =m->get_mus_property ("alteration");
1897                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1898                         m->set_mus_property ("alteration",
1899                                 gh_int2scm (alter + $2));
1900                 } else {
1901                         m->set_mus_property ("alteration", gh_int2scm (0));
1902                 }
1903         }
1904         ;
1905
1906 br_bass_figure:
1907         '[' bass_figure {
1908                 $$ = $2;
1909                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1910         }
1911         | bass_figure   {
1912                 $$ = $1;
1913         }
1914         | br_bass_figure ']' {
1915                 $$ = $1;
1916                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1917         }
1918         ;
1919
1920 figure_list:
1921         /**/            {
1922                 $$ = SCM_EOL;
1923         }
1924         | figure_list br_bass_figure {
1925                 $$ = scm_cons ($2, $1);
1926         }
1927         ;
1928
1929 figure_spec:
1930         FIGURE_OPEN figure_list FIGURE_CLOSE {
1931                 Music * m = MY_MAKE_MUSIC("EventChord");
1932                 $2 = scm_reverse_x ($2, SCM_EOL);
1933                 m->set_mus_property ("elements",  $2);
1934                 $$ = m->self_scm ();
1935         }
1936         ;
1937
1938
1939 optional_rest:
1940         /**/   { $$ = 0; }
1941         | REST { $$ = 1; }
1942         ;
1943
1944 simple_element:
1945         pitch exclamations questions optional_notemode_duration optional_rest {
1946
1947                 Input i = THIS->pop_spot ();
1948                 if (!THIS->lexer_->note_state_b ())
1949                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1950
1951                 Music *n = 0;
1952                 if ($5)
1953                         n =  MY_MAKE_MUSIC("RestEvent");
1954                 else
1955                         n =  MY_MAKE_MUSIC("NoteEvent");
1956
1957                 n->set_mus_property ("pitch", $1);
1958                 n->set_mus_property ("duration", $4);
1959
1960
1961                 if ($3 % 2)
1962                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1963                 if ($2 % 2 || $3 % 2)
1964                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1965
1966                 Music *v = MY_MAKE_MUSIC("EventChord");
1967                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1968                 scm_gc_unprotect_object (n->self_scm());
1969
1970                 v->set_spot (i);
1971                 n->set_spot (i);
1972                 $$ = v;
1973         }
1974         | figure_spec optional_notemode_duration {
1975                 Music * m = unsmob_music ($1);
1976                 Input i = THIS->pop_spot ();
1977                 m->set_spot (i);
1978                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1979                 {
1980                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1981                 }
1982                 $$ = m;
1983         }
1984         | RESTNAME optional_notemode_duration           {
1985
1986                 Input i = THIS->pop_spot ();
1987                 Music * ev = 0;
1988                 if (ly_scm2string ($1) =="s") {
1989                         /* Space */
1990                         ev = MY_MAKE_MUSIC("SkipEvent");
1991                   }
1992                 else {
1993                         ev = MY_MAKE_MUSIC("RestEvent");
1994
1995                     }
1996                 ev->set_mus_property ("duration" ,$2);
1997                 ev->set_spot (i);
1998                 Music * velt = MY_MAKE_MUSIC("EventChord");
1999                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2000                 velt->set_spot (i);
2001
2002                 $$ = velt;
2003         }
2004         | MULTI_MEASURE_REST optional_notemode_duration         {
2005                 THIS->pop_spot ();
2006
2007                 static SCM proc ;
2008                 if (!proc)
2009                         proc = scm_c_eval_string ("make-multi-measure-rest");
2010
2011                 SCM mus = scm_call_2 (proc, $2,
2012                         make_input (THIS->here_input()));
2013                 scm_gc_protect_object (mus);
2014                 $$ = unsmob_music (mus);
2015         }
2016         | STRING optional_notemode_duration     {
2017                 Input i = THIS->pop_spot ();
2018
2019                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2020                 lreq->set_mus_property ("text", $1);
2021                 lreq->set_mus_property ("duration",$2);
2022                 lreq->set_spot (i);
2023                 Music * velt = MY_MAKE_MUSIC("EventChord");
2024                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2025
2026                 $$= velt;
2027         }
2028         | new_chord {
2029                 THIS->pop_spot ();
2030
2031                 if (!THIS->lexer_->chord_state_b ())
2032                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2033                 $$ = unsmob_music ($1);
2034         }
2035         ;
2036
2037 new_chord:
2038         steno_tonic_pitch optional_notemode_duration   {
2039                 $$ = make_chord ($1, $2, SCM_EOL);
2040         }
2041         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2042                 SCM its = scm_reverse_x ($4, SCM_EOL);
2043                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2044         }
2045         ;
2046
2047 chord_items:
2048         /**/ {
2049                 $$ = SCM_EOL;
2050         }
2051         | chord_items chord_item {
2052                 $$ = gh_cons ($2, $$);
2053         }
2054         ;
2055
2056 chord_separator:
2057         CHORD_COLON {
2058                 $$ = ly_symbol2scm ("chord-colon");
2059         }
2060         | CHORD_CARET {
2061                 $$ = ly_symbol2scm ("chord-caret");
2062         }
2063         | CHORD_SLASH steno_tonic_pitch {
2064                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2065         }
2066         | CHORD_BASS steno_tonic_pitch {
2067                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2068         }
2069         ;
2070
2071 chord_item:
2072         chord_separator {
2073                 $$ = $1;
2074         }
2075         | step_numbers {
2076                 $$ = scm_reverse_x ($1, SCM_EOL);
2077         }
2078         | CHORD_MODIFIER  {
2079                 $$ = $1;
2080         }
2081         ;
2082
2083 step_numbers:
2084         step_number { $$ = gh_cons ($1, SCM_EOL); }
2085         | step_numbers '.' step_number {
2086                 $$ = gh_cons ($3, $$);
2087         }
2088         ;
2089
2090 step_number:
2091         bare_unsigned {
2092                 $$ = make_chord_step ($1, 0);
2093         }
2094         | bare_unsigned '+' {
2095                 $$ = make_chord_step ($1, 1);
2096         }
2097         | bare_unsigned CHORD_MINUS {
2098                 $$ = make_chord_step ($1,-1);
2099         }
2100         ;
2101
2102 /*
2103         UTILITIES
2104  */
2105 number_expression:
2106         number_expression '+' number_term {
2107                 $$ = scm_sum ($1, $3);
2108         }
2109         | number_expression '-' number_term {
2110                 $$ = scm_difference ($1, $3);
2111         }
2112         | number_term
2113         ;
2114
2115 number_term:
2116         number_factor {
2117                 $$ = $1;
2118         }
2119         | number_factor '*' number_factor {
2120                 $$ = scm_product ($1, $3);
2121         }
2122         | number_factor '/' number_factor {
2123                 $$ = scm_divide ($1, $3);
2124         }
2125         ;
2126
2127 number_factor:
2128         '-'  number_factor { /* %prec UNARY_MINUS */
2129                 $$ = scm_difference ($2, SCM_UNDEFINED);
2130         }
2131         | bare_number
2132         ;
2133
2134
2135 bare_number:
2136         UNSIGNED        {
2137                 $$ = gh_int2scm ($1);
2138         }
2139         | REAL          {
2140                 $$ = $1;
2141         }
2142         | NUMBER_IDENTIFIER             {
2143                 $$ = $1;
2144         }
2145         | REAL NUMBER_IDENTIFIER        {
2146                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2147         }
2148         | UNSIGNED NUMBER_IDENTIFIER    {
2149                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2150         }
2151         ;
2152
2153
2154 bare_unsigned:
2155         UNSIGNED {
2156                         $$ = $1;
2157         }
2158         | DIGIT {
2159                 $$ = $1;
2160         }
2161         ;
2162
2163 bare_int:
2164         bare_number {
2165                 if (scm_integer_p ($1) == SCM_BOOL_T)
2166                 {
2167                         int k = gh_scm2int ($1);
2168                         $$ = k;
2169                 } else
2170                 {
2171                         THIS->parser_error (_ ("need integer number arg"));
2172                         $$ = 0;
2173                 }
2174         }
2175         | '-' bare_int {
2176                 $$ = -$2;
2177         }
2178         ;
2179
2180
2181 string:
2182         STRING          {
2183                 $$ = $1;
2184         }
2185         | STRING_IDENTIFIER     {
2186                 $$ = $1;
2187         }
2188         | string '+' string {
2189                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2190         }
2191         ;
2192
2193
2194 exclamations:
2195                 { $$ = 0; }
2196         | exclamations '!'      { $$ ++; }
2197         ;
2198
2199 questions:
2200                 { $$ = 0; }
2201         | questions '?' { $$ ++; }
2202         ;
2203
2204
2205
2206 full_markup:
2207         MARKUP_IDENTIFIER {
2208                 $$ = $1;
2209         }
2210         | MARKUP
2211                 { THIS->lexer_->push_markup_state (); }
2212         markup
2213                 { $$ = $3;
2214                   THIS->lexer_->pop_state ();
2215                 }
2216         ;
2217
2218
2219 /*
2220 This should be done more dynamically if possible.
2221 */
2222 markup:
2223         STRING {
2224                 $$ = make_simple_markup ($1);
2225         }
2226         | MARKUP_HEAD_MARKUP0 markup {
2227                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2228         }
2229         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2230                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2231         }
2232         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2233                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2234         }
2235         | markup_line {
2236                 $$ = $1;
2237         }
2238         | MARKUP_HEAD_LIST0 markup_list {
2239                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2240         }
2241         | MARKUP_HEAD_SCM0 embedded_scm {
2242                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2243         }
2244         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2245                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2246         }
2247         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2248                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2249         }
2250         | MARKUP_IDENTIFIER {
2251                 $$ = $1;
2252         }
2253
2254         ;
2255
2256 markup_list:
2257         CHORD_OPEN markup_list_body CHORD_CLOSE { $$ = scm_reverse_x ($2, SCM_EOL); }
2258         ;
2259
2260 markup_line:
2261         '{' markup_list_body '}' {
2262                 static SCM line ;
2263                 if (!line)
2264                         line = scm_c_eval_string ("line-markup");
2265
2266                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2267         }
2268         ;
2269
2270 markup_list_body:
2271         /**/ {  $$ = SCM_EOL; }
2272         | markup_list_body markup {
2273                 $$ = gh_cons ($2, $1) ;
2274         }
2275         ;
2276
2277
2278 %%
2279
2280 void
2281 My_lily_parser::set_yydebug (bool )
2282 {
2283 #if 0
2284         yydebug = 1;
2285 #endif
2286 }
2287
2288 extern My_lily_parser * current_parser;
2289
2290 void
2291 My_lily_parser::do_yyparse ()
2292 {
2293         current_parser = this;;
2294         yyparse ((void*)this);
2295 }
2296
2297
2298 /*
2299 Should make this optional?    It will also complain when you do
2300
2301         [s4]
2302
2303 which is entirely legitimate.
2304
2305 Or we can scrap it. Barchecks should detect wrong durations, and
2306 skipTypesetting speeds it up a lot.
2307 */
2308
2309 void
2310 My_lily_parser::beam_check (SCM dur)
2311 {
2312   Duration *d = unsmob_duration (dur);
2313   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2314     {
2315       Music * m = unsmob_music (last_beam_start_);
2316       m->origin ()->warning (_("Suspect duration found following this beam"));
2317     }
2318   last_beam_start_ = SCM_EOL;
2319 }
2320
2321
2322
2323 bool
2324 markup_p (SCM x)
2325 {
2326         return gh_pair_p (x)
2327                 && SCM_BOOL_F != scm_object_property (gh_car (x), ly_symbol2scm ("markup-signature"));
2328 }
2329 /*
2330 It is a little strange, to have this function in this file, but
2331 otherwise, we have to import music classes into the lexer.
2332
2333 */
2334 int
2335 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2336 {
2337         if (gh_string_p (sid)) {
2338                 *destination = sid;
2339                 return STRING_IDENTIFIER;
2340         } else if (gh_number_p (sid)) {
2341                 *destination = sid;
2342                 return NUMBER_IDENTIFIER;
2343         } else if (unsmob_translator_def (sid)) {
2344                 *destination = unsmob_translator_def (sid)->clone_scm();
2345                 return TRANSLATOR_IDENTIFIER;
2346         } else if (unsmob_score (sid)) {
2347                 Score *sc =  new Score (*unsmob_score (sid));
2348                 *destination =sc->self_scm ();
2349                 return SCORE_IDENTIFIER;
2350         } else if (Music * mus =unsmob_music (sid)) {
2351                 *destination = unsmob_music (sid)->clone ()->self_scm();
2352                 unsmob_music (*destination)->
2353                         set_mus_property ("origin", make_input (last_input_));
2354                 return dynamic_cast<Event*> (mus)
2355                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2356         } else if (unsmob_duration (sid)) {
2357                 *destination = unsmob_duration (sid)->smobbed_copy();
2358                 return DURATION_IDENTIFIER;
2359         } else if (unsmob_music_output_def (sid)) {
2360                 Music_output_def *p = unsmob_music_output_def (sid);
2361                 p = p->clone ();
2362
2363                 *destination = p->self_scm();
2364                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2365         } else if (new_markup_p (sid)) {
2366                 *destination = sid;
2367                 return MARKUP_IDENTIFIER;
2368         }
2369
2370         return -1;
2371 }