lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-module.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83 #include "paper-book.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 is_regular_identifier (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128 /*
 129   isalpha (*s);
 130   s++;
 131 */
 132   while (*s && v)
 133    {
 134         v = v && isalnum (*s);
 135         s++;
 136    }
 137   return v;
 138 }
 139
 140 SCM
 141 make_simple_markup (SCM a)
 142 {
 143         static SCM simple;
 144         if (!simple)
 145         simple = scm_c_eval_string ("simple-markup");
 146
 147         return scm_list_2 (simple, a);
 148 }
 149
 150
 151 bool
 152 is_is_duration (int t)
 153 {
 154   return t && t == 1 << intlog2 (t);
 155 }
 156
 157 void
 158 set_music_properties (Music *p, SCM a)
 159 {
 160   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 161         {
 162         p->internal_set_property (ly_caar (k), ly_cdar (k));
 163         }
 164 }
 165
 166 SCM
 167 make_chord_step (int step, int alter)
 168 {
 169         if (step == 7)
 170                 alter += FLAT;
 171
 172         while(step < 0)
 173                 step += 7;
 174         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 175         return m.smobbed_copy ();
 176 }
 177
 178
 179 SCM
 180 make_chord (SCM pitch, SCM dur, SCM modification_list)
 181 {
 182         static SCM chord_ctor;
 183         if (!chord_ctor)
 184                 chord_ctor= scm_c_eval_string ("construct-chord");
 185         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 186         scm_gc_protect_object (ch);
 187         return ch;
 188 }
 189
 190 /*
 191   Todo: actually also use apply iso. call too ...
 192 */
 193 bool
 194 ly_input_procedure_p (SCM x)
 195 {
 196         return gh_procedure_p (x)
 197                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 198 }
 199
 200 Music*
 201 set_property_music (SCM sym, SCM value)
 202 {
 203         Music * p = MY_MAKE_MUSIC ("PropertySet");
 204         p->set_property ("symbol", sym);
 205         p->set_property ("value", value);
 206         return p;
 207 }
 208
 209 %}
 210
 211 /* We use SCMs to do strings, because it saves us the trouble of
 212 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 213 of the parse stack onto the heap. */
 214
 215
 216 %union {
 217         String * string;
 218     Music *music;
 219     Score *score;
 220     Music_output_def * outputdef;
 221     SCM scm;
 222     int i;
 223 }
 224 %{
 225
 226 int
 227 yylex (YYSTYPE *s,  void * v)
 228 {
 229         My_lily_parser   *pars = (My_lily_parser*) v;
 230         My_lily_lexer * lex = pars->lexer_;
 231
 232         lex->lexval = (void*) s;
 233         lex->prepare_for_next_token ();
 234         return lex->yylex ();
 235 }
 236
 237
 238 %}
 239
 240 %pure_parser
 241
 242
 243 %token ACCEPTS
 244 %token ADDLYRICS
 245 %token ADDQUOTE
 246 %token NEWADDLYRICS
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token APPLY
 250 %token APPLYCONTEXT
 251 %token APPLYOUTPUT
 252 %token AUTOCHANGE
 253 %token BAR
 254 %token BREATHE
 255 %token CHANGE
 256 %token CHORDMODIFIERS
 257 %token CHORDS
 258 %token LESSLESS
 259 %token MOREMORE
 260 %token CLEF
 261 %token COMMANDSPANREQUEST
 262 %token CONSISTS
 263 %token CONSISTSEND
 264 %token CONTEXT
 265 %token DEFAULT
 266 %token DENIES
 267 %token DESCRIPTION
 268 %token EXTENDER
 269 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 270 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 271 %token GRACE
 272 %token ACCIACCATURA
 273 %token APPOGGIATURA
 274 %token GROBDESCRIPTIONS
 275 %token HEADER
 276 %token HYPHEN
 277 %token INVALID
 278 %token KEY
 279 %token LYRICS
 280 %token MARK
 281 %token MIDI
 282 %token MULTI_MEASURE_REST
 283 %token NAME
 284 %token NEWCONTEXT
 285 %token NOTES
 286 %token OCTAVE
 287 %token ONCE
 288 %token OVERRIDE SET REVERT
 289 %token PAPER
 290 %token PARTCOMBINE
 291 %token PARTIAL
 292 %token QUOTE
 293 %token RELATIVE
 294 %token REMOVE
 295 %token REPEAT
 296 %token REST
 297 %token SCM_T
 298 %token SCORE
 299 %token SEQUENTIAL
 300 %token SIMULTANEOUS
 301 %token SKIP
 302 %token SPANREQUEST
 303 %token TAG
 304 %token TEMPO
 305 %token TIMES
 306 %token TIME_T
 307 %token TRANSPOSE
 308 %token TRANSPOSITION
 309 %token TYPE
 310 %token UNSET
 311 %token WITH
 312
 313 /* escaped */
 314 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 315 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 316 %token E_BACKSLASH
 317 %token <i> E_UNSIGNED
 318 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 319 %token FIGURE_SPACE
 320
 321 %type <i>       exclamations questions dots optional_rest
 322 %type <i>        bass_mod
 323 %type <scm>     grace_head
 324 %type <scm>     oct_check
 325 %type <scm>     context_mod_list
 326 %type <scm>     lyric_element
 327 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 328 %token <i>      DIGIT
 329 %token <scm>    NOTENAME_PITCH
 330 %token <scm>    TONICNAME_PITCH
 331 %token <scm>    CHORDMODIFIER_PITCH
 332 %token <scm>    DURATION_IDENTIFIER
 333 %token <scm>    FRACTION
 334 %token <id>     IDENTIFIER
 335 %token DRUMS
 336 %token <scm>    DRUM_PITCH
 337 %token <scm>    CHORD_MODIFIER
 338 %token <scm>    SCORE_IDENTIFIER
 339 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 340 %token <scm>    NUMBER_IDENTIFIER
 341 %token <scm>    EVENT_IDENTIFIER
 342 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 343 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 344 %token <scm>    RESTNAME
 345 %token <scm>    STRING
 346 %token <scm>    SCM_T
 347 %token <i>      UNSIGNED
 348 %token <scm>   REAL
 349
 350 %token MARKUP
 351 %token <scm> MARKUP_HEAD_MARKUP0
 352 %token <scm> MARKUP_HEAD_EMPTY
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 359
 360 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 361 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 362
 363 %type <outputdef> output_def
 364 %type <scm>     lilypond_header lilypond_header_body
 365 %type <music>   open_event close_event
 366 %type <i>       sub_quotes sup_quotes
 367 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 368 %type <music>   Repeated_music
 369 %type <scm>     Alternative_music
 370 %type <i>       tremolo_type
 371 %type <i>       bare_int  bare_unsigned
 372 %type <i>       script_dir
 373 %type <scm>     identifier_init
 374
 375 %type <music> note_chord_element chord_body chord_body_element
 376 %type <scm>  chord_body_elements
 377 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 378
 379 %type <scm>   post_events
 380 %type <music> gen_text_def direction_less_event direction_reqd_event
 381 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 382 %type <scm>    steno_tonic_pitch
 383 %type <scm>     duration_length fraction
 384
 385 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 386
 387 %type <scm>  embedded_scm scalar
 388 %type <music>   Music Sequential_music Simultaneous_music
 389 %type <music>   relative_music re_rhythmed_music
 390 %type <music>   music_property_def context_change
 391 %type <scm> context_prop_spec
 392 %type <scm> Music_list
 393 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 394 %type <outputdef>  music_output_def_body music_output_def_head
 395 %type <music>   post_event tagged_post_event
 396 %type <music> command_req
 397 %type <music> string_number_event
 398 %type <scm>     string bare_number number_expression number_term number_factor
 399 %type <score>   score_block score_body
 400
 401 %type <scm>     context_def_spec_block context_def_spec_body
 402 %type <music>   tempo_event
 403 %type <scm>     script_abbreviation
 404
 405
 406
 407 %left '-' '+'
 408
 409 /* We don't assign precedence to / and *, because we might need varied
 410 prec levels in different prods */
 411
 412 %left UNARY_MINUS
 413
 414 %%
 415
 416 lilypond:       /* empty */
 417         | lilypond toplevel_expression {}
 418         | lilypond assignment  { }
 419         | lilypond error {
 420                 THIS->error_level_  = 1;
 421         }
 422         | lilypond INVALID      {
 423                 THIS->error_level_  = 1;
 424         }
 425         ;
 426
 427 toplevel_expression:
 428         lilypond_header {
 429                 THIS->input_file_->header_ = $1;
 430         }
 431         | add_quote {
 432         }
 433         | score_block {
 434                 Score * sc = $1;
 435
 436                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 437
 438                 Path p = split_path (THIS->output_basename_);
 439                 int *c =  &THIS->input_file_->score_count_;
 440                 if (*c)
 441                         {
 442                         p.base += "-" + to_string (*c);
 443                         }
 444
 445                 (*c)++;
 446                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 447
 448                 for (int i=0; i < sc->defs_.size (); i++)
 449                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 450
 451                 if (sc->defs_.is_empty ())
 452                 {
 453                    Music_output_def *id =
 454                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 455                                 ("$defaultpaper"));
 456
 457                    id = id ? id->clone () : new Paper_def;
 458
 459                    default_rendering (sc->music_, id->self_scm (), head, outname);
 460                    scm_gc_unprotect_object (id->self_scm ());
 461                 }
 462                 scm_gc_unprotect_object (sc->self_scm ());
 463         }
 464         | output_def {
 465                 SCM id = SCM_EOL;
 466                 if (dynamic_cast<Paper_def*> ($1))
 467                         id = scm_makfrom0str ("$defaultpaper");
 468                 else if (dynamic_cast<Midi_def*> ($1))
 469                         id = scm_makfrom0str ("$defaultmidi");
 470                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 471                 scm_gc_unprotect_object ($1->self_scm ());
 472         }
 473         ;
 474
 475
 476 embedded_scm:
 477         SCM_T
 478         | SCM_IDENTIFIER
 479         ;
 480
 481
 482
 483
 484 lilypond_header_body:
 485         {
 486                 $$ = ly_make_anonymous_module ();
 487                 THIS->lexer_->add_scope ($$);
 488         }
 489         | lilypond_header_body assignment  {
 490
 491         }
 492         ;
 493
 494 lilypond_header:
 495         HEADER '{' lilypond_header_body '}'     {
 496                 $$ = THIS->lexer_->remove_scope ();
 497         }
 498         ;
 499
 500
 501 /*
 502         DECLARATIONS
 503 */
 504 assignment:
 505         STRING {
 506                 THIS->push_spot ();
 507         }
 508         /* cont */ '=' identifier_init  {
 509
 510         /*
 511                 Should find generic way of associating input with objects.
 512         */
 513                 Input ip = THIS->pop_spot ();
 514
 515                 if (! is_regular_identifier ($1))
 516                 {
 517                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 518                 }
 519
 520                 THIS->lexer_->set_identifier ($1, $4);
 521
 522 /*
 523  TODO: devise standard for protection in parser.
 524
 525   The parser stack lives on the C-stack, which means that
 526 all objects can be unprotected as soon as they're here.
 527
 528 */
 529         }
 530         | embedded_scm { }
 531         ;
 532
 533
 534 identifier_init:
 535         score_block {
 536                 $$ = $1->self_scm ();
 537                 scm_gc_unprotect_object ($$);
 538         }
 539         | full_markup {
 540                 $$ = $1;
 541         }
 542         | output_def {
 543                 $$ = $1->self_scm ();
 544                 scm_gc_unprotect_object ($$);
 545         }
 546         | context_def_spec_block {
 547                 $$ = $1;
 548         }
 549         | Music  {
 550                 $$ = $1->self_scm ();
 551                 scm_gc_unprotect_object ($$);
 552         }
 553         | post_event {
 554                 $$ = $1->self_scm ();
 555                 scm_gc_unprotect_object ($$);
 556         }
 557         | number_expression {
 558                 $$ = $1;
 559         }
 560         | string {
 561                 $$ = $1;
 562         }
 563         | embedded_scm  {
 564                 $$ = $1;
 565         }
 566         ;
 567
 568 context_def_spec_block:
 569         CONTEXT '{' context_def_spec_body '}'
 570                 {
 571                 $$ = $3;
 572         }
 573         ;
 574
 575 context_def_spec_body:
 576         /**/ {
 577                 $$ = Context_def::make_scm ();
 578                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 579         }
 580         | CONTEXT_DEF_IDENTIFIER        {
 581                 $$ = $1;
 582                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 583         }
 584         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 585                 Context_def*td = unsmob_context_def ($$);
 586
 587                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 588                         SCM tag = gh_caar (p);
 589
 590                         /* TODO: should make new tag "grob-definition" ? */
 591                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 592                                                         tag, gh_cons (ly_cdar (p), SCM_EOL)));
 593                 }
 594         }
 595         | context_def_spec_body context_mod {
 596                 unsmob_context_def ($$)->add_context_mod ($2);
 597         }
 598         ;
 599
 600 /*
 601         SCORE
 602 */
 603 score_block:
 604         SCORE {
 605                 THIS->push_spot ();
 606         }
 607         /*cont*/ '{' score_body '}'     {
 608                 THIS->pop_spot ();
 609                 $$ = $4;
 610
 611         }
 612         ;
 613
 614 score_body:
 615         Music   {
 616                 $$ = new Score;
 617
 618                 $$->set_spot (THIS->here_input ());
 619                 SCM m = $1->self_scm ();
 620                 scm_gc_unprotect_object (m);
 621
 622                 /*
 623                         guh.
 624                 */
 625                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 626                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 627                         m = gh_call1 (gh_car (check_funcs), m);
 628                 $$->music_ = m;
 629
 630         }
 631         | SCORE_IDENTIFIER {
 632                 $$ = new Score ( *unsmob_score ($1));
 633                 $$->set_spot (THIS->here_input ());
 634         }
 635         | score_body lilypond_header    {
 636                 $$->header_ = $2;
 637         }
 638         | score_body output_def {
 639                 $$->defs_.push ($2);
 640                 scm_gc_unprotect_object ($2->self_scm ());
 641         }
 642         | score_body error {
 643
 644         }
 645         ;
 646
 647
 648 /*
 649         MIDI
 650 */
 651 output_def:
 652         music_output_def_body '}' {
 653                 $$ = $1;
 654                 THIS-> lexer_-> remove_scope ();
 655         }
 656         ;
 657
 658 music_output_def_head:
 659         MIDI    {
 660                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 661
 662
 663                 Midi_def* p =0;
 664                 if (id)
 665                         p = dynamic_cast<Midi_def*> (id->clone ());
 666                 else
 667                         p = new Midi_def;
 668
 669                 $$ = p;
 670                 THIS->lexer_->add_scope (p->scope_);
 671         }
 672         | PAPER         {
 673                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 674                   Paper_def *p = 0;
 675                 if (id)
 676                         p = dynamic_cast<Paper_def*> (id->clone ());
 677                 else
 678                         p = new Paper_def;
 679
 680                 THIS->lexer_->add_scope (p->scope_);
 681                 $$ = p;
 682         }
 683         ;
 684
 685
 686 music_output_def_body:
 687         music_output_def_head '{' {
 688                 $$ = $1;
 689                 $$->input_origin_. set_spot (THIS->here_input ());
 690
 691         }
 692         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 693                 scm_gc_unprotect_object ($1->self_scm ());
 694                 Music_output_def * o =  unsmob_music_output_def ($3);
 695                 o->input_origin_.set_spot (THIS->here_input ());
 696                 $$ = o;
 697                 THIS->lexer_->remove_scope ();
 698                 THIS->lexer_->add_scope (o->scope_);
 699         }
 700         | music_output_def_body assignment  {
 701
 702         }
 703         | music_output_def_body context_def_spec_block  {
 704                 $$->assign_context_def ($2);
 705         }
 706         | music_output_def_body tempo_event  {
 707                 /*
 708                         junk this ? there already is tempo stuff in
 709                         music.
 710                 */
 711                 int m = gh_scm2int ( $2->get_property ("metronome-count"));
 712                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 713                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 714                 if (md)
 715                         md->set_tempo (d->get_length (), m);
 716                 scm_gc_unprotect_object ($2->self_scm ());
 717         }
 718         | music_output_def_body error {
 719
 720         }
 721         ;
 722
 723 tempo_event:
 724         TEMPO steno_duration '=' bare_unsigned  {
 725                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 726                 $$->set_property ("tempo-unit", $2);
 727                 $$->set_property ("metronome-count", gh_int2scm ( $4));
 728         }
 729         ;
 730
 731 /*
 732 The representation of a  list is the
 733
 734   (LIST . LAST-CONS)
 735
 736  to have  efficient append.
 737 */
 738 Music_list:
 739         /* empty */ {
 740                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 741         }
 742         | Music_list Music {
 743                 SCM s = $$;
 744                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 745                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 746                 if (gh_pair_p (ly_cdr (s)))
 747                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 748                 else
 749                         gh_set_car_x (s, c); /* set first cons */
 750                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 751         }
 752         | Music_list error {
 753         }
 754         ;
 755
 756
 757 Music:
 758         Simple_music
 759         | Composite_music
 760         ;
 761
 762 Alternative_music:
 763         /* empty */ {
 764                 $$ = SCM_EOL;
 765         }
 766         | ALTERNATIVE '{' Music_list '}' {
 767                 $$ = $3;
 768         }
 769         ;
 770
 771 Repeated_music:
 772         REPEAT string bare_unsigned Music Alternative_music
 773         {
 774                 Music *beg = $4;
 775                 int times = $3;
 776                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 777                 if (times < scm_ilength (alts)) {
 778                   unsmob_music (gh_car (alts))
 779                     ->origin ()->warning (
 780                     _("More alternatives than repeats.  Junking excess alternatives."));
 781                   alts = ly_truncate_list (times, alts);
 782                 }
 783
 784
 785                 static SCM proc;
 786                 if (!proc)
 787                         proc = scm_c_eval_string ("make-repeated-music");
 788
 789                 SCM mus = scm_call_1 (proc, $2);
 790                 scm_gc_protect_object (mus); // UGH.
 791                 Music *r =unsmob_music (mus);
 792                 if (beg)
 793                         {
 794                         r-> set_property ("element", beg->self_scm ());
 795                         scm_gc_unprotect_object (beg->self_scm ());
 796                         }
 797                 r->set_property ("repeat-count", gh_int2scm (times >? 1));
 798
 799                 r-> set_property ("elements",alts);
 800                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 801                         /*
 802                         we can not get durations and other stuff correct down the line, so we have to
 803                         add to the duration log here.
 804                         */
 805                         static SCM func;
 806
 807                         if (!func)
 808                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 809
 810                         int dots = ($3 % 3) ? 0 : 1;
 811                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 812
 813                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 814
 815                         if (seq) {
 816                                 int list_len =scm_ilength (seq->music_list ());
 817                                 if (list_len != 2)
 818                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 819                                 shift -= 1;
 820                                 r->compress (Moment (Rational (1,list_len)));
 821                                 }
 822                         gh_call3 (func, r->self_scm (), gh_int2scm (shift),gh_int2scm (dots));
 823
 824                 }
 825                 r->set_spot (*$4->origin ());
 826
 827                 $$ = r;
 828         }
 829         ;
 830
 831 Sequential_music:
 832         SEQUENTIAL '{' Music_list '}'           {
 833                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 834                 $$->set_property ("elements", ly_car ($3));
 835                 $$->set_spot (THIS->here_input ());
 836         }
 837         | '{' Music_list '}'            {
 838                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 839                 $$->set_property ("elements", ly_car ($2));
 840                 $$->set_spot (THIS->here_input ());
 841         }
 842         ;
 843
 844 Simultaneous_music:
 845         SIMULTANEOUS '{' Music_list '}'{
 846                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 847                 $$->set_property ("elements", ly_car ($3));
 848                 $$->set_spot (THIS->here_input ());
 849
 850         }
 851         | simul_open Music_list simul_close     {
 852                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 853                 $$->set_property ("elements", ly_car ($2));
 854                 $$->set_spot (THIS->here_input ());
 855         }
 856         ;
 857
 858 Simple_music:
 859         event_chord             { $$ = $1; }
 860         | APPLYOUTPUT embedded_scm {
 861                 if (!ly_input_procedure_p ($2))
 862                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 863                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 864                 $$->set_property ("procedure", $2);
 865                 $$->set_spot (THIS->here_input ());
 866         }
 867         | APPLYCONTEXT embedded_scm {
 868                 if (!ly_input_procedure_p ($2))
 869                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 870                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 871                 $$->set_property ("procedure", $2);
 872                 $$->set_spot (THIS->here_input ());
 873         }
 874         | MUSIC_IDENTIFIER {
 875                 $$ = unsmob_music ($1);
 876         }
 877         | music_property_def
 878         | context_change
 879         ;
 880
 881
 882 optional_context_mod:
 883         /**/ { $$ = SCM_EOL; }
 884         | WITH '{' context_mod_list '}'  { $$ = $3; }
 885         ;
 886
 887 grace_head:
 888         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 889         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 890         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 891         ;
 892
 893 context_mod_list:
 894         /* */  { $$ = SCM_EOL; }
 895         | context_mod_list context_mod  {
 896                  $$ = gh_cons ($2, $1);
 897         }
 898         ;
 899
 900 Composite_music:
 901         AUTOCHANGE Music        {
 902                 static SCM proc ;
 903                 if (!proc)
 904                         proc = scm_c_eval_string ("make-autochange-music");
 905
 906                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 907                 scm_gc_unprotect_object ($2->self_scm ());
 908                 $$ = unsmob_music (res);
 909                 scm_gc_protect_object (res);
 910                 $$->set_spot (THIS->here_input ());
 911         }
 912         | PARTCOMBINE Music Music {
 913                 static SCM proc;
 914                 if (!proc)
 915                         proc = scm_c_eval_string ("make-part-combine-music");
 916
 917                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 918                         $3->self_scm (), SCM_UNDEFINED));
 919                 scm_gc_unprotect_object ($3->self_scm ());
 920                 scm_gc_unprotect_object ($2->self_scm ());
 921                 $$ = unsmob_music (res);
 922                 scm_gc_protect_object (res);
 923                 $$->set_spot (THIS->here_input ());
 924         }
 925         | grace_head Music {
 926 #if 1
 927         /*
 928                 The other version is for easier debugging  of
 929                 Sequential_music_iterator in combination with grace notes.
 930         */
 931
 932 /*
 933
 934 TODO: should distinguish between both grace types in the
 935 basic music objects too, since the meaning is different.
 936
 937 */
 938
 939                 String start_str = "start" + ly_scm2string ($1) + "Music";
 940                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 941
 942                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 943                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 944
 945                 Music *startm = unsmob_music (start);
 946                 Music *stopm = unsmob_music (stop);
 947
 948                 SCM ms = SCM_EOL;
 949                 if (stopm) {
 950                         stopm = stopm->clone ();
 951                         ms = scm_cons (stopm->self_scm (), ms);
 952                         scm_gc_unprotect_object (stopm->self_scm ());
 953                 }
 954                 ms = scm_cons ($2->self_scm (), ms);
 955                 scm_gc_unprotect_object ($2->self_scm ());
 956                 if (startm) {
 957                         startm = startm->clone ();
 958                         ms = scm_cons (startm->self_scm () , ms);
 959                         scm_gc_unprotect_object (startm->self_scm ());
 960                 }
 961
 962                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 963                 seq->set_property ("elements", ms);
 964
 965
 966                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 967                 $$->set_property ("element", seq->self_scm ());
 968                 scm_gc_unprotect_object (seq->self_scm ());
 969 #else
 970                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 971                 $$->set_property ("element", $2->self_scm ());
 972                 scm_gc_unprotect_object ($2->self_scm ());
 973 #endif
 974         }
 975         | CONTEXT string '=' string optional_context_mod Music {
 976                 $$ = context_spec_music ($2, $4, $6, $5);
 977
 978         }
 979         | CONTEXT STRING optional_context_mod Music {
 980                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 981         }
 982         | NEWCONTEXT string optional_context_mod Music {
 983                 $$ = context_spec_music ($2, get_next_unique_context (),
 984                                          $4, $3);
 985         }
 986
 987         | TIMES {
 988                 THIS->push_spot ();
 989         }
 990         /* CONTINUED */
 991                 fraction Music
 992
 993         {
 994                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 995                 Music *mp = $4;
 996
 997                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 998                 $$->set_spot (THIS->pop_spot ());
 999
1000                 $$->set_property ("element", mp->self_scm ());
1001                 scm_gc_unprotect_object (mp->self_scm ());
1002                 $$->set_property ("numerator", gh_int2scm (n));
1003                 $$->set_property ("denominator", gh_int2scm (d));
1004                 $$->compress (Moment (Rational (n,d)));
1005
1006         }
1007         | Repeated_music                { $$ = $1; }
1008         | Simultaneous_music            { $$ = $1; }
1009         | Sequential_music              { $$ = $1; }
1010         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1011                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1012                 Music *p = $4;
1013                 Pitch from = *unsmob_pitch ($2);
1014                 Pitch to = *unsmob_pitch ($3);
1015
1016                 p->transpose (interval (from, to));
1017                 $$->set_property ("element", p->self_scm ());
1018                 scm_gc_unprotect_object (p->self_scm ());
1019         }
1020         | APPLY embedded_scm Music  {
1021                 if (!ly_input_procedure_p ($2))
1022                         {
1023                         THIS->parser_error (_ ("\\apply takes function argument"));
1024                         $$ = $3;
1025                         }
1026                 else
1027                         {
1028                         SCM ret = gh_call1 ($2, $3->self_scm ());
1029                         Music *m = unsmob_music (ret);
1030                         if (!m) {
1031                                 THIS->parser_error ("\\apply must return a Music");
1032                                 m = MY_MAKE_MUSIC ("Music");
1033                                 }
1034                         $$ = m;
1035                         }
1036         }
1037         | NOTES
1038                 {
1039                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1040                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1041         }
1042         Music
1043                 { $$ = $3;
1044                   THIS->lexer_->pop_state ();
1045                 }
1046         | DRUMS
1047                 {
1048                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1049                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1050         }
1051         Music
1052                 { $$ = $3;
1053                   THIS->lexer_->pop_state ();
1054                 }
1055         | FIGURES
1056                 { THIS->lexer_->push_figuredbass_state (); }
1057         Music
1058                 {
1059                   Music * chm = MY_MAKE_MUSIC ("UntransposableMusic");
1060                   chm->set_property ("element", $3->self_scm ());
1061                   $$ = chm;
1062                   scm_gc_unprotect_object ($3->self_scm ());
1063
1064                   THIS->lexer_->pop_state ();
1065         }
1066         | CHORDS {
1067                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1068                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1069                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1070                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1071
1072         } Music {
1073                   Music * chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1074                   chm->set_property ("element", $3->self_scm ());
1075                   scm_gc_unprotect_object ($3->self_scm ());
1076                   $$ = chm;
1077
1078                   THIS->lexer_->pop_state ();
1079         }
1080         | LYRICS
1081                 { THIS->lexer_->push_lyric_state (); }
1082         Music
1083                 {
1084                   $$ = $3;
1085                   THIS->lexer_->pop_state ();
1086         }
1087         | relative_music        { $$ = $1; }
1088         | re_rhythmed_music     { $$ = $1; }
1089         | TAG embedded_scm Music {
1090                 tag_music ($3, $2, THIS->here_input ());
1091                 $$ = $3;
1092         }
1093         ;
1094
1095 relative_music:
1096         RELATIVE absolute_pitch Music {
1097                 Music * p = $3;
1098                 Pitch pit = *unsmob_pitch ($2);
1099                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1100
1101                 $$->set_property ("element", p->self_scm ());
1102                 scm_gc_unprotect_object (p->self_scm ());
1103
1104
1105                 Pitch retpitch = p->to_relative_octave (pit);
1106                 if (lily_1_8_relative)
1107                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1108         }
1109         ;
1110
1111 re_rhythmed_music:
1112         ADDLYRICS Music Music {
1113         Music*l =MY_MAKE_MUSIC ("LyricCombineMusic");
1114           l->set_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1115           scm_gc_unprotect_object ($3->self_scm ());
1116           scm_gc_unprotect_object ($2->self_scm ());
1117           $$ = l;
1118         }
1119         | NEWADDLYRICS string Music {
1120           Music*l =MY_MAKE_MUSIC ("NewLyricCombineMusic");
1121           l->set_property ("element", $3->self_scm ());
1122           scm_gc_unprotect_object ($3->self_scm ());
1123           $$ = l;
1124           l->set_property ("associated-context", $2);
1125         }
1126         ;
1127
1128 context_change:
1129         CHANGE STRING '=' STRING  {
1130                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1131                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1132                 t-> set_property ("change-to-id", $4);
1133
1134                 $$ = t;
1135                 $$->set_spot (THIS->here_input ());
1136         }
1137         ;
1138
1139 property_operation:
1140         STRING '='  scalar {
1141                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1142                         scm_string_to_symbol ($1), $3);
1143         }
1144         | UNSET STRING {
1145                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1146                         scm_string_to_symbol ($2));
1147         }
1148         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1149                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1150                         scm_string_to_symbol ($2), $3, $5);
1151         }
1152         | REVERT STRING embedded_scm {
1153                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1154                         scm_string_to_symbol ($2), $3);
1155         }
1156         ;
1157
1158 context_def_mod:
1159         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1160         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1161         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1162
1163         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1164         | DENIES { $$ = ly_symbol2scm ("denies"); }
1165
1166         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1167         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1168         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1169         | NAME { $$ = ly_symbol2scm ("context-name"); }
1170         ;
1171
1172 context_mod:
1173         property_operation { $$ = $1; }
1174         | context_def_mod STRING {
1175                 $$ = scm_list_2 ($1, $2);
1176         }
1177         ;
1178
1179 context_prop_spec:
1180         STRING  {
1181                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1182         }
1183         | STRING '.' STRING {
1184                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1185         }
1186         ;
1187
1188 music_property_def:
1189         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1190                 $$ = property_op_to_music (scm_list_4 (
1191                         ly_symbol2scm ("poppush"),
1192                         gh_cadr ($2),
1193                         $3, $5));
1194                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1195         }
1196         | REVERT context_prop_spec embedded_scm {
1197                 $$ = property_op_to_music (scm_list_3 (
1198                         ly_symbol2scm ("pop"),
1199                         gh_cadr ($2),
1200                         $3));
1201
1202                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1203         }
1204         | SET context_prop_spec '=' scalar {
1205                 $$ = property_op_to_music (scm_list_3 (
1206                         ly_symbol2scm ("assign"),
1207                         gh_cadr ($2),
1208                         $4));
1209                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1210         }
1211         | UNSET context_prop_spec {
1212                 $$ = property_op_to_music (scm_list_2 (
1213                         ly_symbol2scm ("unset"),
1214                         gh_cadr ($2)));
1215                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1216         }
1217         | ONCE music_property_def {
1218                 SCM e = $2->get_property ("element");
1219                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1220                 $$ = $2;
1221
1222         }
1223         ;
1224
1225
1226
1227 scalar:
1228         string          { $$ = $1; }
1229         | bare_int      { $$ = gh_int2scm ($1); }
1230         | embedded_scm  { $$ = $1; }
1231         | full_markup {  $$ = $1; }
1232         | DIGIT { $$ = gh_int2scm ($1); }
1233         ;
1234
1235 /*
1236 This is a trick:
1237
1238 Adding pre_events to the simple_element
1239 makes the choice between
1240
1241   string:  STRING
1242
1243 and
1244
1245   simple_element: STRING
1246
1247 a single shift/reduction conflict.
1248
1249 nevertheless, this is not very clean, and we should find a different
1250 solution.
1251
1252 */
1253 pre_events: {
1254                 THIS->push_spot ();
1255         }
1256         ;
1257
1258 event_chord:
1259         pre_events simple_element post_events   {
1260                 SCM elts = $2-> get_property ("elements");
1261
1262                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1263
1264                 $2->set_property ("elements", elts);
1265                 $$ = $2;
1266         }
1267         | command_element
1268         | note_chord_element
1269         ;
1270
1271
1272 note_chord_element:
1273         chord_body optional_notemode_duration post_events
1274         {
1275                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1276                 SCM es = $1->get_property ("elements");
1277                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1278
1279                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1280                   unsmob_music (gh_car (s))->set_property ("duration", dur);
1281                 es = gh_append2 (es, postevs);
1282
1283                 $1-> set_property ("elements", es);
1284                 $$ = $1;
1285         }
1286         ;
1287
1288 chord_open: '<'
1289         ;
1290
1291 chord_close: '>'
1292         ;
1293
1294 simul_open: LESSLESS
1295         ;
1296
1297 simul_close: MOREMORE
1298         ;
1299
1300 chord_body:
1301         chord_open chord_body_elements chord_close
1302         {
1303                 $$ = MY_MAKE_MUSIC ("EventChord");
1304                 $$->set_property ("elements",
1305                         scm_reverse_x ($2, SCM_EOL));
1306         }
1307         ;
1308
1309 chord_body_elements:
1310         /* empty */             { $$ = SCM_EOL; }
1311         | chord_body_elements chord_body_element {
1312                 $$ = gh_cons ($2->self_scm (), $1);
1313                 scm_gc_unprotect_object ($2->self_scm ());
1314         }
1315         ;
1316
1317 chord_body_element:
1318         pitch exclamations questions post_events
1319         {
1320                 Music * n = MY_MAKE_MUSIC ("NoteEvent");
1321                 n->set_property ("pitch", $1);
1322                 if ($3 % 2)
1323                         n->set_property ("cautionary", SCM_BOOL_T);
1324                 if ($2 % 2 || $3 % 2)
1325                         n->set_property ("force-accidental", SCM_BOOL_T);
1326
1327                 if (gh_pair_p ($4)) {
1328                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1329                         n->set_property ("articulations", arts);
1330                 }
1331                 $$ = n;
1332         }
1333         | DRUM_PITCH post_events {
1334                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
1335                 n->set_property ("duration" ,$2);
1336                 n->set_property ("drum-type" , $1);
1337                 n->set_spot (THIS->here_input ());
1338
1339                 if (gh_pair_p ($2)) {
1340                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1341                         n->set_property ("articulations", arts);
1342                 }
1343                 $$ = n;
1344         }
1345         ;
1346
1347 add_quote:
1348         ADDQUOTE string Music {
1349                 static SCM adder;
1350                 if (!adder)
1351                         adder = scm_c_eval_string ("add-quotable");
1352
1353                 scm_call_2 (adder, $2, $3->self_scm ());
1354                 scm_gc_unprotect_object ($3->self_scm ());
1355         }
1356         ;
1357
1358 command_element:
1359         command_req {
1360                 $$ = MY_MAKE_MUSIC ("EventChord");
1361                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1362                 scm_gc_unprotect_object ($1->self_scm ());
1363
1364                 $$-> set_spot (THIS->here_input ());
1365                 $1-> set_spot (THIS->here_input ());
1366         }
1367         | SKIP duration_length {
1368                 Music * skip = MY_MAKE_MUSIC ("SkipMusic");
1369                 skip->set_property ("duration", $2);
1370
1371                 $$ = skip;
1372         }
1373         | QUOTE STRING duration_length {
1374                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1375                 SCM evs =  SCM_EOL;
1376                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1377                 {
1378                         SCM key = $2; // use symbol?
1379                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1380                 }
1381                 Music * quote = 0;
1382                 if (gh_vector_p (evs))
1383                 {
1384                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1385                         quote->set_property ("duration", $3);
1386                         quote->set_property ("quoted-events", evs);
1387                 } else {
1388                         THIS->here_input ().warning (_f ("Can\'t find music"));
1389                         quote = MY_MAKE_MUSIC ("Event");
1390                 }
1391                 quote->set_spot (THIS->here_input ());
1392                 $$ = quote;
1393         }
1394         | OCTAVE { THIS->push_spot (); }
1395           pitch {
1396                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1397                 $$ = l;
1398                 $$->set_spot (THIS->pop_spot ());
1399                 $$->set_property ("pitch", $3);
1400         }
1401         | E_LEFTSQUARE {
1402                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1403                 l->set_property ("span-direction", gh_int2scm (START));
1404                 l->set_spot (THIS->here_input ());
1405
1406                 $$ = MY_MAKE_MUSIC ("EventChord");
1407                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1408                 scm_gc_unprotect_object (l->self_scm ());
1409                 $$->set_spot (THIS->here_input ());
1410         }
1411         | E_RIGHTSQUARE {
1412                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1413                 l->set_property ("span-direction", gh_int2scm (STOP));
1414                 l->set_spot (THIS->here_input ());
1415
1416                 $$ = MY_MAKE_MUSIC ("EventChord");
1417                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1418                 $$->set_spot (THIS->here_input ());
1419                 scm_gc_unprotect_object (l->self_scm ());
1420         }
1421         | E_BACKSLASH {
1422                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1423                 $$->set_spot (THIS->here_input ());
1424         }
1425         | '|'      {
1426
1427                 $$ = MY_MAKE_MUSIC ("BarCheck");
1428                 $$->set_spot (THIS->here_input ());
1429         }
1430         | TRANSPOSITION pitch {
1431                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1432                                         $2);
1433                 $$->set_spot (THIS-> here_input ());
1434                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1435                         $$ , SCM_EOL);
1436         }
1437         | BAR STRING                    {
1438                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1439
1440                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1441                                         t, SCM_EOL);
1442                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1443                 $$->set_spot (THIS->here_input ());
1444                 t->set_spot (THIS->here_input ());
1445         }
1446         | PARTIAL duration_length       {
1447                 Moment m = - unsmob_duration ($2)->get_length ();
1448                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1449                 p->set_spot (THIS->here_input ());
1450                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1451                                         p, SCM_EOL);
1452                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1453                                         p, SCM_EOL);
1454                 $$ =p ;
1455         }
1456         | CLEF STRING  {
1457                 static SCM proc ;
1458                 if (!proc)
1459                         proc = scm_c_eval_string ("make-clef-set");
1460
1461                 SCM result = scm_call_1 (proc, $2);
1462                 scm_gc_protect_object (result);
1463                 $$ = unsmob_music (result);
1464         }
1465         | TIME_T fraction  {
1466                 static SCM proc;
1467                 if (!proc)
1468                         proc = scm_c_eval_string ("make-time-signature-set");
1469
1470                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1471                 scm_gc_protect_object (result);
1472                 $$ = unsmob_music (result);
1473         }
1474         | MARK scalar {
1475                 static SCM proc;
1476                 if (!proc)
1477                         proc = scm_c_eval_string ("make-mark-set");
1478
1479                 SCM result = scm_call_1 (proc, $2);
1480                 scm_gc_protect_object (result);
1481                 $$ = unsmob_music (result);
1482         }
1483         ;
1484
1485 command_req:
1486         BREATHE {
1487                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1488         }
1489         | E_TILDE {
1490                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1491         }
1492         | MARK DEFAULT  {
1493                 Music * m = MY_MAKE_MUSIC ("MarkEvent");
1494                 $$ = m;
1495         }
1496         | tempo_event {
1497                 $$ = $1;
1498         }
1499         | KEY DEFAULT {
1500                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1501                 $$ = key;
1502         }
1503         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1504
1505                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1506                 if (scm_ilength ($3) > 0)
1507                 {
1508                         key->set_property ("pitch-alist", $3);
1509                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1510                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1511                 } else {
1512                         THIS->parser_error (_("Second argument must be pitch list."));
1513                 }
1514
1515                 $$ = key;
1516         }
1517         ;
1518
1519 post_events:
1520         /* empty */ {
1521                 $$ = SCM_EOL;
1522         }
1523         | post_events post_event {
1524                 $2->set_spot (THIS->here_input ());
1525                 $$ = gh_cons ($2->self_scm (), $$);
1526                 scm_gc_unprotect_object ($2->self_scm ());
1527         }
1528         | post_events tagged_post_event {
1529                 $2 -> set_spot (THIS->here_input ());
1530                 $$ = scm_cons ($2->self_scm (), $$);
1531                 scm_gc_unprotect_object ($2->self_scm ());
1532         }
1533         ;
1534
1535
1536 tagged_post_event:
1537         '-' TAG embedded_scm post_event {
1538                 tag_music ($4, $3, THIS->here_input ());
1539                 $$ = $4;
1540         }
1541         ;
1542
1543 post_event:
1544         direction_less_event {
1545                 $$ = $1;
1546         }
1547         | HYPHEN {
1548                 if (!THIS->lexer_->is_lyric_state ())
1549                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1550                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1551         }
1552         | EXTENDER {
1553                 if (!THIS->lexer_->is_lyric_state ())
1554                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1555                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1556         }
1557         | script_dir direction_reqd_event {
1558                 if ($1)
1559                         $2->set_property ("direction", gh_int2scm ($1));
1560                 $$ = $2;
1561         }
1562         | script_dir direction_less_event {
1563                 if ($1)
1564                         $2->set_property ("direction", gh_int2scm ($1));
1565                 $$ = $2;
1566         }
1567         | string_number_event
1568         ;
1569
1570 string_number_event:
1571         E_UNSIGNED {
1572                 Music * s = MY_MAKE_MUSIC ("StringNumberEvent");
1573                 s->set_property ("string-number",  gh_int2scm ($1));
1574                 s->set_spot (THIS->here_input ());
1575                 $$ = s;
1576         }
1577         ;
1578
1579
1580 direction_less_event:
1581         '['  {
1582
1583
1584 /*
1585
1586 TODO: should take all these defs out of the parser, adn make use
1587 configurable, i.e.
1588
1589
1590 (set-articulation '~ "trill")
1591
1592 */
1593                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1594                 m->set_spot (THIS->here_input ());
1595                 m->set_property ("span-direction" , gh_int2scm (START));
1596                 $$ = m;
1597         }
1598         | ']'  {
1599                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1600                 m->set_spot (THIS->here_input ());
1601                 m->set_property ("span-direction" , gh_int2scm (STOP));
1602                 $$ = m;
1603         }
1604         | '~' {
1605                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1606                 m->set_spot (THIS->here_input ());
1607                 $$ = m;
1608         }
1609         | close_event {
1610                 $$ = $1;
1611                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1612                         gh_int2scm (START));
1613         }
1614         | open_event {
1615                 $$ = $1;
1616                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1617                         gh_int2scm (STOP));
1618         }
1619         | EVENT_IDENTIFIER      {
1620                 $$ = unsmob_music ($1);
1621         }
1622         | tremolo_type  {
1623                Music * a = MY_MAKE_MUSIC ("TremoloEvent");
1624                a->set_spot (THIS->here_input ());
1625                a->set_property ("tremolo-type", gh_int2scm ($1));
1626                $$ = a;
1627         }
1628         ;
1629
1630 direction_reqd_event:
1631         gen_text_def {
1632                 $$ = $1;
1633         }
1634         | script_abbreviation {
1635                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1636                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1637                 if (gh_string_p (s))
1638                         a->set_property ("articulation-type", s);
1639                 else THIS->parser_error (_ ("Expecting string as script definition"));
1640                 $$ = a;
1641         }
1642         ;
1643
1644 oct_check:
1645         /**/ { $$ = SCM_EOL; }
1646         | '='  { $$ = gh_int2scm (0); }
1647         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1648         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1649         ;
1650
1651 sup_quotes:
1652         '\'' {
1653                 $$ = 1;
1654         }
1655         | sup_quotes '\'' {
1656                 $$ ++;
1657         }
1658         ;
1659
1660 sub_quotes:
1661         ',' {
1662                 $$ = 1;
1663         }
1664         | sub_quotes ',' {
1665                 $$ ++ ;
1666         }
1667         ;
1668
1669 steno_pitch:
1670         NOTENAME_PITCH  {
1671                 $$ = $1;
1672         }
1673         | NOTENAME_PITCH sup_quotes     {
1674                 Pitch p = *unsmob_pitch ($1);
1675                 p = p.transposed (Pitch ($2,0,0));
1676                 $$ = p.smobbed_copy ();
1677         }
1678         | NOTENAME_PITCH sub_quotes      {
1679                 Pitch p =* unsmob_pitch ($1);
1680                 p = p.transposed (Pitch (-$2,0,0));
1681                 $$ = p.smobbed_copy ();
1682         }
1683         ;
1684
1685 /*
1686 ugh. duplication
1687 */
1688
1689 steno_tonic_pitch:
1690         TONICNAME_PITCH {
1691                 $$ = $1;
1692         }
1693         | TONICNAME_PITCH sup_quotes    {
1694                 Pitch p = *unsmob_pitch ($1);
1695                 p = p.transposed (Pitch ($2,0,0));
1696                 $$ = p.smobbed_copy ();
1697         }
1698         | TONICNAME_PITCH sub_quotes     {
1699                 Pitch p =* unsmob_pitch ($1);
1700
1701                 p = p.transposed (Pitch (-$2,0,0));
1702                 $$ = p.smobbed_copy ();
1703         }
1704         ;
1705
1706 pitch:
1707         steno_pitch {
1708                 $$ = $1;
1709         }
1710         ;
1711
1712 pitch_also_in_chords:
1713         pitch
1714         | steno_tonic_pitch
1715         ;
1716
1717 close_event:
1718         '('     {
1719                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1720                 $$ = s;
1721                 s->set_spot (THIS->here_input ());
1722         }
1723         | E_OPEN        {
1724                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1725                 $$ = s;
1726                 s->set_spot (THIS->here_input ());
1727         }
1728         | E_SMALLER {
1729                 Music *s =MY_MAKE_MUSIC ("CrescendoEvent");
1730                 $$ = s;
1731                 s->set_spot (THIS->here_input ());
1732         }
1733         | E_BIGGER {
1734                 Music *s =MY_MAKE_MUSIC ("DecrescendoEvent");
1735                 $$ = s;
1736                 s->set_spot (THIS->here_input ());
1737         }
1738         ;
1739
1740
1741 open_event:
1742         E_EXCLAMATION   {
1743                 Music *s =  MY_MAKE_MUSIC ("CrescendoEvent");
1744                 s->set_spot (THIS->here_input ());
1745
1746                 $$ = s;
1747         }
1748         | ')'   {
1749                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1750                 $$ = s;
1751                 s->set_spot (THIS->here_input ());
1752
1753         }
1754         | E_CLOSE       {
1755                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1756                 $$ = s;
1757                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1758                 s->set_spot (THIS->here_input ());
1759         }
1760         ;
1761
1762 gen_text_def:
1763         full_markup {
1764                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1765                 t->set_property ("text", $1);
1766                 t->set_spot (THIS->here_input ());
1767                 $$ = t;
1768         }
1769         | string {
1770                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1771                 t->set_property ("text", make_simple_markup ($1));
1772                 t->set_spot (THIS->here_input ());
1773                 $$ = t;
1774
1775         }
1776         | DIGIT {
1777                 Music * t = MY_MAKE_MUSIC ("FingerEvent");
1778                 t->set_property ("digit",  gh_int2scm ($1));
1779                 t->set_spot (THIS->here_input ());
1780                 $$ = t;
1781         }
1782         ;
1783
1784 script_abbreviation:
1785         '^'             {
1786                 $$ = scm_makfrom0str ("Hat");
1787         }
1788         | '+'           {
1789                 $$ = scm_makfrom0str ("Plus");
1790         }
1791         | '-'           {
1792                 $$ = scm_makfrom0str ("Dash");
1793         }
1794         | '|'           {
1795                 $$ = scm_makfrom0str ("Bar");
1796         }
1797         | '>'           {
1798                 $$ = scm_makfrom0str ("Larger");
1799         }
1800         | '.'           {
1801                 $$ = scm_makfrom0str ("Dot");
1802         }
1803         | '_' {
1804                 $$ = scm_makfrom0str ("Underscore");
1805         }
1806         ;
1807
1808 script_dir:
1809         '_'     { $$ = DOWN; }
1810         | '^'   { $$ = UP; }
1811         | '-'   { $$ = CENTER; }
1812         ;
1813
1814
1815 absolute_pitch:
1816         steno_pitch     {
1817                 $$ = $1;
1818         }
1819         ;
1820
1821 duration_length:
1822         multiplied_duration {
1823                 $$ = $1;
1824         }
1825         ;
1826
1827 optional_notemode_duration:
1828         {
1829                 Duration dd = THIS->default_duration_;
1830                 $$ = dd.smobbed_copy ();
1831
1832                 THIS->beam_check ($$);
1833         }
1834         | multiplied_duration   {
1835                 $$ = $1;
1836                 THIS->default_duration_ = *unsmob_duration ($$);
1837
1838                 THIS->beam_check ($$);
1839         }
1840         ;
1841
1842 steno_duration:
1843         bare_unsigned dots              {
1844                 int l = 0;
1845                 if (!is_is_duration ($1))
1846                         THIS->parser_error (_f ("not a duration: %d", $1));
1847                 else
1848                         l =  intlog2 ($1);
1849
1850                 $$ = Duration (l, $2).smobbed_copy ();
1851         }
1852         | DURATION_IDENTIFIER dots      {
1853                 Duration *d =unsmob_duration ($1);
1854                 Duration k (d->duration_log (),d->dot_count () + $2);
1855
1856                 *d = k;
1857                 $$ = $1;
1858         }
1859         ;
1860
1861
1862
1863
1864 multiplied_duration:
1865         steno_duration {
1866                 $$ = $1;
1867         }
1868         | multiplied_duration '*' bare_unsigned {
1869                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1870         }
1871         | multiplied_duration '*' FRACTION {
1872                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1873
1874                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1875         }
1876         ;
1877
1878 fraction:
1879         FRACTION { $$ = $1; }
1880         | UNSIGNED '/' UNSIGNED {
1881                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1882         }
1883         ;
1884
1885 dots:
1886         /* empty */     {
1887                 $$ = 0;
1888         }
1889         | dots '.' {
1890                 $$ ++;
1891         }
1892         ;
1893
1894
1895 tremolo_type:
1896         ':'     {
1897                 $$ =0;
1898         }
1899         | ':' bare_unsigned {
1900                 if (!is_is_duration ($2))
1901                         THIS->parser_error (_f ("not a duration: %d", $2));
1902                 $$ = $2;
1903         }
1904         ;
1905
1906
1907
1908 /*****************************************************************
1909                 BASS FIGURES
1910 *****************************************************************/
1911 bass_number:
1912         DIGIT   {
1913                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1914         }
1915         | UNSIGNED {
1916                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1917         }
1918         | STRING { $$ =  $1; }
1919         ;
1920
1921 bass_mod:
1922         '-'     { $$ = -2; }
1923         | '+'   { $$ = 2; }
1924         | '!'   { $$ = 0; }
1925         ;
1926
1927 bass_figure:
1928         FIGURE_SPACE {
1929                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1930                 $$ = bfr->self_scm ();
1931                 scm_gc_unprotect_object ($$);
1932         }
1933         | bass_number  {
1934                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1935                 $$ = bfr->self_scm ();
1936
1937                 bfr->set_property ("figure", $1);
1938
1939                 scm_gc_unprotect_object ($$);
1940         }
1941         | bass_figure bass_mod {
1942                 Music *m = unsmob_music ($1);
1943                 if ($2) {
1944                         SCM salter =m->get_property ("alteration");
1945                         int alter = gh_number_p (salter) ? gh_scm2int (salter) : 0;
1946                         m->set_property ("alteration",
1947                                 gh_int2scm (alter + $2));
1948                 } else {
1949                         m->set_property ("alteration", gh_int2scm (0));
1950                 }
1951         }
1952         ;
1953
1954 br_bass_figure:
1955         '[' bass_figure {
1956                 $$ = $2;
1957                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1958         }
1959         | bass_figure   {
1960                 $$ = $1;
1961         }
1962         | br_bass_figure ']' {
1963                 $$ = $1;
1964                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1965         }
1966         ;
1967
1968 figure_list:
1969         /**/            {
1970                 $$ = SCM_EOL;
1971         }
1972         | figure_list br_bass_figure {
1973                 $$ = scm_cons ($2, $1);
1974         }
1975         ;
1976
1977 figure_spec:
1978         FIGURE_OPEN figure_list FIGURE_CLOSE {
1979                 Music * m = MY_MAKE_MUSIC ("EventChord");
1980                 $2 = scm_reverse_x ($2, SCM_EOL);
1981                 m->set_property ("elements",  $2);
1982                 $$ = m->self_scm ();
1983         }
1984         ;
1985
1986
1987 optional_rest:
1988         /**/   { $$ = 0; }
1989         | REST { $$ = 1; }
1990         ;
1991
1992 simple_element:
1993         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1994
1995                 Input i = THIS->pop_spot ();
1996                 if (!THIS->lexer_->is_note_state ())
1997                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1998
1999                 Music *n = 0;
2000                 if ($6)
2001                         n =  MY_MAKE_MUSIC ("RestEvent");
2002                 else
2003                         n =  MY_MAKE_MUSIC ("NoteEvent");
2004
2005                 n->set_property ("pitch", $1);
2006                 n->set_property ("duration", $5);
2007
2008                 if (gh_number_p ($4))
2009                 {
2010                         int q = gh_scm2int ($4);
2011                         n->set_property ("absolute-octave", gh_int2scm (q-1));
2012                 }
2013
2014                 if ($3 % 2)
2015                         n->set_property ("cautionary", SCM_BOOL_T);
2016                 if ($2 % 2 || $3 % 2)
2017                         n->set_property ("force-accidental", SCM_BOOL_T);
2018
2019                 Music *v = MY_MAKE_MUSIC ("EventChord");
2020                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2021                 scm_gc_unprotect_object (n->self_scm ());
2022
2023                 v->set_spot (i);
2024                 n->set_spot (i);
2025                 $$ = v;
2026         }
2027         | DRUM_PITCH optional_notemode_duration {
2028                 Input i = THIS->pop_spot ();
2029
2030                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
2031                 n->set_property ("duration" ,$2);
2032                 n->set_property ("drum-type" , $1);
2033
2034                 Music *v = MY_MAKE_MUSIC ("EventChord");
2035                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2036                 scm_gc_unprotect_object (n->self_scm ());
2037                 v->set_spot (i);
2038                 n->set_spot (i);
2039                 $$ = v;
2040
2041         }
2042         | figure_spec optional_notemode_duration {
2043                 Music * m = unsmob_music ($1);
2044                 Input i = THIS->pop_spot ();
2045                 m->set_spot (i);
2046                 for (SCM s = m->get_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2047                 {
2048                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2049                 }
2050                 $$ = m;
2051         }
2052         | RESTNAME optional_notemode_duration           {
2053
2054                 Input i = THIS->pop_spot ();
2055                 Music * ev = 0;
2056                 if (ly_scm2string ($1) =="s") {
2057                         /* Space */
2058                         ev = MY_MAKE_MUSIC ("SkipEvent");
2059                   }
2060                 else {
2061                         ev = MY_MAKE_MUSIC ("RestEvent");
2062
2063                     }
2064                 ev->set_property ("duration" ,$2);
2065                 ev->set_spot (i);
2066                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2067                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2068                 velt->set_spot (i);
2069
2070                 scm_gc_unprotect_object (ev->self_scm ());
2071
2072                 $$ = velt;
2073         }
2074         | MULTI_MEASURE_REST optional_notemode_duration         {
2075                 THIS->pop_spot ();
2076
2077                 static SCM proc ;
2078                 if (!proc)
2079                         proc = scm_c_eval_string ("make-multi-measure-rest");
2080
2081                 SCM mus = scm_call_2 (proc, $2,
2082                         make_input (THIS->here_input ()));
2083                 scm_gc_protect_object (mus);
2084                 $$ = unsmob_music (mus);
2085         }
2086
2087         | lyric_element optional_notemode_duration      {
2088                 Input i = THIS->pop_spot ();
2089                 if (!THIS->lexer_->is_lyric_state ())
2090                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2091
2092                 Music * lreq = MY_MAKE_MUSIC ("LyricEvent");
2093                 lreq->set_property ("text", $1);
2094                 lreq->set_property ("duration",$2);
2095                 lreq->set_spot (i);
2096                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2097                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2098
2099                 $$= velt;
2100         }
2101         | new_chord {
2102                 THIS->pop_spot ();
2103
2104                 if (!THIS->lexer_->is_chord_state ())
2105                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2106                 $$ = unsmob_music ($1);
2107         }
2108         ;
2109
2110 lyric_element:
2111         full_markup { $$ = $1; }
2112         | STRING {  $$ = $1 ; }
2113         ;
2114
2115 new_chord:
2116         steno_tonic_pitch optional_notemode_duration   {
2117                 $$ = make_chord ($1, $2, SCM_EOL);
2118         }
2119         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2120                 SCM its = scm_reverse_x ($4, SCM_EOL);
2121                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2122         }
2123         ;
2124
2125 chord_items:
2126         /**/ {
2127                 $$ = SCM_EOL;
2128         }
2129         | chord_items chord_item {
2130                 $$ = gh_cons ($2, $$);
2131         }
2132         ;
2133
2134 chord_separator:
2135         CHORD_COLON {
2136                 $$ = ly_symbol2scm ("chord-colon");
2137         }
2138         | CHORD_CARET {
2139                 $$ = ly_symbol2scm ("chord-caret");
2140         }
2141         | CHORD_SLASH steno_tonic_pitch {
2142                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2143         }
2144         | CHORD_BASS steno_tonic_pitch {
2145                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2146         }
2147         ;
2148
2149 chord_item:
2150         chord_separator {
2151                 $$ = $1;
2152         }
2153         | step_numbers {
2154                 $$ = scm_reverse_x ($1, SCM_EOL);
2155         }
2156         | CHORD_MODIFIER  {
2157                 $$ = $1;
2158         }
2159         ;
2160
2161 step_numbers:
2162         step_number { $$ = gh_cons ($1, SCM_EOL); }
2163         | step_numbers '.' step_number {
2164                 $$ = gh_cons ($3, $$);
2165         }
2166         ;
2167
2168 step_number:
2169         bare_unsigned {
2170                 $$ = make_chord_step ($1, 0);
2171         }
2172         | bare_unsigned '+' {
2173                 $$ = make_chord_step ($1, SHARP);
2174         }
2175         | bare_unsigned CHORD_MINUS {
2176                 $$ = make_chord_step ($1, FLAT);
2177         }
2178         ;
2179
2180 /*
2181         UTILITIES
2182
2183 TODO: should deprecate in favor of Scheme?
2184
2185  */
2186 number_expression:
2187         number_expression '+' number_term {
2188                 $$ = scm_sum ($1, $3);
2189         }
2190         | number_expression '-' number_term {
2191                 $$ = scm_difference ($1, $3);
2192         }
2193         | number_term
2194         ;
2195
2196 number_term:
2197         number_factor {
2198                 $$ = $1;
2199         }
2200         | number_factor '*' number_factor {
2201                 $$ = scm_product ($1, $3);
2202         }
2203         | number_factor '/' number_factor {
2204                 $$ = scm_divide ($1, $3);
2205         }
2206         ;
2207
2208 number_factor:
2209         '-'  number_factor { /* %prec UNARY_MINUS */
2210                 $$ = scm_difference ($2, SCM_UNDEFINED);
2211         }
2212         | bare_number
2213         ;
2214
2215
2216 bare_number:
2217         UNSIGNED        {
2218                 $$ = gh_int2scm ($1);
2219         }
2220         | REAL          {
2221                 $$ = $1;
2222         }
2223         | NUMBER_IDENTIFIER             {
2224                 $$ = $1;
2225         }
2226         | REAL NUMBER_IDENTIFIER        {
2227                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2228         }
2229         | UNSIGNED NUMBER_IDENTIFIER    {
2230                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2231         }
2232         ;
2233
2234
2235 bare_unsigned:
2236         UNSIGNED {
2237                         $$ = $1;
2238         }
2239         | DIGIT {
2240                 $$ = $1;
2241         }
2242         ;
2243
2244 bare_int:
2245         bare_number {
2246                 if (scm_integer_p ($1) == SCM_BOOL_T)
2247                 {
2248                         int k = gh_scm2int ($1);
2249                         $$ = k;
2250                 } else
2251                 {
2252                         THIS->parser_error (_ ("need integer number arg"));
2253                         $$ = 0;
2254                 }
2255         }
2256         | '-' bare_int {
2257                 $$ = -$2;
2258         }
2259         ;
2260
2261
2262 string:
2263         STRING          {
2264                 $$ = $1;
2265         }
2266         | STRING_IDENTIFIER     {
2267                 $$ = $1;
2268         }
2269         | string '+' string {
2270                 $$ = scm_string_append (scm_list_2 ($1, $3));
2271         }
2272         ;
2273
2274
2275 exclamations:
2276                 { $$ = 0; }
2277         | exclamations '!'      { $$ ++; }
2278         ;
2279
2280 questions:
2281                 { $$ = 0; }
2282         | questions '?' { $$ ++; }
2283         ;
2284
2285
2286
2287 full_markup:
2288         MARKUP_IDENTIFIER {
2289                 $$ = $1;
2290         }
2291         | MARKUP
2292                 { THIS->lexer_->push_markup_state (); }
2293         markup
2294                 { $$ = $3;
2295                   THIS->lexer_->pop_state ();
2296                 }
2297         ;
2298
2299
2300 /*
2301 This should be done more dynamically if possible.
2302 */
2303 markup:
2304         STRING {
2305                 $$ = make_simple_markup ($1);
2306         }
2307         | MARKUP_HEAD_EMPTY {
2308                 $$ = scm_list_1 ($1);
2309         }
2310         | MARKUP_HEAD_MARKUP0 markup {
2311                 $$ = scm_list_2 ($1, $2);
2312         }
2313         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2314                 $$ = scm_list_3 ($1, $2, $3);
2315         }
2316         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2317                 $$  = scm_list_3 ($1, $2, $3);
2318         }
2319         | markup_line {
2320                 $$ = $1;
2321         }
2322         | MARKUP_HEAD_LIST0 markup_list {
2323                 $$ = scm_list_2 ($1,$2);
2324         }
2325         | MARKUP_HEAD_SCM0 embedded_scm {
2326                 $$ = scm_list_2 ($1, $2);
2327         }
2328         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2329                 $$ = scm_list_4 ($1, $2, $3, $4);
2330         }
2331         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2332                 $$ = scm_list_4 ($1, $2, $3, $4);
2333         }
2334         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2335                 $$ = scm_list_3 ($1, $2, $3);
2336         }
2337         | MARKUP_IDENTIFIER {
2338                 $$ = $1;
2339         }
2340         | STRING_IDENTIFIER {
2341                 $$ = $1;
2342         }
2343         ;
2344
2345 markup_list:
2346         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2347         ;
2348
2349 markup_line:
2350         '{' markup_list_body '}' {
2351                 static SCM line ;
2352                 if (!line)
2353                         line = scm_c_eval_string ("line-markup");
2354
2355                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2356         }
2357         ;
2358
2359 markup_list_body:
2360         /**/ {  $$ = SCM_EOL; }
2361         | markup_list_body markup {
2362                 $$ = gh_cons ($2, $1) ;
2363         }
2364         ;
2365
2366
2367 %%
2368
2369 void
2370 My_lily_parser::set_yydebug (bool )
2371 {
2372 #if 0
2373         yydebug = 1;
2374 #endif
2375 }
2376
2377 extern My_lily_parser * current_parser;
2378
2379 void
2380 My_lily_parser::do_yyparse ()
2381 {
2382         current_parser = this;;
2383         yyparse ((void*)this);
2384 }
2385
2386
2387 /*
2388 Should make this optional?    It will also complain when you do
2389
2390         [s4]
2391
2392 which is entirely legitimate.
2393
2394 Or we can scrap it. Barchecks should detect wrong durations, and
2395 skipTypesetting speeds it up a lot.
2396 */
2397
2398 void
2399 My_lily_parser::beam_check (SCM dur)
2400 {
2401   Duration *d = unsmob_duration (dur);
2402   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2403     {
2404       Music * m = unsmob_music (last_beam_start_);
2405       m->origin ()->warning (_("Suspect duration found following this beam"));
2406     }
2407   last_beam_start_ = SCM_EOL;
2408 }
2409
2410
2411
2412
2413 /*
2414
2415 It is a little strange to have this function in this file, but
2416 otherwise, we have to import music classes into the lexer.
2417
2418 */
2419 int
2420 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2421 {
2422         if (gh_string_p (sid)) {
2423                 *destination = sid;
2424                 return STRING_IDENTIFIER;
2425         } else if (gh_number_p (sid)) {
2426                 *destination = sid;
2427                 return NUMBER_IDENTIFIER;
2428         } else if (unsmob_context_def (sid)) {
2429                 *destination = unsmob_context_def (sid)->clone_scm ();
2430                 return CONTEXT_DEF_IDENTIFIER;
2431         } else if (unsmob_score (sid)) {
2432                 Score *sc =  new Score (*unsmob_score (sid));
2433                 *destination =sc->self_scm ();
2434                 return SCORE_IDENTIFIER;
2435         } else if (Music * mus =unsmob_music (sid)) {
2436                 mus = mus->clone ();
2437                 *destination = mus->self_scm ();
2438                 unsmob_music (*destination)->
2439                         set_property ("origin", make_input (last_input_));
2440                 return dynamic_cast<Event*> (mus)
2441                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2442         } else if (unsmob_duration (sid)) {
2443                 *destination = unsmob_duration (sid)->smobbed_copy ();
2444                 return DURATION_IDENTIFIER;
2445         } else if (unsmob_music_output_def (sid)) {
2446                 Music_output_def *p = unsmob_music_output_def (sid);
2447                 p = p->clone ();
2448
2449                 *destination = p->self_scm ();
2450                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2451         } else if (Text_item::markup_p (sid)) {
2452                 *destination = sid;
2453                 return MARKUP_IDENTIFIER;
2454         }
2455
2456         return -1;
2457 }
2458
2459 Music *
2460 property_op_to_music (SCM op)
2461 {
2462         Music * m = 0;
2463         SCM tag = gh_car (op);
2464         SCM symbol  = gh_cadr (op);
2465         SCM args = gh_cddr (op);
2466         SCM grob_val = SCM_UNDEFINED;
2467         SCM grob_sym = SCM_UNDEFINED;
2468         SCM val = SCM_UNDEFINED;
2469
2470         if (tag == ly_symbol2scm ("assign"))
2471                 {
2472                 m =  MY_MAKE_MUSIC ("PropertySet");
2473                 val = gh_car (args);
2474                 }
2475         else if (tag == ly_symbol2scm ("unset"))
2476                 m =  MY_MAKE_MUSIC ("PropertyUnset");
2477         else if (tag == ly_symbol2scm ("poppush")
2478                  || tag == ly_symbol2scm ("push"))
2479                 {
2480                 m  = MY_MAKE_MUSIC ("OverrideProperty");
2481                 grob_sym = gh_car (args);
2482                 grob_val = gh_cadr (args);
2483                 }
2484         else if (tag == ly_symbol2scm ("pop")) {
2485                 m = MY_MAKE_MUSIC ("RevertProperty");
2486                 grob_sym = gh_car (args);
2487                 }
2488
2489         m->set_property ("symbol", symbol);
2490
2491         if (val != SCM_UNDEFINED)
2492                 m->set_property ("value", val);
2493         if (grob_val != SCM_UNDEFINED)
2494                 m->set_property ("grob-value", grob_val);
2495
2496         if (grob_sym != SCM_UNDEFINED)
2497                 {
2498                 bool itc = internal_type_checking_global_b;
2499                 /* UGH.
2500                 */
2501                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2502                 if (autobeam)
2503                         internal_type_checking_global_b = false;
2504                 m->set_property ("grob-property", grob_sym);
2505                 if (autobeam)
2506                         internal_type_checking_global_b = itc;
2507                 }
2508
2509         if (op == ly_symbol2scm ("poppush"))
2510                 m->set_property ("pop-first", SCM_BOOL_T);
2511
2512
2513         return m;
2514 }
2515
2516 Music*
2517 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2518 {
2519         Music * csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2520
2521         csm->set_property ("element", m->self_scm ());
2522         scm_gc_unprotect_object (m->self_scm ());
2523
2524         csm->set_property ("context-type",
2525                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2526         csm->set_property ("property-operations", ops);
2527
2528         if (gh_string_p (id))
2529                 csm->set_property ("context-id", id);
2530         return csm;
2531 }
2532
2533
2534 SCM
2535 get_next_unique_context ()
2536 {
2537         static int new_context_count;
2538
2539         char s[1024];
2540         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2541
2542         return scm_makfrom0str (s);
2543 }
2544