lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2009 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_TOP
  44 %left ADDLYRICS
  45 %left PREC_BOT
  46
  47 %expect 1
  48
  49 /* One shift/reduce problem
  50
  51 1.  \repeat
  52         \repeat .. \alternative
  53
  54     \repeat { \repeat .. \alternative }
  55
  56 or
  57
  58     \repeat { \repeat } \alternative
  59 */
  60
  61
  62 %pure_parser
  63 %locations
  64
  65
  66
  67 %{ // -*-Fundamental-*-
  68
  69 /*
  70 FIXME:
  71
  72    * The rules for who is protecting what are very shady.  Uniformise
  73      this.
  74
  75    * There are too many lexical modes?
  76 */
  77
  78 #include "config.hh"
  79
  80 #include <cctype>
  81 #include <cstdlib>
  82 #include <cstdio>
  83 using namespace std;
  84
  85 #include "book.hh"
  86 #include "context-def.hh"
  87 #include "dimensions.hh"
  88 #include "file-path.hh"
  89 #include "input.hh"
  90 #include "international.hh"
  91 #include "lily-guile.hh"
  92 #include "lily-lexer.hh"
  93 #include "lily-parser.hh"
  94 #include "main.hh"
  95 #include "misc.hh"
  96 #include "music.hh"
  97 #include "music.hh"
  98 #include "output-def.hh"
  99 #include "paper-book.hh"
 100 #include "program-option.hh"
 101 #include "scm-hash.hh"
 102 #include "score.hh"
 103 #include "text-interface.hh"
 104 #include "warn.hh"
 105
 106 %}
 107
 108
 109 %union {
 110         Book *book;
 111         Output_def *outputdef;
 112         SCM scm;
 113         std::string *string;
 114         Music *music;
 115         Score *score;
 116         int i;
 117 }
 118
 119 %{
 120
 121 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 122
 123 /* ES TODO:
 124 - Don't use lily module, create a new module instead.
 125 - delay application of the function
 126 */
 127 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 128   scm_apply_0 (proc, args)
 129 /* Syntactic Sugar. */
 130 #define MAKE_SYNTAX(name, location, ...)        \
 131   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 132
 133 SCM get_next_unique_context_id ();
 134 SCM get_next_unique_lyrics_context_id ();
 135
 136 #undef _
 137 #if !HAVE_GETTEXT
 138 #define _(x) x
 139 #else
 140 #include <libintl.h>
 141 #define _(x) gettext (x)
 142 #endif
 143
 144
 145 static Music *make_music_with_input (SCM name, Input where);
 146 SCM make_music_relative (Pitch start, SCM music, Input loc);
 147 SCM run_music_function (Lily_parser *, SCM expr);
 148 SCM get_first_context_id (SCM type, Music *m);
 149 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 150 SCM make_chord_step (int step, Rational alter);
 151 SCM make_simple_markup (SCM a);
 152 bool is_duration (int t);
 153 bool is_regular_identifier (SCM id);
 154 bool ly_input_procedure_p (SCM x);
 155 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 156 void set_music_properties (Music *p, SCM a);
 157
 158 %}
 159
 160 /* The third option is an alias that will be used to display the
 161    syntax error.  Bison CVS now correctly handles backslash escapes.
 162
 163    FIXME: Bison needs to translate some of these, eg, STRING.
 164
 165 */
 166
 167 /* Keyword tokens with plain escaped name.  */
 168 %token ACCEPTS "\\accepts"
 169 %token ADDLYRICS "\\addlyrics"
 170 %token ALIAS "\\alias"
 171 %token ALTERNATIVE "\\alternative"
 172 %token BOOK "\\book"
 173 %token BOOKPART "\\bookpart"
 174 %token CHANGE "\\change"
 175 %token CHORDMODE "\\chordmode"
 176 %token CHORDS "\\chords"
 177 %token CONSISTS "\\consists"
 178 %token CONTEXT "\\context"
 179 %token DEFAULT "\\default"
 180 %token DEFAULTCHILD "\\defaultchild"
 181 %token DENIES "\\denies"
 182 %token DESCRIPTION "\\description"
 183 %token DRUMMODE "\\drummode"
 184 %token DRUMS "\\drums"
 185 %token FIGUREMODE "\\figuremode"
 186 %token FIGURES "\\figures"
 187 %token GROBDESCRIPTIONS "\\grobdescriptions"
 188 %token HEADER "\\header"
 189 %token INVALID "\\invalid"
 190 %token KEY "\\key"
 191 %token LAYOUT "\\layout"
 192 %token LYRICMODE "\\lyricmode"
 193 %token LYRICS "\\lyrics"
 194 %token LYRICSTO "\\lyricsto"
 195 %token MARK "\\mark"
 196 %token MARKUP "\\markup"
 197 %token MARKUPLINES "\\markuplines"
 198 %token MIDI "\\midi"
 199 %token NAME "\\name"
 200 %token NOTEMODE "\\notemode"
 201 %token OBJECTID "\\objectid"
 202 %token OCTAVE "\\octave"
 203 %token ONCE "\\once"
 204 %token OVERRIDE "\\override"
 205 %token PAPER "\\paper"
 206 %token PARTIAL "\\partial"
 207 %token RELATIVE "\\relative"
 208 %token REMOVE "\\remove"
 209 %token REPEAT "\\repeat"
 210 %token REST "\\rest"
 211 %token REVERT "\\revert"
 212 %token SCORE "\\score"
 213 %token SEQUENTIAL "\\sequential"
 214 %token SET "\\set"
 215 %token SIMULTANEOUS "\\simultaneous"
 216 %token SKIP "\\skip"
 217 %token TEMPO "\\tempo"
 218 %token TIMES "\\times"
 219 %token TRANSPOSE "\\transpose"
 220 %token TYPE "\\type"
 221 %token UNSET "\\unset"
 222 %token WITH "\\with"
 223
 224 /* Keyword token exceptions.  */
 225 %token TIME_T "\\time"
 226 %token NEWCONTEXT "\\new"
 227
 228
 229 /* Other string tokens.  */
 230
 231 %token CHORD_BASS "/+"
 232 %token CHORD_CARET "^"
 233 %token CHORD_COLON ":"
 234 %token CHORD_MINUS "-"
 235 %token CHORD_SLASH "/"
 236 %token ANGLE_OPEN "<"
 237 %token ANGLE_CLOSE ">"
 238 %token DOUBLE_ANGLE_OPEN "<<"
 239 %token DOUBLE_ANGLE_CLOSE ">>"
 240 %token E_BACKSLASH "\\"
 241 %token E_ANGLE_CLOSE "\\>"
 242 %token E_CHAR "\\C[haracter]"
 243 %token E_CLOSE "\\)"
 244 %token E_EXCLAMATION "\\!"
 245 %token E_BRACKET_OPEN "\\["
 246 %token E_OPEN "\\("
 247 %token E_BRACKET_CLOSE "\\]"
 248 %token E_ANGLE_OPEN "\\<"
 249 %token E_PLUS "\\+"
 250 %token E_TILDE "\\~"
 251 %token EXTENDER "__"
 252
 253 /*
 254 If we give names, Bison complains.
 255 */
 256 %token FIGURE_CLOSE /* "\\>" */
 257 %token FIGURE_OPEN /* "\\<" */
 258 %token FIGURE_SPACE "_"
 259 %token HYPHEN "--"
 260
 261 %token CHORDMODIFIERS
 262 %token LYRIC_MARKUP
 263 %token MULTI_MEASURE_REST
 264
 265
 266 %token <i> DIGIT
 267 %token <i> E_UNSIGNED
 268 %token <i> UNSIGNED
 269
 270 /* Artificial tokens, for more generic function syntax */
 271 %token <i> EXPECT_MARKUP;
 272 %token <i> EXPECT_MUSIC;
 273 %token <i> EXPECT_SCM;
 274 /* After the last argument. */
 275 %token <i> EXPECT_NO_MORE_ARGS;
 276
 277 %token <scm> BOOK_IDENTIFIER
 278 %token <scm> CHORDMODIFIER_PITCH
 279 %token <scm> CHORD_MODIFIER
 280 %token <scm> CHORD_REPETITION
 281 %token <scm> CONTEXT_DEF_IDENTIFIER
 282 %token <scm> DRUM_PITCH
 283 %token <scm> DURATION_IDENTIFIER
 284 %token <scm> EVENT_IDENTIFIER
 285 %token <scm> FRACTION
 286 %token <scm> LYRICS_STRING
 287 %token <scm> LYRIC_MARKUP_IDENTIFIER
 288 %token <scm> MARKUP_HEAD_EMPTY
 289 %token <scm> MARKUP_HEAD_LIST0
 290 %token <scm> MARKUP_HEAD_MARKUP0
 291 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 292 %token <scm> MARKUP_HEAD_SCM0
 293 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 294 %token <scm> MARKUP_HEAD_SCM0_SCM1
 295 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 296 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2_MARKUP3
 297 %token <scm> MARKUP_HEAD_SCM0_MARKUP1_MARKUP2
 298 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 299 %token <scm> MARKUP_LIST_HEAD_EMPTY
 300 %token <scm> MARKUP_LIST_HEAD_LIST0
 301 %token <scm> MARKUP_LIST_HEAD_SCM0
 302 %token <scm> MARKUP_LIST_HEAD_SCM0_LIST1
 303 %token <scm> MARKUP_LIST_HEAD_SCM0_SCM1_LIST2
 304 %token <scm> MARKUP_IDENTIFIER
 305 %token <scm> MUSIC_FUNCTION
 306 %token <scm> MUSIC_IDENTIFIER
 307 %token <scm> NOTENAME_PITCH
 308 %token <scm> NUMBER_IDENTIFIER
 309 %token <scm> OUTPUT_DEF_IDENTIFIER
 310 %token <scm> REAL
 311 %token <scm> RESTNAME
 312 %token <scm> SCM_IDENTIFIER
 313 %token <scm> SCM_TOKEN
 314 %token <scm> SCORE_IDENTIFIER
 315 %token <scm> STRING
 316 %token <scm> STRING_IDENTIFIER
 317 %token <scm> TONICNAME_PITCH
 318
 319
 320 %type <book> book_block
 321 %type <book> book_body
 322 %type <book> bookpart_block
 323 %type <book> bookpart_body
 324
 325 %type <i> bare_unsigned
 326 %type <scm> figured_bass_alteration
 327 %type <i> dots
 328 %type <i> exclamations
 329 %type <i> optional_rest
 330 %type <i> questions
 331 %type <i> script_dir
 332 %type <i> sub_quotes
 333 %type <i> sup_quotes
 334 %type <i> tremolo_type
 335
 336 /* Music */
 337 %type <scm> composite_music
 338 %type <scm> grouped_music_list
 339 %type <scm> music
 340 %type <scm> prefix_composite_music
 341 %type <scm> repeated_music
 342 %type <scm> sequential_music
 343 %type <scm> simple_music
 344 %type <scm> simultaneous_music
 345 %type <scm> chord_body
 346 %type <scm> chord_body_element
 347 %type <scm> command_element
 348 %type <scm> command_event
 349 %type <scm> context_change
 350 %type <scm> direction_less_event
 351 %type <scm> direction_reqd_event
 352 %type <scm> event_chord
 353 %type <scm> gen_text_def
 354 %type <scm> music_property_def
 355 %type <scm> note_chord_element
 356 %type <scm> post_event
 357 %type <scm> re_rhythmed_music
 358 %type <scm> relative_music
 359 %type <scm> simple_element
 360 %type <scm> simple_music_property_def
 361 %type <scm> string_number_event
 362 %type <scm> tempo_event
 363
 364 %type <outputdef> output_def_body
 365 %type <outputdef> output_def_head
 366 %type <outputdef> output_def_head_with_mode_switch
 367 %type <outputdef> output_def
 368 %type <outputdef> paper_block
 369
 370 %type <scm> alternative_music
 371 %type <scm> generic_prefix_music_scm
 372 %type <scm> music_list
 373 %type <scm> absolute_pitch
 374 %type <scm> assignment_id
 375 %type <scm> bare_number
 376 %type <scm> unsigned_number
 377 %type <scm> bass_figure
 378 %type <scm> figured_bass_modification
 379 %type <scm> br_bass_figure
 380 %type <scm> bass_number
 381 %type <scm> chord_body_elements
 382 %type <scm> chord_item
 383 %type <scm> chord_items
 384 %type <scm> chord_separator
 385 %type <scm> context_def_mod
 386 %type <scm> context_def_spec_block
 387 %type <scm> context_def_spec_body
 388 %type <scm> context_mod
 389 %type <scm> context_mod_list
 390 %type <scm> context_prop_spec
 391 %type <scm> direction_less_char
 392 %type <scm> duration_length
 393 %type <scm> embedded_scm
 394 %type <scm> figure_list
 395 %type <scm> figure_spec
 396 %type <scm> fraction
 397 %type <scm> full_markup
 398 %type <scm> full_markup_list
 399 %type <scm> function_scm_argument
 400 %type <scm> function_arglist
 401 %type <scm> function_arglist_music_last
 402 %type <scm> function_arglist_nonmusic_last
 403 %type <scm> function_arglist_nonmusic
 404 %type <scm> identifier_init
 405 %type <scm> lilypond_header
 406 %type <scm> lilypond_header_body
 407 %type <scm> lyric_element
 408 %type <scm> lyric_markup
 409 %type <scm> markup
 410 %type <scm> markup_braced_list
 411 %type <scm> markup_braced_list_body
 412 %type <scm> markup_composed_list
 413 %type <scm> markup_command_list
 414 %type <scm> markup_head_1_item
 415 %type <scm> markup_head_1_list
 416 %type <scm> markup_list
 417 %type <scm> markup_top
 418 %type <scm> mode_changing_head
 419 %type <scm> mode_changing_head_with_context
 420 %type <scm> multiplied_duration
 421 %type <scm> music_function_identifier_musicless_prefix
 422 %type <scm> music_function_event
 423 %type <scm> music_function_chord_body
 424 %type <scm> new_chord
 425 %type <scm> new_lyrics
 426 %type <scm> number_expression
 427 %type <scm> number_factor
 428 %type <scm> number_term
 429 %type <scm> object_id_setting
 430 %type <scm> octave_check
 431 %type <scm> optional_context_mod
 432 %type <scm> optional_id
 433 %type <scm> optional_notemode_duration
 434 %type <scm> pitch
 435 %type <scm> pitch_also_in_chords
 436 %type <scm> post_events
 437 %type <scm> property_operation
 438 %type <scm> property_path property_path_revved
 439 %type <scm> scalar
 440 %type <scm> script_abbreviation
 441 %type <scm> simple_chord_elements
 442 %type <scm> simple_markup
 443 %type <scm> simple_string
 444 %type <scm> steno_duration
 445 %type <scm> steno_pitch
 446 %type <scm> steno_tonic_pitch
 447 %type <scm> step_number
 448 %type <scm> step_numbers
 449 %type <scm> string
 450
 451 %type <score> score_block
 452 %type <score> score_body
 453
 454
 455 %left '-' '+'
 456
 457 /* We don't assign precedence to / and *, because we might need varied
 458 prec levels in different prods */
 459
 460 %left UNARY_MINUS
 461
 462 %%
 463
 464 lilypond:       /* empty */
 465         | lilypond toplevel_expression {
 466         }
 467         | lilypond assignment {
 468         }
 469         | lilypond error {
 470                 PARSER->error_level_ = 1;
 471         }
 472         | lilypond INVALID      {
 473                 PARSER->error_level_ = 1;
 474         }
 475         ;
 476
 477
 478 object_id_setting:
 479         OBJECTID STRING { $$ = $2; }
 480         ;
 481
 482 toplevel_expression:
 483         lilypond_header {
 484                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 485         }
 486         | book_block {
 487                 Book *book = $1;
 488                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 489                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 490                 book->unprotect ();
 491         }
 492         | bookpart_block {
 493                 Book *bookpart = $1;
 494                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 495                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 496                 bookpart->unprotect ();
 497         }
 498         | score_block {
 499                 Score *score = $1;
 500
 501                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 502                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 503                 score->unprotect ();
 504         }
 505         | composite_music {
 506                 Music *music = unsmob_music ($1);
 507                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 508                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 509         }
 510         | full_markup {
 511                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 512                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 513         }
 514         | full_markup_list {
 515                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 516                 scm_call_2 (proc, PARSER->self_scm (), $1);
 517         }
 518         | output_def {
 519                 SCM id = SCM_EOL;
 520                 Output_def * od = $1;
 521
 522                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 523                         id = ly_symbol2scm ("$defaultpaper");
 524                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 525                         id = ly_symbol2scm ("$defaultmidi");
 526                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 527                         id = ly_symbol2scm ("$defaultlayout");
 528
 529                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 530                 od->unprotect();
 531         }
 532         ;
 533
 534 embedded_scm:
 535         SCM_TOKEN
 536         | SCM_IDENTIFIER
 537         ;
 538
 539
 540 lilypond_header_body:
 541         {
 542                 $$ = get_header (PARSER);
 543                 PARSER->lexer_->add_scope ($$);
 544         }
 545         | lilypond_header_body assignment  {
 546
 547         }
 548         ;
 549
 550 lilypond_header:
 551         HEADER '{' lilypond_header_body '}'     {
 552                 $$ = PARSER->lexer_->remove_scope ();
 553         }
 554         ;
 555
 556 /*
 557         DECLARATIONS
 558 */
 559 assignment_id:
 560         STRING          { $$ = $1; }
 561         | LYRICS_STRING { $$ = $1; }
 562         ;
 563
 564 assignment:
 565         assignment_id '=' identifier_init  {
 566                 PARSER->lexer_->set_identifier ($1, $3);
 567
 568 /*
 569  TODO: devise standard for protection in parser.
 570
 571   The parser stack lives on the C-stack, which means that
 572 all objects can be unprotected as soon as they're here.
 573
 574 */
 575         }
 576         | embedded_scm { }
 577         ;
 578
 579
 580 identifier_init:
 581         score_block {
 582                 $$ = $1->self_scm ();
 583                 $1->unprotect ();
 584         }
 585         | book_block {
 586                 $$ = $1->self_scm ();
 587                 $1->unprotect ();
 588         }
 589         | bookpart_block {
 590                 $$ = $1->self_scm ();
 591                 $1->unprotect ();
 592         }
 593         | output_def {
 594                 $$ = $1->self_scm ();
 595                 $1->unprotect ();
 596         }
 597         | context_def_spec_block {
 598                 $$ = $1;
 599         }
 600         | music  {
 601                 /* Hack: Create event-chord around standalone events.
 602                    Prevents the identifier from being interpreted as a post-event. */
 603                 Music *mus = unsmob_music ($1);
 604                 bool is_event = mus &&
 605                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 606                                 != SCM_BOOL_F);
 607                 if (!is_event)
 608                         $$ = $1;
 609                 else
 610                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 611         }
 612         | post_event {
 613                 $$ = $1;
 614         }
 615         | number_expression {
 616                 $$ = $1;
 617         }
 618         | string {
 619                 $$ = $1;
 620         }
 621         | embedded_scm {
 622                 $$ = $1;
 623         }
 624         | full_markup {
 625                 $$ = $1;
 626         }
 627         | DIGIT {
 628                 $$ = scm_from_int ($1);
 629         }
 630         ;
 631
 632 context_def_spec_block:
 633         CONTEXT '{' context_def_spec_body '}'
 634                 {
 635                 $$ = $3;
 636         }
 637         ;
 638
 639 context_def_spec_body:
 640         /**/ {
 641                 $$ = Context_def::make_scm ();
 642                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 643         }
 644         | CONTEXT_DEF_IDENTIFIER {
 645                 $$ = $1;
 646                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 647         }
 648         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 649                 Context_def*td = unsmob_context_def ($$);
 650
 651                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 652                         SCM tag = scm_caar (p);
 653
 654                         /* TODO: should make new tag "grob-definition" ? */
 655                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 656                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 657                 }
 658         }
 659         | context_def_spec_body context_mod {
 660                 unsmob_context_def ($$)->add_context_mod ($2);
 661         }
 662         ;
 663
 664
 665
 666 book_block:
 667         BOOK '{' book_body '}'  {
 668                 $$ = $3;
 669                 pop_paper (PARSER);
 670                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 671         }
 672         ;
 673
 674 /* FIXME:
 675    * Use 'handlers' like for toplevel-* stuff?
 676    * grok \layout and \midi?  */
 677 book_body:
 678         {
 679                 $$ = new Book;
 680                 init_papers (PARSER);
 681                 $$->origin ()->set_spot (@$);
 682                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 683                 $$->paper_->unprotect ();
 684                 push_paper (PARSER, $$->paper_);
 685                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 686                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 687                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 688                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 689         }
 690         | BOOK_IDENTIFIER {
 691                 $$ = unsmob_book ($1);
 692                 $$->protect ();
 693                 $$->origin ()->set_spot (@$);
 694                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 695         }
 696         | book_body paper_block {
 697                 $$->paper_ = $2;
 698                 $2->unprotect ();
 699                 set_paper (PARSER, $2);
 700         }
 701         | book_body bookpart_block {
 702                 Book *bookpart = $2;
 703                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 704                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 705                 bookpart->unprotect ();
 706         }
 707         | book_body score_block {
 708                 Score *score = $2;
 709                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 710                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 711                 score->unprotect ();
 712         }
 713         | book_body composite_music {
 714                 Music *music = unsmob_music ($2);
 715                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 716                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 717         }
 718         | book_body full_markup {
 719                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 720                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 721         }
 722         | book_body full_markup_list {
 723                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 724                 scm_call_2 (proc, $$->self_scm (), $2);
 725         }
 726         | book_body lilypond_header {
 727                 $$->header_ = $2;
 728         }
 729         | book_body error {
 730                 $$->paper_ = 0;
 731                 $$->scores_ = SCM_EOL;
 732                 $$->bookparts_ = SCM_EOL;
 733         }
 734         | book_body object_id_setting {
 735                 $$->user_key_ = ly_scm2string ($2);
 736         }
 737         ;
 738
 739 bookpart_block:
 740         BOOKPART '{' bookpart_body '}' {
 741                 $$ = $3;
 742                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 743         }
 744         ;
 745
 746 bookpart_body:
 747         {
 748                 $$ = new Book;
 749                 $$->origin ()->set_spot (@$);
 750                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 751         }
 752         | BOOK_IDENTIFIER {
 753                 $$ = unsmob_book ($1);
 754                 $$->protect ();
 755                 $$->origin ()->set_spot (@$);
 756                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 757         }
 758         | bookpart_body paper_block {
 759                 $$->paper_ = $2;
 760                 $2->unprotect ();
 761         }
 762         | bookpart_body score_block {
 763                 Score *score = $2;
 764                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 765                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 766                 score->unprotect ();
 767         }
 768         | bookpart_body composite_music {
 769                 Music *music = unsmob_music ($2);
 770                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 771                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 772         }
 773         | bookpart_body full_markup {
 774                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 775                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 776         }
 777         | bookpart_body full_markup_list {
 778                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 779                 scm_call_2 (proc, $$->self_scm (), $2);
 780         }
 781         | bookpart_body lilypond_header {
 782                 $$->header_ = $2;
 783         }
 784         | bookpart_body error {
 785                 $$->paper_ = 0;
 786                 $$->scores_ = SCM_EOL;
 787         }
 788         | bookpart_body object_id_setting {
 789                 $$->user_key_ = ly_scm2string ($2);
 790         }
 791         ;
 792
 793 score_block:
 794         SCORE '{' score_body '}'        {
 795                 $$ = $3;
 796         }
 797         ;
 798
 799 score_body:
 800         music {
 801                 SCM m = $1;
 802                 SCM scorify = ly_lily_module_constant ("scorify-music");
 803                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 804
 805                 // pass ownernship to C++ again.
 806                 $$ = unsmob_score (score);
 807                 $$->protect ();
 808                 $$->origin ()->set_spot (@$);
 809         }
 810         | SCORE_IDENTIFIER {
 811                 $$ = unsmob_score ($1);
 812                 $$->protect ();
 813                 $$->origin ()->set_spot (@$);
 814         }
 815         | score_body object_id_setting {
 816                 $$->user_key_ = ly_scm2string ($2);
 817         }
 818         | score_body lilypond_header    {
 819                 $$->set_header ($2);
 820         }
 821         | score_body output_def {
 822                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 823                 {
 824                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 825
 826                 }
 827                 else
 828                 {
 829                         $$->add_output_def ($2);
 830                 }
 831                 $2->unprotect ();
 832         }
 833         | score_body error {
 834                 $$->error_found_ = true;
 835         }
 836         ;
 837
 838
 839 /*
 840         OUTPUT DEF
 841 */
 842
 843 paper_block:
 844         output_def {
 845                 $$ = $1;
 846                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 847                 {
 848                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 849                         $1->unprotect ();
 850                         $$ = get_paper (PARSER);
 851                 }
 852         }
 853         ;
 854
 855
 856 output_def:
 857         output_def_body '}' {
 858                 $$ = $1;
 859
 860                 PARSER->lexer_->remove_scope ();
 861                 PARSER->lexer_->pop_state ();
 862         }
 863         ;
 864
 865 output_def_head:
 866         PAPER {
 867                 $$ = get_paper (PARSER);
 868                 $$->input_origin_ = @$;
 869                 PARSER->lexer_->add_scope ($$->scope_);
 870         }
 871         | MIDI    {
 872                 Output_def *p = get_midi (PARSER);
 873                 $$ = p;
 874                 PARSER->lexer_->add_scope (p->scope_);
 875         }
 876         | LAYOUT        {
 877                 Output_def *p = get_layout (PARSER);
 878
 879                 PARSER->lexer_->add_scope (p->scope_);
 880                 $$ = p;
 881         }
 882         ;
 883
 884 output_def_head_with_mode_switch:
 885         output_def_head {
 886                 PARSER->lexer_->push_initial_state ();
 887                 $$ = $1;
 888         }
 889         ;
 890
 891 output_def_body:
 892         output_def_head_with_mode_switch '{' {
 893                 $$ = $1;
 894                 $$->input_origin_.set_spot (@$);
 895         }
 896         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 897                 $1->unprotect ();
 898
 899                 Output_def *o = unsmob_output_def ($3);
 900                 o->input_origin_.set_spot (@$);
 901                 $$ = o;
 902                 $$->protect ();
 903                 PARSER->lexer_->remove_scope ();
 904                 PARSER->lexer_->add_scope (o->scope_);
 905         }
 906         | output_def_body assignment  {
 907
 908         }
 909         | output_def_body context_def_spec_block        {
 910                 assign_context_def ($$, $2);
 911         }
 912         | output_def_body error {
 913
 914         }
 915         ;
 916
 917 tempo_event:
 918         TEMPO steno_duration '=' bare_unsigned  {
 919                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_BOOL_F, $2, scm_int2num ($4));
 920         }
 921         | TEMPO string steno_duration '=' bare_unsigned {
 922                 $$ = MAKE_SYNTAX ("tempo", @$, make_simple_markup($2), $3, scm_int2num ($5));
 923         }
 924         | TEMPO full_markup steno_duration '=' bare_unsigned    {
 925                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, scm_int2num ($5));
 926         }
 927         | TEMPO string {
 928                 $$ = MAKE_SYNTAX ("tempoText", @$, make_simple_markup($2) );
 929         }
 930         | TEMPO full_markup {
 931                 $$ = MAKE_SYNTAX ("tempoText", @$, $2 );
 932         }
 933         ;
 934
 935 /*
 936 The representation of a  list is the
 937
 938   (LIST . LAST-CONS)
 939
 940  to have efficient append.  */
 941
 942 music_list:
 943         /* empty */ {
 944                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 945         }
 946         | music_list music {
 947                 SCM s = $$;
 948                 SCM c = scm_cons ($2, SCM_EOL);
 949
 950                 if (scm_is_pair (scm_cdr (s)))
 951                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 952                 else
 953                         scm_set_car_x (s, c); /* set first cons */
 954                 scm_set_cdr_x (s, c);  /* remember last cell */
 955         }
 956         | music_list embedded_scm {
 957
 958         }
 959         | music_list error {
 960                 Music *m = MY_MAKE_MUSIC("Music", @$);
 961                 // ugh. code dup
 962                 m->set_property ("error-found", SCM_BOOL_T);
 963                 SCM s = $$;
 964                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 965                 m->unprotect (); /* UGH */
 966
 967                 if (scm_is_pair (scm_cdr (s)))
 968                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 969                 else
 970                         scm_set_car_x (s, c); /* set first cons */
 971                 scm_set_cdr_x (s, c);  /* remember last cell */
 972         }
 973         ;
 974
 975 music:
 976         simple_music
 977         | composite_music
 978         ;
 979
 980 alternative_music:
 981         /* empty */ {
 982                 $$ = SCM_EOL;
 983         }
 984         | ALTERNATIVE '{' music_list '}' {
 985                 $$ = scm_car ($3);
 986         }
 987         ;
 988
 989
 990 repeated_music:
 991         REPEAT simple_string unsigned_number music alternative_music
 992         {
 993                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $5);
 994         }
 995         ;
 996
 997 sequential_music:
 998         SEQUENTIAL '{' music_list '}'           {
 999                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
1000         }
1001         | '{' music_list '}'            {
1002                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
1003         }
1004         ;
1005
1006 simultaneous_music:
1007         SIMULTANEOUS '{' music_list '}'{
1008                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
1009         }
1010         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1011                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
1012         }
1013         ;
1014
1015 simple_music:
1016         event_chord {
1017                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1018         }
1019         | MUSIC_IDENTIFIER
1020         | music_property_def
1021         | context_change
1022         ;
1023
1024 optional_context_mod:
1025         /**/ { $$ = SCM_EOL; }
1026         | WITH { PARSER->lexer_->push_initial_state (); }
1027         '{' context_mod_list '}'
1028         {
1029                 PARSER->lexer_->pop_state ();
1030                 $$ = $4;
1031         }
1032         ;
1033
1034 context_mod_list:
1035         /* */  { $$ = SCM_EOL; }
1036         | context_mod_list context_mod  {
1037                  $$ = scm_cons ($2, $1);
1038         }
1039         ;
1040
1041 composite_music:
1042         prefix_composite_music { $$ = $1; }
1043         | grouped_music_list { $$ = $1; }
1044         ;
1045
1046 grouped_music_list:
1047         simultaneous_music              { $$ = $1; }
1048         | sequential_music              { $$ = $1; }
1049         ;
1050
1051 function_scm_argument:
1052         embedded_scm
1053         | simple_string
1054         ;
1055
1056 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
1057  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM
1058 and this rule returns the reversed list of arguments. */
1059
1060 function_arglist_music_last:
1061         EXPECT_MUSIC function_arglist music {
1062                 $$ = scm_cons ($3, $2);
1063         }
1064         ;
1065
1066 function_arglist_nonmusic_last:
1067         EXPECT_MARKUP function_arglist full_markup {
1068                 $$ = scm_cons ($3, $2);
1069         }
1070         | EXPECT_MARKUP function_arglist simple_string {
1071                 $$ = scm_cons ($3, $2);
1072         }
1073         | EXPECT_SCM function_arglist function_scm_argument {
1074                 $$ = scm_cons ($3, $2);
1075         }
1076         ;
1077
1078 function_arglist_nonmusic: EXPECT_NO_MORE_ARGS {
1079                 $$ = SCM_EOL;
1080         }
1081         | EXPECT_MARKUP function_arglist_nonmusic full_markup {
1082                 $$ = scm_cons ($3, $2);
1083         }
1084         | EXPECT_MARKUP function_arglist_nonmusic simple_string {
1085                 $$ = scm_cons ($3, $2);
1086         }
1087         | EXPECT_SCM function_arglist_nonmusic function_scm_argument {
1088                 $$ = scm_cons ($3, $2);
1089         }
1090         ;
1091
1092 function_arglist: EXPECT_NO_MORE_ARGS {
1093                 /* This is for 0-ary functions, so they don't need to
1094                    read a lookahead token */
1095                 $$ = SCM_EOL;
1096         }
1097         | function_arglist_music_last
1098         | function_arglist_nonmusic_last
1099         ;
1100
1101 generic_prefix_music_scm:
1102         MUSIC_FUNCTION function_arglist {
1103                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1104         }
1105         ;
1106
1107
1108 optional_id:
1109         /**/ { $$ = SCM_EOL; }
1110         | '=' simple_string {
1111                 $$ = $2;
1112         }
1113         ;
1114
1115
1116 prefix_composite_music:
1117         generic_prefix_music_scm {
1118                 $$ = run_music_function (PARSER, $1);
1119         }
1120         | CONTEXT simple_string optional_id optional_context_mod music {
1121                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_F);
1122         }
1123         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1124                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_T);
1125         }
1126
1127         | TIMES fraction music {
1128                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1129         }
1130         | repeated_music                { $$ = $1; }
1131         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
1132                 Pitch from = *unsmob_pitch ($2);
1133                 Pitch to = *unsmob_pitch ($3);
1134                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
1135                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
1136         }
1137         | mode_changing_head grouped_music_list {
1138                 if ($1 == ly_symbol2scm ("chords"))
1139                 {
1140                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1141                 }
1142                 else
1143                 {
1144                   $$ = $2;
1145                 }
1146                 PARSER->lexer_->pop_state ();
1147         }
1148         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1149                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, $2, SCM_BOOL_T);
1150                 if ($1 == ly_symbol2scm ("ChordNames"))
1151                 {
1152                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1153                 }
1154                 PARSER->lexer_->pop_state ();
1155         }
1156         | relative_music        { $$ = $1; }
1157         | re_rhythmed_music     { $$ = $1; }
1158         ;
1159
1160 mode_changing_head:
1161         NOTEMODE {
1162                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1163                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1164
1165                 $$ = ly_symbol2scm ("notes");
1166         }
1167         | DRUMMODE
1168                 {
1169                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1170                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1171
1172                 $$ = ly_symbol2scm ("drums");
1173         }
1174         | FIGUREMODE {
1175                 PARSER->lexer_->push_figuredbass_state ();
1176
1177                 $$ = ly_symbol2scm ("figures");
1178         }
1179         | CHORDMODE {
1180                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1181                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1182                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1183                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1184                 $$ = ly_symbol2scm ("chords");
1185
1186         }
1187         | LYRICMODE
1188                 { PARSER->lexer_->push_lyric_state ();
1189                 $$ = ly_symbol2scm ("lyrics");
1190         }
1191         ;
1192
1193 mode_changing_head_with_context:
1194         DRUMS {
1195                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1196                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1197
1198                 $$ = ly_symbol2scm ("DrumStaff");
1199         }
1200         | FIGURES {
1201                 PARSER->lexer_->push_figuredbass_state ();
1202
1203                 $$ = ly_symbol2scm ("FiguredBass");
1204         }
1205         | CHORDS {
1206                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1207                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1208                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1209                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1210                 $$ = ly_symbol2scm ("ChordNames");
1211         }
1212         | LYRICS
1213                 { PARSER->lexer_->push_lyric_state ();
1214                 $$ = ly_symbol2scm ("Lyrics");
1215         }
1216         ;
1217
1218
1219 relative_music:
1220         RELATIVE absolute_pitch music {
1221                 Pitch start = *unsmob_pitch ($2);
1222                 $$ = make_music_relative (start, $3, @$);
1223         }
1224         | RELATIVE composite_music {
1225                 Pitch middle_c (0, 0, 0);
1226                 $$ = make_music_relative (middle_c, $2, @$);
1227         }
1228         ;
1229
1230 new_lyrics:
1231         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1232         /*cont */
1233         grouped_music_list {
1234         /* Can also use music at the expensive of two S/Rs similar to
1235            \repeat \alternative */
1236                 PARSER->lexer_->pop_state ();
1237
1238                 $$ = scm_cons ($3, SCM_EOL);
1239         }
1240         | new_lyrics ADDLYRICS {
1241                 PARSER->lexer_->push_lyric_state ();
1242         } grouped_music_list {
1243                 PARSER->lexer_->pop_state ();
1244                 $$ = scm_cons ($4, $1);
1245         }
1246         ;
1247
1248 re_rhythmed_music:
1249         grouped_music_list new_lyrics {
1250                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1251         }
1252         | LYRICSTO simple_string {
1253                 PARSER->lexer_->push_lyric_state ();
1254         } music {
1255                 PARSER->lexer_->pop_state ();
1256                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1257         }
1258         ;
1259
1260 context_change:
1261         CHANGE STRING '=' STRING  {
1262                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1263         }
1264         ;
1265
1266
1267 property_path_revved:
1268         embedded_scm {
1269                 $$ = scm_cons ($1, SCM_EOL);
1270         }
1271         | property_path_revved embedded_scm {
1272                 $$ = scm_cons ($2, $1);
1273         }
1274         ;
1275
1276 property_path:
1277         property_path_revved  {
1278                 $$ = scm_reverse_x ($1, SCM_EOL);
1279         }
1280         ;
1281
1282 property_operation:
1283         STRING '=' scalar {
1284                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1285                         scm_string_to_symbol ($1), $3);
1286         }
1287         | UNSET simple_string {
1288                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1289                         scm_string_to_symbol ($2));
1290         }
1291         | OVERRIDE simple_string property_path '=' scalar {
1292                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1293                                                         scm_string_to_symbol ($2), $5),
1294                                              $3));
1295         }
1296         | REVERT simple_string embedded_scm {
1297                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1298                         scm_string_to_symbol ($2), $3);
1299         }
1300         ;
1301
1302 context_def_mod:
1303         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1304         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1305
1306         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1307         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1308         | DENIES { $$ = ly_symbol2scm ("denies"); }
1309
1310         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1311         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1312         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1313         | NAME { $$ = ly_symbol2scm ("context-name"); }
1314         ;
1315
1316 context_mod:
1317         property_operation { $$ = $1; }
1318         | context_def_mod STRING {
1319                 $$ = scm_list_2 ($1, $2);
1320         }
1321         ;
1322
1323 context_prop_spec:
1324         simple_string {
1325                 if (!is_regular_identifier ($1))
1326                 {
1327                         @$.error (_("Grob name should be alphanumeric"));
1328                 }
1329
1330                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1331                         scm_string_to_symbol ($1));
1332         }
1333         | simple_string '.' simple_string {
1334                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1335                         scm_string_to_symbol ($3));
1336         }
1337         ;
1338
1339 simple_music_property_def:
1340         OVERRIDE context_prop_spec property_path '=' scalar {
1341                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1342                                 ly_symbol2scm ("OverrideProperty"),
1343                                 scm_cadr ($2),
1344                                 $5, SCM_UNDEFINED),
1345                                 $3));
1346         }
1347         | REVERT context_prop_spec embedded_scm {
1348                 $$ = scm_list_4 (scm_car ($2),
1349                         ly_symbol2scm ("RevertProperty"),
1350                         scm_cadr ($2),
1351                         $3);
1352         }
1353         | SET context_prop_spec '=' scalar {
1354                 $$ = scm_list_4 (scm_car ($2),
1355                         ly_symbol2scm ("PropertySet"),
1356                         scm_cadr ($2),
1357                         $4);
1358         }
1359         | UNSET context_prop_spec {
1360                 $$ = scm_list_3 (scm_car ($2),
1361                         ly_symbol2scm ("PropertyUnset"),
1362                         scm_cadr ($2));
1363         }
1364         ;
1365
1366 music_property_def:
1367         simple_music_property_def {
1368                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1369         }
1370         | ONCE simple_music_property_def {
1371                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1372         }
1373         ;
1374
1375 string:
1376         STRING {
1377                 $$ = $1;
1378         }
1379         | STRING_IDENTIFIER {
1380                 $$ = $1;
1381         }
1382         | string '+' string {
1383                 $$ = scm_string_append (scm_list_2 ($1, $3));
1384         }
1385         ;
1386
1387 simple_string: STRING {
1388                 $$ = $1;
1389         }
1390         | LYRICS_STRING {
1391                 $$ = $1;
1392         }
1393         | STRING_IDENTIFIER {
1394                 $$ = $1;
1395         }
1396         ;
1397
1398 scalar: string {
1399                 $$ = $1;
1400         }
1401         | LYRICS_STRING {
1402                 $$ = $1;
1403         }
1404         | bare_number {
1405                 $$ = $1;
1406         }
1407         | embedded_scm {
1408                 $$ = $1;
1409         }
1410         | full_markup {
1411                 $$ = $1;
1412         }
1413         | DIGIT {
1414                 $$ = scm_from_int ($1);
1415         }
1416         ;
1417
1418 event_chord:
1419         /* TODO: Create a special case that avoids the creation of
1420            EventChords around simple_elements that have no post_events?
1421          */
1422         simple_chord_elements post_events       {
1423                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1424
1425                 Input i;
1426                 /* why is this giving wrong start location? -ns
1427                  * i = @$; */
1428                 i.set_location (@1, @2);
1429                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1430         }
1431         | CHORD_REPETITION optional_notemode_duration post_events {
1432                 Input i;
1433                 i.set_location (@1, @3);
1434                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1435                                   PARSER->lexer_->chord_repetition_.last_chord_,
1436                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1437                                   $2, $3);
1438         }
1439         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1440                 Input i;
1441                 i.set_location (@1, @3);
1442                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2, $3);
1443         }
1444         | command_element
1445         | note_chord_element
1446         ;
1447
1448
1449 note_chord_element:
1450         chord_body optional_notemode_duration post_events
1451         {
1452                 Music *m = unsmob_music ($1);
1453                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1454                 SCM es = m->get_property ("elements");
1455                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1456
1457                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1458                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1459                 es = ly_append2 (es, postevs);
1460
1461                 m-> set_property ("elements", es);
1462                 m->set_spot (@$);
1463                 $$ = m->self_scm ();
1464         }
1465         ;
1466
1467 chord_body:
1468         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1469         {
1470                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1471         }
1472         ;
1473
1474 chord_body_elements:
1475         /* empty */             { $$ = SCM_EOL; }
1476         | chord_body_elements chord_body_element {
1477                 $$ = scm_cons ($2, $1);
1478         }
1479         ;
1480
1481 chord_body_element:
1482         pitch exclamations questions octave_check post_events
1483         {
1484                 int q = $3;
1485                 int ex = $2;
1486                 SCM check = $4;
1487                 SCM post = $5;
1488
1489                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1490                 n->set_property ("pitch", $1);
1491                 if (q % 2)
1492                         n->set_property ("cautionary", SCM_BOOL_T);
1493                 if (ex % 2 || q % 2)
1494                         n->set_property ("force-accidental", SCM_BOOL_T);
1495
1496                 if (scm_is_pair (post)) {
1497                         SCM arts = scm_reverse_x (post, SCM_EOL);
1498                         n->set_property ("articulations", arts);
1499                 }
1500                 if (scm_is_number (check))
1501                 {
1502                         int q = scm_to_int (check);
1503                         n->set_property ("absolute-octave", scm_from_int (q-1));
1504                 }
1505
1506                 $$ = n->unprotect ();
1507         }
1508         | DRUM_PITCH post_events {
1509                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1510                 n->set_property ("duration", $2);
1511                 n->set_property ("drum-type", $1);
1512
1513                 if (scm_is_pair ($2)) {
1514                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1515                         n->set_property ("articulations", arts);
1516                 }
1517                 $$ = n->unprotect ();
1518         }
1519         | music_function_chord_body {
1520                 $$ = run_music_function (PARSER, $1);
1521         }
1522         ;
1523
1524 music_function_identifier_musicless_prefix: MUSIC_FUNCTION {
1525                 SCM sig = scm_object_property (yylval.scm, ly_symbol2scm ("music-function-signature"));
1526                 if (scm_is_pair (sig) && to_boolean (scm_memq (ly_music_p_proc, scm_cdr (scm_reverse (sig)))))
1527                 {
1528                         PARSER->parser_error (@$, "Music function applied to event may not have a Music argument, except as the last argument.");
1529                 }
1530         }
1531         ;
1532
1533 music_function_chord_body:
1534         /* We could allow chord functions to have multiple music arguments,
1535            but it's more consistent with music_function_event if we
1536            prohibit it here too */
1537         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic chord_body_element {
1538                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1539         }
1540         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1541                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1542         }
1543         ;
1544
1545 music_function_event:
1546         /* Post-events can only have the last argument as music, without this
1547            restriction we get a shift/reduce conflict from e.g.
1548            c8-\partcombine c8 -. */
1549         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic post_event {
1550                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1551         }
1552         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1553                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1554         }
1555         ;
1556
1557 command_element:
1558         command_event {
1559                 $$ = $1;
1560         }
1561         | SKIP duration_length {
1562                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1563         }
1564         | E_BRACKET_OPEN {
1565                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1566                 m->set_property ("span-direction", scm_from_int (START));
1567                 $$ = m->unprotect();
1568         }
1569         | E_BRACKET_CLOSE {
1570                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1571                 m->set_property ("span-direction", scm_from_int (STOP));
1572                 $$ = m->unprotect ();
1573         }
1574         | E_BACKSLASH {
1575                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1576         }
1577         | '|'      {
1578                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1579
1580                 Music *m = unsmob_music (pipe);
1581                 if (m)
1582                 {
1583                         m = m->clone ();
1584                         m->set_spot (@$);
1585                         $$ = m->unprotect ();
1586                 }
1587                 else
1588                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1589
1590         }
1591         | PARTIAL duration_length       {
1592                 Moment m = - unsmob_duration ($2)->get_length ();
1593                 $$ = MAKE_SYNTAX ("property-operation", @$, SCM_BOOL_F, ly_symbol2scm ("Timing"), ly_symbol2scm ("PropertySet"), ly_symbol2scm ("measurePosition"), m.smobbed_copy ());
1594                 $$ = MAKE_SYNTAX ("context-specification", @$, ly_symbol2scm ("Score"), SCM_BOOL_F, $$, SCM_EOL, SCM_BOOL_F);
1595         }
1596
1597         | TIME_T fraction  {
1598                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1599
1600                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1601         }
1602         | MARK scalar {
1603                 SCM proc = ly_lily_module_constant ("make-mark-set");
1604
1605                 $$ = scm_call_1 (proc, $2);
1606         }
1607         ;
1608
1609 command_event:
1610         E_TILDE {
1611                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1612         }
1613         | MARK DEFAULT  {
1614                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1615                 $$ = m->unprotect ();
1616         }
1617         | tempo_event {
1618                 $$ = $1;
1619         }
1620         | KEY DEFAULT {
1621                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1622                 $$ = key->unprotect ();
1623         }
1624         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1625
1626                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1627                 if (scm_ilength ($3) > 0)
1628                 {
1629                         key->set_property ("pitch-alist", $3);
1630                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1631                         key->transpose (* unsmob_pitch ($2));
1632                 } else {
1633                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1634                 }
1635
1636                 $$ = key->unprotect ();
1637         }
1638         ;
1639
1640
1641 post_events:
1642         /* empty */ {
1643                 $$ = SCM_EOL;
1644         }
1645         | post_events post_event {
1646                 unsmob_music ($2)->set_spot (@2);
1647                 $$ = scm_cons ($2, $$);
1648         }
1649         ;
1650
1651 post_event:
1652         direction_less_event {
1653                 $$ = $1;
1654         }
1655         | '-' music_function_event {
1656                 $$ = run_music_function (PARSER, $2);
1657         }
1658         | HYPHEN {
1659                 if (!PARSER->lexer_->is_lyric_state ())
1660                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1661                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1662         }
1663         | EXTENDER {
1664                 if (!PARSER->lexer_->is_lyric_state ())
1665                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1666                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1667         }
1668         | script_dir direction_reqd_event {
1669                 if ($1)
1670                 {
1671                         Music *m = unsmob_music ($2);
1672                         m->set_property ("direction", scm_from_int ($1));
1673                 }
1674                 $$ = $2;
1675         }
1676         | script_dir direction_less_event {
1677                 if ($1)
1678                 {
1679                         Music *m = unsmob_music ($2);
1680                         m->set_property ("direction", scm_from_int ($1));
1681                 }
1682                 $$ = $2;
1683         }
1684         | string_number_event
1685         ;
1686
1687 string_number_event:
1688         E_UNSIGNED {
1689                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1690                 s->set_property ("string-number", scm_from_int ($1));
1691                 $$ = s->unprotect ();
1692         }
1693         ;
1694
1695 direction_less_char:
1696         '['  {
1697                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1698         }
1699         | ']'  {
1700                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1701         }
1702         | '~'  {
1703                 $$ = ly_symbol2scm ("tildeSymbol");
1704         }
1705         | '('  {
1706                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1707         }
1708         | ')'  {
1709                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1710         }
1711         | E_EXCLAMATION  {
1712                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1713         }
1714         | E_OPEN  {
1715                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1716         }
1717         | E_CLOSE  {
1718                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1719         }
1720         | E_ANGLE_CLOSE  {
1721                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1722         }
1723         | E_ANGLE_OPEN  {
1724                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1725         }
1726         ;
1727
1728 direction_less_event:
1729         direction_less_char {
1730                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1731                 Music *m = 0;
1732                 if (unsmob_music (predefd))
1733                 {
1734                         m = unsmob_music (predefd)->clone ();
1735                         m->set_spot (@$);
1736                 }
1737                 else
1738                 {
1739                         m = MY_MAKE_MUSIC ("Music", @$);
1740                 }
1741                 $$ = m->unprotect ();
1742         }
1743         | EVENT_IDENTIFIER      {
1744                 $$ = $1;
1745         }
1746         | tremolo_type  {
1747                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
1748                a->set_property ("tremolo-type", scm_from_int ($1));
1749                $$ = a->unprotect ();
1750         }
1751         ;
1752
1753 direction_reqd_event:
1754         gen_text_def {
1755                 $$ = $1;
1756         }
1757         | script_abbreviation {
1758                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1759                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
1760                 if (scm_is_string (s))
1761                         a->set_property ("articulation-type", s);
1762                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1763                 $$ = a->unprotect ();
1764         }
1765         ;
1766
1767 octave_check:
1768         /**/ { $$ = SCM_EOL; }
1769         | '='  { $$ = scm_from_int (0); }
1770         | '=' sub_quotes { $$ = scm_from_int (-$2); }
1771         | '=' sup_quotes { $$ = scm_from_int ($2); }
1772         ;
1773
1774 sup_quotes:
1775         '\'' {
1776                 $$ = 1;
1777         }
1778         | sup_quotes '\'' {
1779                 $$ ++;
1780         }
1781         ;
1782
1783 sub_quotes:
1784         ',' {
1785                 $$ = 1;
1786         }
1787         | sub_quotes ',' {
1788                 $$++;
1789         }
1790         ;
1791
1792 steno_pitch:
1793         NOTENAME_PITCH  {
1794                 $$ = $1;
1795         }
1796         | NOTENAME_PITCH sup_quotes     {
1797                 Pitch p = *unsmob_pitch ($1);
1798                 p = p.transposed (Pitch ($2,0,0));
1799                 $$ = p.smobbed_copy ();
1800         }
1801         | NOTENAME_PITCH sub_quotes      {
1802                 Pitch p =* unsmob_pitch ($1);
1803                 p = p.transposed (Pitch (-$2,0,0));
1804                 $$ = p.smobbed_copy ();
1805         }
1806         ;
1807
1808 /*
1809 ugh. duplication
1810 */
1811
1812 steno_tonic_pitch:
1813         TONICNAME_PITCH {
1814                 $$ = $1;
1815         }
1816         | TONICNAME_PITCH sup_quotes    {
1817                 Pitch p = *unsmob_pitch ($1);
1818                 p = p.transposed (Pitch ($2,0,0));
1819                 $$ = p.smobbed_copy ();
1820         }
1821         | TONICNAME_PITCH sub_quotes     {
1822                 Pitch p = *unsmob_pitch ($1);
1823
1824                 p = p.transposed (Pitch (-$2,0,0));
1825                 $$ = p.smobbed_copy ();
1826         }
1827         ;
1828
1829 pitch:
1830         steno_pitch {
1831                 $$ = $1;
1832         }
1833         ;
1834
1835 pitch_also_in_chords:
1836         pitch
1837         | steno_tonic_pitch
1838         ;
1839
1840 gen_text_def:
1841         full_markup {
1842                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1843                 t->set_property ("text", $1);
1844                 $$ = t->unprotect ();
1845         }
1846         | string {
1847                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1848                 t->set_property ("text",
1849                         make_simple_markup ($1));
1850                 $$ = t->unprotect ();
1851         }
1852         | DIGIT {
1853                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
1854                 t->set_property ("digit", scm_from_int ($1));
1855                 $$ = t->unprotect ();
1856         }
1857         ;
1858
1859 script_abbreviation:
1860         '^'             {
1861                 $$ = scm_from_locale_string ("Hat");
1862         }
1863         | '+'           {
1864                 $$ = scm_from_locale_string ("Plus");
1865         }
1866         | '-'           {
1867                 $$ = scm_from_locale_string ("Dash");
1868         }
1869         | '|'           {
1870                 $$ = scm_from_locale_string ("Bar");
1871         }
1872         | ANGLE_CLOSE   {
1873                 $$ = scm_from_locale_string ("Larger");
1874         }
1875         | '.'           {
1876                 $$ = scm_from_locale_string ("Dot");
1877         }
1878         | '_' {
1879                 $$ = scm_from_locale_string ("Underscore");
1880         }
1881         ;
1882
1883 script_dir:
1884         '_'     { $$ = DOWN; }
1885         | '^'   { $$ = UP; }
1886         | '-'   { $$ = CENTER; }
1887         ;
1888
1889
1890 absolute_pitch:
1891         steno_pitch     {
1892                 $$ = $1;
1893         }
1894         ;
1895
1896 duration_length:
1897         multiplied_duration {
1898                 $$ = $1;
1899         }
1900         ;
1901
1902 optional_notemode_duration:
1903         {
1904                 Duration dd = PARSER->default_duration_;
1905                 $$ = dd.smobbed_copy ();
1906         }
1907         | multiplied_duration   {
1908                 $$ = $1;
1909                 PARSER->default_duration_ = *unsmob_duration ($$);
1910         }
1911         ;
1912
1913 steno_duration:
1914         bare_unsigned dots              {
1915                 int len = 0;
1916                 if (!is_duration ($1))
1917                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1918                 else
1919                         len = intlog2 ($1);
1920
1921                 $$ = Duration (len, $2).smobbed_copy ();
1922         }
1923         | DURATION_IDENTIFIER dots      {
1924                 Duration *d = unsmob_duration ($1);
1925                 Duration k (d->duration_log (), d->dot_count () + $2);
1926                 *d = k;
1927                 $$ = $1;
1928         }
1929         ;
1930
1931 multiplied_duration:
1932         steno_duration {
1933                 $$ = $1;
1934         }
1935         | multiplied_duration '*' bare_unsigned {
1936                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1937         }
1938         | multiplied_duration '*' FRACTION {
1939                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1940
1941                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1942         }
1943         ;
1944
1945 fraction:
1946         FRACTION { $$ = $1; }
1947         | UNSIGNED '/' UNSIGNED {
1948                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1949         }
1950         ;
1951
1952 dots:
1953         /* empty */     {
1954                 $$ = 0;
1955         }
1956         | dots '.' {
1957                 $$ ++;
1958         }
1959         ;
1960
1961 tremolo_type:
1962         ':'     {
1963                 $$ = 0;
1964         }
1965         | ':' bare_unsigned {
1966                 if (!is_duration ($2))
1967                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1968                 $$ = $2;
1969         }
1970         ;
1971
1972 bass_number:
1973         DIGIT   {
1974                 $$ = scm_from_int ($1);
1975         }
1976         | UNSIGNED {
1977                 $$ = scm_from_int ($1);
1978         }
1979         | STRING { $$ = $1; }
1980         | full_markup { $$ = $1; }
1981         ;
1982
1983 figured_bass_alteration:
1984         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
1985         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
1986         | '!'   { $$ = scm_from_int (0); }
1987         ;
1988
1989 bass_figure:
1990         FIGURE_SPACE {
1991                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
1992                 $$ = bfr->unprotect ();
1993         }
1994         | bass_number  {
1995                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
1996                 $$ = bfr->self_scm ();
1997
1998                 if (scm_is_number ($1))
1999                         bfr->set_property ("figure", $1);
2000                 else if (Text_interface::is_markup ($1))
2001                         bfr->set_property ("text", $1);
2002
2003                 bfr->unprotect ();
2004         }
2005         | bass_figure ']' {
2006                 $$ = $1;
2007                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2008         }
2009         | bass_figure figured_bass_alteration {
2010                 Music *m = unsmob_music ($1);
2011                 if (scm_to_double ($2)) {
2012                         SCM salter = m->get_property ("alteration");
2013                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2014                         m->set_property ("alteration",
2015                                          scm_sum (alter, $2));
2016                 } else {
2017                         m->set_property ("alteration", scm_from_int (0));
2018                 }
2019         }
2020         | bass_figure figured_bass_modification  {
2021                 Music *m = unsmob_music ($1);
2022                 if ($2 == ly_symbol2scm ("plus"))
2023                         {
2024                         m->set_property ("augmented", SCM_BOOL_T);
2025                         }
2026                 else if ($2 == ly_symbol2scm ("slash"))
2027                         {
2028                         m->set_property ("diminished", SCM_BOOL_T);
2029                         }
2030                 else if ($2 == ly_symbol2scm ("exclamation"))
2031                         {
2032                         m->set_property ("no-continuation", SCM_BOOL_T);
2033                         }
2034                 else if ($2 == ly_symbol2scm ("backslash"))
2035                         {
2036                         m->set_property ("augmented-slash", SCM_BOOL_T);
2037                         }
2038         }
2039         ;
2040
2041
2042 figured_bass_modification:
2043         E_PLUS          {
2044                 $$ = ly_symbol2scm ("plus");
2045         }
2046         | E_EXCLAMATION {
2047                 $$ = ly_symbol2scm ("exclamation");
2048         }
2049         | '/'           {
2050                 $$ = ly_symbol2scm ("slash");
2051         }
2052         | E_BACKSLASH {
2053                 $$ = ly_symbol2scm ("backslash");
2054         }
2055         ;
2056
2057 br_bass_figure:
2058         bass_figure {
2059                 $$ = $1;
2060         }
2061         | '[' bass_figure {
2062                 $$ = $2;
2063                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2064         }
2065         ;
2066
2067 figure_list:
2068         /**/            {
2069                 $$ = SCM_EOL;
2070         }
2071         | figure_list br_bass_figure {
2072                 $$ = scm_cons ($2, $1);
2073         }
2074         ;
2075
2076 figure_spec:
2077         FIGURE_OPEN figure_list FIGURE_CLOSE {
2078                 $$ = scm_reverse_x ($2, SCM_EOL);
2079         }
2080         ;
2081
2082
2083 optional_rest:
2084         /**/   { $$ = 0; }
2085         | REST { $$ = 1; }
2086         ;
2087
2088 simple_element:
2089         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2090                 if (!PARSER->lexer_->is_note_state ())
2091                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2092
2093                 Music *n = 0;
2094                 if ($6)
2095                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2096                 else
2097                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2098
2099                 n->set_property ("pitch", $1);
2100                 n->set_property ("duration", $5);
2101
2102                 if (scm_is_number ($4))
2103                 {
2104                         int q = scm_to_int ($4);
2105                         n->set_property ("absolute-octave", scm_from_int (q-1));
2106                 }
2107
2108                 if ($3 % 2)
2109                         n->set_property ("cautionary", SCM_BOOL_T);
2110                 if ($2 % 2 || $3 % 2)
2111                         n->set_property ("force-accidental", SCM_BOOL_T);
2112
2113                 $$ = n->unprotect ();
2114         }
2115         | DRUM_PITCH optional_notemode_duration {
2116                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2117                 n->set_property ("duration", $2);
2118                 n->set_property ("drum-type", $1);
2119
2120                 $$ = n->unprotect ();
2121         }
2122         | RESTNAME optional_notemode_duration           {
2123                 Music *ev = 0;
2124                 if (ly_scm2string ($1) == "s") {
2125                         /* Space */
2126                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2127                   }
2128                 else {
2129                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2130
2131                     }
2132                 ev->set_property ("duration", $2);
2133                 $$ = ev->unprotect ();
2134         }
2135         | lyric_element optional_notemode_duration      {
2136                 if (!PARSER->lexer_->is_lyric_state ())
2137                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2138
2139                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2140                 levent->set_property ("text", $1);
2141                 levent->set_property ("duration",$2);
2142                 $$= levent->unprotect ();
2143         }
2144         ;
2145
2146 simple_chord_elements:
2147         simple_element  {
2148                 $$ = scm_list_1 ($1);
2149         }
2150         | new_chord {
2151                 if (!PARSER->lexer_->is_chord_state ())
2152                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2153                 $$ = $1;
2154         }
2155         | figure_spec optional_notemode_duration {
2156                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2157                 {
2158                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2159                 }
2160                 $$ = $1;
2161         }
2162         ;
2163
2164 lyric_element:
2165         lyric_markup {
2166                 $$ = $1;
2167         }
2168         | LYRICS_STRING {
2169                 $$ = $1;
2170         }
2171         ;
2172
2173 new_chord:
2174         steno_tonic_pitch optional_notemode_duration   {
2175                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2176         }
2177         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2178                 SCM its = scm_reverse_x ($4, SCM_EOL);
2179                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2180         }
2181         ;
2182
2183 chord_items:
2184         /**/ {
2185                 $$ = SCM_EOL;
2186         }
2187         | chord_items chord_item {
2188                 $$ = scm_cons ($2, $$);
2189         }
2190         ;
2191
2192 chord_separator:
2193         CHORD_COLON {
2194                 $$ = ly_symbol2scm ("chord-colon");
2195         }
2196         | CHORD_CARET {
2197                 $$ = ly_symbol2scm ("chord-caret");
2198         }
2199         | CHORD_SLASH steno_tonic_pitch {
2200                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2201         }
2202         | CHORD_BASS steno_tonic_pitch {
2203                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2204         }
2205         ;
2206
2207 chord_item:
2208         chord_separator {
2209                 $$ = $1;
2210         }
2211         | step_numbers {
2212                 $$ = scm_reverse_x ($1, SCM_EOL);
2213         }
2214         | CHORD_MODIFIER  {
2215                 $$ = $1;
2216         }
2217         ;
2218
2219 step_numbers:
2220         step_number { $$ = scm_cons ($1, SCM_EOL); }
2221         | step_numbers '.' step_number {
2222                 $$ = scm_cons ($3, $$);
2223         }
2224         ;
2225
2226 step_number:
2227         bare_unsigned {
2228                 $$ = make_chord_step ($1, 0);
2229         }
2230         | bare_unsigned '+' {
2231                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2232         }
2233         | bare_unsigned CHORD_MINUS {
2234                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2235         }
2236         ;
2237
2238 /*
2239         UTILITIES
2240
2241 TODO: should deprecate in favor of Scheme?
2242
2243  */
2244 number_expression:
2245         number_expression '+' number_term {
2246                 $$ = scm_sum ($1, $3);
2247         }
2248         | number_expression '-' number_term {
2249                 $$ = scm_difference ($1, $3);
2250         }
2251         | number_term
2252         ;
2253
2254 number_term:
2255         number_factor {
2256                 $$ = $1;
2257         }
2258         | number_factor '*' number_factor {
2259                 $$ = scm_product ($1, $3);
2260         }
2261         | number_factor '/' number_factor {
2262                 $$ = scm_divide ($1, $3);
2263         }
2264         ;
2265
2266 number_factor:
2267         '-'  number_factor { /* %prec UNARY_MINUS */
2268                 $$ = scm_difference ($2, SCM_UNDEFINED);
2269         }
2270         | bare_number
2271         ;
2272
2273
2274 bare_number:
2275         UNSIGNED        {
2276                 $$ = scm_from_int ($1);
2277         }
2278         | REAL          {
2279                 $$ = $1;
2280         }
2281         | NUMBER_IDENTIFIER             {
2282                 $$ = $1;
2283         }
2284         | REAL NUMBER_IDENTIFIER        {
2285                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2286         }
2287         | UNSIGNED NUMBER_IDENTIFIER    {
2288                 $$ = scm_from_double ($1 *scm_to_double ($2));
2289         }
2290         ;
2291
2292
2293 bare_unsigned:
2294         UNSIGNED {
2295                         $$ = $1;
2296         }
2297         | DIGIT {
2298                 $$ = $1;
2299         }
2300         ;
2301
2302 unsigned_number:
2303         bare_unsigned  { $$ = scm_from_int ($1); }
2304         | NUMBER_IDENTIFIER {
2305                 $$ = $1;
2306         }
2307         ;
2308
2309
2310 exclamations:
2311                 { $$ = 0; }
2312         | exclamations '!'      { $$ ++; }
2313         ;
2314
2315 questions:
2316                 { $$ = 0; }
2317         | questions '?' { $$ ++; }
2318         ;
2319
2320 /*
2321 This should be done more dynamically if possible.
2322 */
2323
2324 lyric_markup:
2325         LYRIC_MARKUP_IDENTIFIER {
2326                 $$ = $1;
2327         }
2328         | LYRIC_MARKUP
2329                 { PARSER->lexer_->push_markup_state (); }
2330         markup_top {
2331                 $$ = $3;
2332                 PARSER->lexer_->pop_state ();
2333         }
2334         ;
2335
2336 full_markup_list:
2337         MARKUPLINES
2338                 { PARSER->lexer_->push_markup_state (); }
2339         markup_list {
2340                 $$ = $3;
2341                 PARSER->lexer_->pop_state ();
2342         }
2343         ;
2344
2345 full_markup:
2346         MARKUP_IDENTIFIER {
2347                 $$ = $1;
2348         }
2349         | MARKUP
2350                 { PARSER->lexer_->push_markup_state (); }
2351         markup_top {
2352                 $$ = $3;
2353                 PARSER->lexer_->pop_state ();
2354         }
2355         ;
2356
2357 markup_top:
2358         markup_list {
2359                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2360         }
2361         | markup_head_1_list simple_markup      {
2362                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2363         }
2364         | simple_markup {
2365                 $$ = $1;
2366         }
2367         ;
2368
2369 markup_list:
2370         markup_composed_list {
2371                 $$ = $1;
2372         }
2373         | markup_braced_list {
2374                 $$ = $1;
2375         }
2376         | markup_command_list {
2377                 $$ = scm_list_1 ($1);
2378         }
2379         ;
2380
2381 markup_composed_list:
2382         markup_head_1_list markup_braced_list {
2383                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2384
2385         }
2386         ;
2387
2388 markup_braced_list:
2389         '{' markup_braced_list_body '}' {
2390                 $$ = scm_reverse_x ($2, SCM_EOL);
2391         }
2392         ;
2393
2394 markup_braced_list_body:
2395         /* empty */     {  $$ = SCM_EOL; }
2396         | markup_braced_list_body markup {
2397                 $$ = scm_cons ($2, $1);
2398         }
2399         | markup_braced_list_body markup_list {
2400                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2401         }
2402         ;
2403
2404 markup_command_list:
2405         MARKUP_LIST_HEAD_EMPTY  {
2406                 $$ = scm_list_1 ($1);
2407         }
2408         | MARKUP_LIST_HEAD_LIST0 markup_list    {
2409                 $$ = scm_list_2 ($1, $2);
2410         }
2411         | MARKUP_LIST_HEAD_SCM0 embedded_scm    {
2412                 $$ = scm_list_2 ($1, $2);
2413         }
2414         | MARKUP_LIST_HEAD_SCM0_LIST1 embedded_scm markup_list  {
2415                 $$ = scm_list_3 ($1, $2, $3);
2416         }
2417         | MARKUP_LIST_HEAD_SCM0_SCM1_LIST2 embedded_scm embedded_scm markup_list        {
2418                 $$ = scm_list_4 ($1, $2, $3, $4);
2419         }
2420         ;
2421
2422 markup_head_1_item:
2423         MARKUP_HEAD_MARKUP0     {
2424                 $$ = scm_list_1 ($1);
2425         }
2426         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2427                 $$ = scm_list_2 ($1, $2);
2428         }
2429         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2430                 $$ = scm_list_3 ($1, $2, $3);
2431         }
2432         ;
2433
2434 markup_head_1_list:
2435         markup_head_1_item      {
2436                 $$ = scm_list_1 ($1);
2437         }
2438         | markup_head_1_list markup_head_1_item {
2439                 $$ = scm_cons ($2, $1);
2440         }
2441         ;
2442
2443 simple_markup:
2444         STRING {
2445                 $$ = make_simple_markup ($1);
2446         }
2447         | MARKUP_IDENTIFIER {
2448                 $$ = $1;
2449         }
2450         | LYRIC_MARKUP_IDENTIFIER {
2451                 $$ = $1;
2452         }
2453         | STRING_IDENTIFIER {
2454                 $$ = $1;
2455         }
2456         | SCORE {
2457                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2458                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2459         } '{' score_body '}' {
2460                 Score * sc = $4;
2461                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2462                 sc->unprotect ();
2463                 PARSER->lexer_->pop_state ();
2464         }
2465         | MARKUP_HEAD_SCM0 embedded_scm {
2466                 $$ = scm_list_2 ($1, $2);
2467         }
2468         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2469                 $$ = scm_list_4 ($1, $2, $3, $4);
2470         }
2471         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2472                 $$ = scm_list_3 ($1, $2, $3);
2473         }
2474         | MARKUP_HEAD_SCM0_MARKUP1_MARKUP2 embedded_scm markup markup {
2475                 $$ = scm_list_4 ($1, $2, $3, $4);
2476         }
2477         | MARKUP_HEAD_SCM0_SCM1_MARKUP2_MARKUP3 embedded_scm embedded_scm markup markup {
2478                 $$ = scm_list_5 ($1, $2, $3, $4, $5);
2479         }
2480         | MARKUP_HEAD_EMPTY {
2481                 $$ = scm_list_1 ($1);
2482         }
2483         | MARKUP_HEAD_LIST0 markup_list {
2484                 $$ = scm_list_2 ($1,$2);
2485         }
2486         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2487                 $$ = scm_list_3 ($1, $2, $3);
2488         }
2489         ;
2490
2491 markup:
2492         markup_head_1_list simple_markup        {
2493                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2494                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2495         }
2496         | simple_markup {
2497                 $$ = $1;
2498         }
2499         ;
2500
2501 %%
2502
2503 void
2504 Lily_parser::set_yydebug (bool x)
2505 {
2506         yydebug = x;
2507 }
2508
2509 void
2510 Lily_parser::do_yyparse ()
2511 {
2512         yyparse ((void*)this);
2513 }
2514
2515
2516
2517
2518
2519 /*
2520
2521 It is a little strange to have this function in this file, but
2522 otherwise, we have to import music classes into the lexer.
2523
2524 */
2525 int
2526 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2527 {
2528         if (scm_is_string (sid)) {
2529                 *destination = sid;
2530                 return STRING_IDENTIFIER;
2531         } else if (unsmob_book (sid)) {
2532                 Book *book =  unsmob_book (sid)->clone ();
2533                 *destination = book->self_scm ();
2534                 book->unprotect ();
2535
2536                 return BOOK_IDENTIFIER;
2537         } else if (scm_is_number (sid)) {
2538                 *destination = sid;
2539                 return NUMBER_IDENTIFIER;
2540         } else if (unsmob_context_def (sid)) {
2541                 Context_def *def= unsmob_context_def (sid)->clone ();
2542
2543                 *destination = def->self_scm ();
2544                 def->unprotect ();
2545
2546                 return CONTEXT_DEF_IDENTIFIER;
2547         } else if (unsmob_score (sid)) {
2548                 Score *score = new Score (*unsmob_score (sid));
2549                 *destination = score->self_scm ();
2550
2551                 score->unprotect ();
2552                 return SCORE_IDENTIFIER;
2553         } else if (Music *mus = unsmob_music (sid)) {
2554                 mus = mus->clone ();
2555                 *destination = mus->self_scm ();
2556                 unsmob_music (*destination)->
2557                         set_property ("origin", make_input (last_input_));
2558
2559                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2560                         != SCM_BOOL_F;
2561
2562                 mus->unprotect ();
2563                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2564         } else if (unsmob_duration (sid)) {
2565                 *destination = unsmob_duration (sid)->smobbed_copy ();
2566                 return DURATION_IDENTIFIER;
2567         } else if (unsmob_output_def (sid)) {
2568                 Output_def *p = unsmob_output_def (sid);
2569                 p = p->clone ();
2570
2571                 *destination = p->self_scm ();
2572                 p->unprotect ();
2573                 return OUTPUT_DEF_IDENTIFIER;
2574         } else if (Text_interface::is_markup (sid)) {
2575                 *destination = sid;
2576                 if (is_lyric_state ())
2577                         return LYRIC_MARKUP_IDENTIFIER;
2578                 return MARKUP_IDENTIFIER;
2579         }
2580
2581         return -1;
2582 }
2583
2584 SCM
2585 get_next_unique_context_id ()
2586 {
2587         return scm_from_locale_string ("$uniqueContextId");
2588 }
2589
2590
2591 SCM
2592 get_next_unique_lyrics_context_id ()
2593 {
2594         static int new_context_count;
2595         char s[128];
2596         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2597         return scm_from_locale_string (s);
2598 }
2599
2600
2601 SCM
2602 run_music_function (Lily_parser *parser, SCM expr)
2603 {
2604         SCM func = scm_car (expr);
2605         Input *loc = unsmob_input (scm_cadr (expr));
2606         SCM args = scm_cddr (expr);
2607         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2608
2609         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2610
2611         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2612         {
2613                 parser->error_level_ = 1;
2614                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2615         }
2616
2617         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2618         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2619 }
2620
2621 bool
2622 is_regular_identifier (SCM id)
2623 {
2624   string str = ly_scm2string (id);
2625   char const *s = str.c_str ();
2626
2627   bool v = true;
2628 #if 0
2629   isalpha (*s);
2630   s++;
2631 #endif
2632   while (*s && v)
2633    {
2634         v = v && isalnum (*s);
2635         s++;
2636    }
2637   return v;
2638 }
2639
2640 Music *
2641 make_music_with_input (SCM name, Input where)
2642 {
2643        Music *m = make_music_by_name (name);
2644        m->set_spot (where);
2645        return m;
2646 }
2647
2648 SCM
2649 get_first_context_id (SCM type, Music *m)
2650 {
2651         SCM id = m->get_property ("context-id");
2652         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2653             && scm_is_string (m->get_property ("context-id"))
2654             && scm_c_string_length (id) > 0)
2655         {
2656                 return id;
2657         }
2658         return SCM_EOL;
2659 }
2660
2661 SCM
2662 make_simple_markup (SCM a)
2663 {
2664         return a;
2665 }
2666
2667 bool
2668 is_duration (int t)
2669 {
2670   return t && t == 1 << intlog2 (t);
2671 }
2672
2673 void
2674 set_music_properties (Music *p, SCM a)
2675 {
2676   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2677         p->set_property (scm_caar (k), scm_cdar (k));
2678 }
2679
2680
2681 SCM
2682 make_chord_step (int step, Rational alter)
2683 {
2684         if (step == 7)
2685                 alter += FLAT_ALTERATION;
2686
2687         while (step < 0)
2688                 step += 7;
2689         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2690         return m.smobbed_copy ();
2691 }
2692
2693
2694 SCM
2695 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2696 {
2697         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2698         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2699 }
2700
2701
2702 /* Todo: actually also use apply iso. call too ...  */
2703 bool
2704 ly_input_procedure_p (SCM x)
2705 {
2706         return ly_is_procedure (x)
2707                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2708 }
2709
2710 SCM
2711 make_music_relative (Pitch start, SCM music, Input loc)
2712 {
2713         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic", loc);
2714         relative->set_property ("element", music);
2715
2716         Music *m = unsmob_music (music);
2717         Pitch last = m->to_relative_octave (start);
2718         if (lily_1_8_relative)
2719                 m->set_property ("last-pitch", last.smobbed_copy ());
2720         return relative->unprotect ();
2721 }
2722
2723 int
2724 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2725 {
2726         Lily_parser *pars = (Lily_parser*) v;
2727         Lily_lexer *lex = pars->lexer_;
2728
2729         lex->lexval = (void*) s;
2730         lex->lexloc = loc;
2731         lex->prepare_for_next_token ();
2732         return lex->yylex ();
2733 }