lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-module.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83 #include "paper-book.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 is_regular_identifier (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128 /*
 129   isalpha (*s);
 130   s++;
 131 */
 132   while (*s && v)
 133    {
 134         v = v && isalnum (*s);
 135         s++;
 136    }
 137   return v;
 138 }
 139
 140 SCM
 141 make_simple_markup (SCM a)
 142 {
 143         SCM simple = ly_scheme_function ("simple-markup");
 144
 145         return scm_list_2 (simple, a);
 146 }
 147
 148
 149 bool
 150 is_is_duration (int t)
 151 {
 152   return t && t == 1 << intlog2 (t);
 153 }
 154
 155 void
 156 set_music_properties (Music *p, SCM a)
 157 {
 158   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 159         {
 160         p->internal_set_property (ly_caar (k), ly_cdar (k));
 161         }
 162 }
 163
 164 SCM
 165 make_chord_step (int step, int alter)
 166 {
 167         if (step == 7)
 168                 alter += FLAT;
 169
 170         while(step < 0)
 171                 step += 7;
 172         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 173         return m.smobbed_copy ();
 174 }
 175
 176
 177 SCM
 178 make_chord (SCM pitch, SCM dur, SCM modification_list)
 179 {
 180         SCM chord_ctor = ly_scheme_function ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC ("PropertySet");
 200         p->set_property ("symbol", sym);
 201         p->set_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token ();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token ADDQUOTE
 242 %token NEWADDLYRICS
 243 %token ALIAS
 244 %token ALTERNATIVE
 245 %token APPLY
 246 %token APPLYCONTEXT
 247 %token APPLYOUTPUT
 248 %token AUTOCHANGE
 249 %token BAR
 250 %token BREATHE
 251 %token CHANGE
 252 %token CHORDMODIFIERS
 253 %token CHORDS
 254 %token LESSLESS
 255 %token MOREMORE
 256 %token CLEF
 257 %token COMMANDSPANREQUEST
 258 %token CONSISTS
 259 %token CONSISTSEND
 260 %token CONTEXT
 261 %token DEFAULT
 262 %token DENIES
 263 %token DESCRIPTION
 264 %token EXTENDER
 265 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 266 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 267 %token GRACE
 268 %token ACCIACCATURA
 269 %token APPOGGIATURA
 270 %token GROBDESCRIPTIONS
 271 %token HEADER
 272 %token HYPHEN
 273 %token INVALID
 274 %token KEY
 275 %token LYRICS
 276 %token MARK
 277 %token MIDI
 278 %token MULTI_MEASURE_REST
 279 %token NAME
 280 %token NEWCONTEXT
 281 %token NOTES
 282 %token OCTAVE
 283 %token ONCE
 284 %token OVERRIDE SET REVERT
 285 %token PAPER
 286 %token PARTCOMBINE
 287 %token PARTIAL
 288 %token QUOTE
 289 %token RELATIVE
 290 %token REMOVE
 291 %token REPEAT
 292 %token REST
 293 %token SCM_T
 294 %token SCORE
 295 %token SEQUENTIAL
 296 %token SIMULTANEOUS
 297 %token SKIP
 298 %token SPANREQUEST
 299 %token TAG
 300 %token TEMPO
 301 %token TIMES
 302 %token TIME_T
 303 %token TRANSPOSE
 304 %token TRANSPOSITION
 305 %token TYPE
 306 %token UNSET
 307 %token WITH
 308
 309 /* escaped */
 310 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 311 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 312 %token E_BACKSLASH
 313 %token <i> E_UNSIGNED
 314 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 315 %token FIGURE_SPACE
 316
 317 %type <i>       exclamations questions dots optional_rest
 318 %type <i>        bass_mod
 319 %type <scm>     grace_head
 320 %type <scm>     oct_check
 321 %type <scm>     context_mod_list
 322 %type <scm>     lyric_element
 323 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 324 %token <i>      DIGIT
 325 %token <scm>    NOTENAME_PITCH
 326 %token <scm>    TONICNAME_PITCH
 327 %token <scm>    CHORDMODIFIER_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    FRACTION
 330 %token <id>     IDENTIFIER
 331 %token DRUMS
 332 %token <scm>    DRUM_PITCH
 333 %token <scm>    CHORD_MODIFIER
 334 %token <scm>    SCORE_IDENTIFIER
 335 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 336 %token <scm>    NUMBER_IDENTIFIER
 337 %token <scm>    EVENT_IDENTIFIER
 338 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 339 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 340 %token <scm>    RESTNAME
 341 %token <scm>    STRING
 342 %token <scm>    SCM_T
 343 %token <i>      UNSIGNED
 344 %token <scm>   REAL
 345
 346 %token MARKUP
 347 %token <scm> MARKUP_HEAD_MARKUP0
 348 %token <scm> MARKUP_HEAD_EMPTY
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 355
 356 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 357 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 358
 359 %type <outputdef> output_def
 360 %type <scm>     lilypond_header lilypond_header_body
 361 %type <music>   open_event close_event
 362 %type <i>       sub_quotes sup_quotes
 363 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 364 %type <music>   Repeated_music
 365 %type <scm>     Alternative_music
 366 %type <i>       tremolo_type
 367 %type <i>       bare_int  bare_unsigned
 368 %type <i>       script_dir
 369 %type <scm>     identifier_init
 370
 371 %type <music> note_chord_element chord_body chord_body_element
 372 %type <scm>  chord_body_elements
 373 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 374
 375 %type <scm>   post_events
 376 %type <music> gen_text_def direction_less_event direction_reqd_event
 377 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 378 %type <scm>    steno_tonic_pitch
 379 %type <scm>     duration_length fraction
 380
 381 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 382
 383 %type <scm>  embedded_scm scalar
 384 %type <music>   Music Sequential_music Simultaneous_music
 385 %type <music>   relative_music re_rhythmed_music
 386 %type <music>   music_property_def context_change
 387 %type <scm> context_prop_spec
 388 %type <scm> Music_list
 389 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 390 %type <outputdef>  music_output_def_body music_output_def_head
 391 %type <music>   post_event tagged_post_event
 392 %type <music> command_req
 393 %type <music> string_number_event
 394 %type <scm>     string bare_number number_expression number_term number_factor
 395 %type <score>   score_block score_body
 396
 397 %type <scm>     context_def_spec_block context_def_spec_body
 398 %type <music>   tempo_event
 399 %type <scm>     script_abbreviation
 400
 401
 402
 403 %left '-' '+'
 404
 405 /* We don't assign precedence to / and *, because we might need varied
 406 prec levels in different prods */
 407
 408 %left UNARY_MINUS
 409
 410 %%
 411
 412 lilypond:       /* empty */
 413         | lilypond toplevel_expression {}
 414         | lilypond assignment  { }
 415         | lilypond error {
 416                 THIS->error_level_  = 1;
 417         }
 418         | lilypond INVALID      {
 419                 THIS->error_level_  = 1;
 420         }
 421         ;
 422
 423 toplevel_expression:
 424         lilypond_header {
 425                 THIS->input_file_->header_ = $1;
 426         }
 427         | add_quote {
 428         }
 429         | score_block {
 430                 Score * sc = $1;
 431
 432                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 433
 434                 Path p = split_path (THIS->output_basename_);
 435                 int *c =  &THIS->input_file_->score_count_;
 436                 if (*c)
 437                         {
 438                         p.base += "-" + to_string (*c);
 439                         }
 440
 441                 (*c)++;
 442                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 443
 444                 for (int i=0; i < sc->defs_.size (); i++)
 445                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 446
 447                 if (sc->defs_.is_empty ())
 448                 {
 449                    Music_output_def *id =
 450                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 451                                 ("$defaultpaper"));
 452
 453                    id = id ? id->clone () : new Paper_def;
 454
 455                    default_rendering (sc->music_, id->self_scm (), head, outname);
 456                    scm_gc_unprotect_object (id->self_scm ());
 457                 }
 458                 scm_gc_unprotect_object (sc->self_scm ());
 459         }
 460         | output_def {
 461                 SCM id = SCM_EOL;
 462                 if (dynamic_cast<Paper_def*> ($1))
 463                         id = scm_makfrom0str ("$defaultpaper");
 464                 else if (dynamic_cast<Midi_def*> ($1))
 465                         id = scm_makfrom0str ("$defaultmidi");
 466                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 467                 scm_gc_unprotect_object ($1->self_scm ());
 468         }
 469         ;
 470
 471
 472 embedded_scm:
 473         SCM_T
 474         | SCM_IDENTIFIER
 475         ;
 476
 477
 478
 479
 480 lilypond_header_body:
 481         {
 482                 $$ = ly_make_anonymous_module ();
 483                 THIS->lexer_->add_scope ($$);
 484         }
 485         | lilypond_header_body assignment  {
 486
 487         }
 488         ;
 489
 490 lilypond_header:
 491         HEADER '{' lilypond_header_body '}'     {
 492                 $$ = THIS->lexer_->remove_scope ();
 493         }
 494         ;
 495
 496
 497 /*
 498         DECLARATIONS
 499 */
 500 assignment:
 501         STRING {
 502                 THIS->push_spot ();
 503         }
 504         /* cont */ '=' identifier_init  {
 505
 506         /*
 507                 Should find generic way of associating input with objects.
 508         */
 509                 Input ip = THIS->pop_spot ();
 510
 511                 if (! is_regular_identifier ($1))
 512                 {
 513                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 514                 }
 515
 516                 THIS->lexer_->set_identifier ($1, $4);
 517
 518 /*
 519  TODO: devise standard for protection in parser.
 520
 521   The parser stack lives on the C-stack, which means that
 522 all objects can be unprotected as soon as they're here.
 523
 524 */
 525         }
 526         | embedded_scm { }
 527         ;
 528
 529
 530 identifier_init:
 531         score_block {
 532                 $$ = $1->self_scm ();
 533                 scm_gc_unprotect_object ($$);
 534         }
 535         | full_markup {
 536                 $$ = $1;
 537         }
 538         | output_def {
 539                 $$ = $1->self_scm ();
 540                 scm_gc_unprotect_object ($$);
 541         }
 542         | context_def_spec_block {
 543                 $$ = $1;
 544         }
 545         | Music  {
 546                 $$ = $1->self_scm ();
 547                 scm_gc_unprotect_object ($$);
 548         }
 549         | post_event {
 550                 $$ = $1->self_scm ();
 551                 scm_gc_unprotect_object ($$);
 552         }
 553         | number_expression {
 554                 $$ = $1;
 555         }
 556         | string {
 557                 $$ = $1;
 558         }
 559         | embedded_scm  {
 560                 $$ = $1;
 561         }
 562         ;
 563
 564 context_def_spec_block:
 565         CONTEXT '{' context_def_spec_body '}'
 566                 {
 567                 $$ = $3;
 568         }
 569         ;
 570
 571 context_def_spec_body:
 572         /**/ {
 573                 $$ = Context_def::make_scm ();
 574                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 575         }
 576         | CONTEXT_DEF_IDENTIFIER        {
 577                 $$ = $1;
 578                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 579         }
 580         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 581                 Context_def*td = unsmob_context_def ($$);
 582
 583                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 584                         SCM tag = gh_caar (p);
 585
 586                         /* TODO: should make new tag "grob-definition" ? */
 587                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 588                                                         tag, gh_cons (ly_cdar (p), SCM_EOL)));
 589                 }
 590         }
 591         | context_def_spec_body context_mod {
 592                 unsmob_context_def ($$)->add_context_mod ($2);
 593         }
 594         ;
 595
 596 /*
 597         SCORE
 598 */
 599 score_block:
 600         SCORE {
 601                 THIS->push_spot ();
 602         }
 603         /*cont*/ '{' score_body '}'     {
 604                 THIS->pop_spot ();
 605                 $$ = $4;
 606
 607         }
 608         ;
 609
 610 score_body:
 611         Music   {
 612                 $$ = new Score;
 613
 614                 $$->set_spot (THIS->here_input ());
 615                 SCM m = $1->self_scm ();
 616                 scm_gc_unprotect_object (m);
 617
 618                 /*
 619                         guh.
 620                 */
 621                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 622                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 623                         m = gh_call1 (gh_car (check_funcs), m);
 624                 $$->music_ = m;
 625
 626         }
 627         | SCORE_IDENTIFIER {
 628                 $$ = new Score ( *unsmob_score ($1));
 629                 $$->set_spot (THIS->here_input ());
 630         }
 631         | score_body lilypond_header    {
 632                 $$->header_ = $2;
 633         }
 634         | score_body output_def {
 635                 $$->defs_.push ($2);
 636                 scm_gc_unprotect_object ($2->self_scm ());
 637         }
 638         | score_body error {
 639
 640         }
 641         ;
 642
 643
 644 /*
 645         MIDI
 646 */
 647 output_def:
 648         music_output_def_body '}' {
 649                 $$ = $1;
 650                 THIS-> lexer_-> remove_scope ();
 651         }
 652         ;
 653
 654 music_output_def_head:
 655         MIDI    {
 656                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 657
 658
 659                 Midi_def* p =0;
 660                 if (id)
 661                         p = dynamic_cast<Midi_def*> (id->clone ());
 662                 else
 663                         p = new Midi_def;
 664
 665                 $$ = p;
 666                 THIS->lexer_->add_scope (p->scope_);
 667         }
 668         | PAPER         {
 669                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 670                   Paper_def *p = 0;
 671                 if (id)
 672                         p = dynamic_cast<Paper_def*> (id->clone ());
 673                 else
 674                         p = new Paper_def;
 675
 676                 THIS->lexer_->add_scope (p->scope_);
 677                 $$ = p;
 678         }
 679         ;
 680
 681
 682 music_output_def_body:
 683         music_output_def_head '{' {
 684                 $$ = $1;
 685                 $$->input_origin_. set_spot (THIS->here_input ());
 686
 687         }
 688         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 689                 scm_gc_unprotect_object ($1->self_scm ());
 690                 Music_output_def * o =  unsmob_music_output_def ($3);
 691                 o->input_origin_.set_spot (THIS->here_input ());
 692                 $$ = o;
 693                 THIS->lexer_->remove_scope ();
 694                 THIS->lexer_->add_scope (o->scope_);
 695         }
 696         | music_output_def_body assignment  {
 697
 698         }
 699         | music_output_def_body context_def_spec_block  {
 700                 $$->assign_context_def ($2);
 701         }
 702         | music_output_def_body tempo_event  {
 703                 /*
 704                         junk this ? there already is tempo stuff in
 705                         music.
 706                 */
 707                 int m = gh_scm2int ( $2->get_property ("metronome-count"));
 708                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 709                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 710                 if (md)
 711                         md->set_tempo (d->get_length (), m);
 712                 scm_gc_unprotect_object ($2->self_scm ());
 713         }
 714         | music_output_def_body error {
 715
 716         }
 717         ;
 718
 719 tempo_event:
 720         TEMPO steno_duration '=' bare_unsigned  {
 721                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 722                 $$->set_property ("tempo-unit", $2);
 723                 $$->set_property ("metronome-count", gh_int2scm ( $4));
 724         }
 725         ;
 726
 727 /*
 728 The representation of a  list is the
 729
 730   (LIST . LAST-CONS)
 731
 732  to have  efficient append.
 733 */
 734 Music_list:
 735         /* empty */ {
 736                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 737         }
 738         | Music_list Music {
 739                 SCM s = $$;
 740                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 741                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 742                 if (gh_pair_p (ly_cdr (s)))
 743                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 744                 else
 745                         gh_set_car_x (s, c); /* set first cons */
 746                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 747         }
 748         | Music_list error {
 749         }
 750         ;
 751
 752
 753 Music:
 754         Simple_music
 755         | Composite_music
 756         ;
 757
 758 Alternative_music:
 759         /* empty */ {
 760                 $$ = SCM_EOL;
 761         }
 762         | ALTERNATIVE '{' Music_list '}' {
 763                 $$ = $3;
 764         }
 765         ;
 766
 767 Repeated_music:
 768         REPEAT string bare_unsigned Music Alternative_music
 769         {
 770                 Music *beg = $4;
 771                 int times = $3;
 772                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 773                 if (times < scm_ilength (alts)) {
 774                   unsmob_music (gh_car (alts))
 775                     ->origin ()->warning (
 776                     _("More alternatives than repeats.  Junking excess alternatives."));
 777                   alts = ly_truncate_list (times, alts);
 778                 }
 779
 780
 781                 SCM proc = ly_scheme_function ("make-repeated-music");
 782
 783                 SCM mus = scm_call_1 (proc, $2);
 784                 scm_gc_protect_object (mus); // UGH.
 785                 Music *r =unsmob_music (mus);
 786                 if (beg)
 787                         {
 788                         r-> set_property ("element", beg->self_scm ());
 789                         scm_gc_unprotect_object (beg->self_scm ());
 790                         }
 791                 r->set_property ("repeat-count", gh_int2scm (times >? 1));
 792
 793                 r-> set_property ("elements",alts);
 794                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 795                         /*
 796                         TODO: move this code to Scheme.
 797                         */
 798
 799                         /*
 800                         we can not get durations and other stuff correct down the line, so we have to
 801                         add to the duration log here.
 802                         */
 803                         SCM func = ly_scheme_function ("shift-duration-log");
 804
 805                         int dots = ($3 % 3) ? 0 : 1;
 806                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 807
 808                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 809
 810                         if (seq) {
 811                                 int list_len =scm_ilength (seq->music_list ());
 812                                 if (list_len != 2)
 813                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 814                                 shift -= 1;
 815                                 r->compress (Moment (Rational (1, list_len)));
 816                                 }
 817                         gh_call3 (func, r->self_scm (), gh_int2scm (shift),gh_int2scm (dots));
 818
 819                 }
 820                 r->set_spot (*$4->origin ());
 821
 822                 $$ = r;
 823         }
 824         ;
 825
 826 Sequential_music:
 827         SEQUENTIAL '{' Music_list '}'           {
 828                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 829                 $$->set_property ("elements", ly_car ($3));
 830                 $$->set_spot (THIS->here_input ());
 831         }
 832         | '{' Music_list '}'            {
 833                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 834                 $$->set_property ("elements", ly_car ($2));
 835                 $$->set_spot (THIS->here_input ());
 836         }
 837         ;
 838
 839 Simultaneous_music:
 840         SIMULTANEOUS '{' Music_list '}'{
 841                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 842                 $$->set_property ("elements", ly_car ($3));
 843                 $$->set_spot (THIS->here_input ());
 844
 845         }
 846         | simul_open Music_list simul_close     {
 847                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 848                 $$->set_property ("elements", ly_car ($2));
 849                 $$->set_spot (THIS->here_input ());
 850         }
 851         ;
 852
 853 Simple_music:
 854         event_chord             { $$ = $1; }
 855         | APPLYOUTPUT embedded_scm {
 856                 if (!ly_input_procedure_p ($2))
 857                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 858                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 859                 $$->set_property ("procedure", $2);
 860                 $$->set_spot (THIS->here_input ());
 861         }
 862         | APPLYCONTEXT embedded_scm {
 863                 if (!ly_input_procedure_p ($2))
 864                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 865                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 866                 $$->set_property ("procedure", $2);
 867                 $$->set_spot (THIS->here_input ());
 868         }
 869         | MUSIC_IDENTIFIER {
 870                 $$ = unsmob_music ($1);
 871         }
 872         | music_property_def
 873         | context_change
 874         ;
 875
 876
 877 optional_context_mod:
 878         /**/ { $$ = SCM_EOL; }
 879         | WITH '{' context_mod_list '}'  { $$ = $3; }
 880         ;
 881
 882 grace_head:
 883         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 884         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 885         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 886         ;
 887
 888 context_mod_list:
 889         /* */  { $$ = SCM_EOL; }
 890         | context_mod_list context_mod  {
 891                  $$ = gh_cons ($2, $1);
 892         }
 893         ;
 894
 895 Composite_music:
 896         AUTOCHANGE Music        {
 897                 SCM proc = ly_scheme_function ("make-autochange-music");
 898
 899                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 900                 scm_gc_unprotect_object ($2->self_scm ());
 901                 $$ = unsmob_music (res);
 902                 scm_gc_protect_object (res);
 903                 $$->set_spot (THIS->here_input ());
 904         }
 905         | PARTCOMBINE Music Music {
 906                 SCM proc = ly_scheme_function ("make-part-combine-music");
 907
 908                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 909                         $3->self_scm (), SCM_UNDEFINED));
 910                 scm_gc_unprotect_object ($3->self_scm ());
 911                 scm_gc_unprotect_object ($2->self_scm ());
 912                 $$ = unsmob_music (res);
 913                 scm_gc_protect_object (res);
 914                 $$->set_spot (THIS->here_input ());
 915         }
 916         | grace_head Music {
 917 #if 1
 918         /*
 919                 The other version is for easier debugging  of
 920                 Sequential_music_iterator in combination with grace notes.
 921         */
 922
 923 /*
 924
 925 TODO: should distinguish between both grace types in the
 926 basic music objects too, since the meaning is different.
 927
 928 */
 929
 930                 String start_str = "start" + ly_scm2string ($1) + "Music";
 931                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 932
 933                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 934                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 935
 936                 Music *startm = unsmob_music (start);
 937                 Music *stopm = unsmob_music (stop);
 938
 939                 SCM ms = SCM_EOL;
 940                 if (stopm) {
 941                         stopm = stopm->clone ();
 942                         ms = scm_cons (stopm->self_scm (), ms);
 943                         scm_gc_unprotect_object (stopm->self_scm ());
 944                 }
 945                 ms = scm_cons ($2->self_scm (), ms);
 946                 scm_gc_unprotect_object ($2->self_scm ());
 947                 if (startm) {
 948                         startm = startm->clone ();
 949                         ms = scm_cons (startm->self_scm () , ms);
 950                         scm_gc_unprotect_object (startm->self_scm ());
 951                 }
 952
 953                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 954                 seq->set_property ("elements", ms);
 955
 956
 957                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 958                 $$->set_property ("element", seq->self_scm ());
 959                 scm_gc_unprotect_object (seq->self_scm ());
 960 #else
 961                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 962                 $$->set_property ("element", $2->self_scm ());
 963                 scm_gc_unprotect_object ($2->self_scm ());
 964 #endif
 965         }
 966         | CONTEXT string '=' string optional_context_mod Music {
 967                 $$ = context_spec_music ($2, $4, $6, $5);
 968
 969         }
 970         | CONTEXT STRING optional_context_mod Music {
 971                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 972         }
 973         | NEWCONTEXT string optional_context_mod Music {
 974                 $$ = context_spec_music ($2, get_next_unique_context (),
 975                                          $4, $3);
 976         }
 977
 978         | TIMES {
 979                 THIS->push_spot ();
 980         }
 981         /* CONTINUED */
 982                 fraction Music
 983
 984         {
 985                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 986                 Music *mp = $4;
 987
 988                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 989                 $$->set_spot (THIS->pop_spot ());
 990
 991                 $$->set_property ("element", mp->self_scm ());
 992                 scm_gc_unprotect_object (mp->self_scm ());
 993                 $$->set_property ("numerator", gh_int2scm (n));
 994                 $$->set_property ("denominator", gh_int2scm (d));
 995                 $$->compress (Moment (Rational (n,d)));
 996
 997         }
 998         | Repeated_music                { $$ = $1; }
 999         | Simultaneous_music            { $$ = $1; }
1000         | Sequential_music              { $$ = $1; }
1001         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1002                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1003                 Music *p = $4;
1004                 Pitch from = *unsmob_pitch ($2);
1005                 Pitch to = *unsmob_pitch ($3);
1006
1007                 p->transpose (interval (from, to));
1008                 $$->set_property ("element", p->self_scm ());
1009                 scm_gc_unprotect_object (p->self_scm ());
1010         }
1011         | APPLY embedded_scm Music  {
1012                 if (!ly_input_procedure_p ($2))
1013                         {
1014                         THIS->parser_error (_ ("\\apply takes function argument"));
1015                         $$ = $3;
1016                         }
1017                 else
1018                         {
1019                         SCM ret = gh_call1 ($2, $3->self_scm ());
1020                         Music *m = unsmob_music (ret);
1021                         if (!m) {
1022                                 THIS->parser_error ("\\apply must return a Music");
1023                                 m = MY_MAKE_MUSIC ("Music");
1024                                 }
1025                         $$ = m;
1026                         }
1027         }
1028         | NOTES
1029                 {
1030                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1031                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1032         }
1033         Music
1034                 { $$ = $3;
1035                   THIS->lexer_->pop_state ();
1036                 }
1037         | DRUMS
1038                 {
1039                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1040                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1041         }
1042         Music
1043                 { $$ = $3;
1044                   THIS->lexer_->pop_state ();
1045                 }
1046         | FIGURES
1047                 { THIS->lexer_->push_figuredbass_state (); }
1048         Music
1049                 {
1050                   Music * chm = MY_MAKE_MUSIC ("UntransposableMusic");
1051                   chm->set_property ("element", $3->self_scm ());
1052                   $$ = chm;
1053                   scm_gc_unprotect_object ($3->self_scm ());
1054
1055                   THIS->lexer_->pop_state ();
1056         }
1057         | CHORDS {
1058                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1059                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1060                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1061                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1062
1063         } Music {
1064                   Music * chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1065                   chm->set_property ("element", $3->self_scm ());
1066                   scm_gc_unprotect_object ($3->self_scm ());
1067                   $$ = chm;
1068
1069                   THIS->lexer_->pop_state ();
1070         }
1071         | LYRICS
1072                 { THIS->lexer_->push_lyric_state (); }
1073         Music
1074                 {
1075                   $$ = $3;
1076                   THIS->lexer_->pop_state ();
1077         }
1078         | relative_music        { $$ = $1; }
1079         | re_rhythmed_music     { $$ = $1; }
1080         | TAG embedded_scm Music {
1081                 tag_music ($3, $2, THIS->here_input ());
1082                 $$ = $3;
1083         }
1084         ;
1085
1086 relative_music:
1087         RELATIVE absolute_pitch Music {
1088                 Music * p = $3;
1089                 Pitch pit = *unsmob_pitch ($2);
1090                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1091
1092                 $$->set_property ("element", p->self_scm ());
1093                 scm_gc_unprotect_object (p->self_scm ());
1094
1095
1096                 Pitch retpitch = p->to_relative_octave (pit);
1097                 if (lily_1_8_relative)
1098                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1099         }
1100         ;
1101
1102 re_rhythmed_music:
1103         ADDLYRICS Music Music {
1104         Music*l =MY_MAKE_MUSIC ("LyricCombineMusic");
1105           l->set_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1106           scm_gc_unprotect_object ($3->self_scm ());
1107           scm_gc_unprotect_object ($2->self_scm ());
1108           $$ = l;
1109         }
1110         | NEWADDLYRICS string Music {
1111           Music*l =MY_MAKE_MUSIC ("NewLyricCombineMusic");
1112           l->set_property ("element", $3->self_scm ());
1113           scm_gc_unprotect_object ($3->self_scm ());
1114           $$ = l;
1115           l->set_property ("associated-context", $2);
1116         }
1117         ;
1118
1119 context_change:
1120         CHANGE STRING '=' STRING  {
1121                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1122                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1123                 t-> set_property ("change-to-id", $4);
1124
1125                 $$ = t;
1126                 $$->set_spot (THIS->here_input ());
1127         }
1128         ;
1129
1130 property_operation:
1131         STRING '='  scalar {
1132                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1133                         scm_string_to_symbol ($1), $3);
1134         }
1135         | UNSET STRING {
1136                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1137                         scm_string_to_symbol ($2));
1138         }
1139         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1140                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1141                         scm_string_to_symbol ($2), $3, $5);
1142         }
1143         | REVERT STRING embedded_scm {
1144                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1145                         scm_string_to_symbol ($2), $3);
1146         }
1147         ;
1148
1149 context_def_mod:
1150         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1151         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1152         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1153
1154         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1155         | DENIES { $$ = ly_symbol2scm ("denies"); }
1156
1157         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1158         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1159         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1160         | NAME { $$ = ly_symbol2scm ("context-name"); }
1161         ;
1162
1163 context_mod:
1164         property_operation { $$ = $1; }
1165         | context_def_mod STRING {
1166                 $$ = scm_list_2 ($1, $2);
1167         }
1168         ;
1169
1170 context_prop_spec:
1171         STRING  {
1172                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1173         }
1174         | STRING '.' STRING {
1175                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1176         }
1177         ;
1178
1179 music_property_def:
1180         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1181                 $$ = property_op_to_music (scm_list_4 (
1182                         ly_symbol2scm ("poppush"),
1183                         gh_cadr ($2),
1184                         $3, $5));
1185                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1186         }
1187         | REVERT context_prop_spec embedded_scm {
1188                 $$ = property_op_to_music (scm_list_3 (
1189                         ly_symbol2scm ("pop"),
1190                         gh_cadr ($2),
1191                         $3));
1192
1193                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1194         }
1195         | SET context_prop_spec '=' scalar {
1196                 $$ = property_op_to_music (scm_list_3 (
1197                         ly_symbol2scm ("assign"),
1198                         gh_cadr ($2),
1199                         $4));
1200                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1201         }
1202         | UNSET context_prop_spec {
1203                 $$ = property_op_to_music (scm_list_2 (
1204                         ly_symbol2scm ("unset"),
1205                         gh_cadr ($2)));
1206                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1207         }
1208         | ONCE music_property_def {
1209                 SCM e = $2->get_property ("element");
1210                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1211                 $$ = $2;
1212
1213         }
1214         ;
1215
1216
1217
1218 scalar:
1219         string          { $$ = $1; }
1220         | bare_int      { $$ = gh_int2scm ($1); }
1221         | embedded_scm  { $$ = $1; }
1222         | full_markup {  $$ = $1; }
1223         | DIGIT { $$ = gh_int2scm ($1); }
1224         ;
1225
1226 /*
1227 This is a trick:
1228
1229 Adding pre_events to the simple_element
1230 makes the choice between
1231
1232   string:  STRING
1233
1234 and
1235
1236   simple_element: STRING
1237
1238 a single shift/reduction conflict.
1239
1240 nevertheless, this is not very clean, and we should find a different
1241 solution.
1242
1243 */
1244 pre_events: {
1245                 THIS->push_spot ();
1246         }
1247         ;
1248
1249 event_chord:
1250         pre_events simple_element post_events   {
1251                 SCM elts = $2-> get_property ("elements");
1252
1253                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1254
1255                 $2->set_property ("elements", elts);
1256                 $$ = $2;
1257         }
1258         | command_element
1259         | note_chord_element
1260         ;
1261
1262
1263 note_chord_element:
1264         chord_body optional_notemode_duration post_events
1265         {
1266                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1267                 SCM es = $1->get_property ("elements");
1268                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1269
1270                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1271                   unsmob_music (gh_car (s))->set_property ("duration", dur);
1272                 es = gh_append2 (es, postevs);
1273
1274                 $1-> set_property ("elements", es);
1275                 $$ = $1;
1276         }
1277         ;
1278
1279 chord_open: '<'
1280         ;
1281
1282 chord_close: '>'
1283         ;
1284
1285 simul_open: LESSLESS
1286         ;
1287
1288 simul_close: MOREMORE
1289         ;
1290
1291 chord_body:
1292         chord_open chord_body_elements chord_close
1293         {
1294                 $$ = MY_MAKE_MUSIC ("EventChord");
1295                 $$->set_property ("elements",
1296                         scm_reverse_x ($2, SCM_EOL));
1297         }
1298         ;
1299
1300 chord_body_elements:
1301         /* empty */             { $$ = SCM_EOL; }
1302         | chord_body_elements chord_body_element {
1303                 $$ = gh_cons ($2->self_scm (), $1);
1304                 scm_gc_unprotect_object ($2->self_scm ());
1305         }
1306         ;
1307
1308 chord_body_element:
1309         pitch exclamations questions post_events
1310         {
1311                 Music * n = MY_MAKE_MUSIC ("NoteEvent");
1312                 n->set_property ("pitch", $1);
1313                 if ($3 % 2)
1314                         n->set_property ("cautionary", SCM_BOOL_T);
1315                 if ($2 % 2 || $3 % 2)
1316                         n->set_property ("force-accidental", SCM_BOOL_T);
1317
1318                 if (gh_pair_p ($4)) {
1319                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1320                         n->set_property ("articulations", arts);
1321                 }
1322                 $$ = n;
1323         }
1324         | DRUM_PITCH post_events {
1325                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
1326                 n->set_property ("duration" ,$2);
1327                 n->set_property ("drum-type" , $1);
1328                 n->set_spot (THIS->here_input ());
1329
1330                 if (gh_pair_p ($2)) {
1331                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1332                         n->set_property ("articulations", arts);
1333                 }
1334                 $$ = n;
1335         }
1336         ;
1337
1338 add_quote:
1339         ADDQUOTE string Music {
1340                 SCM adder = ly_scheme_function ("add-quotable");
1341
1342                 scm_call_2 (adder, $2, $3->self_scm ());
1343                 scm_gc_unprotect_object ($3->self_scm ());
1344         }
1345         ;
1346
1347 command_element:
1348         command_req {
1349                 $$ = MY_MAKE_MUSIC ("EventChord");
1350                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1351                 scm_gc_unprotect_object ($1->self_scm ());
1352
1353                 $$-> set_spot (THIS->here_input ());
1354                 $1-> set_spot (THIS->here_input ());
1355         }
1356         | SKIP duration_length {
1357                 Music * skip = MY_MAKE_MUSIC ("SkipMusic");
1358                 skip->set_property ("duration", $2);
1359
1360                 $$ = skip;
1361         }
1362         | QUOTE STRING duration_length {
1363                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1364                 SCM evs =  SCM_EOL;
1365                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1366                 {
1367                         SCM key = $2; // use symbol?
1368                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1369                 }
1370                 Music * quote = 0;
1371                 if (gh_vector_p (evs))
1372                 {
1373                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1374                         quote->set_property ("duration", $3);
1375                         quote->set_property ("quoted-events", evs);
1376                 } else {
1377                         THIS->here_input ().warning (_f ("Can\'t find music"));
1378                         quote = MY_MAKE_MUSIC ("Event");
1379                 }
1380                 quote->set_spot (THIS->here_input ());
1381                 $$ = quote;
1382         }
1383         | OCTAVE { THIS->push_spot (); }
1384           pitch {
1385                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1386                 $$ = l;
1387                 $$->set_spot (THIS->pop_spot ());
1388                 $$->set_property ("pitch", $3);
1389         }
1390         | E_LEFTSQUARE {
1391                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1392                 l->set_property ("span-direction", gh_int2scm (START));
1393                 l->set_spot (THIS->here_input ());
1394
1395                 $$ = MY_MAKE_MUSIC ("EventChord");
1396                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1397                 scm_gc_unprotect_object (l->self_scm ());
1398                 $$->set_spot (THIS->here_input ());
1399         }
1400         | E_RIGHTSQUARE {
1401                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1402                 l->set_property ("span-direction", gh_int2scm (STOP));
1403                 l->set_spot (THIS->here_input ());
1404
1405                 $$ = MY_MAKE_MUSIC ("EventChord");
1406                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1407                 $$->set_spot (THIS->here_input ());
1408                 scm_gc_unprotect_object (l->self_scm ());
1409         }
1410         | E_BACKSLASH {
1411                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1412                 $$->set_spot (THIS->here_input ());
1413         }
1414         | '|'      {
1415
1416                 $$ = MY_MAKE_MUSIC ("BarCheck");
1417                 $$->set_spot (THIS->here_input ());
1418         }
1419         | TRANSPOSITION pitch {
1420                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1421                                         $2);
1422                 $$->set_spot (THIS-> here_input ());
1423                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1424                         $$ , SCM_EOL);
1425         }
1426         | BAR STRING                    {
1427                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1428
1429                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1430                                         t, SCM_EOL);
1431                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1432                 $$->set_spot (THIS->here_input ());
1433                 t->set_spot (THIS->here_input ());
1434         }
1435         | PARTIAL duration_length       {
1436                 Moment m = - unsmob_duration ($2)->get_length ();
1437                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1438                 p->set_spot (THIS->here_input ());
1439                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1440                                         p, SCM_EOL);
1441                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1442                                         p, SCM_EOL);
1443                 $$ =p ;
1444         }
1445         | CLEF STRING  {
1446                 SCM proc = ly_scheme_function ("make-clef-set");
1447
1448                 SCM result = scm_call_1 (proc, $2);
1449                 scm_gc_protect_object (result);
1450                 $$ = unsmob_music (result);
1451         }
1452         | TIME_T fraction  {
1453                 SCM proc= ly_scheme_function ("make-time-signature-set");
1454
1455                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1456                 scm_gc_protect_object (result);
1457                 $$ = unsmob_music (result);
1458         }
1459         | MARK scalar {
1460                 SCM proc = ly_scheme_function ("make-mark-set");
1461
1462                 SCM result = scm_call_1 (proc, $2);
1463                 scm_gc_protect_object (result);
1464                 $$ = unsmob_music (result);
1465         }
1466         ;
1467
1468 command_req:
1469         BREATHE {
1470                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1471         }
1472         | E_TILDE {
1473                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1474         }
1475         | MARK DEFAULT  {
1476                 Music * m = MY_MAKE_MUSIC ("MarkEvent");
1477                 $$ = m;
1478         }
1479         | tempo_event {
1480                 $$ = $1;
1481         }
1482         | KEY DEFAULT {
1483                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1484                 $$ = key;
1485         }
1486         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1487
1488                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1489                 if (scm_ilength ($3) > 0)
1490                 {
1491                         key->set_property ("pitch-alist", $3);
1492                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1493                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1494                 } else {
1495                         THIS->parser_error (_("Second argument must be pitch list."));
1496                 }
1497
1498                 $$ = key;
1499         }
1500         ;
1501
1502 post_events:
1503         /* empty */ {
1504                 $$ = SCM_EOL;
1505         }
1506         | post_events post_event {
1507                 $2->set_spot (THIS->here_input ());
1508                 $$ = gh_cons ($2->self_scm (), $$);
1509                 scm_gc_unprotect_object ($2->self_scm ());
1510         }
1511         | post_events tagged_post_event {
1512                 $2 -> set_spot (THIS->here_input ());
1513                 $$ = scm_cons ($2->self_scm (), $$);
1514                 scm_gc_unprotect_object ($2->self_scm ());
1515         }
1516         ;
1517
1518
1519 tagged_post_event:
1520         '-' TAG embedded_scm post_event {
1521                 tag_music ($4, $3, THIS->here_input ());
1522                 $$ = $4;
1523         }
1524         ;
1525
1526 post_event:
1527         direction_less_event {
1528                 $$ = $1;
1529         }
1530         | HYPHEN {
1531                 if (!THIS->lexer_->is_lyric_state ())
1532                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1533                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1534         }
1535         | EXTENDER {
1536                 if (!THIS->lexer_->is_lyric_state ())
1537                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1538                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1539         }
1540         | script_dir direction_reqd_event {
1541                 if ($1)
1542                         $2->set_property ("direction", gh_int2scm ($1));
1543                 $$ = $2;
1544         }
1545         | script_dir direction_less_event {
1546                 if ($1)
1547                         $2->set_property ("direction", gh_int2scm ($1));
1548                 $$ = $2;
1549         }
1550         | string_number_event
1551         ;
1552
1553 string_number_event:
1554         E_UNSIGNED {
1555                 Music * s = MY_MAKE_MUSIC ("StringNumberEvent");
1556                 s->set_property ("string-number",  gh_int2scm ($1));
1557                 s->set_spot (THIS->here_input ());
1558                 $$ = s;
1559         }
1560         ;
1561
1562
1563 direction_less_event:
1564         '['  {
1565
1566
1567 /*
1568
1569 TODO: should take all these defs out of the parser, adn make use
1570 configurable, i.e.
1571
1572
1573 (set-articulation '~ "trill")
1574
1575 */
1576                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1577                 m->set_spot (THIS->here_input ());
1578                 m->set_property ("span-direction" , gh_int2scm (START));
1579                 $$ = m;
1580         }
1581         | ']'  {
1582                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1583                 m->set_spot (THIS->here_input ());
1584                 m->set_property ("span-direction" , gh_int2scm (STOP));
1585                 $$ = m;
1586         }
1587         | '~' {
1588                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1589                 m->set_spot (THIS->here_input ());
1590                 $$ = m;
1591         }
1592         | close_event {
1593                 $$ = $1;
1594                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1595                         gh_int2scm (START));
1596         }
1597         | open_event {
1598                 $$ = $1;
1599                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1600                         gh_int2scm (STOP));
1601         }
1602         | EVENT_IDENTIFIER      {
1603                 $$ = unsmob_music ($1);
1604         }
1605         | tremolo_type  {
1606                Music * a = MY_MAKE_MUSIC ("TremoloEvent");
1607                a->set_spot (THIS->here_input ());
1608                a->set_property ("tremolo-type", gh_int2scm ($1));
1609                $$ = a;
1610         }
1611         ;
1612
1613 direction_reqd_event:
1614         gen_text_def {
1615                 $$ = $1;
1616         }
1617         | script_abbreviation {
1618                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1619                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1620                 if (gh_string_p (s))
1621                         a->set_property ("articulation-type", s);
1622                 else THIS->parser_error (_ ("Expecting string as script definition"));
1623                 $$ = a;
1624         }
1625         ;
1626
1627 oct_check:
1628         /**/ { $$ = SCM_EOL; }
1629         | '='  { $$ = gh_int2scm (0); }
1630         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1631         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1632         ;
1633
1634 sup_quotes:
1635         '\'' {
1636                 $$ = 1;
1637         }
1638         | sup_quotes '\'' {
1639                 $$ ++;
1640         }
1641         ;
1642
1643 sub_quotes:
1644         ',' {
1645                 $$ = 1;
1646         }
1647         | sub_quotes ',' {
1648                 $$ ++ ;
1649         }
1650         ;
1651
1652 steno_pitch:
1653         NOTENAME_PITCH  {
1654                 $$ = $1;
1655         }
1656         | NOTENAME_PITCH sup_quotes     {
1657                 Pitch p = *unsmob_pitch ($1);
1658                 p = p.transposed (Pitch ($2,0,0));
1659                 $$ = p.smobbed_copy ();
1660         }
1661         | NOTENAME_PITCH sub_quotes      {
1662                 Pitch p =* unsmob_pitch ($1);
1663                 p = p.transposed (Pitch (-$2,0,0));
1664                 $$ = p.smobbed_copy ();
1665         }
1666         ;
1667
1668 /*
1669 ugh. duplication
1670 */
1671
1672 steno_tonic_pitch:
1673         TONICNAME_PITCH {
1674                 $$ = $1;
1675         }
1676         | TONICNAME_PITCH sup_quotes    {
1677                 Pitch p = *unsmob_pitch ($1);
1678                 p = p.transposed (Pitch ($2,0,0));
1679                 $$ = p.smobbed_copy ();
1680         }
1681         | TONICNAME_PITCH sub_quotes     {
1682                 Pitch p =* unsmob_pitch ($1);
1683
1684                 p = p.transposed (Pitch (-$2,0,0));
1685                 $$ = p.smobbed_copy ();
1686         }
1687         ;
1688
1689 pitch:
1690         steno_pitch {
1691                 $$ = $1;
1692         }
1693         ;
1694
1695 pitch_also_in_chords:
1696         pitch
1697         | steno_tonic_pitch
1698         ;
1699
1700 close_event:
1701         '('     {
1702                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1703                 $$ = s;
1704                 s->set_spot (THIS->here_input ());
1705         }
1706         | E_OPEN        {
1707                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1708                 $$ = s;
1709                 s->set_spot (THIS->here_input ());
1710         }
1711         | E_SMALLER {
1712                 Music *s =MY_MAKE_MUSIC ("CrescendoEvent");
1713                 $$ = s;
1714                 s->set_spot (THIS->here_input ());
1715         }
1716         | E_BIGGER {
1717                 Music *s =MY_MAKE_MUSIC ("DecrescendoEvent");
1718                 $$ = s;
1719                 s->set_spot (THIS->here_input ());
1720         }
1721         ;
1722
1723
1724 open_event:
1725         E_EXCLAMATION   {
1726                 Music *s =  MY_MAKE_MUSIC ("CrescendoEvent");
1727                 s->set_spot (THIS->here_input ());
1728
1729                 $$ = s;
1730         }
1731         | ')'   {
1732                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1733                 $$ = s;
1734                 s->set_spot (THIS->here_input ());
1735
1736         }
1737         | E_CLOSE       {
1738                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1739                 $$ = s;
1740                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1741                 s->set_spot (THIS->here_input ());
1742         }
1743         ;
1744
1745 gen_text_def:
1746         full_markup {
1747                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1748                 t->set_property ("text", $1);
1749                 t->set_spot (THIS->here_input ());
1750                 $$ = t;
1751         }
1752         | string {
1753                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1754                 t->set_property ("text", make_simple_markup ($1));
1755                 t->set_spot (THIS->here_input ());
1756                 $$ = t;
1757
1758         }
1759         | DIGIT {
1760                 Music * t = MY_MAKE_MUSIC ("FingerEvent");
1761                 t->set_property ("digit",  gh_int2scm ($1));
1762                 t->set_spot (THIS->here_input ());
1763                 $$ = t;
1764         }
1765         ;
1766
1767 script_abbreviation:
1768         '^'             {
1769                 $$ = scm_makfrom0str ("Hat");
1770         }
1771         | '+'           {
1772                 $$ = scm_makfrom0str ("Plus");
1773         }
1774         | '-'           {
1775                 $$ = scm_makfrom0str ("Dash");
1776         }
1777         | '|'           {
1778                 $$ = scm_makfrom0str ("Bar");
1779         }
1780         | '>'           {
1781                 $$ = scm_makfrom0str ("Larger");
1782         }
1783         | '.'           {
1784                 $$ = scm_makfrom0str ("Dot");
1785         }
1786         | '_' {
1787                 $$ = scm_makfrom0str ("Underscore");
1788         }
1789         ;
1790
1791 script_dir:
1792         '_'     { $$ = DOWN; }
1793         | '^'   { $$ = UP; }
1794         | '-'   { $$ = CENTER; }
1795         ;
1796
1797
1798 absolute_pitch:
1799         steno_pitch     {
1800                 $$ = $1;
1801         }
1802         ;
1803
1804 duration_length:
1805         multiplied_duration {
1806                 $$ = $1;
1807         }
1808         ;
1809
1810 optional_notemode_duration:
1811         {
1812                 Duration dd = THIS->default_duration_;
1813                 $$ = dd.smobbed_copy ();
1814
1815                 THIS->beam_check ($$);
1816         }
1817         | multiplied_duration   {
1818                 $$ = $1;
1819                 THIS->default_duration_ = *unsmob_duration ($$);
1820
1821                 THIS->beam_check ($$);
1822         }
1823         ;
1824
1825 steno_duration:
1826         bare_unsigned dots              {
1827                 int l = 0;
1828                 if (!is_is_duration ($1))
1829                         THIS->parser_error (_f ("not a duration: %d", $1));
1830                 else
1831                         l =  intlog2 ($1);
1832
1833                 $$ = Duration (l, $2).smobbed_copy ();
1834         }
1835         | DURATION_IDENTIFIER dots      {
1836                 Duration *d =unsmob_duration ($1);
1837                 Duration k (d->duration_log (),d->dot_count () + $2);
1838
1839                 *d = k;
1840                 $$ = $1;
1841         }
1842         ;
1843
1844
1845
1846
1847 multiplied_duration:
1848         steno_duration {
1849                 $$ = $1;
1850         }
1851         | multiplied_duration '*' bare_unsigned {
1852                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1853         }
1854         | multiplied_duration '*' FRACTION {
1855                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1856
1857                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1858         }
1859         ;
1860
1861 fraction:
1862         FRACTION { $$ = $1; }
1863         | UNSIGNED '/' UNSIGNED {
1864                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1865         }
1866         ;
1867
1868 dots:
1869         /* empty */     {
1870                 $$ = 0;
1871         }
1872         | dots '.' {
1873                 $$ ++;
1874         }
1875         ;
1876
1877
1878 tremolo_type:
1879         ':'     {
1880                 $$ =0;
1881         }
1882         | ':' bare_unsigned {
1883                 if (!is_is_duration ($2))
1884                         THIS->parser_error (_f ("not a duration: %d", $2));
1885                 $$ = $2;
1886         }
1887         ;
1888
1889
1890
1891 /*****************************************************************
1892                 BASS FIGURES
1893 *****************************************************************/
1894 bass_number:
1895         DIGIT   {
1896                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1897         }
1898         | UNSIGNED {
1899                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1900         }
1901         | STRING { $$ =  $1; }
1902         ;
1903
1904 bass_mod:
1905         '-'     { $$ = -2; }
1906         | '+'   { $$ = 2; }
1907         | '!'   { $$ = 0; }
1908         ;
1909
1910 bass_figure:
1911         FIGURE_SPACE {
1912                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1913                 $$ = bfr->self_scm ();
1914                 scm_gc_unprotect_object ($$);
1915         }
1916         | bass_number  {
1917                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1918                 $$ = bfr->self_scm ();
1919
1920                 bfr->set_property ("figure", $1);
1921
1922                 scm_gc_unprotect_object ($$);
1923         }
1924         | bass_figure bass_mod {
1925                 Music *m = unsmob_music ($1);
1926                 if ($2) {
1927                         SCM salter =m->get_property ("alteration");
1928                         int alter = gh_number_p (salter) ? gh_scm2int (salter) : 0;
1929                         m->set_property ("alteration",
1930                                 gh_int2scm (alter + $2));
1931                 } else {
1932                         m->set_property ("alteration", gh_int2scm (0));
1933                 }
1934         }
1935         ;
1936
1937 br_bass_figure:
1938         '[' bass_figure {
1939                 $$ = $2;
1940                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1941         }
1942         | bass_figure   {
1943                 $$ = $1;
1944         }
1945         | br_bass_figure ']' {
1946                 $$ = $1;
1947                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1948         }
1949         ;
1950
1951 figure_list:
1952         /**/            {
1953                 $$ = SCM_EOL;
1954         }
1955         | figure_list br_bass_figure {
1956                 $$ = scm_cons ($2, $1);
1957         }
1958         ;
1959
1960 figure_spec:
1961         FIGURE_OPEN figure_list FIGURE_CLOSE {
1962                 Music * m = MY_MAKE_MUSIC ("EventChord");
1963                 $2 = scm_reverse_x ($2, SCM_EOL);
1964                 m->set_property ("elements",  $2);
1965                 $$ = m->self_scm ();
1966         }
1967         ;
1968
1969
1970 optional_rest:
1971         /**/   { $$ = 0; }
1972         | REST { $$ = 1; }
1973         ;
1974
1975 simple_element:
1976         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1977
1978                 Input i = THIS->pop_spot ();
1979                 if (!THIS->lexer_->is_note_state ())
1980                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1981
1982                 Music *n = 0;
1983                 if ($6)
1984                         n =  MY_MAKE_MUSIC ("RestEvent");
1985                 else
1986                         n =  MY_MAKE_MUSIC ("NoteEvent");
1987
1988                 n->set_property ("pitch", $1);
1989                 n->set_property ("duration", $5);
1990
1991                 if (gh_number_p ($4))
1992                 {
1993                         int q = gh_scm2int ($4);
1994                         n->set_property ("absolute-octave", gh_int2scm (q-1));
1995                 }
1996
1997                 if ($3 % 2)
1998                         n->set_property ("cautionary", SCM_BOOL_T);
1999                 if ($2 % 2 || $3 % 2)
2000                         n->set_property ("force-accidental", SCM_BOOL_T);
2001
2002                 Music *v = MY_MAKE_MUSIC ("EventChord");
2003                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2004                 scm_gc_unprotect_object (n->self_scm ());
2005
2006                 v->set_spot (i);
2007                 n->set_spot (i);
2008                 $$ = v;
2009         }
2010         | DRUM_PITCH optional_notemode_duration {
2011                 Input i = THIS->pop_spot ();
2012
2013                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
2014                 n->set_property ("duration" ,$2);
2015                 n->set_property ("drum-type" , $1);
2016
2017                 Music *v = MY_MAKE_MUSIC ("EventChord");
2018                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2019                 scm_gc_unprotect_object (n->self_scm ());
2020                 v->set_spot (i);
2021                 n->set_spot (i);
2022                 $$ = v;
2023
2024         }
2025         | figure_spec optional_notemode_duration {
2026                 Music * m = unsmob_music ($1);
2027                 Input i = THIS->pop_spot ();
2028                 m->set_spot (i);
2029                 for (SCM s = m->get_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2030                 {
2031                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2032                 }
2033                 $$ = m;
2034         }
2035         | RESTNAME optional_notemode_duration           {
2036
2037                 Input i = THIS->pop_spot ();
2038                 Music * ev = 0;
2039                 if (ly_scm2string ($1) =="s") {
2040                         /* Space */
2041                         ev = MY_MAKE_MUSIC ("SkipEvent");
2042                   }
2043                 else {
2044                         ev = MY_MAKE_MUSIC ("RestEvent");
2045
2046                     }
2047                 ev->set_property ("duration" ,$2);
2048                 ev->set_spot (i);
2049                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2050                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2051                 velt->set_spot (i);
2052
2053                 scm_gc_unprotect_object (ev->self_scm ());
2054
2055                 $$ = velt;
2056         }
2057         | MULTI_MEASURE_REST optional_notemode_duration         {
2058                 THIS->pop_spot ();
2059
2060                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2061                 SCM mus = scm_call_2 (proc, $2,
2062                         make_input (THIS->here_input ()));
2063                 scm_gc_protect_object (mus);
2064                 $$ = unsmob_music (mus);
2065         }
2066
2067         | lyric_element optional_notemode_duration      {
2068                 Input i = THIS->pop_spot ();
2069                 if (!THIS->lexer_->is_lyric_state ())
2070                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2071
2072                 Music * lreq = MY_MAKE_MUSIC ("LyricEvent");
2073                 lreq->set_property ("text", $1);
2074                 lreq->set_property ("duration",$2);
2075                 lreq->set_spot (i);
2076                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2077                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2078
2079                 $$= velt;
2080         }
2081         | new_chord {
2082                 THIS->pop_spot ();
2083
2084                 if (!THIS->lexer_->is_chord_state ())
2085                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2086                 $$ = unsmob_music ($1);
2087         }
2088         ;
2089
2090 lyric_element:
2091         full_markup { $$ = $1; }
2092         | STRING {  $$ = $1 ; }
2093         ;
2094
2095 new_chord:
2096         steno_tonic_pitch optional_notemode_duration   {
2097                 $$ = make_chord ($1, $2, SCM_EOL);
2098         }
2099         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2100                 SCM its = scm_reverse_x ($4, SCM_EOL);
2101                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2102         }
2103         ;
2104
2105 chord_items:
2106         /**/ {
2107                 $$ = SCM_EOL;
2108         }
2109         | chord_items chord_item {
2110                 $$ = gh_cons ($2, $$);
2111         }
2112         ;
2113
2114 chord_separator:
2115         CHORD_COLON {
2116                 $$ = ly_symbol2scm ("chord-colon");
2117         }
2118         | CHORD_CARET {
2119                 $$ = ly_symbol2scm ("chord-caret");
2120         }
2121         | CHORD_SLASH steno_tonic_pitch {
2122                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2123         }
2124         | CHORD_BASS steno_tonic_pitch {
2125                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2126         }
2127         ;
2128
2129 chord_item:
2130         chord_separator {
2131                 $$ = $1;
2132         }
2133         | step_numbers {
2134                 $$ = scm_reverse_x ($1, SCM_EOL);
2135         }
2136         | CHORD_MODIFIER  {
2137                 $$ = $1;
2138         }
2139         ;
2140
2141 step_numbers:
2142         step_number { $$ = gh_cons ($1, SCM_EOL); }
2143         | step_numbers '.' step_number {
2144                 $$ = gh_cons ($3, $$);
2145         }
2146         ;
2147
2148 step_number:
2149         bare_unsigned {
2150                 $$ = make_chord_step ($1, 0);
2151         }
2152         | bare_unsigned '+' {
2153                 $$ = make_chord_step ($1, SHARP);
2154         }
2155         | bare_unsigned CHORD_MINUS {
2156                 $$ = make_chord_step ($1, FLAT);
2157         }
2158         ;
2159
2160 /*
2161         UTILITIES
2162
2163 TODO: should deprecate in favor of Scheme?
2164
2165  */
2166 number_expression:
2167         number_expression '+' number_term {
2168                 $$ = scm_sum ($1, $3);
2169         }
2170         | number_expression '-' number_term {
2171                 $$ = scm_difference ($1, $3);
2172         }
2173         | number_term
2174         ;
2175
2176 number_term:
2177         number_factor {
2178                 $$ = $1;
2179         }
2180         | number_factor '*' number_factor {
2181                 $$ = scm_product ($1, $3);
2182         }
2183         | number_factor '/' number_factor {
2184                 $$ = scm_divide ($1, $3);
2185         }
2186         ;
2187
2188 number_factor:
2189         '-'  number_factor { /* %prec UNARY_MINUS */
2190                 $$ = scm_difference ($2, SCM_UNDEFINED);
2191         }
2192         | bare_number
2193         ;
2194
2195
2196 bare_number:
2197         UNSIGNED        {
2198                 $$ = gh_int2scm ($1);
2199         }
2200         | REAL          {
2201                 $$ = $1;
2202         }
2203         | NUMBER_IDENTIFIER             {
2204                 $$ = $1;
2205         }
2206         | REAL NUMBER_IDENTIFIER        {
2207                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2208         }
2209         | UNSIGNED NUMBER_IDENTIFIER    {
2210                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2211         }
2212         ;
2213
2214
2215 bare_unsigned:
2216         UNSIGNED {
2217                         $$ = $1;
2218         }
2219         | DIGIT {
2220                 $$ = $1;
2221         }
2222         ;
2223
2224 bare_int:
2225         bare_number {
2226                 if (scm_integer_p ($1) == SCM_BOOL_T)
2227                 {
2228                         int k = gh_scm2int ($1);
2229                         $$ = k;
2230                 } else
2231                 {
2232                         THIS->parser_error (_ ("need integer number arg"));
2233                         $$ = 0;
2234                 }
2235         }
2236         | '-' bare_int {
2237                 $$ = -$2;
2238         }
2239         ;
2240
2241
2242 string:
2243         STRING          {
2244                 $$ = $1;
2245         }
2246         | STRING_IDENTIFIER     {
2247                 $$ = $1;
2248         }
2249         | string '+' string {
2250                 $$ = scm_string_append (scm_list_2 ($1, $3));
2251         }
2252         ;
2253
2254
2255 exclamations:
2256                 { $$ = 0; }
2257         | exclamations '!'      { $$ ++; }
2258         ;
2259
2260 questions:
2261                 { $$ = 0; }
2262         | questions '?' { $$ ++; }
2263         ;
2264
2265
2266
2267 full_markup:
2268         MARKUP_IDENTIFIER {
2269                 $$ = $1;
2270         }
2271         | MARKUP
2272                 { THIS->lexer_->push_markup_state (); }
2273         markup
2274                 { $$ = $3;
2275                   THIS->lexer_->pop_state ();
2276                 }
2277         ;
2278
2279
2280 /*
2281 This should be done more dynamically if possible.
2282 */
2283 markup:
2284         STRING {
2285                 $$ = make_simple_markup ($1);
2286         }
2287         | MARKUP_HEAD_EMPTY {
2288                 $$ = scm_list_1 ($1);
2289         }
2290         | MARKUP_HEAD_MARKUP0 markup {
2291                 $$ = scm_list_2 ($1, $2);
2292         }
2293         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2294                 $$ = scm_list_3 ($1, $2, $3);
2295         }
2296         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2297                 $$  = scm_list_3 ($1, $2, $3);
2298         }
2299         | markup_line {
2300                 $$ = $1;
2301         }
2302         | MARKUP_HEAD_LIST0 markup_list {
2303                 $$ = scm_list_2 ($1,$2);
2304         }
2305         | MARKUP_HEAD_SCM0 embedded_scm {
2306                 $$ = scm_list_2 ($1, $2);
2307         }
2308         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2309                 $$ = scm_list_4 ($1, $2, $3, $4);
2310         }
2311         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2312                 $$ = scm_list_4 ($1, $2, $3, $4);
2313         }
2314         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2315                 $$ = scm_list_3 ($1, $2, $3);
2316         }
2317         | MARKUP_IDENTIFIER {
2318                 $$ = $1;
2319         }
2320         | STRING_IDENTIFIER {
2321                 $$ = $1;
2322         }
2323         ;
2324
2325 markup_list:
2326         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2327         ;
2328
2329 markup_line:
2330         '{' markup_list_body '}' {
2331                 SCM line = ly_scheme_function ("line-markup");
2332
2333                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2334         }
2335         ;
2336
2337 markup_list_body:
2338         /**/ {  $$ = SCM_EOL; }
2339         | markup_list_body markup {
2340                 $$ = gh_cons ($2, $1) ;
2341         }
2342         ;
2343
2344
2345 %%
2346
2347 void
2348 My_lily_parser::set_yydebug (bool )
2349 {
2350 #if 0
2351         yydebug = 1;
2352 #endif
2353 }
2354
2355 extern My_lily_parser * current_parser;
2356
2357 void
2358 My_lily_parser::do_yyparse ()
2359 {
2360         current_parser = this;;
2361         yyparse ((void*)this);
2362 }
2363
2364
2365 /*
2366 Should make this optional?    It will also complain when you do
2367
2368         [s4]
2369
2370 which is entirely legitimate.
2371
2372 Or we can scrap it. Barchecks should detect wrong durations, and
2373 skipTypesetting speeds it up a lot.
2374 */
2375
2376 void
2377 My_lily_parser::beam_check (SCM dur)
2378 {
2379   Duration *d = unsmob_duration (dur);
2380   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2381     {
2382       Music * m = unsmob_music (last_beam_start_);
2383       m->origin ()->warning (_("Suspect duration found following this beam"));
2384     }
2385   last_beam_start_ = SCM_EOL;
2386 }
2387
2388
2389
2390
2391 /*
2392
2393 It is a little strange to have this function in this file, but
2394 otherwise, we have to import music classes into the lexer.
2395
2396 */
2397 int
2398 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2399 {
2400         if (gh_string_p (sid)) {
2401                 *destination = sid;
2402                 return STRING_IDENTIFIER;
2403         } else if (gh_number_p (sid)) {
2404                 *destination = sid;
2405                 return NUMBER_IDENTIFIER;
2406         } else if (unsmob_context_def (sid)) {
2407                 *destination = unsmob_context_def (sid)->clone_scm ();
2408                 return CONTEXT_DEF_IDENTIFIER;
2409         } else if (unsmob_score (sid)) {
2410                 Score *sc =  new Score (*unsmob_score (sid));
2411                 *destination =sc->self_scm ();
2412                 return SCORE_IDENTIFIER;
2413         } else if (Music * mus =unsmob_music (sid)) {
2414                 mus = mus->clone ();
2415                 *destination = mus->self_scm ();
2416                 unsmob_music (*destination)->
2417                         set_property ("origin", make_input (last_input_));
2418                 return dynamic_cast<Event*> (mus)
2419                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2420         } else if (unsmob_duration (sid)) {
2421                 *destination = unsmob_duration (sid)->smobbed_copy ();
2422                 return DURATION_IDENTIFIER;
2423         } else if (unsmob_music_output_def (sid)) {
2424                 Music_output_def *p = unsmob_music_output_def (sid);
2425                 p = p->clone ();
2426
2427                 *destination = p->self_scm ();
2428                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2429         } else if (Text_item::markup_p (sid)) {
2430                 *destination = sid;
2431                 return MARKUP_IDENTIFIER;
2432         }
2433
2434         return -1;
2435 }
2436
2437 Music *
2438 property_op_to_music (SCM op)
2439 {
2440         Music * m = 0;
2441         SCM tag = gh_car (op);
2442         SCM symbol  = gh_cadr (op);
2443         SCM args = gh_cddr (op);
2444         SCM grob_val = SCM_UNDEFINED;
2445         SCM grob_sym = SCM_UNDEFINED;
2446         SCM val = SCM_UNDEFINED;
2447
2448         if (tag == ly_symbol2scm ("assign"))
2449                 {
2450                 m =  MY_MAKE_MUSIC ("PropertySet");
2451                 val = gh_car (args);
2452                 }
2453         else if (tag == ly_symbol2scm ("unset"))
2454                 m =  MY_MAKE_MUSIC ("PropertyUnset");
2455         else if (tag == ly_symbol2scm ("poppush")
2456                  || tag == ly_symbol2scm ("push"))
2457                 {
2458                 m  = MY_MAKE_MUSIC ("OverrideProperty");
2459                 grob_sym = gh_car (args);
2460                 grob_val = gh_cadr (args);
2461                 }
2462         else if (tag == ly_symbol2scm ("pop")) {
2463                 m = MY_MAKE_MUSIC ("RevertProperty");
2464                 grob_sym = gh_car (args);
2465                 }
2466
2467         m->set_property ("symbol", symbol);
2468
2469         if (val != SCM_UNDEFINED)
2470                 m->set_property ("value", val);
2471         if (grob_val != SCM_UNDEFINED)
2472                 m->set_property ("grob-value", grob_val);
2473
2474         if (grob_sym != SCM_UNDEFINED)
2475                 {
2476                 bool itc = internal_type_checking_global_b;
2477                 /* UGH.
2478                 */
2479                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2480                 if (autobeam)
2481                         internal_type_checking_global_b = false;
2482                 m->set_property ("grob-property", grob_sym);
2483                 if (autobeam)
2484                         internal_type_checking_global_b = itc;
2485                 }
2486
2487         if (op == ly_symbol2scm ("poppush"))
2488                 m->set_property ("pop-first", SCM_BOOL_T);
2489
2490
2491         return m;
2492 }
2493
2494 Music*
2495 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2496 {
2497         Music * csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2498
2499         csm->set_property ("element", m->self_scm ());
2500         scm_gc_unprotect_object (m->self_scm ());
2501
2502         csm->set_property ("context-type",
2503                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2504         csm->set_property ("property-operations", ops);
2505
2506         if (gh_string_p (id))
2507                 csm->set_property ("context-id", id);
2508         return csm;
2509 }
2510
2511
2512 SCM
2513 get_next_unique_context ()
2514 {
2515         static int new_context_count;
2516
2517         char s[1024];
2518         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2519
2520         return scm_makfrom0str (s);
2521 }
2522