lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13 FIXME:
  14
  15    * The rules for who is protecting what are very shady.  Uniformise
  16      this.
  17
  18    * There are too many lexical modes?
  19 */
  20
  21 #include "config.hh"
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "music.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "main.hh"
  38 #include "misc.hh"
  39 #include "lily-lexer.hh"
  40 #include "lily-parser.hh"
  41 #include "paper-book.hh"
  42 #include "output-def.hh"
  43 #include "scm-hash.hh"
  44 #include "program-option.hh"
  45 #include "score.hh"
  46 #include "text-interface.hh"
  47 #include "warn.hh"
  48 #include "music.hh"
  49
  50 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  51
  52 Music *property_op_to_music (SCM op);
  53 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  54 SCM get_next_unique_context_id ();
  55 SCM get_next_unique_lyrics_context_id ();
  56
  57 #undef _
  58 #if !HAVE_GETTEXT
  59 #define _(x) x
  60 #else
  61 #include <libintl.h>
  62 #define _(x) gettext (x)
  63 #endif
  64
  65 #define YYERROR_VERBOSE 1
  66
  67 #define YYPARSE_PARAM my_lily_parser
  68 #define YYLEX_PARAM my_lily_parser
  69 #define THIS\
  70         ((Lily_parser *) my_lily_parser)
  71
  72 #define yyerror THIS->parser_error
  73
  74 /* We use custom location type: Input objects */
  75 #define YYLTYPE Input
  76 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  77         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  78
  79
  80 /* Add symbols to the TAGS field of a music object.  */
  81
  82 void
  83 tag_music (Music *m, SCM tag, Input ip)
  84 {
  85         SCM tags = m->get_property ("tags");
  86         if (scm_is_symbol (tag))
  87                 tags = scm_cons (tag, tags);
  88         else if (ly_is_list (tag))
  89                 tags = ly_append2 (tag, tags);
  90         else
  91                 ip.warning (_ ("tag must be symbol or list of symbols"));
  92
  93         m->set_property ("tags", tags);
  94 }
  95
  96 bool
  97 is_regular_identifier (SCM id)
  98 {
  99   String str = ly_scm2string (id);
 100   char const *s = str.to_str0 ();
 101
 102   bool v = true;
 103 #if 0
 104   isalpha (*s);
 105   s++;
 106 #endif
 107   while (*s && v)
 108    {
 109         v = v && isalnum (*s);
 110         s++;
 111    }
 112   return v;
 113 }
 114
 115
 116 SCM
 117 get_first_context_id (SCM type, Music *m)
 118 {
 119         SCM id = m->get_property ("context-id");
 120         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
 121             && scm_is_string (m->get_property ("context-id"))
 122             && scm_c_string_length (id) > 0)
 123         {
 124                 return id;
 125         }
 126         return SCM_EOL;
 127 }
 128
 129 SCM
 130 make_simple_markup (SCM a)
 131 {
 132         SCM simple = ly_lily_module_constant ("simple-markup");
 133         return scm_list_2 (simple, a);
 134 }
 135
 136 bool
 137 is_duration (int t)
 138 {
 139   return t && t == 1 << intlog2 (t);
 140 }
 141
 142 void
 143 set_music_properties (Music *p, SCM a)
 144 {
 145   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 146         p->internal_set_property (scm_caar (k), scm_cdar (k));
 147 }
 148
 149 SCM
 150 make_chord_step (int step, int alter)
 151 {
 152         if (step == 7)
 153                 alter += FLAT;
 154
 155         while (step < 0)
 156                 step += 7;
 157         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 158         return m.smobbed_copy ();
 159 }
 160
 161
 162 SCM
 163 make_chord (SCM pitch, SCM dur, SCM modification_list)
 164 {
 165         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
 166         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 167         scm_gc_protect_object (ch);
 168         return ch;
 169 }
 170
 171 /* Todo: actually also use apply iso. call too ...  */
 172 bool
 173 ly_input_procedure_p (SCM x)
 174 {
 175         return ly_is_procedure (x)
 176                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
 177 }
 178
 179 Music*
 180 set_property_music (SCM sym, SCM value)
 181 {
 182         Music *p = MY_MAKE_MUSIC ("PropertySet");
 183         p->set_property ("symbol", sym);
 184         p->set_property ("value", value);
 185         return p;
 186 }
 187
 188 Music*
 189 make_music_relative (Pitch start, Music *music)
 190 {
 191         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 192         relative->set_property ("element", music->self_scm ());
 193
 194         Pitch last = music->to_relative_octave (start);
 195         if (lily_1_8_relative)
 196                 music->set_property ("last-pitch", last.smobbed_copy ());
 197         return relative;
 198 }
 199
 200 Music*
 201 make_lyric_combine_music (SCM name, Music *music)
 202 {
 203         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
 204         combine->set_property ("element", music->self_scm ());
 205         combine->set_property ("associated-context", name);
 206         return combine;
 207 }
 208
 209 %}
 210
 211 /* We use SCMs to do strings, because it saves us the trouble of
 212 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 213 of the parse stack onto the heap. */
 214
 215 %left ADDLYRICS
 216
 217 %union {
 218         Book *book;
 219         Output_def *outputdef;
 220         SCM scm;
 221         String *string;
 222         Music *music;
 223         Score *score;
 224         int i;
 225 }
 226 %{
 227
 228 int
 229 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
 230 {
 231         Lily_parser *pars = (Lily_parser*) v;
 232         Lily_lexer *lex = pars->lexer_;
 233
 234         lex->lexval = (void*) s;
 235         lex->lexloc = loc;
 236         lex->prepare_for_next_token ();
 237         return lex->yylex ();
 238 }
 239
 240
 241 %}
 242
 243 %expect 1
 244
 245 /* One shift/reduce problem
 246
 247 1.  \repeat
 248         \repeat .. \alternative
 249
 250     \repeat { \repeat .. \alternative }
 251
 252 or
 253
 254     \repeat { \repeat } \alternative
 255 */
 256
 257
 258 %pure_parser
 259 %locations
 260
 261 /* The third option is an alias that will be used to display the
 262    syntax error.  Bison CVS now correctly handles backslash escapes.
 263
 264    FIXME: Bison needs to translate some of these, eg, STRING.
 265
 266 */
 267
 268 /* Keyword tokens with plain escaped name.  */
 269 %token ACCEPTS "\\accepts"
 270 %token ADDLYRICS "\\addlyrics"
 271 %token ADDQUOTE "\\addquote"
 272 %token ALIAS "\\alias"
 273 %token ALTERNATIVE "\\alternative"
 274 %token BAR "\\bar"
 275 %token BOOK "\book"
 276 %token CHANGE "\\change"
 277 %token CHORDMODE "\\chordmode"
 278 %token CHORDS "\\chords"
 279 %token CLEF "\\clef"
 280 %token CONSISTS "\\consists"
 281 %token CONTEXT "\\context"
 282 %token DEFAULT "\\default"
 283 %token DEFAULTCHILD "\\defaultchild"
 284 %token DENIES "\\denies"
 285 %token DESCRIPTION "\\description"
 286 %token DRUMMODE "\\drummode"
 287 %token DRUMS "\\drums"
 288 %token FIGUREMODE "\\figuremode"
 289 %token FIGURES "\\figures"
 290 %token GROBDESCRIPTIONS "\\grobdescriptions"
 291 %token HEADER "\\header"
 292 %token INVALID "\\invalid"
 293 %token KEY "\\key"
 294 %token LAYOUT "\\layout"
 295 %token LYRICMODE "\\lyricmode"
 296 %token LYRICS "\\lyrics"
 297 %token LYRICSTO "\\lyricsto"
 298 %token MARK "\\mark"
 299 %token MARKUP "\\markup"
 300 %token MIDI "\\midi"
 301 %token NAME "\\name"
 302 %token NOTEMODE "\\notemode"
 303 %token OBJECTID "\\objectid"
 304 %token OCTAVE "\\octave"
 305 %token ONCE "\\once"
 306 %token OVERRIDE "\\override"
 307 %token PAPER "\\paper"
 308 %token PARTIAL "\\partial"
 309 %token RELATIVE "\\relative"
 310 %token REMOVE "\\remove"
 311 %token REPEAT "\\repeat"
 312 %token REST "\\rest"
 313 %token REVERT "\\revert"
 314 %token SCORE "\\score"
 315 %token SEQUENTIAL "\\sequential"
 316 %token SET "\\set"
 317 %token SIMULTANEOUS "\\simultaneous"
 318 %token SKIP "\\skip"
 319 %token TAG "\\tag"
 320 %token TEMPO "\\tempo"
 321 %token TIMES "\\times"
 322 %token TRANSPOSE "\\transpose"
 323 %token TRANSPOSITION "\\transposition"
 324 %token TYPE "\\type"
 325 %token UNSET "\\unset"
 326 %token WITH "\\with"
 327
 328 /* Keyword token exceptions.  */
 329 %token TIME_T "\\time"
 330 %token NEWCONTEXT "\\new"
 331
 332
 333 /* Other string tokens.  */
 334
 335 %token CHORD_BASS "/+"
 336 %token CHORD_CARET "^"
 337 %token CHORD_COLON ":"
 338 %token CHORD_MINUS "-"
 339 %token CHORD_SLASH "/"
 340 %token DOUBLE_ANGLE_CLOSE ">>"
 341 %token DOUBLE_ANGLE_OPEN "<<"
 342 %token E_BACKSLASH "\\"
 343 %token E_ANGLE_CLOSE "\\>"
 344 %token E_CHAR "\\C[haracter]"
 345 %token E_CLOSE "\\)"
 346 %token E_EXCLAMATION "\\!"
 347 %token E_BRACKET_OPEN "\\["
 348 %token E_OPEN "\\("
 349 %token E_BRACKET_CLOSE "\\]"
 350 %token E_ANGLE_OPEN "\\<"
 351 %token E_TILDE "\\~"
 352 %token EXTENDER "__"
 353 /*  These used at all?
 354   %token FIGURE_BRACKET_CLOSE
 355   %token FIGURE_BRACKET_OPEN
 356
 357 parser.yy:348.8-25: warning: symbol `"\\>"' used more than once as a literal string
 358 parser.yy:352.8-24: warning: symbol `"\\<"' used more than once as a literal string
 359
 360 */
 361 %token FIGURE_CLOSE /* "\\>" */
 362 %token FIGURE_OPEN /* "\\<" */
 363 %token FIGURE_SPACE "_"
 364 %token HYPHEN "--"
 365
 366 %token CHORDMODIFIERS
 367 %token COMMANDSPANREQUEST
 368 %token LYRIC_MARKUP
 369 %token MULTI_MEASURE_REST
 370 %token SCM_T
 371
 372
 373 %token <i> DIGIT
 374 %token <i> E_UNSIGNED
 375 %token <i> UNSIGNED
 376
 377 %token <id> IDENTIFIER
 378
 379 %token <scm> CHORDMODIFIER_PITCH
 380 %token <scm> CHORD_MODIFIER
 381 %token <scm> CONTEXT_DEF_IDENTIFIER
 382 %token <scm> DRUM_PITCH
 383 %token <scm> DURATION_IDENTIFIER
 384 %token <scm> EVENT_IDENTIFIER
 385 %token <scm> FRACTION
 386 %token <scm> LYRICS_STRING
 387 %token <scm> LYRIC_MARKUP_IDENTIFIER
 388 %token <scm> MARKUP_HEAD_EMPTY
 389 %token <scm> MARKUP_HEAD_LIST0
 390 %token <scm> MARKUP_HEAD_MARKUP0
 391 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 392 %token <scm> MARKUP_HEAD_SCM0
 393 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 394 %token <scm> MARKUP_HEAD_SCM0_SCM1
 395 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 396 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 397 %token <scm> MARKUP_IDENTIFIER
 398 %token <scm> MUSIC_FUNCTION
 399 %token <scm> MUSIC_FUNCTION_MARKUP
 400 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 401 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 402 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 403 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 404 %token <scm> MUSIC_FUNCTION_MUSIC
 405 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 406 %token <scm> MUSIC_FUNCTION_SCM
 407 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 408 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 409 %token <scm> MUSIC_FUNCTION_SCM_SCM
 410 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 411 %token <scm> MUSIC_IDENTIFIER
 412 %token <scm> NOTENAME_PITCH
 413 %token <scm> NUMBER_IDENTIFIER
 414 %token <scm> OUTPUT_DEF_IDENTIFIER
 415 %token <scm> REAL
 416 %token <scm> RESTNAME
 417 %token <scm> SCM_IDENTIFIER
 418 %token <scm> SCM_T
 419 %token <scm> SCORE_IDENTIFIER
 420 %token <scm> STRING
 421 %token <scm> STRING_IDENTIFIER
 422 %token <scm> TONICNAME_PITCH
 423
 424
 425 %type <book> book_block
 426 %type <book> book_body
 427
 428 %type <i> bare_unsigned
 429 %type <i> bass_mod
 430 %type <i> dots
 431 %type <i> exclamations
 432 %type <i> optional_rest
 433 %type <i> questions
 434 %type <i> script_dir
 435 %type <i> sub_quotes
 436 %type <i> sup_quotes
 437 %type <i> tremolo_type
 438
 439 %type <music> Composite_music
 440 %type <music> Generic_prefix_music
 441 %type <music> Grouped_music_list
 442 %type <music> Music
 443 %type <music> Prefix_composite_music
 444 %type <music> Repeated_music
 445 %type <music> Sequential_music
 446 %type <music> Simple_music
 447 %type <music> Simultaneous_music
 448 %type <music> chord_body
 449 %type <music> chord_body_element
 450 %type <music> command_element
 451 %type <music> command_req
 452 %type <music> context_change
 453 %type <music> direction_less_event
 454 %type <music> direction_reqd_event
 455 %type <music> event_chord
 456 %type <music> gen_text_def
 457 %type <music> music_property_def
 458 %type <music> note_chord_element
 459 %type <music> post_event
 460 %type <music> re_rhythmed_music
 461 %type <music> relative_music
 462 %type <music> simple_element
 463 %type <music> string_number_event
 464 %type <music> tagged_post_event
 465 %type <music> tempo_event
 466 %type <music> toplevel_music
 467
 468 %type <outputdef> output_def_body
 469 %type <outputdef> output_def_head
 470 %type <outputdef> output_def
 471 %type <outputdef> paper_block
 472
 473 %type <scm> Alternative_music
 474 %type <scm> Generic_prefix_music_scm
 475 %type <scm> Music_list
 476 %type <scm> absolute_pitch
 477 %type <scm> assignment_id
 478 %type <scm> bare_number
 479 %type <scm> bass_figure
 480 %type <scm> bass_number
 481 %type <scm> br_bass_figure
 482 %type <scm> chord_body_elements
 483 %type <scm> chord_item
 484 %type <scm> chord_items
 485 %type <scm> chord_separator
 486 %type <scm> context_def_mod
 487 %type <scm> context_def_spec_block
 488 %type <scm> context_def_spec_body
 489 %type <scm> context_mod
 490 %type <scm> context_mod_list
 491 %type <scm> context_prop_spec
 492 %type <scm> direction_less_char
 493 %type <scm> duration_length
 494 %type <scm> embedded_scm
 495 %type <scm> figure_list
 496 %type <scm> figure_spec
 497 %type <scm> fraction
 498 %type <scm> full_markup
 499 %type <scm> identifier_init
 500 %type <scm> lilypond_header
 501 %type <scm> lilypond_header_body
 502 %type <scm> lyric_element
 503 %type <scm> lyric_markup
 504 %type <scm> markup
 505 %type <scm> markup_braced_list
 506 %type <scm> markup_braced_list_body
 507 %type <scm> markup_composed_list
 508 %type <scm> markup_head_1_item
 509 %type <scm> markup_head_1_list
 510 %type <scm> markup_list
 511 %type <scm> markup_top
 512 %type <scm> mode_changing_head
 513 %type <scm> mode_changing_head_with_context
 514 %type <scm> multiplied_duration
 515 %type <scm> new_chord
 516 %type <scm> new_lyrics
 517 %type <scm> number_expression
 518 %type <scm> number_factor
 519 %type <scm> number_term
 520 %type <scm> object_id_setting
 521 %type <scm> octave_check
 522 %type <scm> optional_context_mod
 523 %type <scm> optional_notemode_duration
 524 %type <scm> pitch
 525 %type <scm> pitch_also_in_chords
 526 %type <scm> post_events
 527 %type <scm> property_operation
 528 %type <scm> scalar
 529 %type <scm> script_abbreviation
 530 %type <scm> simple_markup
 531 %type <scm> simple_string
 532 %type <scm> steno_duration
 533 %type <scm> steno_pitch
 534 %type <scm> steno_tonic_pitch
 535 %type <scm> step_number
 536 %type <scm> step_numbers
 537 %type <scm> string
 538
 539 %type <score> score_block
 540 %type <score> score_body
 541
 542
 543 %left '-' '+'
 544
 545 /* We don't assign precedence to / and *, because we might need varied
 546 prec levels in different prods */
 547
 548 %left UNARY_MINUS
 549
 550 %%
 551
 552 lilypond:       /* empty */
 553         | lilypond toplevel_expression {
 554         }
 555         | lilypond assignment {
 556         }
 557         | lilypond error {
 558                 THIS->error_level_ = 1;
 559         }
 560         | lilypond INVALID      {
 561                 THIS->error_level_ = 1;
 562         }
 563         ;
 564
 565
 566 object_id_setting:
 567         OBJECTID STRING { $$ = $2; }
 568         ;
 569
 570 toplevel_expression:
 571         lilypond_header {
 572                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 573         }
 574         | add_quote {
 575
 576         }
 577         | book_block {
 578                 Book *book = $1;
 579                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 580                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 581                 scm_gc_unprotect_object (book->self_scm ());
 582         }
 583         | score_block {
 584                 Score *score = $1;
 585
 586                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 587                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 588                 scm_gc_unprotect_object (score->self_scm ());
 589         }
 590         | toplevel_music {
 591                 Music *music = $1;
 592                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 593                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 594                 scm_gc_unprotect_object (music->self_scm ());
 595         }
 596         | full_markup {
 597                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 598                 scm_call_2 (proc, THIS->self_scm (), $1);
 599         }
 600         | output_def {
 601                 SCM id = SCM_EOL;
 602                 Output_def * od = $1;
 603
 604                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 605                         id = ly_symbol2scm ("$defaultpaper");
 606                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 607                         id = ly_symbol2scm ("$defaultmidi");
 608                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 609                         id = ly_symbol2scm ("$defaultlayout");
 610
 611                 THIS->lexer_->set_identifier (id, od->self_scm ());
 612                 scm_gc_unprotect_object (od->self_scm ());
 613         }
 614         ;
 615
 616 toplevel_music:
 617         Composite_music {
 618         }
 619         ;
 620
 621 embedded_scm:
 622         SCM_T
 623         | SCM_IDENTIFIER
 624         ;
 625
 626
 627 lilypond_header_body:
 628         {
 629                 $$ = ly_make_anonymous_module (be_safe_global);
 630                 THIS->lexer_->add_scope ($$);
 631         }
 632         | lilypond_header_body assignment  {
 633
 634         }
 635         ;
 636
 637 lilypond_header:
 638         HEADER '{' lilypond_header_body '}'     {
 639                 $$ = THIS->lexer_->remove_scope ();
 640         }
 641         ;
 642
 643 /*
 644         DECLARATIONS
 645 */
 646 assignment_id:
 647         STRING          { $$ = $1; }
 648         | LYRICS_STRING { $$ = $1; }
 649         ;
 650
 651 assignment:
 652         assignment_id '=' identifier_init  {
 653                 if (! is_regular_identifier ($1))
 654                 {
 655                         @1.warning (_ ("identifier should have alphabetic characters only"));
 656                 }
 657
 658                 THIS->lexer_->set_identifier ($1, $3);
 659
 660 /*
 661  TODO: devise standard for protection in parser.
 662
 663   The parser stack lives on the C-stack, which means that
 664 all objects can be unprotected as soon as they're here.
 665
 666 */
 667         }
 668         | embedded_scm { }
 669         ;
 670
 671
 672 identifier_init:
 673         score_block {
 674                 $$ = $1->self_scm ();
 675                 scm_gc_unprotect_object ($$);
 676         }
 677         | output_def {
 678                 $$ = $1->self_scm ();
 679                 scm_gc_unprotect_object ($$);
 680         }
 681         | context_def_spec_block {
 682                 $$ = $1;
 683         }
 684         | Music  {
 685                 $$ = $1->self_scm ();
 686                 scm_gc_unprotect_object ($$);
 687         }
 688         | post_event {
 689                 $$ = $1->self_scm ();
 690                 scm_gc_unprotect_object ($$);
 691         }
 692         | number_expression {
 693                 $$ = $1;
 694         }
 695         | string {
 696                 $$ = $1;
 697         }
 698         | embedded_scm {
 699                 $$ = $1;
 700         }
 701         | full_markup {
 702                 $$ = $1;
 703         }
 704         | DIGIT {
 705                 $$ = scm_int2num ($1);
 706         }
 707         ;
 708
 709 context_def_spec_block:
 710         CONTEXT '{' context_def_spec_body '}'
 711                 {
 712                 $$ = $3;
 713         }
 714         ;
 715
 716 context_def_spec_body:
 717         /**/ {
 718                 $$ = Context_def::make_scm ();
 719                 unsmob_context_def ($$)->set_spot (@$);
 720         }
 721         | CONTEXT_DEF_IDENTIFIER {
 722                 $$ = $1;
 723                 unsmob_context_def ($$)->set_spot (@$);
 724         }
 725         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 726                 Context_def*td = unsmob_context_def ($$);
 727
 728                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 729                         SCM tag = scm_caar (p);
 730
 731                         /* TODO: should make new tag "grob-definition" ? */
 732                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 733                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 734                 }
 735         }
 736         | context_def_spec_body context_mod {
 737                 unsmob_context_def ($$)->add_context_mod ($2);
 738         }
 739         ;
 740
 741
 742
 743 book_block:
 744         BOOK '{' book_body '}'  {
 745                 $$ = $3;
 746         }
 747         ;
 748
 749 /* FIXME:
 750    * Use 'handlers' like for toplevel-* stuff?
 751    * grok \layout and \midi?  */
 752 book_body:
 753         {
 754                 $$ = new Book;
 755                 $$->set_spot (@$);
 756                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 757                 scm_gc_unprotect_object ($$->paper_->self_scm ());
 758                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 759         }
 760         | book_body paper_block {
 761                 $$->paper_ = $2;
 762                 scm_gc_unprotect_object ($2->self_scm ());
 763         }
 764         | book_body score_block {
 765                 SCM s = $2->self_scm ();
 766                 $$->add_score (s);
 767                 scm_gc_unprotect_object (s);
 768         }
 769         | book_body full_markup {
 770                 $$->add_score ($2);
 771         }
 772         | book_body lilypond_header {
 773                 $$->header_ = $2;
 774         }
 775         | book_body error {
 776                 $$->paper_ = 0;
 777                 $$->scores_ = SCM_EOL;
 778         }
 779         | book_body object_id_setting {
 780                 $$->user_key_ = ly_scm2string ($2);
 781         }
 782         ;
 783
 784 score_block:
 785         SCORE '{' score_body '}'        {
 786                 $$ = $3;
 787         }
 788         ;
 789
 790 score_body:
 791         Music {
 792                 SCM m = $1->self_scm ();
 793                 scm_gc_unprotect_object (m);
 794                 SCM scorify = ly_lily_module_constant ("scorify-music");
 795                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 796
 797                 // pass ownernship to C++ again.
 798                 scm_gc_protect_object (score);
 799                 $$ = unsmob_score (score);
 800                 $$->set_spot (@$);
 801         }
 802         | SCORE_IDENTIFIER {
 803                 $$ = unsmob_score ($1);
 804                 $$->set_spot (@$);
 805         }
 806         | score_body object_id_setting {
 807                 $$->user_key_ = ly_scm2string ($2);
 808         }
 809         | score_body lilypond_header    {
 810                 $$->header_ = $2;
 811         }
 812         | score_body output_def {
 813                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 814                 {
 815                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 816
 817                 }
 818                 else
 819                 {
 820                         $$->defs_.push ($2);
 821                 }
 822                 scm_gc_unprotect_object ($2->self_scm ());
 823         }
 824         | score_body error {
 825                 $$->error_found_ = true;
 826         }
 827         ;
 828
 829
 830 /*
 831         OUTPUT DEF
 832 */
 833
 834 paper_block:
 835         output_def {
 836                 $$ = $1;
 837                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 838                 {
 839                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 840                         $$ = get_paper (THIS);
 841                 }
 842         }
 843         ;
 844
 845
 846 output_def:
 847         output_def_body '}' {
 848                 $$ = $1;
 849
 850                 THIS->lexer_->remove_scope ();
 851                 THIS->lexer_->pop_state ();
 852         }
 853         ;
 854
 855 output_def_head:
 856         PAPER {
 857                 $$ = get_paper (THIS);
 858                 $$->input_origin_ = @$;
 859                 THIS->lexer_->add_scope ($$->scope_);
 860         }
 861         | MIDI    {
 862                 Output_def *p = get_midi (THIS);
 863                 $$ = p;
 864                 THIS->lexer_->add_scope (p->scope_);
 865         }
 866         | LAYOUT        {
 867                 Output_def *p = get_layout (THIS);
 868
 869                 THIS->lexer_->add_scope (p->scope_);
 870                 $$ = p;
 871         }
 872         ;
 873
 874
 875 output_def_body:
 876         output_def_head '{' {
 877                 $$ = $1;
 878                 $$->input_origin_.set_spot (@$);
 879                 THIS->lexer_->push_initial_state ();
 880         }
 881         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 882                 scm_gc_unprotect_object ($1->self_scm ());
 883                 Output_def *o = unsmob_output_def ($3);
 884                 o->input_origin_.set_spot (@$);
 885                 $$ = o;
 886                 THIS->lexer_->remove_scope ();
 887                 THIS->lexer_->add_scope (o->scope_);
 888                 THIS->lexer_->push_initial_state ();
 889         }
 890         | output_def_body assignment  {
 891
 892         }
 893         | output_def_body context_def_spec_block        {
 894                 assign_context_def ($$, $2);
 895         }
 896         | output_def_body tempo_event  {
 897                 /*
 898                         junk this ? there already is tempo stuff in
 899                         music.
 900                 */
 901                 int m = scm_to_int ($2->get_property ("metronome-count"));
 902                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 903                 set_tempo ($$, d->get_length (), m);
 904                 scm_gc_unprotect_object ($2->self_scm ());
 905         }
 906         | output_def_body error {
 907
 908         }
 909         ;
 910
 911 tempo_event:
 912         TEMPO steno_duration '=' bare_unsigned  {
 913                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 914                 $$->set_property ("tempo-unit", $2);
 915                 $$->set_property ("metronome-count", scm_int2num ( $4));
 916         }
 917         ;
 918
 919 /*
 920 The representation of a  list is the
 921
 922   (LIST . LAST-CONS)
 923
 924  to have efficient append.  */
 925
 926 Music_list:
 927         /* empty */ {
 928                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 929         }
 930         | Music_list Music {
 931                 SCM s = $$;
 932                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 933                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 934
 935                 if (scm_is_pair (scm_cdr (s)))
 936                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 937                 else
 938                         scm_set_car_x (s, c); /* set first cons */
 939                 scm_set_cdr_x (s, c);  /* remember last cell */
 940         }
 941         | Music_list embedded_scm {
 942
 943         }
 944         | Music_list error {
 945                 Music * m = MY_MAKE_MUSIC("Music");
 946                 // ugh. code dup
 947                 m->set_property ("error-found", SCM_BOOL_T);
 948                 SCM s = $$;
 949                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 950                 scm_gc_unprotect_object (m->self_scm ()); /* UGH */
 951
 952                 if (scm_is_pair (scm_cdr (s)))
 953                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 954                 else
 955                         scm_set_car_x (s, c); /* set first cons */
 956                 scm_set_cdr_x (s, c);  /* remember last cell */
 957         }
 958         ;
 959
 960 Music:
 961         Simple_music
 962         | Composite_music
 963         ;
 964
 965 Alternative_music:
 966         /* empty */ {
 967                 $$ = SCM_EOL;
 968         }
 969         | ALTERNATIVE '{' Music_list '}' {
 970                 $$ = $3;
 971         }
 972         ;
 973
 974
 975 Repeated_music:
 976         REPEAT simple_string bare_unsigned Music Alternative_music
 977         {
 978                 Music *beg = $4;
 979                 int times = $3;
 980                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 981                 if (times < scm_ilength (alts)) {
 982                   unsmob_music (scm_car (alts))
 983                     ->origin ()->warning (
 984                     _ ("more alternatives than repeats"));
 985                     warning ("junking excess alternatives");
 986                   alts = ly_truncate_list (times, alts);
 987                 }
 988
 989
 990                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 991
 992                 SCM mus = scm_call_1 (proc, $2);
 993                 scm_gc_protect_object (mus); // UGH.
 994                 Music *r = unsmob_music (mus);
 995                 if (beg)
 996                         {
 997                         r-> set_property ("element", beg->self_scm ());
 998                         scm_gc_unprotect_object (beg->self_scm ());
 999                         }
1000                 r->set_property ("repeat-count", scm_int2num (max (times, 1)));
1001
1002                 r-> set_property ("elements",alts);
1003                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
1004                         /*
1005                         TODO: move this code to Scheme.
1006                         */
1007
1008                         /* we cannot get durations and other stuff
1009                            correct down the line,
1010                            so we have to add to the duration log here. */
1011                         SCM func = ly_lily_module_constant ("shift-duration-log");
1012
1013                         int dots = ($3 % 3) ? 0 : 1;
1014                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
1015
1016
1017                         if ($4->is_mus_type ("sequential-music"))
1018                         {
1019                                 int list_len = scm_ilength ($4->get_property ("elements"));
1020                                 if (list_len != 2)
1021                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
1022                                 shift -= 1;
1023                                 r->compress (Moment (Rational (1, list_len)));
1024                         }
1025                         scm_call_3 (func, r->self_scm (), scm_int2num (shift), scm_int2num (dots));
1026
1027                 }
1028                 r->set_spot (*$4->origin ());
1029
1030                 $$ = r;
1031         }
1032         ;
1033
1034 Sequential_music:
1035         SEQUENTIAL '{' Music_list '}'           {
1036                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
1037                 $$->set_property ("elements", scm_car ($3));
1038                 $$->set_spot (@$);
1039         }
1040         | '{' Music_list '}'            {
1041                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
1042                 $$->set_property ("elements", scm_car ($2));
1043                 $$->set_spot (@$);
1044         }
1045         ;
1046
1047 Simultaneous_music:
1048         SIMULTANEOUS '{' Music_list '}'{
1049                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
1050                 $$->set_property ("elements", scm_car ($3));
1051                 $$->set_spot (@$);
1052
1053         }
1054         | simul_open Music_list simul_close     {
1055                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
1056                 $$->set_property ("elements", scm_car ($2));
1057                 $$->set_spot (@$);
1058         }
1059         ;
1060
1061 Simple_music:
1062         event_chord             { $$ = $1; }
1063         | MUSIC_IDENTIFIER {
1064                 $$ = unsmob_music ($1);
1065         }
1066         | music_property_def
1067         | context_change
1068         ;
1069
1070
1071 optional_context_mod:
1072         /**/ { $$ = SCM_EOL; }
1073         | WITH { THIS->lexer_->push_initial_state (); }
1074         '{' context_mod_list '}'
1075         {
1076                 THIS->lexer_->pop_state ();
1077                 $$ = $4;
1078         }
1079         ;
1080
1081 context_mod_list:
1082         /* */  { $$ = SCM_EOL; }
1083         | context_mod_list context_mod  {
1084                  $$ = scm_cons ($2, $1);
1085         }
1086         ;
1087
1088
1089 Composite_music:
1090         Prefix_composite_music { $$ = $1; }
1091         | Grouped_music_list { $$ = $1; }
1092         ;
1093
1094 Grouped_music_list:
1095         Simultaneous_music              { $$ = $1; }
1096         | Sequential_music              { $$ = $1; }
1097         ;
1098
1099 Generic_prefix_music_scm:
1100         MUSIC_FUNCTION {
1101                 $$ = scm_list_2 ($1, make_input (@$));
1102         }
1103         | MUSIC_FUNCTION_SCM embedded_scm {
1104                 $$ = scm_list_3 ($1, make_input (@$), $2);
1105         }
1106         | MUSIC_FUNCTION_MARKUP full_markup {
1107                 $$ = scm_list_3 ($1, make_input (@$), $2);
1108         }
1109         | MUSIC_FUNCTION_MUSIC Music {
1110                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1111                 scm_gc_unprotect_object ($2->self_scm ());
1112         }
1113         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm Music {
1114                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1115                 scm_gc_unprotect_object ($3->self_scm ());
1116         }
1117         | MUSIC_FUNCTION_SCM_SCM embedded_scm embedded_scm {
1118                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1119         }
1120         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm Music {
1121                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1122         }
1123         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1124                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1125                 scm_gc_unprotect_object ($3->self_scm ());
1126         }
1127         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1128                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1129         }
1130         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1131                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1132                 scm_gc_unprotect_object ($2->self_scm ());
1133                 scm_gc_unprotect_object ($3->self_scm ());
1134         }
1135         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC embedded_scm Music Music {
1136                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1137                 scm_gc_unprotect_object ($4->self_scm ());
1138                 scm_gc_unprotect_object ($3->self_scm ());
1139         }
1140         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1141                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1142                 scm_gc_unprotect_object ($3->self_scm ());
1143                 scm_gc_unprotect_object ($4->self_scm ());
1144         }
1145         ;
1146
1147 Generic_prefix_music:
1148         Generic_prefix_music_scm {
1149                 SCM func = scm_car ($1);
1150                 Input *loc = unsmob_input (scm_cadr ($1));
1151                 SCM args = scm_cddr ($1);
1152                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1153
1154                 SCM type_check_proc = ly_lily_module_constant ("type-check-list");
1155                 bool ok  = true;
1156
1157                 if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr ($1), sig, args)))
1158                 {
1159                         THIS->error_level_ = 1;
1160                         ok = false;
1161                 }
1162
1163                 SCM m = SCM_EOL;
1164                 if (ok)
1165                         m = scm_apply_0 (func, scm_cons (THIS->self_scm(),
1166                                                          scm_cdr ($1)));
1167
1168                 if (unsmob_music (m))
1169                         {
1170                         $$ = unsmob_music (m);
1171                         scm_gc_protect_object (m);
1172                         }
1173                 else
1174                         {
1175                         if (ok)
1176                                 loc->error (_ ("music head function must return Music object"));
1177                         $$ = MY_MAKE_MUSIC ("Music");
1178                         }
1179                 $$->set_spot (*loc);
1180         }
1181         ;
1182
1183
1184 Prefix_composite_music:
1185         Generic_prefix_music {
1186                 $$ = $1;
1187         }
1188         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1189                 $$ = context_spec_music ($2, $4, $6, $5);
1190
1191         }
1192         | CONTEXT simple_string optional_context_mod Music {
1193                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1194         }
1195         | NEWCONTEXT simple_string optional_context_mod Music {
1196                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1197                         $3);
1198         }
1199
1200         | TIMES fraction Music
1201
1202         {
1203                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1204                 Music *mp = $3;
1205
1206                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1207                 $$->set_spot (@$);
1208
1209                 $$->set_property ("element", mp->self_scm ());
1210                 scm_gc_unprotect_object (mp->self_scm ());
1211                 $$->set_property ("numerator", scm_int2num (n));
1212                 $$->set_property ("denominator", scm_int2num (d));
1213                 $$->compress (Moment (Rational (n,d)));
1214
1215         }
1216         | Repeated_music                { $$ = $1; }
1217         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1218                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1219                 Music *p = $4;
1220                 Pitch from = *unsmob_pitch ($2);
1221                 Pitch to = *unsmob_pitch ($3);
1222
1223                 p->transpose (pitch_interval (from, to));
1224                 $$->set_property ("element", p->self_scm ());
1225                 scm_gc_unprotect_object (p->self_scm ());
1226         }
1227         | mode_changing_head Grouped_music_list {
1228                 if ($1 == ly_symbol2scm ("chords"))
1229                 {
1230                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1231                   chm->set_property ("element", $2->self_scm ());
1232                   $$ = chm;
1233                   scm_gc_unprotect_object ($2->self_scm ());
1234                 }
1235                 else
1236                 {
1237                   $$ = $2;
1238                 }
1239                 THIS->lexer_->pop_state ();
1240         }
1241         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1242                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1243                                          $3, $2);
1244                 if ($1 == ly_symbol2scm ("ChordNames"))
1245                 {
1246                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1247                   chm->set_property ("element", $$->self_scm ());
1248                   scm_gc_unprotect_object ($$->self_scm ());
1249                   $$ = chm;
1250                 }
1251                 THIS->lexer_->pop_state ();
1252         }
1253         | relative_music        { $$ = $1; }
1254         | re_rhythmed_music     { $$ = $1; }
1255         | TAG embedded_scm Music {
1256                 tag_music ($3, $2, @$);
1257                 $$ = $3;
1258         }
1259         ;
1260
1261 mode_changing_head:
1262         NOTEMODE {
1263                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1264                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1265
1266                 $$ = ly_symbol2scm ("notes");
1267         }
1268         | DRUMMODE
1269                 {
1270                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1271                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1272
1273                 $$ = ly_symbol2scm ("drums");
1274         }
1275         | FIGUREMODE {
1276                 THIS->lexer_->push_figuredbass_state ();
1277
1278                 $$ = ly_symbol2scm ("figures");
1279         }
1280         | CHORDMODE {
1281                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1282                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1283                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1284                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1285                 $$ = ly_symbol2scm ("chords");
1286
1287         }
1288         | LYRICMODE
1289                 { THIS->lexer_->push_lyric_state ();
1290                 $$ = ly_symbol2scm ("lyrics");
1291         }
1292         ;
1293
1294 mode_changing_head_with_context:
1295         DRUMS {
1296                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1297                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1298
1299                 $$ = ly_symbol2scm ("DrumStaff");
1300         }
1301         | FIGURES {
1302                 THIS->lexer_->push_figuredbass_state ();
1303
1304                 $$ = ly_symbol2scm ("FiguredBass");
1305         }
1306         | CHORDS {
1307                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1308                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1309                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1310                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1311                 $$ = ly_symbol2scm ("ChordNames");
1312         }
1313         | LYRICS
1314                 { THIS->lexer_->push_lyric_state ();
1315                 $$ = ly_symbol2scm ("Lyrics");
1316         }
1317         ;
1318
1319
1320 relative_music:
1321         RELATIVE absolute_pitch Music {
1322                 Music *m = $3;
1323                 Pitch start = *unsmob_pitch ($2);
1324                 $$ = make_music_relative (start, m);
1325                 scm_gc_unprotect_object (m->self_scm ());
1326         }
1327         | RELATIVE Composite_music {
1328                 Music *m = $2;
1329
1330                 Pitch middle_c (0, 0, 0);
1331                 $$ = make_music_relative (middle_c, m);
1332                 scm_gc_unprotect_object (m->self_scm ());
1333         }
1334         ;
1335
1336 new_lyrics:
1337         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1338         /*cont */
1339         Grouped_music_list {
1340         /* Can also use Music at the expensive of two S/Rs similar to
1341            \repeat \alternative */
1342                 THIS->lexer_->pop_state ();
1343
1344                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1345         }
1346         | new_lyrics ADDLYRICS {
1347                 THIS->lexer_->push_lyric_state ();
1348         } Grouped_music_list {
1349                 THIS->lexer_->pop_state ();
1350                 $$ = scm_cons ($4->self_scm (), $1);
1351         }
1352         ;
1353
1354 re_rhythmed_music:
1355         Grouped_music_list new_lyrics {
1356                 Music * voice = $1;
1357                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1358                 if (!scm_is_string (name))
1359                 {
1360                         name = get_next_unique_lyrics_context_id ();
1361                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1362                                                     name,
1363                                                     voice, SCM_EOL);
1364                 }
1365
1366                 SCM context = scm_makfrom0str ("Lyrics");
1367                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1368
1369                 SCM lst = SCM_EOL;
1370                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1371                 {
1372                         Music *music = unsmob_music (scm_car (s));
1373                         Music *com = make_lyric_combine_music (name, music);
1374                         Music *csm = context_spec_music (context,
1375                                 get_next_unique_context_id (), com, SCM_EOL);
1376                         lst = scm_cons (csm->self_scm (), lst);
1377                 }
1378                 all->set_property ("elements", scm_cons (voice->self_scm (),
1379                         lst));
1380                 $$ = all;
1381                 scm_gc_unprotect_object (voice->self_scm ());
1382         }
1383         | LYRICSTO simple_string {
1384                 THIS->lexer_->push_lyric_state ();
1385         } Music {
1386                 THIS->lexer_->pop_state ();
1387                 Music *music = $4;
1388                 SCM name = $2;
1389                 $$ = make_lyric_combine_music (name, music);
1390                 scm_gc_unprotect_object (music->self_scm ());
1391         }
1392         ;
1393
1394 context_change:
1395         CHANGE STRING '=' STRING  {
1396                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1397                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1398                 t-> set_property ("change-to-id", $4);
1399
1400                 $$ = t;
1401                 $$->set_spot (@$);
1402         }
1403         ;
1404
1405 property_operation:
1406         STRING '=' scalar {
1407                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1408                         scm_string_to_symbol ($1), $3);
1409         }
1410         | UNSET simple_string {
1411                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1412                         scm_string_to_symbol ($2));
1413         }
1414         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1415                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1416                         scm_string_to_symbol ($2), $3, $5);
1417         }
1418         | REVERT simple_string embedded_scm {
1419                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1420                         scm_string_to_symbol ($2), $3);
1421         }
1422         ;
1423
1424 context_def_mod:
1425         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1426         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1427
1428         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1429         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1430         | DENIES { $$ = ly_symbol2scm ("denies"); }
1431
1432         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1433         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1434         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1435         | NAME { $$ = ly_symbol2scm ("context-name"); }
1436         ;
1437
1438 context_mod:
1439         property_operation { $$ = $1; }
1440         | context_def_mod STRING {
1441                 $$ = scm_list_2 ($1, $2);
1442         }
1443         ;
1444
1445 context_prop_spec:
1446         simple_string {
1447                 if (!is_regular_identifier ($1))
1448                 {
1449                         @$.error (_("Grob name should be alphanumeric"));
1450                 }
1451
1452                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1453                         scm_string_to_symbol ($1));
1454         }
1455         | simple_string '.' simple_string {
1456                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1457                         scm_string_to_symbol ($3));
1458         }
1459         ;
1460
1461 music_property_def:
1462         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1463                 $$ = property_op_to_music (scm_list_4 (
1464                         ly_symbol2scm ("poppush"),
1465                         scm_cadr ($2),
1466                         $3, $5));
1467                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1468         }
1469         | REVERT context_prop_spec embedded_scm {
1470                 $$ = property_op_to_music (scm_list_3 (
1471                         ly_symbol2scm ("pop"),
1472                         scm_cadr ($2),
1473                         $3));
1474
1475                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1476         }
1477         | SET context_prop_spec '=' scalar {
1478                 $$ = property_op_to_music (scm_list_3 (
1479                         ly_symbol2scm ("assign"),
1480                         scm_cadr ($2),
1481                         $4));
1482                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1483         }
1484         | UNSET context_prop_spec {
1485                 $$ = property_op_to_music (scm_list_2 (
1486                         ly_symbol2scm ("unset"),
1487                         scm_cadr ($2)));
1488                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1489         }
1490         | ONCE music_property_def {
1491                 SCM e = $2->get_property ("element");
1492                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1493                 $$ = $2;
1494
1495         }
1496         ;
1497
1498
1499 string:
1500         STRING {
1501                 $$ = $1;
1502         }
1503         | STRING_IDENTIFIER {
1504                 $$ = $1;
1505         }
1506         | string '+' string {
1507                 $$ = scm_string_append (scm_list_2 ($1, $3));
1508         }
1509         ;
1510
1511 simple_string: STRING {
1512                 $$ = $1;
1513         }
1514         | LYRICS_STRING {
1515                 $$ = $1;
1516         }
1517         ;
1518
1519 scalar: string {
1520                 $$ = $1;
1521         }
1522         | LYRICS_STRING {
1523                 $$ = $1;
1524         }
1525         | bare_number {
1526                 $$ = $1;
1527 /*              if (scm_integer_p ($1) == SCM_BOOL_T)
1528                 {
1529                         int k = scm_to_int (scm_inexact_to_exact ($1));
1530                         $$ = k;
1531                 } else
1532                 {
1533                         THIS->parser_error (@1, _ ("need integer number arg"));
1534                         $$ = 0;
1535                 }*/
1536         }
1537         | embedded_scm {
1538                 $$ = $1;
1539         }
1540         | full_markup {
1541                 $$ = $1;
1542         }
1543         | DIGIT {
1544                 $$ = scm_int2num ($1);
1545         }
1546         ;
1547
1548 /*
1549
1550 pre_events doesn't contain anything. It is a trick:
1551
1552 Adding pre_events to the simple_element
1553 makes the choice between
1554
1555   string:  STRING
1556
1557 and
1558
1559   simple_element: STRING
1560
1561 a single shift/reduction conflict.
1562
1563 nevertheless, this is not very clean, and we should find a different
1564 solution.
1565
1566 */
1567 pre_events: /* empty */
1568         ;
1569
1570 event_chord:
1571         pre_events simple_element post_events   {
1572                 SCM elts = $2-> get_property ("elements");
1573
1574                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1575
1576                 $2->set_property ("elements", elts);
1577                 /* why is this giving wrong start location? -ns
1578                  * $2->set_spot (@$); */
1579                 Input i;
1580                 i.set_location (@2, @3);
1581                 $2->set_spot (i);
1582                 $$ = $2;
1583         }
1584         | command_element
1585         | note_chord_element
1586         ;
1587
1588
1589 note_chord_element:
1590         chord_body optional_notemode_duration post_events
1591         {
1592                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1593                 SCM es = $1->get_property ("elements");
1594                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1595
1596                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1597                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1598                 es = ly_append2 (es, postevs);
1599
1600                 $1-> set_property ("elements", es);
1601                 $1->set_spot (@$);
1602                 $$ = $1;
1603         }
1604         ;
1605
1606 chord_open: '<'
1607         ;
1608
1609 chord_close: '>'
1610         ;
1611
1612 simul_open: DOUBLE_ANGLE_OPEN
1613         ;
1614
1615 simul_close: DOUBLE_ANGLE_CLOSE
1616         ;
1617
1618 chord_body:
1619         chord_open chord_body_elements chord_close
1620         {
1621                 $$ = MY_MAKE_MUSIC ("EventChord");
1622                 $$->set_spot (@$);
1623                 $$->set_property ("elements",
1624                         scm_reverse_x ($2, SCM_EOL));
1625         }
1626         ;
1627
1628 chord_body_elements:
1629         /* empty */             { $$ = SCM_EOL; }
1630         | chord_body_elements chord_body_element {
1631                 $$ = scm_cons ($2->self_scm (), $1);
1632                 scm_gc_unprotect_object ($2->self_scm ());
1633         }
1634         ;
1635
1636 chord_body_element:
1637         pitch exclamations questions octave_check post_events
1638         {
1639                 int q = $3;
1640                 int ex = $2;
1641                 SCM check = $4;
1642                 SCM post = $5;
1643
1644                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1645                 n->set_property ("pitch", $1);
1646                 n->set_spot (@$);
1647                 if (q % 2)
1648                         n->set_property ("cautionary", SCM_BOOL_T);
1649                 if (ex % 2 || q % 2)
1650                         n->set_property ("force-accidental", SCM_BOOL_T);
1651
1652                 if (scm_is_pair (post)) {
1653                         SCM arts = scm_reverse_x (post, SCM_EOL);
1654                         n->set_property ("articulations", arts);
1655                 }
1656                 if (scm_is_number (check))
1657                 {
1658                         int q = scm_to_int (check);
1659                         n->set_property ("absolute-octave", scm_int2num (q-1));
1660                 }
1661
1662
1663                 $$ = n;
1664         }
1665         | DRUM_PITCH post_events {
1666                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1667                 n->set_property ("duration", $2);
1668                 n->set_property ("drum-type", $1);
1669                 n->set_spot (@$);
1670
1671                 if (scm_is_pair ($2)) {
1672                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1673                         n->set_property ("articulations", arts);
1674                 }
1675                 $$ = n;
1676         }
1677         ;
1678
1679 add_quote:
1680         ADDQUOTE string Music {
1681                 SCM adder = ly_lily_module_constant ("add-quotable");
1682
1683                 scm_call_2 (adder, $2, $3->self_scm ());
1684                 scm_gc_unprotect_object ($3->self_scm ());
1685         }
1686         ;
1687
1688 command_element:
1689         command_req {
1690                 $$ = MY_MAKE_MUSIC ("EventChord");
1691                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1692                 scm_gc_unprotect_object ($1->self_scm ());
1693
1694                 $$-> set_spot (@$);
1695                 $1-> set_spot (@$);
1696         }
1697         | SKIP duration_length {
1698                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1699                 skip->set_property ("duration", $2);
1700                 skip->set_spot (@$);
1701                 $$ = skip;
1702         }
1703         | OCTAVE pitch {
1704                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1705                 $$ = m;
1706                 $$->set_spot (@$);
1707                 $$->set_property ("pitch", $2);
1708         }
1709         | E_BRACKET_OPEN {
1710                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1711                 m->set_property ("span-direction", scm_int2num (START));
1712                 m->set_spot (@$);
1713
1714                 $$ = MY_MAKE_MUSIC ("EventChord");
1715                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1716                 scm_gc_unprotect_object (m->self_scm ());
1717                 $$->set_spot (@$);
1718         }
1719         | E_BRACKET_CLOSE {
1720                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1721                 m->set_property ("span-direction", scm_int2num (STOP));
1722                 m->set_spot (@$);
1723
1724                 $$ = MY_MAKE_MUSIC ("EventChord");
1725                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1726                 $$->set_spot (@$);
1727                 scm_gc_unprotect_object (m->self_scm ());
1728         }
1729         | E_BACKSLASH {
1730                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1731                 $$->set_spot (@$);
1732         }
1733         | '|'      {
1734                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1735
1736                 if (Music * m = unsmob_music (pipe))
1737                         $$ = m->clone ();
1738                 else
1739                         $$ = MY_MAKE_MUSIC ("BarCheck");
1740
1741                 $$->set_spot (@$);
1742         }
1743         | TRANSPOSITION pitch {
1744                 Pitch middle_c;
1745                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1746                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1747                                          sounds_as_c.smobbed_copy());
1748                 $$->set_spot (@$);
1749                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1750                         $$, SCM_EOL);
1751         }
1752         | BAR STRING                    {
1753                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1754
1755                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1756                                         t, SCM_EOL);
1757                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1758                 $$->set_spot (@$);
1759                 t->set_spot (@$);
1760         }
1761         | PARTIAL duration_length       {
1762                 Moment m = - unsmob_duration ($2)->get_length ();
1763                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1764                 p->set_spot (@$);
1765                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1766                                         p, SCM_EOL);
1767                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1768                                         p, SCM_EOL);
1769                 $$ = p;
1770         }
1771         | CLEF STRING  {
1772                 SCM proc = ly_lily_module_constant ("make-clef-set");
1773
1774                 SCM result = scm_call_1 (proc, $2);
1775                 scm_gc_protect_object (result);
1776                 $$ = unsmob_music (result);
1777         }
1778         | TIME_T fraction  {
1779                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1780
1781                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1782                 scm_gc_protect_object (result);
1783                 $$ = unsmob_music (result);
1784         }
1785         | MARK scalar {
1786                 SCM proc = ly_lily_module_constant ("make-mark-set");
1787
1788                 SCM result = scm_call_1 (proc, $2);
1789                 scm_gc_protect_object (result);
1790                 $$ = unsmob_music (result);
1791         }
1792         ;
1793
1794 command_req:
1795         E_TILDE {
1796                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1797         }
1798         | MARK DEFAULT  {
1799                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1800                 $$ = m;
1801         }
1802         | tempo_event {
1803                 $$ = $1;
1804         }
1805         | KEY DEFAULT {
1806                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1807                 $$ = key;
1808         }
1809         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1810
1811                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1812                 if (scm_ilength ($3) > 0)
1813                 {
1814                         key->set_property ("pitch-alist", $3);
1815                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1816                         key->transpose (* unsmob_pitch ($2));
1817                 } else {
1818                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1819                 }
1820
1821                 $$ = key;
1822         }
1823         ;
1824
1825
1826 post_events:
1827         /* empty */ {
1828                 $$ = SCM_EOL;
1829         }
1830         | post_events post_event {
1831                 $2->set_spot (@2);
1832                 $$ = scm_cons ($2->self_scm (), $$);
1833                 scm_gc_unprotect_object ($2->self_scm ());
1834         }
1835         | post_events tagged_post_event {
1836                 $2 -> set_spot (@2);
1837                 $$ = scm_cons ($2->self_scm (), $$);
1838                 scm_gc_unprotect_object ($2->self_scm ());
1839         }
1840         ;
1841
1842
1843 tagged_post_event:
1844         '-' TAG embedded_scm post_event {
1845                 tag_music ($4, $3, @$);
1846                 $$ = $4;
1847         }
1848         ;
1849
1850
1851 post_event:
1852         direction_less_event {
1853                 $$ = $1;
1854         }
1855         | HYPHEN {
1856                 if (!THIS->lexer_->is_lyric_state ())
1857                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1858                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1859         }
1860         | EXTENDER {
1861                 if (!THIS->lexer_->is_lyric_state ())
1862                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1863                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1864         }
1865         | script_dir direction_reqd_event {
1866                 if ($1)
1867                         $2->set_property ("direction", scm_int2num ($1));
1868                 $$ = $2;
1869         }
1870         | script_dir direction_less_event {
1871                 if ($1)
1872                         $2->set_property ("direction", scm_int2num ($1));
1873                 $$ = $2;
1874         }
1875         | string_number_event
1876         ;
1877
1878 string_number_event:
1879         E_UNSIGNED {
1880                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1881                 s->set_property ("string-number", scm_int2num ($1));
1882                 s->set_spot (@$);
1883                 $$ = s;
1884         }
1885         ;
1886
1887 direction_less_char:
1888         '['  {
1889                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1890         }
1891         | ']'  {
1892                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1893         }
1894         | '~'  {
1895                 $$ = ly_symbol2scm ("tildeSymbol");
1896         }
1897         | '('  {
1898                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1899         }
1900         | ')'  {
1901                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1902         }
1903         | E_EXCLAMATION  {
1904                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1905         }
1906         | E_OPEN  {
1907                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1908         }
1909         | E_CLOSE  {
1910                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1911         }
1912         | E_ANGLE_CLOSE  {
1913                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1914         }
1915         | E_ANGLE_OPEN  {
1916                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1917         }
1918         ;
1919
1920 direction_less_event:
1921         direction_less_char {
1922                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1923                 Music * m = 0;
1924                 if (unsmob_music (predefd))
1925                 {
1926                         m = unsmob_music (predefd)->clone ();
1927                 }
1928                 else
1929                 {
1930                         m = MY_MAKE_MUSIC ("Music");
1931                 }
1932                 m->set_spot (@$);
1933                 $$ = m;
1934         }
1935         | EVENT_IDENTIFIER      {
1936                 $$ = unsmob_music ($1);
1937         }
1938         | tremolo_type  {
1939                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1940                a->set_spot (@$);
1941                a->set_property ("tremolo-type", scm_int2num ($1));
1942                $$ = a;
1943         }
1944         ;
1945
1946 direction_reqd_event:
1947         gen_text_def {
1948                 $$ = $1;
1949         }
1950         | script_abbreviation {
1951                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1952                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1953                 if (scm_is_string (s))
1954                         a->set_property ("articulation-type", s);
1955                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1956                 $$ = a;
1957         }
1958         ;
1959
1960 octave_check:
1961         /**/ { $$ = SCM_EOL; }
1962         | '='  { $$ = scm_int2num (0); }
1963         | '=' sub_quotes { $$ = scm_int2num ($2); }
1964         | '=' sup_quotes { $$ = scm_int2num ($2); }
1965         ;
1966
1967 sup_quotes:
1968         '\'' {
1969                 $$ = 1;
1970         }
1971         | sup_quotes '\'' {
1972                 $$ ++;
1973         }
1974         ;
1975
1976 sub_quotes:
1977         ',' {
1978                 $$ = 1;
1979         }
1980         | sub_quotes ',' {
1981                 $$++;
1982         }
1983         ;
1984
1985 steno_pitch:
1986         NOTENAME_PITCH  {
1987                 $$ = $1;
1988         }
1989         | NOTENAME_PITCH sup_quotes     {
1990                 Pitch p = *unsmob_pitch ($1);
1991                 p = p.transposed (Pitch ($2,0,0));
1992                 $$ = p.smobbed_copy ();
1993         }
1994         | NOTENAME_PITCH sub_quotes      {
1995                 Pitch p =* unsmob_pitch ($1);
1996                 p = p.transposed (Pitch (-$2,0,0));
1997                 $$ = p.smobbed_copy ();
1998         }
1999         ;
2000
2001 /*
2002 ugh. duplication
2003 */
2004
2005 steno_tonic_pitch:
2006         TONICNAME_PITCH {
2007                 $$ = $1;
2008         }
2009         | TONICNAME_PITCH sup_quotes    {
2010                 Pitch p = *unsmob_pitch ($1);
2011                 p = p.transposed (Pitch ($2,0,0));
2012                 $$ = p.smobbed_copy ();
2013         }
2014         | TONICNAME_PITCH sub_quotes     {
2015                 Pitch p =* unsmob_pitch ($1);
2016
2017                 p = p.transposed (Pitch (-$2,0,0));
2018                 $$ = p.smobbed_copy ();
2019         }
2020         ;
2021
2022 pitch:
2023         steno_pitch {
2024                 $$ = $1;
2025         }
2026         ;
2027
2028 pitch_also_in_chords:
2029         pitch
2030         | steno_tonic_pitch
2031         ;
2032
2033 gen_text_def:
2034         full_markup {
2035                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
2036                 t->set_property ("text", $1);
2037                 t->set_spot (@$);
2038                 $$ = t;
2039         }
2040         | string {
2041                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
2042                 t->set_property ("text",
2043                         make_simple_markup ($1));
2044                 t->set_spot (@$);
2045                 $$ = t;
2046
2047         }
2048         | DIGIT {
2049                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
2050                 t->set_property ("digit", scm_int2num ($1));
2051                 t->set_spot (@$);
2052                 $$ = t;
2053         }
2054         ;
2055
2056 script_abbreviation:
2057         '^'             {
2058                 $$ = scm_makfrom0str ("Hat");
2059         }
2060         | '+'           {
2061                 $$ = scm_makfrom0str ("Plus");
2062         }
2063         | '-'           {
2064                 $$ = scm_makfrom0str ("Dash");
2065         }
2066         | '|'           {
2067                 $$ = scm_makfrom0str ("Bar");
2068         }
2069         | '>'           {
2070                 $$ = scm_makfrom0str ("Larger");
2071         }
2072         | '.'           {
2073                 $$ = scm_makfrom0str ("Dot");
2074         }
2075         | '_' {
2076                 $$ = scm_makfrom0str ("Underscore");
2077         }
2078         ;
2079
2080 script_dir:
2081         '_'     { $$ = DOWN; }
2082         | '^'   { $$ = UP; }
2083         | '-'   { $$ = CENTER; }
2084         ;
2085
2086
2087 absolute_pitch:
2088         steno_pitch     {
2089                 $$ = $1;
2090         }
2091         ;
2092
2093 duration_length:
2094         multiplied_duration {
2095                 $$ = $1;
2096         }
2097         ;
2098
2099 optional_notemode_duration:
2100         {
2101                 Duration dd = THIS->default_duration_;
2102                 $$ = dd.smobbed_copy ();
2103         }
2104         | multiplied_duration   {
2105                 $$ = $1;
2106                 THIS->default_duration_ = *unsmob_duration ($$);
2107         }
2108         ;
2109
2110 steno_duration:
2111         bare_unsigned dots              {
2112                 int len = 0;
2113                 if (!is_duration ($1))
2114                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
2115                 else
2116                         len = intlog2 ($1);
2117
2118                 $$ = Duration (len, $2).smobbed_copy ();
2119         }
2120         | DURATION_IDENTIFIER dots      {
2121                 Duration *d = unsmob_duration ($1);
2122                 Duration k (d->duration_log (), d->dot_count () + $2);
2123                 *d = k;
2124                 $$ = $1;
2125         }
2126         ;
2127
2128 multiplied_duration:
2129         steno_duration {
2130                 $$ = $1;
2131         }
2132         | multiplied_duration '*' bare_unsigned {
2133                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2134         }
2135         | multiplied_duration '*' FRACTION {
2136                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2137
2138                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2139         }
2140         ;
2141
2142 fraction:
2143         FRACTION { $$ = $1; }
2144         | UNSIGNED '/' UNSIGNED {
2145                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2146         }
2147         ;
2148
2149 dots:
2150         /* empty */     {
2151                 $$ = 0;
2152         }
2153         | dots '.' {
2154                 $$ ++;
2155         }
2156         ;
2157
2158 tremolo_type:
2159         ':'     {
2160                 $$ = 0;
2161         }
2162         | ':' bare_unsigned {
2163                 if (!is_duration ($2))
2164                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2165                 $$ = $2;
2166         }
2167         ;
2168
2169 bass_number:
2170         DIGIT   {
2171                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2172                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2173                                 $$);
2174         }
2175         | UNSIGNED {
2176                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2177                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2178                                 $$);
2179         }
2180         | STRING { $$ = $1; }
2181         | full_markup { $$ = $1; }
2182         ;
2183
2184 bass_mod:
2185         '-'     { $$ = -2; }
2186         | '+'   { $$ = 2; }
2187         | '!'   { $$ = 0; }
2188         ;
2189
2190 bass_figure:
2191         FIGURE_SPACE {
2192                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2193                 $$ = bfr->self_scm ();
2194                 scm_gc_unprotect_object ($$);
2195         }
2196         | bass_number  {
2197                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2198                 $$ = bfr->self_scm ();
2199
2200                 bfr->set_property ("figure", $1);
2201
2202                 scm_gc_unprotect_object ($$);
2203         }
2204         | bass_figure bass_mod {
2205                 Music *m = unsmob_music ($1);
2206                 if ($2) {
2207                         SCM salter = m->get_property ("alteration");
2208                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2209                         m->set_property ("alteration",
2210                                 scm_int2num (alter + $2));
2211                 } else {
2212                         m->set_property ("alteration", scm_int2num (0));
2213                 }
2214         }
2215         ;
2216
2217 br_bass_figure:
2218         '[' bass_figure {
2219                 $$ = $2;
2220                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2221         }
2222         | bass_figure   {
2223                 $$ = $1;
2224         }
2225         | br_bass_figure ']' {
2226                 $$ = $1;
2227                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2228         }
2229         ;
2230
2231 figure_list:
2232         /**/            {
2233                 $$ = SCM_EOL;
2234         }
2235         | figure_list br_bass_figure {
2236                 $$ = scm_cons ($2, $1);
2237         }
2238         ;
2239
2240 figure_spec:
2241         FIGURE_OPEN figure_list FIGURE_CLOSE {
2242                 Music *m = MY_MAKE_MUSIC ("EventChord");
2243                 $2 = scm_reverse_x ($2, SCM_EOL);
2244                 m->set_property ("elements", $2);
2245                 $$ = m->self_scm ();
2246         }
2247         ;
2248
2249
2250 optional_rest:
2251         /**/   { $$ = 0; }
2252         | REST { $$ = 1; }
2253         ;
2254
2255 simple_element:
2256         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2257                 if (!THIS->lexer_->is_note_state ())
2258                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2259
2260                 Music *n = 0;
2261                 if ($6)
2262                         n = MY_MAKE_MUSIC ("RestEvent");
2263                 else
2264                         n = MY_MAKE_MUSIC ("NoteEvent");
2265
2266                 n->set_property ("pitch", $1);
2267                 n->set_property ("duration", $5);
2268
2269                 if (scm_is_number ($4))
2270                 {
2271                         int q = scm_to_int ($4);
2272                         n->set_property ("absolute-octave", scm_int2num (q-1));
2273                 }
2274
2275                 if ($3 % 2)
2276                         n->set_property ("cautionary", SCM_BOOL_T);
2277                 if ($2 % 2 || $3 % 2)
2278                         n->set_property ("force-accidental", SCM_BOOL_T);
2279
2280                 Music *v = MY_MAKE_MUSIC ("EventChord");
2281                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2282                 scm_gc_unprotect_object (n->self_scm ());
2283
2284                 v->set_spot (@$);
2285                 n->set_spot (@$);
2286                 $$ = v;
2287         }
2288         | DRUM_PITCH optional_notemode_duration {
2289                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2290                 n->set_property ("duration", $2);
2291                 n->set_property ("drum-type", $1);
2292
2293                 Music *v = MY_MAKE_MUSIC ("EventChord");
2294                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2295                 scm_gc_unprotect_object (n->self_scm ());
2296                 v->set_spot (@$);
2297                 n->set_spot (@$);
2298                 $$ = v;
2299
2300         }
2301         | figure_spec optional_notemode_duration {
2302                 Music *m = unsmob_music ($1);
2303                 m->set_spot (@$);
2304                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2305                 {
2306                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2307                 }
2308                 $$ = m;
2309         }
2310         | RESTNAME optional_notemode_duration           {
2311                 Music *ev = 0;
2312                 if (ly_scm2string ($1) == "s") {
2313                         /* Space */
2314                         ev = MY_MAKE_MUSIC ("SkipEvent");
2315                   }
2316                 else {
2317                         ev = MY_MAKE_MUSIC ("RestEvent");
2318
2319                     }
2320                 ev->set_property ("duration", $2);
2321                 ev->set_spot (@$);
2322                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2323                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2324                 velt->set_spot (@$);
2325
2326                 scm_gc_unprotect_object (ev->self_scm ());
2327
2328                 $$ = velt;
2329         }
2330         | MULTI_MEASURE_REST optional_notemode_duration         {
2331                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2332                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2333                 scm_gc_protect_object (mus);
2334                 $$ = unsmob_music (mus);
2335         }
2336
2337         | lyric_element optional_notemode_duration      {
2338                 if (!THIS->lexer_->is_lyric_state ())
2339                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2340
2341                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2342                 lreq->set_property ("text", $1);
2343                 lreq->set_property ("duration",$2);
2344                 lreq->set_spot (@$);
2345                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2346                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2347
2348                 $$= velt;
2349         }
2350         | new_chord {
2351                 if (!THIS->lexer_->is_chord_state ())
2352                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2353                 $$ = unsmob_music ($1);
2354         }
2355         ;
2356
2357 lyric_element:
2358         lyric_markup {
2359                 $$ = $1;
2360         }
2361         | LYRICS_STRING {
2362                 $$ = make_simple_markup ($1);
2363         }
2364         ;
2365
2366 new_chord:
2367         steno_tonic_pitch optional_notemode_duration   {
2368                 $$ = make_chord ($1, $2, SCM_EOL);
2369         }
2370         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2371                 SCM its = scm_reverse_x ($4, SCM_EOL);
2372                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2373         }
2374         ;
2375
2376 chord_items:
2377         /**/ {
2378                 $$ = SCM_EOL;
2379         }
2380         | chord_items chord_item {
2381                 $$ = scm_cons ($2, $$);
2382         }
2383         ;
2384
2385 chord_separator:
2386         CHORD_COLON {
2387                 $$ = ly_symbol2scm ("chord-colon");
2388         }
2389         | CHORD_CARET {
2390                 $$ = ly_symbol2scm ("chord-caret");
2391         }
2392         | CHORD_SLASH steno_tonic_pitch {
2393                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2394         }
2395         | CHORD_BASS steno_tonic_pitch {
2396                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2397         }
2398         ;
2399
2400 chord_item:
2401         chord_separator {
2402                 $$ = $1;
2403         }
2404         | step_numbers {
2405                 $$ = scm_reverse_x ($1, SCM_EOL);
2406         }
2407         | CHORD_MODIFIER  {
2408                 $$ = $1;
2409         }
2410         ;
2411
2412 step_numbers:
2413         step_number { $$ = scm_cons ($1, SCM_EOL); }
2414         | step_numbers '.' step_number {
2415                 $$ = scm_cons ($3, $$);
2416         }
2417         ;
2418
2419 step_number:
2420         bare_unsigned {
2421                 $$ = make_chord_step ($1, 0);
2422         }
2423         | bare_unsigned '+' {
2424                 $$ = make_chord_step ($1, SHARP);
2425         }
2426         | bare_unsigned CHORD_MINUS {
2427                 $$ = make_chord_step ($1, FLAT);
2428         }
2429         ;
2430
2431 /*
2432         UTILITIES
2433
2434 TODO: should deprecate in favor of Scheme?
2435
2436  */
2437 number_expression:
2438         number_expression '+' number_term {
2439                 $$ = scm_sum ($1, $3);
2440         }
2441         | number_expression '-' number_term {
2442                 $$ = scm_difference ($1, $3);
2443         }
2444         | number_term
2445         ;
2446
2447 number_term:
2448         number_factor {
2449                 $$ = $1;
2450         }
2451         | number_factor '*' number_factor {
2452                 $$ = scm_product ($1, $3);
2453         }
2454         | number_factor '/' number_factor {
2455                 $$ = scm_divide ($1, $3);
2456         }
2457         ;
2458
2459 number_factor:
2460         '-'  number_factor { /* %prec UNARY_MINUS */
2461                 $$ = scm_difference ($2, SCM_UNDEFINED);
2462         }
2463         | bare_number
2464         ;
2465
2466
2467 bare_number:
2468         UNSIGNED        {
2469                 $$ = scm_int2num ($1);
2470         }
2471         | REAL          {
2472                 $$ = $1;
2473         }
2474         | NUMBER_IDENTIFIER             {
2475                 $$ = $1;
2476         }
2477         | REAL NUMBER_IDENTIFIER        {
2478                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2479         }
2480         | UNSIGNED NUMBER_IDENTIFIER    {
2481                 $$ = scm_make_real ($1 *scm_to_double ($2));
2482         }
2483         ;
2484
2485
2486 bare_unsigned:
2487         UNSIGNED {
2488                         $$ = $1;
2489         }
2490         | DIGIT {
2491                 $$ = $1;
2492         }
2493         ;
2494
2495 exclamations:
2496                 { $$ = 0; }
2497         | exclamations '!'      { $$ ++; }
2498         ;
2499
2500 questions:
2501                 { $$ = 0; }
2502         | questions '?' { $$ ++; }
2503         ;
2504
2505 /*
2506 This should be done more dynamically if possible.
2507 */
2508
2509 lyric_markup:
2510         LYRIC_MARKUP_IDENTIFIER {
2511                 $$ = $1;
2512         }
2513         | LYRIC_MARKUP
2514                 { THIS->lexer_->push_markup_state (); }
2515         markup_top {
2516                 $$ = $3;
2517                 THIS->lexer_->pop_state ();
2518         }
2519         ;
2520
2521 full_markup:
2522         MARKUP_IDENTIFIER {
2523                 $$ = $1;
2524         }
2525         | MARKUP
2526                 { THIS->lexer_->push_markup_state (); }
2527         markup_top {
2528                 $$ = $3;
2529                 THIS->lexer_->pop_state ();
2530         }
2531         ;
2532
2533 markup_top:
2534         markup_list {
2535                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2536         }
2537         | markup_head_1_list simple_markup      {
2538                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2539         }
2540         | simple_markup {
2541                 $$ = $1;
2542         }
2543         ;
2544
2545 markup_list:
2546         markup_composed_list {
2547                 $$ = $1;
2548         }
2549         | markup_braced_list {
2550                 $$ = $1;
2551         }
2552         ;
2553
2554 markup_composed_list:
2555         markup_head_1_list markup_braced_list {
2556                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2557
2558         }
2559         ;
2560
2561 markup_braced_list:
2562         '{' markup_braced_list_body '}' {
2563                 $$ = scm_reverse_x ($2, SCM_EOL);
2564         }
2565         ;
2566
2567 markup_braced_list_body:
2568         /* empty */     {  $$ = SCM_EOL; }
2569         | markup_braced_list_body markup {
2570                 $$ = scm_cons ($2, $1);
2571         }
2572         | markup_braced_list_body markup_list {
2573                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2574         }
2575         ;
2576
2577 markup_head_1_item:
2578         MARKUP_HEAD_MARKUP0     {
2579                 $$ = scm_list_1 ($1);
2580         }
2581         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2582                 $$ = scm_list_2 ($1, $2);
2583         }
2584         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2585                 $$ = scm_list_3 ($1, $2, $3);
2586         }
2587         ;
2588
2589 markup_head_1_list:
2590         markup_head_1_item      {
2591                 $$ = scm_list_1 ($1);
2592         }
2593         | markup_head_1_list markup_head_1_item {
2594                 $$ = scm_cons ($2, $1);
2595         }
2596         ;
2597
2598 simple_markup:
2599         STRING {
2600                 $$ = make_simple_markup ($1);
2601         }
2602         | MARKUP_IDENTIFIER {
2603                 $$ = $1;
2604         }
2605         | LYRIC_MARKUP_IDENTIFIER {
2606                 $$ = $1;
2607         }
2608         | STRING_IDENTIFIER {
2609                 $$ = $1;
2610         }
2611         | SCORE {
2612                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2613                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2614         } '{' score_body '}' {
2615                 Score * sc = $4;
2616                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2617                 scm_gc_unprotect_object (sc->self_scm ());
2618                 THIS->lexer_->pop_state ();
2619         }
2620         | MARKUP_HEAD_SCM0 embedded_scm {
2621                 $$ = scm_list_2 ($1, $2);
2622         }
2623         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2624                 $$ = scm_list_4 ($1, $2, $3, $4);
2625         }
2626         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2627                 $$ = scm_list_3 ($1, $2, $3);
2628         }
2629         | MARKUP_HEAD_EMPTY {
2630                 $$ = scm_list_1 ($1);
2631         }
2632         | MARKUP_HEAD_LIST0 markup_list {
2633                 $$ = scm_list_2 ($1,$2);
2634         }
2635         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2636                 $$ = scm_list_3 ($1, $2, $3);
2637         }
2638         ;
2639
2640 markup:
2641         markup_head_1_list simple_markup        {
2642                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2643                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2644         }
2645         | simple_markup {
2646                 $$ = $1;
2647         }
2648         ;
2649
2650 %%
2651
2652 void
2653 Lily_parser::set_yydebug (bool )
2654 {
2655 #if 0
2656         yydebug = 1;
2657 #endif
2658 }
2659
2660 void
2661 Lily_parser::do_yyparse ()
2662 {
2663         yyparse ((void*)this);
2664 }
2665
2666
2667
2668
2669
2670 /*
2671
2672 It is a little strange to have this function in this file, but
2673 otherwise, we have to import music classes into the lexer.
2674
2675 */
2676 int
2677 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2678 {
2679         if (scm_is_string (sid)) {
2680                 *destination = sid;
2681                 return STRING_IDENTIFIER;
2682         } else if (scm_is_number (sid)) {
2683                 *destination = sid;
2684                 return NUMBER_IDENTIFIER;
2685         } else if (unsmob_context_def (sid)) {
2686                 *destination = unsmob_context_def (sid)->clone_scm ();
2687                 return CONTEXT_DEF_IDENTIFIER;
2688         } else if (unsmob_score (sid)) {
2689                 Score *score = new Score (*unsmob_score (sid));
2690                 *destination = score->self_scm ();
2691                 return SCORE_IDENTIFIER;
2692         } else if (Music *mus = unsmob_music (sid)) {
2693                 mus = mus->clone ();
2694                 *destination = mus->self_scm ();
2695                 unsmob_music (*destination)->
2696                         set_property ("origin", make_input (last_input_));
2697
2698                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2699                         != SCM_BOOL_F;
2700
2701                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2702         } else if (unsmob_duration (sid)) {
2703                 *destination = unsmob_duration (sid)->smobbed_copy ();
2704                 return DURATION_IDENTIFIER;
2705         } else if (unsmob_output_def (sid)) {
2706                 Output_def *p = unsmob_output_def (sid);
2707                 p = p->clone ();
2708
2709                 *destination = p->self_scm ();
2710                 return OUTPUT_DEF_IDENTIFIER;
2711         } else if (Text_interface::markup_p (sid)) {
2712                 *destination = sid;
2713                 if (is_lyric_state ())
2714                         return LYRIC_MARKUP_IDENTIFIER;
2715                 return MARKUP_IDENTIFIER;
2716         }
2717
2718         return -1;
2719 }
2720
2721 Music *
2722 property_op_to_music (SCM op)
2723 {
2724         Music *m = 0;
2725         SCM tag = scm_car (op);
2726         SCM symbol = scm_cadr (op);
2727         SCM args = scm_cddr (op);
2728         SCM grob_val = SCM_UNDEFINED;
2729         SCM grob_sym = SCM_UNDEFINED;
2730         SCM val = SCM_UNDEFINED;
2731
2732         if (tag == ly_symbol2scm ("assign"))
2733                 {
2734                 m = MY_MAKE_MUSIC ("PropertySet");
2735                 val = scm_car (args);
2736                 }
2737         else if (tag == ly_symbol2scm ("unset"))
2738                 m = MY_MAKE_MUSIC ("PropertyUnset");
2739         else if (tag == ly_symbol2scm ("poppush")
2740                  || tag == ly_symbol2scm ("push"))
2741                 {
2742                 m = MY_MAKE_MUSIC ("OverrideProperty");
2743                 grob_sym = scm_car (args);
2744                 grob_val = scm_cadr (args);
2745                 }
2746         else if (tag == ly_symbol2scm ("pop")) {
2747                 m = MY_MAKE_MUSIC ("RevertProperty");
2748                 grob_sym = scm_car (args);
2749                 }
2750
2751         m->set_property ("symbol", symbol);
2752
2753         if (val != SCM_UNDEFINED)
2754                 m->set_property ("value", val);
2755         if (grob_val != SCM_UNDEFINED)
2756                 m->set_property ("grob-value", grob_val);
2757
2758         if (grob_sym != SCM_UNDEFINED)
2759                 {
2760                 bool itc = do_internal_type_checking_global;
2761                 /* UGH.
2762                 */
2763                 bool autobeam = ly_is_equal (symbol, ly_symbol2scm ("autoBeamSettings"));
2764                 if (autobeam)
2765                         do_internal_type_checking_global = false;
2766                 m->set_property ("grob-property", grob_sym);
2767                 if (autobeam)
2768                         do_internal_type_checking_global = itc;
2769                 }
2770
2771         if (tag == ly_symbol2scm ("poppush"))
2772                 m->set_property ("pop-first", SCM_BOOL_T);
2773
2774
2775         return m;
2776 }
2777
2778 Music*
2779 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2780 {
2781         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2782
2783         csm->set_property ("element", m->self_scm ());
2784         scm_gc_unprotect_object (m->self_scm ());
2785
2786         csm->set_property ("context-type",
2787                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2788         csm->set_property ("property-operations", ops);
2789
2790         if (scm_is_string (id))
2791                 csm->set_property ("context-id", id);
2792         return csm;
2793 }
2794
2795 SCM
2796 get_next_unique_context_id ()
2797 {
2798         return scm_makfrom0str ("$uniqueContextId");
2799 }
2800
2801
2802 SCM
2803 get_next_unique_lyrics_context_id ()
2804 {
2805         static int new_context_count;
2806         char s[128];
2807         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2808         return scm_makfrom0str (s);
2809 }