lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /* Four shift/reduce problems
  13
  14 1.  foo = bar
  15
  16     "bar" -> String -> Lyric -> Music -> music-assignment
  17   or
  18     "bar" -> String -> string-assignment
  19
  20 Similar problem for
  21
  22 2.  \markup identifier
  23 3.  \markup { }
  24
  25 4.  \repeat
  26     \repeat .. \alternative
  27     \repeat { \repeat .. \alternative }
  28 or
  29     \repeat { \repeat } \alternative
  30
  31 --hwn
  32
  33 */
  34
  35 /*
  36
  37 TODO:
  38
  39 * The rules for who is protecting what are very shady. Uniformise
  40   this.
  41
  42 * There are too many lexical modes?
  43
  44 */
  45
  46 #include <ctype.h>
  47 #include <stdlib.h>
  48 #include <stdio.h>
  49
  50
  51 #include "scm-option.hh"
  52 #include "context-def.hh"
  53 #include "lily-guile.hh"
  54 #include "misc.hh"
  55 #include "my-lily-lexer.hh"
  56 #include "paper-def.hh"
  57 #include "midi-def.hh"
  58 #include "main.hh"
  59 #include "file-path.hh"
  60 #include "warn.hh"
  61 #include "dimensions.hh"
  62 #include "my-lily-parser.hh"
  63 #include "score.hh"
  64 #include "input-file-results.hh"
  65 #include "input.hh"
  66 #include "lilypond-input-version.hh"
  67 #include "scm-hash.hh"
  68 #include "ly-module.hh"
  69 #include "music-sequence.hh"
  70 #include "input-smob.hh"
  71 #include "event.hh"
  72 #include "text-item.hh"
  73 #include "music-list.hh"
  74 #include "paper-book.hh"
  75
  76 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  77
  78 Music *property_op_to_music (SCM op);
  79 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  80 SCM get_next_unique_context ();
  81
  82 #define YYERROR_VERBOSE 1
  83
  84 My_lily_parser* my_lily_parser;
  85 #define YYPARSE_PARAM my_lily_parser
  86 #define YYLEX_PARAM my_lily_parser
  87 #define THIS\
  88         ((My_lily_parser *) my_lily_parser)
  89
  90 #define yyerror THIS->parser_error
  91
  92 /* Add symbols to the TAGS field of a music object.  */
  93
  94 void
  95 tag_music (Music *m, SCM tag, Input ip)
  96 {
  97         SCM tags = m->get_property ("tags");
  98         if (gh_symbol_p (tag))
  99                 tags = scm_cons (tag, tags);
 100         else if (gh_list_p (tag))
 101                 tags = gh_append2 (tag, tags);
 102         else
 103                 ip.warning (_ ("Tag must be symbol or list of symbols."));
 104
 105         m->set_property ("tags", tags);
 106 }
 107
 108
 109
 110 bool
 111 is_regular_identifier (SCM id)
 112 {
 113   String str = ly_scm2string (id);
 114   char const *s = str.to_str0 ();
 115
 116   bool v = true;
 117 #if 0
 118   isalpha (*s);
 119   s++;
 120 #endif
 121   while (*s && v)
 122    {
 123         v = v && isalnum (*s);
 124         s++;
 125    }
 126   return v;
 127 }
 128
 129 SCM
 130 make_simple_markup (SCM a)
 131 {
 132         SCM simple = ly_scheme_function ("simple-markup");
 133
 134         return scm_list_2 (simple, a);
 135 }
 136
 137
 138 bool
 139 is_is_duration (int t)
 140 {
 141   return t && t == 1 << intlog2 (t);
 142 }
 143
 144 void
 145 set_music_properties (Music *p, SCM a)
 146 {
 147   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 148         {
 149         p->internal_set_property (ly_caar (k), ly_cdar (k));
 150         }
 151 }
 152
 153 SCM
 154 make_chord_step (int step, int alter)
 155 {
 156         if (step == 7)
 157                 alter += FLAT;
 158
 159         while (step < 0)
 160                 step += 7;
 161         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 162         return m.smobbed_copy ();
 163 }
 164
 165
 166 SCM
 167 make_chord (SCM pitch, SCM dur, SCM modification_list)
 168 {
 169         SCM chord_ctor = ly_scheme_function ("construct-chord");
 170         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 171         scm_gc_protect_object (ch);
 172         return ch;
 173 }
 174
 175 /* Todo: actually also use apply iso. call too ...  */
 176 bool
 177 ly_input_procedure_p (SCM x)
 178 {
 179         return gh_procedure_p (x)
 180                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 181 }
 182
 183 Music*
 184 set_property_music (SCM sym, SCM value)
 185 {
 186         Music *p = MY_MAKE_MUSIC ("PropertySet");
 187         p->set_property ("symbol", sym);
 188         p->set_property ("value", value);
 189         return p;
 190 }
 191
 192 %}
 193
 194 /* We use SCMs to do strings, because it saves us the trouble of
 195 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 196 of the parse stack onto the heap. */
 197
 198
 199 %union {
 200         String *string;
 201     Music *music;
 202     Score *score;
 203     Music_output_def *outputdef;
 204     SCM scm;
 205     int i;
 206 }
 207 %{
 208
 209 int
 210 yylex (YYSTYPE *s, void *v)
 211 {
 212         My_lily_parser   *pars = (My_lily_parser*) v;
 213         My_lily_lexer *lex = pars->lexer_;
 214
 215         lex->lexval = (void*) s;
 216         lex->prepare_for_next_token ();
 217         return lex->yylex ();
 218 }
 219
 220
 221 %}
 222
 223 %pure_parser
 224
 225
 226 %token ACCEPTS
 227 %token ADDLYRICS
 228 %token ADDQUOTE
 229 %token NEWADDLYRICS
 230 %token ALIAS
 231 %token ALTERNATIVE
 232 %token APPLY
 233 %token APPLYCONTEXT
 234 %token APPLYOUTPUT
 235 %token AUTOCHANGE
 236 %token BAR
 237 %token BREATHE
 238 %token CHANGE
 239 %token CHORDMODIFIERS
 240 %token CHORDS
 241 %token LESSLESS
 242 %token MOREMORE
 243 %token CLEF
 244 %token COMMANDSPANREQUEST
 245 %token CONSISTS
 246 %token CONSISTSEND
 247 %token CONTEXT
 248 %token DEFAULT
 249 %token DENIES
 250 %token DESCRIPTION
 251 %token EXTENDER
 252 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 253 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 254 %token GRACE
 255 %token ACCIACCATURA
 256 %token APPOGGIATURA
 257 %token GROBDESCRIPTIONS
 258 %token HEADER
 259 %token HYPHEN
 260 %token INVALID
 261 %token KEY
 262 %token LYRICS
 263 %token MARK
 264 %token MIDI
 265 %token MULTI_MEASURE_REST
 266 %token NAME
 267 %token NEWCONTEXT
 268 %token NOTES
 269 %token OCTAVE
 270 %token ONCE
 271 %token OVERRIDE SET REVERT
 272 %token PAPER
 273 %token PARTCOMBINE
 274 %token PARTIAL
 275 %token QUOTE
 276 %token RELATIVE
 277 %token REMOVE
 278 %token REPEAT
 279 %token REST
 280 %token SCM_T
 281 %token SCORE
 282 %token SEQUENTIAL
 283 %token SIMULTANEOUS
 284 %token SKIP
 285 %token SPANREQUEST
 286 %token TAG
 287 %token TEMPO
 288 %token TIMES
 289 %token TIME_T
 290 %token TRANSPOSE
 291 %token TRANSPOSITION
 292 %token TYPE
 293 %token UNSET
 294 %token WITH
 295
 296 /* escaped */
 297 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 298 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 299 %token E_BACKSLASH
 300 %token <i> E_UNSIGNED
 301 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 302 %token FIGURE_SPACE
 303
 304 %type <i>       exclamations questions dots optional_rest
 305 %type <i>        bass_mod
 306 %type <scm>     grace_head
 307 %type <scm>     oct_check
 308 %type <scm>     context_mod_list
 309 %type <scm>     lyric_element
 310 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 311 %token <i>      DIGIT
 312 %token <scm>    NOTENAME_PITCH
 313 %token <scm>    TONICNAME_PITCH
 314 %token <scm>    CHORDMODIFIER_PITCH
 315 %token <scm>    DURATION_IDENTIFIER
 316 %token <scm>    FRACTION
 317 %token <id>     IDENTIFIER
 318 %token DRUMS
 319 %token <scm>    DRUM_PITCH
 320 %token <scm>    CHORD_MODIFIER
 321 %token <scm>    SCORE_IDENTIFIER
 322 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 323 %token <scm>    NUMBER_IDENTIFIER
 324 %token <scm>    EVENT_IDENTIFIER
 325 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 326 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 327 %token <scm>    RESTNAME
 328 %token <scm>    STRING
 329 %token <scm>    SCM_T
 330 %token <i>      UNSIGNED
 331 %token <scm>   REAL
 332
 333 %token MARKUP
 334 %token <scm> MARKUP_HEAD_MARKUP0
 335 %token <scm> MARKUP_HEAD_EMPTY
 336 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 337 %token <scm> MARKUP_HEAD_SCM0
 338 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 339 %token <scm> MARKUP_HEAD_SCM0_SCM1
 340 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 341 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 342
 343 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 344 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 345
 346 %type <outputdef> output_def
 347 %type <scm>     lilypond_header lilypond_header_body
 348 %type <music>   open_event close_event
 349 %type <i>       sub_quotes sup_quotes
 350 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 351 %type <music>   Repeated_music
 352 %type <scm>     Alternative_music
 353 %type <i>       tremolo_type
 354 %type <i>       bare_int  bare_unsigned
 355 %type <i>       script_dir
 356 %type <scm>     identifier_init
 357
 358 %type <music> note_chord_element chord_body chord_body_element
 359 %type <scm>  chord_body_elements
 360 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 361
 362 %type <scm>   post_events
 363 %type <music> gen_text_def direction_less_event direction_reqd_event
 364 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 365 %type <scm>    steno_tonic_pitch
 366 %type <scm>     duration_length fraction
 367
 368 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 369
 370 %type <scm>  embedded_scm scalar
 371 %type <music>   Music Sequential_music Simultaneous_music
 372 %type <music>   relative_music re_rhythmed_music
 373 %type <music>   music_property_def context_change
 374 %type <scm> context_prop_spec
 375 %type <scm> Music_list
 376 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 377 %type <outputdef>  music_output_def_body music_output_def_head
 378 %type <music>   post_event tagged_post_event
 379 %type <music> command_req
 380 %type <music> string_number_event
 381 %type <scm>     string bare_number number_expression number_term number_factor
 382 %type <score>   score_block score_body
 383
 384 %type <scm>     context_def_spec_block context_def_spec_body
 385 %type <music>   tempo_event
 386 %type <scm>     script_abbreviation
 387
 388
 389
 390 %left '-' '+'
 391
 392 /* We don't assign precedence to / and *, because we might need varied
 393 prec levels in different prods */
 394
 395 %left UNARY_MINUS
 396
 397 %%
 398
 399 lilypond:       /* empty */
 400         | lilypond toplevel_expression {}
 401         | lilypond assignment  { }
 402         | lilypond error {
 403                 THIS->error_level_ = 1;
 404         }
 405         | lilypond INVALID      {
 406                 THIS->error_level_ = 1;
 407         }
 408         ;
 409
 410 toplevel_expression:
 411         lilypond_header {
 412                 THIS->input_file_->header_ = $1;
 413         }
 414         | add_quote {
 415         }
 416         | score_block {
 417                 Score *sc = $1;
 418
 419                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 420
 421                 Path p = split_path (THIS->output_basename_);
 422                 int *c = &THIS->input_file_->score_count_;
 423                 if (*c)
 424                         {
 425                         p.base += "-" + to_string (*c);
 426                         }
 427
 428                 (*c)++;
 429                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 430
 431                 for (int i = 0; i < sc->defs_.size (); i++)
 432                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 433
 434                 if (sc->defs_.is_empty ())
 435                 {
 436                    Music_output_def *id = unsmob_music_output_def
 437                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 438                    id = id ? id->clone () : new Paper_def;
 439                    default_rendering (sc->music_, id->self_scm (), head,
 440                         outname);
 441                    scm_gc_unprotect_object (id->self_scm ());
 442                 }
 443                 scm_gc_unprotect_object (sc->self_scm ());
 444         }
 445         | output_def {
 446                 SCM id = SCM_EOL;
 447                 if (dynamic_cast<Paper_def*> ($1))
 448                         id = scm_makfrom0str ("$defaultpaper");
 449                 else if (dynamic_cast<Midi_def*> ($1))
 450                         id = scm_makfrom0str ("$defaultmidi");
 451                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 452                 scm_gc_unprotect_object ($1->self_scm ());
 453         }
 454         ;
 455
 456
 457 embedded_scm:
 458         SCM_T
 459         | SCM_IDENTIFIER
 460         ;
 461
 462
 463
 464
 465 lilypond_header_body:
 466         {
 467                 $$ = ly_make_anonymous_module ();
 468                 THIS->lexer_->add_scope ($$);
 469         }
 470         | lilypond_header_body assignment  {
 471
 472         }
 473         ;
 474
 475 lilypond_header:
 476         HEADER '{' lilypond_header_body '}'     {
 477                 $$ = THIS->lexer_->remove_scope ();
 478         }
 479         ;
 480
 481
 482 /*
 483         DECLARATIONS
 484 */
 485 assignment:
 486         STRING {
 487                 THIS->push_spot ();
 488         }
 489         /* cont */ '=' identifier_init  {
 490
 491         /*
 492                 Should find generic way of associating input with objects.
 493         */
 494                 Input ip = THIS->pop_spot ();
 495
 496                 if (! is_regular_identifier ($1))
 497                 {
 498                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 499                 }
 500
 501                 THIS->lexer_->set_identifier ($1, $4);
 502
 503 /*
 504  TODO: devise standard for protection in parser.
 505
 506   The parser stack lives on the C-stack, which means that
 507 all objects can be unprotected as soon as they're here.
 508
 509 */
 510         }
 511         | embedded_scm { }
 512         ;
 513
 514
 515 identifier_init:
 516         score_block {
 517                 $$ = $1->self_scm ();
 518                 scm_gc_unprotect_object ($$);
 519         }
 520         | full_markup {
 521                 $$ = $1;
 522         }
 523         | output_def {
 524                 $$ = $1->self_scm ();
 525                 scm_gc_unprotect_object ($$);
 526         }
 527         | context_def_spec_block {
 528                 $$ = $1;
 529         }
 530         | Music  {
 531                 $$ = $1->self_scm ();
 532                 scm_gc_unprotect_object ($$);
 533         }
 534         | post_event {
 535                 $$ = $1->self_scm ();
 536                 scm_gc_unprotect_object ($$);
 537         }
 538         | number_expression {
 539                 $$ = $1;
 540         }
 541         | string {
 542                 $$ = $1;
 543         }
 544         | embedded_scm  {
 545                 $$ = $1;
 546         }
 547         ;
 548
 549 context_def_spec_block:
 550         CONTEXT '{' context_def_spec_body '}'
 551                 {
 552                 $$ = $3;
 553         }
 554         ;
 555
 556 context_def_spec_body:
 557         /**/ {
 558                 $$ = Context_def::make_scm ();
 559                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 560         }
 561         | CONTEXT_DEF_IDENTIFIER        {
 562                 $$ = $1;
 563                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 564         }
 565         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 566                 Context_def*td = unsmob_context_def ($$);
 567
 568                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 569                         SCM tag = gh_caar (p);
 570
 571                         /* TODO: should make new tag "grob-definition" ? */
 572                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 573                                                         tag, gh_cons (ly_cdar (p), SCM_EOL)));
 574                 }
 575         }
 576         | context_def_spec_body context_mod {
 577                 unsmob_context_def ($$)->add_context_mod ($2);
 578         }
 579         ;
 580
 581 /*
 582         SCORE
 583 */
 584 score_block:
 585         SCORE {
 586                 THIS->push_spot ();
 587         }
 588         /*cont*/ '{' score_body '}'     {
 589                 THIS->pop_spot ();
 590                 $$ = $4;
 591
 592         }
 593         ;
 594
 595 score_body:
 596         Music   {
 597                 $$ = new Score;
 598
 599                 $$->set_spot (THIS->here_input ());
 600                 SCM m = $1->self_scm ();
 601                 scm_gc_unprotect_object (m);
 602
 603                 /*
 604                         guh.
 605                 */
 606                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 607                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 608                         m = gh_call1 (gh_car (check_funcs), m);
 609                 $$->music_ = m;
 610
 611         }
 612         | SCORE_IDENTIFIER {
 613                 $$ = new Score ( *unsmob_score ($1));
 614                 $$->set_spot (THIS->here_input ());
 615         }
 616         | score_body lilypond_header    {
 617                 $$->header_ = $2;
 618         }
 619         | score_body output_def {
 620                 $$->defs_.push ($2);
 621                 scm_gc_unprotect_object ($2->self_scm ());
 622         }
 623         | score_body error {
 624
 625         }
 626         ;
 627
 628
 629 /*
 630         MIDI
 631 */
 632 output_def:
 633         music_output_def_body '}' {
 634                 $$ = $1;
 635                 THIS-> lexer_-> remove_scope ();
 636         }
 637         ;
 638
 639 music_output_def_head:
 640         MIDI    {
 641                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 642
 643
 644                 Midi_def *p = 0;
 645                 if (id)
 646                         p = dynamic_cast<Midi_def*> (id->clone ());
 647                 else
 648                         p = new Midi_def;
 649
 650                 $$ = p;
 651                 THIS->lexer_->add_scope (p->scope_);
 652         }
 653         | PAPER         {
 654                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 655                   Paper_def *p = 0;
 656                 if (id)
 657                         p = dynamic_cast<Paper_def*> (id->clone ());
 658                 else
 659                         p = new Paper_def;
 660
 661                 THIS->lexer_->add_scope (p->scope_);
 662                 $$ = p;
 663         }
 664         ;
 665
 666
 667 music_output_def_body:
 668         music_output_def_head '{' {
 669                 $$ = $1;
 670                 $$->input_origin_. set_spot (THIS->here_input ());
 671
 672         }
 673         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 674                 scm_gc_unprotect_object ($1->self_scm ());
 675                 Music_output_def *o = unsmob_music_output_def ($3);
 676                 o->input_origin_.set_spot (THIS->here_input ());
 677                 $$ = o;
 678                 THIS->lexer_->remove_scope ();
 679                 THIS->lexer_->add_scope (o->scope_);
 680         }
 681         | music_output_def_body assignment  {
 682
 683         }
 684         | music_output_def_body context_def_spec_block  {
 685                 $$->assign_context_def ($2);
 686         }
 687         | music_output_def_body tempo_event  {
 688                 /*
 689                         junk this ? there already is tempo stuff in
 690                         music.
 691                 */
 692                 int m = gh_scm2int ( $2->get_property ("metronome-count"));
 693                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 694                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 695                 if (md)
 696                         md->set_tempo (d->get_length (), m);
 697                 scm_gc_unprotect_object ($2->self_scm ());
 698         }
 699         | music_output_def_body error {
 700
 701         }
 702         ;
 703
 704 tempo_event:
 705         TEMPO steno_duration '=' bare_unsigned  {
 706                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 707                 $$->set_property ("tempo-unit", $2);
 708                 $$->set_property ("metronome-count", gh_int2scm ( $4));
 709         }
 710         ;
 711
 712 /*
 713 The representation of a  list is the
 714
 715   (LIST . LAST-CONS)
 716
 717  to have  efficient append.
 718 */
 719 Music_list:
 720         /* empty */ {
 721                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 722         }
 723         | Music_list Music {
 724                 SCM s = $$;
 725                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 726                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 727                 if (gh_pair_p (ly_cdr (s)))
 728                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 729                 else
 730                         gh_set_car_x (s, c); /* set first cons */
 731                 gh_set_cdr_x (s, c);  /* remember last cell */
 732         }
 733         | Music_list error {
 734         }
 735         ;
 736
 737
 738 Music:
 739         Simple_music
 740         | Composite_music
 741         ;
 742
 743 Alternative_music:
 744         /* empty */ {
 745                 $$ = SCM_EOL;
 746         }
 747         | ALTERNATIVE '{' Music_list '}' {
 748                 $$ = $3;
 749         }
 750         ;
 751
 752 Repeated_music:
 753         REPEAT string bare_unsigned Music Alternative_music
 754         {
 755                 Music *beg = $4;
 756                 int times = $3;
 757                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 758                 if (times < scm_ilength (alts)) {
 759                   unsmob_music (gh_car (alts))
 760                     ->origin ()->warning (
 761                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 762                   alts = ly_truncate_list (times, alts);
 763                 }
 764
 765
 766                 SCM proc = ly_scheme_function ("make-repeated-music");
 767
 768                 SCM mus = scm_call_1 (proc, $2);
 769                 scm_gc_protect_object (mus); // UGH.
 770                 Music *r = unsmob_music (mus);
 771                 if (beg)
 772                         {
 773                         r-> set_property ("element", beg->self_scm ());
 774                         scm_gc_unprotect_object (beg->self_scm ());
 775                         }
 776                 r->set_property ("repeat-count", gh_int2scm (times >? 1));
 777
 778                 r-> set_property ("elements",alts);
 779                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 780                         /*
 781                         TODO: move this code to Scheme.
 782                         */
 783
 784                         /*
 785                         we can not get durations and other stuff correct down the line, so we have to
 786                         add to the duration log here.
 787                         */
 788                         SCM func = ly_scheme_function ("shift-duration-log");
 789
 790                         int dots = ($3 % 3) ? 0 : 1;
 791                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 792
 793                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 794
 795                         if (seq) {
 796                                 int list_len = scm_ilength (seq->music_list ());
 797                                 if (list_len != 2)
 798                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 799                                 shift -= 1;
 800                                 r->compress (Moment (Rational (1, list_len)));
 801                                 }
 802                         gh_call3 (func, r->self_scm (), gh_int2scm (shift),gh_int2scm (dots));
 803
 804                 }
 805                 r->set_spot (*$4->origin ());
 806
 807                 $$ = r;
 808         }
 809         ;
 810
 811 Sequential_music:
 812         SEQUENTIAL '{' Music_list '}'           {
 813                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 814                 $$->set_property ("elements", ly_car ($3));
 815                 $$->set_spot (THIS->here_input ());
 816         }
 817         | '{' Music_list '}'            {
 818                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 819                 $$->set_property ("elements", ly_car ($2));
 820                 $$->set_spot (THIS->here_input ());
 821         }
 822         ;
 823
 824 Simultaneous_music:
 825         SIMULTANEOUS '{' Music_list '}'{
 826                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 827                 $$->set_property ("elements", ly_car ($3));
 828                 $$->set_spot (THIS->here_input ());
 829
 830         }
 831         | simul_open Music_list simul_close     {
 832                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 833                 $$->set_property ("elements", ly_car ($2));
 834                 $$->set_spot (THIS->here_input ());
 835         }
 836         ;
 837
 838 Simple_music:
 839         event_chord             { $$ = $1; }
 840         | APPLYOUTPUT embedded_scm {
 841                 if (!ly_input_procedure_p ($2))
 842                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 843                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 844                 $$->set_property ("procedure", $2);
 845                 $$->set_spot (THIS->here_input ());
 846         }
 847         | APPLYCONTEXT embedded_scm {
 848                 if (!ly_input_procedure_p ($2))
 849                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 850                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 851                 $$->set_property ("procedure", $2);
 852                 $$->set_spot (THIS->here_input ());
 853         }
 854         | MUSIC_IDENTIFIER {
 855                 $$ = unsmob_music ($1);
 856         }
 857         | music_property_def
 858         | context_change
 859         ;
 860
 861
 862 optional_context_mod:
 863         /**/ { $$ = SCM_EOL; }
 864         | WITH '{' context_mod_list '}'  { $$ = $3; }
 865         ;
 866
 867 grace_head:
 868         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 869         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 870         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 871         ;
 872
 873 context_mod_list:
 874         /* */  { $$ = SCM_EOL; }
 875         | context_mod_list context_mod  {
 876                  $$ = gh_cons ($2, $1);
 877         }
 878         ;
 879
 880 Composite_music:
 881         AUTOCHANGE Music        {
 882                 SCM proc = ly_scheme_function ("make-autochange-music");
 883
 884                 SCM res = scm_call_1 (proc, $2->self_scm ());
 885                 scm_gc_unprotect_object ($2->self_scm ());
 886                 $$ = unsmob_music (res);
 887                 scm_gc_protect_object (res);
 888                 $$->set_spot (THIS->here_input ());
 889         }
 890         | PARTCOMBINE Music Music {
 891                 SCM proc = ly_scheme_function ("make-part-combine-music");
 892
 893                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 894                         $3->self_scm (), SCM_UNDEFINED));
 895                 scm_gc_unprotect_object ($3->self_scm ());
 896                 scm_gc_unprotect_object ($2->self_scm ());
 897                 $$ = unsmob_music (res);
 898                 scm_gc_protect_object (res);
 899                 $$->set_spot (THIS->here_input ());
 900         }
 901         | grace_head Music {
 902 #if 1
 903         /*
 904                 The other version is for easier debugging  of
 905                 Sequential_music_iterator in combination with grace notes.
 906         */
 907
 908 /*
 909
 910 TODO: should distinguish between both grace types in the
 911 basic music objects too, since the meaning is different.
 912
 913 */
 914
 915                 String start_str = "start" + ly_scm2string ($1) + "Music";
 916                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 917
 918                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 919                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 920
 921                 Music *startm = unsmob_music (start);
 922                 Music *stopm = unsmob_music (stop);
 923
 924                 SCM ms = SCM_EOL;
 925                 if (stopm) {
 926                         stopm = stopm->clone ();
 927                         ms = scm_cons (stopm->self_scm (), ms);
 928                         scm_gc_unprotect_object (stopm->self_scm ());
 929                 }
 930                 ms = scm_cons ($2->self_scm (), ms);
 931                 scm_gc_unprotect_object ($2->self_scm ());
 932                 if (startm) {
 933                         startm = startm->clone ();
 934                         ms = scm_cons (startm->self_scm (), ms);
 935                         scm_gc_unprotect_object (startm->self_scm ());
 936                 }
 937
 938                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 939                 seq->set_property ("elements", ms);
 940
 941
 942                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 943                 $$->set_property ("element", seq->self_scm ());
 944                 scm_gc_unprotect_object (seq->self_scm ());
 945 #else
 946                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 947                 $$->set_property ("element", $2->self_scm ());
 948                 scm_gc_unprotect_object ($2->self_scm ());
 949 #endif
 950         }
 951         | CONTEXT string '=' string optional_context_mod Music {
 952                 $$ = context_spec_music ($2, $4, $6, $5);
 953
 954         }
 955         | CONTEXT STRING optional_context_mod Music {
 956                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 957         }
 958         | NEWCONTEXT string optional_context_mod Music {
 959                 $$ = context_spec_music ($2, get_next_unique_context (),
 960                                          $4, $3);
 961         }
 962
 963         | TIMES {
 964                 THIS->push_spot ();
 965         }
 966         /* CONTINUED */
 967                 fraction Music
 968
 969         {
 970                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 971                 Music *mp = $4;
 972
 973                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 974                 $$->set_spot (THIS->pop_spot ());
 975
 976                 $$->set_property ("element", mp->self_scm ());
 977                 scm_gc_unprotect_object (mp->self_scm ());
 978                 $$->set_property ("numerator", gh_int2scm (n));
 979                 $$->set_property ("denominator", gh_int2scm (d));
 980                 $$->compress (Moment (Rational (n,d)));
 981
 982         }
 983         | Repeated_music                { $$ = $1; }
 984         | Simultaneous_music            { $$ = $1; }
 985         | Sequential_music              { $$ = $1; }
 986         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 987                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
 988                 Music *p = $4;
 989                 Pitch from = *unsmob_pitch ($2);
 990                 Pitch to = *unsmob_pitch ($3);
 991
 992                 p->transpose (interval (from, to));
 993                 $$->set_property ("element", p->self_scm ());
 994                 scm_gc_unprotect_object (p->self_scm ());
 995         }
 996         | APPLY embedded_scm Music  {
 997                 if (!ly_input_procedure_p ($2))
 998                         {
 999                         THIS->parser_error (_ ("\\apply takes function argument"));
1000                         $$ = $3;
1001                         }
1002                 else
1003                         {
1004                         SCM ret = gh_call1 ($2, $3->self_scm ());
1005                         Music *m = unsmob_music (ret);
1006                         if (!m) {
1007                                 THIS->parser_error ("\\apply must return a Music");
1008                                 m = MY_MAKE_MUSIC ("Music");
1009                                 }
1010                         $$ = m;
1011                         }
1012         }
1013         | NOTES
1014                 {
1015                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1016                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1017         }
1018         Music
1019                 { $$ = $3;
1020                   THIS->lexer_->pop_state ();
1021                 }
1022         | DRUMS
1023                 {
1024                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1025                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1026         }
1027         Music
1028                 { $$ = $3;
1029                   THIS->lexer_->pop_state ();
1030                 }
1031         | FIGURES
1032                 { THIS->lexer_->push_figuredbass_state (); }
1033         Music
1034                 {
1035                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1036                   chm->set_property ("element", $3->self_scm ());
1037                   $$ = chm;
1038                   scm_gc_unprotect_object ($3->self_scm ());
1039
1040                   THIS->lexer_->pop_state ();
1041         }
1042         | CHORDS {
1043                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1044                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1045                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1046                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1047
1048         } Music {
1049                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1050                   chm->set_property ("element", $3->self_scm ());
1051                   scm_gc_unprotect_object ($3->self_scm ());
1052                   $$ = chm;
1053
1054                   THIS->lexer_->pop_state ();
1055         }
1056         | LYRICS
1057                 { THIS->lexer_->push_lyric_state (); }
1058         Music
1059                 {
1060                   $$ = $3;
1061                   THIS->lexer_->pop_state ();
1062         }
1063         | relative_music        { $$ = $1; }
1064         | re_rhythmed_music     { $$ = $1; }
1065         | TAG embedded_scm Music {
1066                 tag_music ($3, $2, THIS->here_input ());
1067                 $$ = $3;
1068         }
1069         ;
1070
1071 relative_music:
1072         RELATIVE absolute_pitch Music {
1073                 Music *p = $3;
1074                 Pitch pit = *unsmob_pitch ($2);
1075                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1076
1077                 $$->set_property ("element", p->self_scm ());
1078                 scm_gc_unprotect_object (p->self_scm ());
1079
1080
1081                 Pitch retpitch = p->to_relative_octave (pit);
1082                 if (lily_1_8_relative)
1083                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1084         }
1085         ;
1086
1087 re_rhythmed_music:
1088         ADDLYRICS Music Music {
1089         Music *l = MY_MAKE_MUSIC ("LyricCombineMusic");
1090           l->set_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1091           scm_gc_unprotect_object ($3->self_scm ());
1092           scm_gc_unprotect_object ($2->self_scm ());
1093           $$ = l;
1094         }
1095         | NEWADDLYRICS string Music {
1096           Music *l = MY_MAKE_MUSIC ("NewLyricCombineMusic");
1097           l->set_property ("element", $3->self_scm ());
1098           scm_gc_unprotect_object ($3->self_scm ());
1099           $$ = l;
1100           l->set_property ("associated-context", $2);
1101         }
1102         ;
1103
1104 context_change:
1105         CHANGE STRING '=' STRING  {
1106                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1107                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1108                 t-> set_property ("change-to-id", $4);
1109
1110                 $$ = t;
1111                 $$->set_spot (THIS->here_input ());
1112         }
1113         ;
1114
1115 property_operation:
1116         STRING '='  scalar {
1117                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1118                         scm_string_to_symbol ($1), $3);
1119         }
1120         | UNSET STRING {
1121                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1122                         scm_string_to_symbol ($2));
1123         }
1124         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1125                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1126                         scm_string_to_symbol ($2), $3, $5);
1127         }
1128         | REVERT STRING embedded_scm {
1129                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1130                         scm_string_to_symbol ($2), $3);
1131         }
1132         ;
1133
1134 context_def_mod:
1135         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1136         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1137         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1138
1139         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1140         | DENIES { $$ = ly_symbol2scm ("denies"); }
1141
1142         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1143         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1144         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1145         | NAME { $$ = ly_symbol2scm ("context-name"); }
1146         ;
1147
1148 context_mod:
1149         property_operation { $$ = $1; }
1150         | context_def_mod STRING {
1151                 $$ = scm_list_2 ($1, $2);
1152         }
1153         ;
1154
1155 context_prop_spec:
1156         STRING  {
1157                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1158         }
1159         | STRING '.' STRING {
1160                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1161         }
1162         ;
1163
1164 music_property_def:
1165         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1166                 $$ = property_op_to_music (scm_list_4 (
1167                         ly_symbol2scm ("poppush"),
1168                         gh_cadr ($2),
1169                         $3, $5));
1170                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1171         }
1172         | REVERT context_prop_spec embedded_scm {
1173                 $$ = property_op_to_music (scm_list_3 (
1174                         ly_symbol2scm ("pop"),
1175                         gh_cadr ($2),
1176                         $3));
1177
1178                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1179         }
1180         | SET context_prop_spec '=' scalar {
1181                 $$ = property_op_to_music (scm_list_3 (
1182                         ly_symbol2scm ("assign"),
1183                         gh_cadr ($2),
1184                         $4));
1185                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1186         }
1187         | UNSET context_prop_spec {
1188                 $$ = property_op_to_music (scm_list_2 (
1189                         ly_symbol2scm ("unset"),
1190                         gh_cadr ($2)));
1191                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1192         }
1193         | ONCE music_property_def {
1194                 SCM e = $2->get_property ("element");
1195                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1196                 $$ = $2;
1197
1198         }
1199         ;
1200
1201
1202
1203 scalar:
1204         string          { $$ = $1; }
1205         | bare_int      { $$ = gh_int2scm ($1); }
1206         | embedded_scm  { $$ = $1; }
1207         | full_markup {  $$ = $1; }
1208         | DIGIT { $$ = gh_int2scm ($1); }
1209         ;
1210
1211 /*
1212 This is a trick:
1213
1214 Adding pre_events to the simple_element
1215 makes the choice between
1216
1217   string:  STRING
1218
1219 and
1220
1221   simple_element: STRING
1222
1223 a single shift/reduction conflict.
1224
1225 nevertheless, this is not very clean, and we should find a different
1226 solution.
1227
1228 */
1229 pre_events: {
1230                 THIS->push_spot ();
1231         }
1232         ;
1233
1234 event_chord:
1235         pre_events simple_element post_events   {
1236                 SCM elts = $2-> get_property ("elements");
1237
1238                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1239
1240                 $2->set_property ("elements", elts);
1241                 $$ = $2;
1242         }
1243         | command_element
1244         | note_chord_element
1245         ;
1246
1247
1248 note_chord_element:
1249         chord_body optional_notemode_duration post_events
1250         {
1251                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1252                 SCM es = $1->get_property ("elements");
1253                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1254
1255                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1256                   unsmob_music (gh_car (s))->set_property ("duration", dur);
1257                 es = gh_append2 (es, postevs);
1258
1259                 $1-> set_property ("elements", es);
1260                 $$ = $1;
1261         }
1262         ;
1263
1264 chord_open: '<'
1265         ;
1266
1267 chord_close: '>'
1268         ;
1269
1270 simul_open: LESSLESS
1271         ;
1272
1273 simul_close: MOREMORE
1274         ;
1275
1276 chord_body:
1277         chord_open chord_body_elements chord_close
1278         {
1279                 $$ = MY_MAKE_MUSIC ("EventChord");
1280                 $$->set_property ("elements",
1281                         scm_reverse_x ($2, SCM_EOL));
1282         }
1283         ;
1284
1285 chord_body_elements:
1286         /* empty */             { $$ = SCM_EOL; }
1287         | chord_body_elements chord_body_element {
1288                 $$ = gh_cons ($2->self_scm (), $1);
1289                 scm_gc_unprotect_object ($2->self_scm ());
1290         }
1291         ;
1292
1293 chord_body_element:
1294         pitch exclamations questions post_events
1295         {
1296                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1297                 n->set_property ("pitch", $1);
1298                 if ($3 % 2)
1299                         n->set_property ("cautionary", SCM_BOOL_T);
1300                 if ($2 % 2 || $3 % 2)
1301                         n->set_property ("force-accidental", SCM_BOOL_T);
1302
1303                 if (gh_pair_p ($4)) {
1304                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1305                         n->set_property ("articulations", arts);
1306                 }
1307                 $$ = n;
1308         }
1309         | DRUM_PITCH post_events {
1310                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1311                 n->set_property ("duration", $2);
1312                 n->set_property ("drum-type", $1);
1313                 n->set_spot (THIS->here_input ());
1314
1315                 if (gh_pair_p ($2)) {
1316                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1317                         n->set_property ("articulations", arts);
1318                 }
1319                 $$ = n;
1320         }
1321         ;
1322
1323 add_quote:
1324         ADDQUOTE string Music {
1325                 SCM adder = ly_scheme_function ("add-quotable");
1326
1327                 scm_call_2 (adder, $2, $3->self_scm ());
1328                 scm_gc_unprotect_object ($3->self_scm ());
1329         }
1330         ;
1331
1332 command_element:
1333         command_req {
1334                 $$ = MY_MAKE_MUSIC ("EventChord");
1335                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1336                 scm_gc_unprotect_object ($1->self_scm ());
1337
1338                 $$-> set_spot (THIS->here_input ());
1339                 $1-> set_spot (THIS->here_input ());
1340         }
1341         | SKIP duration_length {
1342                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1343                 skip->set_property ("duration", $2);
1344
1345                 $$ = skip;
1346         }
1347         | QUOTE STRING duration_length {
1348                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1349                 SCM evs = SCM_EOL;
1350                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1351                 {
1352                         SCM key = $2; // use symbol?
1353                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1354                 }
1355                 Music *quote = 0;
1356                 if (gh_vector_p (evs))
1357                 {
1358                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1359                         quote->set_property ("duration", $3);
1360                         quote->set_property ("quoted-events", evs);
1361                 } else {
1362                         THIS->here_input ().warning (_f ("Can\'t find music"));
1363                         quote = MY_MAKE_MUSIC ("Event");
1364                 }
1365                 quote->set_spot (THIS->here_input ());
1366                 $$ = quote;
1367         }
1368         | OCTAVE { THIS->push_spot (); }
1369           pitch {
1370                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1371                 $$ = l;
1372                 $$->set_spot (THIS->pop_spot ());
1373                 $$->set_property ("pitch", $3);
1374         }
1375         | E_LEFTSQUARE {
1376                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1377                 l->set_property ("span-direction", gh_int2scm (START));
1378                 l->set_spot (THIS->here_input ());
1379
1380                 $$ = MY_MAKE_MUSIC ("EventChord");
1381                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1382                 scm_gc_unprotect_object (l->self_scm ());
1383                 $$->set_spot (THIS->here_input ());
1384         }
1385         | E_RIGHTSQUARE {
1386                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1387                 l->set_property ("span-direction", gh_int2scm (STOP));
1388                 l->set_spot (THIS->here_input ());
1389
1390                 $$ = MY_MAKE_MUSIC ("EventChord");
1391                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1392                 $$->set_spot (THIS->here_input ());
1393                 scm_gc_unprotect_object (l->self_scm ());
1394         }
1395         | E_BACKSLASH {
1396                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1397                 $$->set_spot (THIS->here_input ());
1398         }
1399         | '|'      {
1400
1401                 $$ = MY_MAKE_MUSIC ("BarCheck");
1402                 $$->set_spot (THIS->here_input ());
1403         }
1404         | TRANSPOSITION pitch {
1405                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1406                                         $2);
1407                 $$->set_spot (THIS-> here_input ());
1408                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1409                         $$, SCM_EOL);
1410         }
1411         | BAR STRING                    {
1412                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1413
1414                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1415                                         t, SCM_EOL);
1416                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1417                 $$->set_spot (THIS->here_input ());
1418                 t->set_spot (THIS->here_input ());
1419         }
1420         | PARTIAL duration_length       {
1421                 Moment m = - unsmob_duration ($2)->get_length ();
1422                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1423                 p->set_spot (THIS->here_input ());
1424                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1425                                         p, SCM_EOL);
1426                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1427                                         p, SCM_EOL);
1428                 $$ = p;
1429         }
1430         | CLEF STRING  {
1431                 SCM proc = ly_scheme_function ("make-clef-set");
1432
1433                 SCM result = scm_call_1 (proc, $2);
1434                 scm_gc_protect_object (result);
1435                 $$ = unsmob_music (result);
1436         }
1437         | TIME_T fraction  {
1438                 SCM proc= ly_scheme_function ("make-time-signature-set");
1439
1440                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1441                 scm_gc_protect_object (result);
1442                 $$ = unsmob_music (result);
1443         }
1444         | MARK scalar {
1445                 SCM proc = ly_scheme_function ("make-mark-set");
1446
1447                 SCM result = scm_call_1 (proc, $2);
1448                 scm_gc_protect_object (result);
1449                 $$ = unsmob_music (result);
1450         }
1451         ;
1452
1453 command_req:
1454         BREATHE {
1455                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1456         }
1457         | E_TILDE {
1458                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1459         }
1460         | MARK DEFAULT  {
1461                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1462                 $$ = m;
1463         }
1464         | tempo_event {
1465                 $$ = $1;
1466         }
1467         | KEY DEFAULT {
1468                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1469                 $$ = key;
1470         }
1471         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1472
1473                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1474                 if (scm_ilength ($3) > 0)
1475                 {
1476                         key->set_property ("pitch-alist", $3);
1477                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1478                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1479                 } else {
1480                         THIS->parser_error (_ ("Second argument must be pitch list."));
1481                 }
1482
1483                 $$ = key;
1484         }
1485         ;
1486
1487 post_events:
1488         /* empty */ {
1489                 $$ = SCM_EOL;
1490         }
1491         | post_events post_event {
1492                 $2->set_spot (THIS->here_input ());
1493                 $$ = gh_cons ($2->self_scm (), $$);
1494                 scm_gc_unprotect_object ($2->self_scm ());
1495         }
1496         | post_events tagged_post_event {
1497                 $2 -> set_spot (THIS->here_input ());
1498                 $$ = scm_cons ($2->self_scm (), $$);
1499                 scm_gc_unprotect_object ($2->self_scm ());
1500         }
1501         ;
1502
1503
1504 tagged_post_event:
1505         '-' TAG embedded_scm post_event {
1506                 tag_music ($4, $3, THIS->here_input ());
1507                 $$ = $4;
1508         }
1509         ;
1510
1511 post_event:
1512         direction_less_event {
1513                 $$ = $1;
1514         }
1515         | HYPHEN {
1516                 if (!THIS->lexer_->is_lyric_state ())
1517                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1518                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1519         }
1520         | EXTENDER {
1521                 if (!THIS->lexer_->is_lyric_state ())
1522                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1523                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1524         }
1525         | script_dir direction_reqd_event {
1526                 if ($1)
1527                         $2->set_property ("direction", gh_int2scm ($1));
1528                 $$ = $2;
1529         }
1530         | script_dir direction_less_event {
1531                 if ($1)
1532                         $2->set_property ("direction", gh_int2scm ($1));
1533                 $$ = $2;
1534         }
1535         | string_number_event
1536         ;
1537
1538 string_number_event:
1539         E_UNSIGNED {
1540                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1541                 s->set_property ("string-number", gh_int2scm ($1));
1542                 s->set_spot (THIS->here_input ());
1543                 $$ = s;
1544         }
1545         ;
1546
1547
1548 direction_less_event:
1549         '['  {
1550
1551
1552 /*
1553
1554 TODO: should take all these defs out of the parser, adn make use
1555 configurable, i.e.
1556
1557
1558 (set-articulation '~ "trill")
1559
1560 */
1561                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1562                 m->set_spot (THIS->here_input ());
1563                 m->set_property ("span-direction", gh_int2scm (START));
1564                 $$ = m;
1565         }
1566         | ']'  {
1567                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1568                 m->set_spot (THIS->here_input ());
1569                 m->set_property ("span-direction", gh_int2scm (STOP));
1570                 $$ = m;
1571         }
1572         | '~' {
1573                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1574                 m->set_spot (THIS->here_input ());
1575                 $$ = m;
1576         }
1577         | close_event {
1578                 $$ = $1;
1579                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1580                         gh_int2scm (START));
1581         }
1582         | open_event {
1583                 $$ = $1;
1584                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1585                         gh_int2scm (STOP));
1586         }
1587         | EVENT_IDENTIFIER      {
1588                 $$ = unsmob_music ($1);
1589         }
1590         | tremolo_type  {
1591                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1592                a->set_spot (THIS->here_input ());
1593                a->set_property ("tremolo-type", gh_int2scm ($1));
1594                $$ = a;
1595         }
1596         ;
1597
1598 direction_reqd_event:
1599         gen_text_def {
1600                 $$ = $1;
1601         }
1602         | script_abbreviation {
1603                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1604                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1605                 if (gh_string_p (s))
1606                         a->set_property ("articulation-type", s);
1607                 else THIS->parser_error (_ ("Expecting string as script definition"));
1608                 $$ = a;
1609         }
1610         ;
1611
1612 oct_check:
1613         /**/ { $$ = SCM_EOL; }
1614         | '='  { $$ = gh_int2scm (0); }
1615         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1616         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1617         ;
1618
1619 sup_quotes:
1620         '\'' {
1621                 $$ = 1;
1622         }
1623         | sup_quotes '\'' {
1624                 $$ ++;
1625         }
1626         ;
1627
1628 sub_quotes:
1629         ',' {
1630                 $$ = 1;
1631         }
1632         | sub_quotes ',' {
1633                 $$++;
1634         }
1635         ;
1636
1637 steno_pitch:
1638         NOTENAME_PITCH  {
1639                 $$ = $1;
1640         }
1641         | NOTENAME_PITCH sup_quotes     {
1642                 Pitch p = *unsmob_pitch ($1);
1643                 p = p.transposed (Pitch ($2,0,0));
1644                 $$ = p.smobbed_copy ();
1645         }
1646         | NOTENAME_PITCH sub_quotes      {
1647                 Pitch p =* unsmob_pitch ($1);
1648                 p = p.transposed (Pitch (-$2,0,0));
1649                 $$ = p.smobbed_copy ();
1650         }
1651         ;
1652
1653 /*
1654 ugh. duplication
1655 */
1656
1657 steno_tonic_pitch:
1658         TONICNAME_PITCH {
1659                 $$ = $1;
1660         }
1661         | TONICNAME_PITCH sup_quotes    {
1662                 Pitch p = *unsmob_pitch ($1);
1663                 p = p.transposed (Pitch ($2,0,0));
1664                 $$ = p.smobbed_copy ();
1665         }
1666         | TONICNAME_PITCH sub_quotes     {
1667                 Pitch p =* unsmob_pitch ($1);
1668
1669                 p = p.transposed (Pitch (-$2,0,0));
1670                 $$ = p.smobbed_copy ();
1671         }
1672         ;
1673
1674 pitch:
1675         steno_pitch {
1676                 $$ = $1;
1677         }
1678         ;
1679
1680 pitch_also_in_chords:
1681         pitch
1682         | steno_tonic_pitch
1683         ;
1684
1685 close_event:
1686         '('     {
1687                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1688                 $$ = s;
1689                 s->set_spot (THIS->here_input ());
1690         }
1691         | E_OPEN        {
1692                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1693                 $$ = s;
1694                 s->set_spot (THIS->here_input ());
1695         }
1696         | E_SMALLER {
1697                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1698                 $$ = s;
1699                 s->set_spot (THIS->here_input ());
1700         }
1701         | E_BIGGER {
1702                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1703                 $$ = s;
1704                 s->set_spot (THIS->here_input ());
1705         }
1706         ;
1707
1708
1709 open_event:
1710         E_EXCLAMATION   {
1711                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1712                 s->set_spot (THIS->here_input ());
1713
1714                 $$ = s;
1715         }
1716         | ')'   {
1717                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1718                 $$ = s;
1719                 s->set_spot (THIS->here_input ());
1720
1721         }
1722         | E_CLOSE       {
1723                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1724                 $$ = s;
1725                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1726                 s->set_spot (THIS->here_input ());
1727         }
1728         ;
1729
1730 gen_text_def:
1731         full_markup {
1732                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1733                 t->set_property ("text", $1);
1734                 t->set_spot (THIS->here_input ());
1735                 $$ = t;
1736         }
1737         | string {
1738                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1739                 t->set_property ("text", make_simple_markup ($1));
1740                 t->set_spot (THIS->here_input ());
1741                 $$ = t;
1742
1743         }
1744         | DIGIT {
1745                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1746                 t->set_property ("digit", gh_int2scm ($1));
1747                 t->set_spot (THIS->here_input ());
1748                 $$ = t;
1749         }
1750         ;
1751
1752 script_abbreviation:
1753         '^'             {
1754                 $$ = scm_makfrom0str ("Hat");
1755         }
1756         | '+'           {
1757                 $$ = scm_makfrom0str ("Plus");
1758         }
1759         | '-'           {
1760                 $$ = scm_makfrom0str ("Dash");
1761         }
1762         | '|'           {
1763                 $$ = scm_makfrom0str ("Bar");
1764         }
1765         | '>'           {
1766                 $$ = scm_makfrom0str ("Larger");
1767         }
1768         | '.'           {
1769                 $$ = scm_makfrom0str ("Dot");
1770         }
1771         | '_' {
1772                 $$ = scm_makfrom0str ("Underscore");
1773         }
1774         ;
1775
1776 script_dir:
1777         '_'     { $$ = DOWN; }
1778         | '^'   { $$ = UP; }
1779         | '-'   { $$ = CENTER; }
1780         ;
1781
1782
1783 absolute_pitch:
1784         steno_pitch     {
1785                 $$ = $1;
1786         }
1787         ;
1788
1789 duration_length:
1790         multiplied_duration {
1791                 $$ = $1;
1792         }
1793         ;
1794
1795 optional_notemode_duration:
1796         {
1797                 Duration dd = THIS->default_duration_;
1798                 $$ = dd.smobbed_copy ();
1799
1800                 THIS->beam_check ($$);
1801         }
1802         | multiplied_duration   {
1803                 $$ = $1;
1804                 THIS->default_duration_ = *unsmob_duration ($$);
1805
1806                 THIS->beam_check ($$);
1807         }
1808         ;
1809
1810 steno_duration:
1811         bare_unsigned dots              {
1812                 int len = 0;
1813                 if (!is_is_duration ($1))
1814                         THIS->parser_error (_f ("not a duration: %d", $1));
1815                 else
1816                         len = intlog2 ($1);
1817
1818                 $$ = Duration (len, $2).smobbed_copy ();
1819         }
1820         | DURATION_IDENTIFIER dots      {
1821                 Duration *d = unsmob_duration ($1);
1822                 Duration k (d->duration_log (), d->dot_count () + $2);
1823                 *d = k;
1824                 $$ = $1;
1825         }
1826         ;
1827
1828
1829
1830
1831 multiplied_duration:
1832         steno_duration {
1833                 $$ = $1;
1834         }
1835         | multiplied_duration '*' bare_unsigned {
1836                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1837         }
1838         | multiplied_duration '*' FRACTION {
1839                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1840
1841                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1842         }
1843         ;
1844
1845 fraction:
1846         FRACTION { $$ = $1; }
1847         | UNSIGNED '/' UNSIGNED {
1848                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1849         }
1850         ;
1851
1852 dots:
1853         /* empty */     {
1854                 $$ = 0;
1855         }
1856         | dots '.' {
1857                 $$ ++;
1858         }
1859         ;
1860
1861
1862 tremolo_type:
1863         ':'     {
1864                 $$ = 0;
1865         }
1866         | ':' bare_unsigned {
1867                 if (!is_is_duration ($2))
1868                         THIS->parser_error (_f ("not a duration: %d", $2));
1869                 $$ = $2;
1870         }
1871         ;
1872
1873
1874
1875 /*****************************************************************
1876                 BASS FIGURES
1877 *****************************************************************/
1878 bass_number:
1879         DIGIT   {
1880                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1881         }
1882         | UNSIGNED {
1883                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1884         }
1885         | STRING { $$ = $1; }
1886         ;
1887
1888 bass_mod:
1889         '-'     { $$ = -2; }
1890         | '+'   { $$ = 2; }
1891         | '!'   { $$ = 0; }
1892         ;
1893
1894 bass_figure:
1895         FIGURE_SPACE {
1896                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1897                 $$ = bfr->self_scm ();
1898                 scm_gc_unprotect_object ($$);
1899         }
1900         | bass_number  {
1901                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1902                 $$ = bfr->self_scm ();
1903
1904                 bfr->set_property ("figure", $1);
1905
1906                 scm_gc_unprotect_object ($$);
1907         }
1908         | bass_figure bass_mod {
1909                 Music *m = unsmob_music ($1);
1910                 if ($2) {
1911                         SCM salter = m->get_property ("alteration");
1912                         int alter = gh_number_p (salter) ? gh_scm2int (salter) : 0;
1913                         m->set_property ("alteration",
1914                                 gh_int2scm (alter + $2));
1915                 } else {
1916                         m->set_property ("alteration", gh_int2scm (0));
1917                 }
1918         }
1919         ;
1920
1921 br_bass_figure:
1922         '[' bass_figure {
1923                 $$ = $2;
1924                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1925         }
1926         | bass_figure   {
1927                 $$ = $1;
1928         }
1929         | br_bass_figure ']' {
1930                 $$ = $1;
1931                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1932         }
1933         ;
1934
1935 figure_list:
1936         /**/            {
1937                 $$ = SCM_EOL;
1938         }
1939         | figure_list br_bass_figure {
1940                 $$ = scm_cons ($2, $1);
1941         }
1942         ;
1943
1944 figure_spec:
1945         FIGURE_OPEN figure_list FIGURE_CLOSE {
1946                 Music *m = MY_MAKE_MUSIC ("EventChord");
1947                 $2 = scm_reverse_x ($2, SCM_EOL);
1948                 m->set_property ("elements", $2);
1949                 $$ = m->self_scm ();
1950         }
1951         ;
1952
1953
1954 optional_rest:
1955         /**/   { $$ = 0; }
1956         | REST { $$ = 1; }
1957         ;
1958
1959 simple_element:
1960         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1961
1962                 Input i = THIS->pop_spot ();
1963                 if (!THIS->lexer_->is_note_state ())
1964                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1965
1966                 Music *n = 0;
1967                 if ($6)
1968                         n = MY_MAKE_MUSIC ("RestEvent");
1969                 else
1970                         n = MY_MAKE_MUSIC ("NoteEvent");
1971
1972                 n->set_property ("pitch", $1);
1973                 n->set_property ("duration", $5);
1974
1975                 if (gh_number_p ($4))
1976                 {
1977                         int q = gh_scm2int ($4);
1978                         n->set_property ("absolute-octave", gh_int2scm (q-1));
1979                 }
1980
1981                 if ($3 % 2)
1982                         n->set_property ("cautionary", SCM_BOOL_T);
1983                 if ($2 % 2 || $3 % 2)
1984                         n->set_property ("force-accidental", SCM_BOOL_T);
1985
1986                 Music *v = MY_MAKE_MUSIC ("EventChord");
1987                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
1988                 scm_gc_unprotect_object (n->self_scm ());
1989
1990                 v->set_spot (i);
1991                 n->set_spot (i);
1992                 $$ = v;
1993         }
1994         | DRUM_PITCH optional_notemode_duration {
1995                 Input i = THIS->pop_spot ();
1996
1997                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1998                 n->set_property ("duration", $2);
1999                 n->set_property ("drum-type", $1);
2000
2001                 Music *v = MY_MAKE_MUSIC ("EventChord");
2002                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2003                 scm_gc_unprotect_object (n->self_scm ());
2004                 v->set_spot (i);
2005                 n->set_spot (i);
2006                 $$ = v;
2007
2008         }
2009         | figure_spec optional_notemode_duration {
2010                 Music *m = unsmob_music ($1);
2011                 Input i = THIS->pop_spot ();
2012                 m->set_spot (i);
2013                 for (SCM s = m->get_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2014                 {
2015                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2016                 }
2017                 $$ = m;
2018         }
2019         | RESTNAME optional_notemode_duration           {
2020
2021                 Input i = THIS->pop_spot ();
2022                 Music *ev = 0;
2023                 if (ly_scm2string ($1) == "s") {
2024                         /* Space */
2025                         ev = MY_MAKE_MUSIC ("SkipEvent");
2026                   }
2027                 else {
2028                         ev = MY_MAKE_MUSIC ("RestEvent");
2029
2030                     }
2031                 ev->set_property ("duration", $2);
2032                 ev->set_spot (i);
2033                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2034                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2035                 velt->set_spot (i);
2036
2037                 scm_gc_unprotect_object (ev->self_scm ());
2038
2039                 $$ = velt;
2040         }
2041         | MULTI_MEASURE_REST optional_notemode_duration         {
2042                 THIS->pop_spot ();
2043
2044                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2045                 SCM mus = scm_call_2 (proc, $2,
2046                         make_input (THIS->here_input ()));
2047                 scm_gc_protect_object (mus);
2048                 $$ = unsmob_music (mus);
2049         }
2050
2051         | lyric_element optional_notemode_duration      {
2052                 Input i = THIS->pop_spot ();
2053                 if (!THIS->lexer_->is_lyric_state ())
2054                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2055
2056                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2057                 lreq->set_property ("text", $1);
2058                 lreq->set_property ("duration",$2);
2059                 lreq->set_spot (i);
2060                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2061                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2062
2063                 $$= velt;
2064         }
2065         | new_chord {
2066                 THIS->pop_spot ();
2067
2068                 if (!THIS->lexer_->is_chord_state ())
2069                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2070                 $$ = unsmob_music ($1);
2071         }
2072         ;
2073
2074 lyric_element:
2075         full_markup { $$ = $1; }
2076         | STRING { $$ = $1; }
2077         ;
2078
2079 new_chord:
2080         steno_tonic_pitch optional_notemode_duration   {
2081                 $$ = make_chord ($1, $2, SCM_EOL);
2082         }
2083         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2084                 SCM its = scm_reverse_x ($4, SCM_EOL);
2085                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2086         }
2087         ;
2088
2089 chord_items:
2090         /**/ {
2091                 $$ = SCM_EOL;
2092         }
2093         | chord_items chord_item {
2094                 $$ = gh_cons ($2, $$);
2095         }
2096         ;
2097
2098 chord_separator:
2099         CHORD_COLON {
2100                 $$ = ly_symbol2scm ("chord-colon");
2101         }
2102         | CHORD_CARET {
2103                 $$ = ly_symbol2scm ("chord-caret");
2104         }
2105         | CHORD_SLASH steno_tonic_pitch {
2106                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2107         }
2108         | CHORD_BASS steno_tonic_pitch {
2109                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2110         }
2111         ;
2112
2113 chord_item:
2114         chord_separator {
2115                 $$ = $1;
2116         }
2117         | step_numbers {
2118                 $$ = scm_reverse_x ($1, SCM_EOL);
2119         }
2120         | CHORD_MODIFIER  {
2121                 $$ = $1;
2122         }
2123         ;
2124
2125 step_numbers:
2126         step_number { $$ = gh_cons ($1, SCM_EOL); }
2127         | step_numbers '.' step_number {
2128                 $$ = gh_cons ($3, $$);
2129         }
2130         ;
2131
2132 step_number:
2133         bare_unsigned {
2134                 $$ = make_chord_step ($1, 0);
2135         }
2136         | bare_unsigned '+' {
2137                 $$ = make_chord_step ($1, SHARP);
2138         }
2139         | bare_unsigned CHORD_MINUS {
2140                 $$ = make_chord_step ($1, FLAT);
2141         }
2142         ;
2143
2144 /*
2145         UTILITIES
2146
2147 TODO: should deprecate in favor of Scheme?
2148
2149  */
2150 number_expression:
2151         number_expression '+' number_term {
2152                 $$ = scm_sum ($1, $3);
2153         }
2154         | number_expression '-' number_term {
2155                 $$ = scm_difference ($1, $3);
2156         }
2157         | number_term
2158         ;
2159
2160 number_term:
2161         number_factor {
2162                 $$ = $1;
2163         }
2164         | number_factor '*' number_factor {
2165                 $$ = scm_product ($1, $3);
2166         }
2167         | number_factor '/' number_factor {
2168                 $$ = scm_divide ($1, $3);
2169         }
2170         ;
2171
2172 number_factor:
2173         '-'  number_factor { /* %prec UNARY_MINUS */
2174                 $$ = scm_difference ($2, SCM_UNDEFINED);
2175         }
2176         | bare_number
2177         ;
2178
2179
2180 bare_number:
2181         UNSIGNED        {
2182                 $$ = gh_int2scm ($1);
2183         }
2184         | REAL          {
2185                 $$ = $1;
2186         }
2187         | NUMBER_IDENTIFIER             {
2188                 $$ = $1;
2189         }
2190         | REAL NUMBER_IDENTIFIER        {
2191                 $$ = gh_double2scm (gh_scm2double ($1) *gh_scm2double ($2));
2192         }
2193         | UNSIGNED NUMBER_IDENTIFIER    {
2194                 $$ = gh_double2scm ($1 *gh_scm2double ($2));
2195         }
2196         ;
2197
2198
2199 bare_unsigned:
2200         UNSIGNED {
2201                         $$ = $1;
2202         }
2203         | DIGIT {
2204                 $$ = $1;
2205         }
2206         ;
2207
2208 bare_int:
2209         bare_number {
2210                 if (scm_integer_p ($1) == SCM_BOOL_T)
2211                 {
2212                         int k = gh_scm2int ($1);
2213                         $$ = k;
2214                 } else
2215                 {
2216                         THIS->parser_error (_ ("need integer number arg"));
2217                         $$ = 0;
2218                 }
2219         }
2220         | '-' bare_int {
2221                 $$ = -$2;
2222         }
2223         ;
2224
2225
2226 string:
2227         STRING          {
2228                 $$ = $1;
2229         }
2230         | STRING_IDENTIFIER     {
2231                 $$ = $1;
2232         }
2233         | string '+' string {
2234                 $$ = scm_string_append (scm_list_2 ($1, $3));
2235         }
2236         ;
2237
2238
2239 exclamations:
2240                 { $$ = 0; }
2241         | exclamations '!'      { $$ ++; }
2242         ;
2243
2244 questions:
2245                 { $$ = 0; }
2246         | questions '?' { $$ ++; }
2247         ;
2248
2249
2250
2251 full_markup:
2252         MARKUP_IDENTIFIER {
2253                 $$ = $1;
2254         }
2255         | MARKUP
2256                 { THIS->lexer_->push_markup_state (); }
2257         markup
2258                 { $$ = $3;
2259                   THIS->lexer_->pop_state ();
2260                 }
2261         ;
2262
2263
2264 /*
2265 This should be done more dynamically if possible.
2266 */
2267 markup:
2268         STRING {
2269                 $$ = make_simple_markup ($1);
2270         }
2271         | MARKUP_HEAD_EMPTY {
2272                 $$ = scm_list_1 ($1);
2273         }
2274         | MARKUP_HEAD_MARKUP0 markup {
2275                 $$ = scm_list_2 ($1, $2);
2276         }
2277         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2278                 $$ = scm_list_3 ($1, $2, $3);
2279         }
2280         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2281                 $$ = scm_list_3 ($1, $2, $3);
2282         }
2283         | markup_line {
2284                 $$ = $1;
2285         }
2286         | MARKUP_HEAD_LIST0 markup_list {
2287                 $$ = scm_list_2 ($1,$2);
2288         }
2289         | MARKUP_HEAD_SCM0 embedded_scm {
2290                 $$ = scm_list_2 ($1, $2);
2291         }
2292         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2293                 $$ = scm_list_4 ($1, $2, $3, $4);
2294         }
2295         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2296                 $$ = scm_list_4 ($1, $2, $3, $4);
2297         }
2298         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2299                 $$ = scm_list_3 ($1, $2, $3);
2300         }
2301         | MARKUP_IDENTIFIER {
2302                 $$ = $1;
2303         }
2304         | STRING_IDENTIFIER {
2305                 $$ = $1;
2306         }
2307         ;
2308
2309 markup_list:
2310         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2311         ;
2312
2313 markup_line:
2314         '{' markup_list_body '}' {
2315                 SCM line = ly_scheme_function ("line-markup");
2316
2317                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2318         }
2319         ;
2320
2321 markup_list_body:
2322         /**/ {  $$ = SCM_EOL; }
2323         | markup_list_body markup {
2324                 $$ = gh_cons ($2, $1);
2325         }
2326         ;
2327
2328
2329 %%
2330
2331 void
2332 My_lily_parser::set_yydebug (bool )
2333 {
2334 #if 0
2335         yydebug = 1;
2336 #endif
2337 }
2338
2339 extern My_lily_parser *current_parser;
2340
2341 void
2342 My_lily_parser::do_yyparse ()
2343 {
2344         current_parser = this;;
2345         yyparse ((void*)this);
2346 }
2347
2348
2349 /*
2350 Should make this optional?    It will also complain when you do
2351
2352         [s4]
2353
2354 which is entirely legitimate.
2355
2356 Or we can scrap it. Barchecks should detect wrong durations, and
2357 skipTypesetting speeds it up a lot.
2358 */
2359
2360 void
2361 My_lily_parser::beam_check (SCM dur)
2362 {
2363   Duration *d = unsmob_duration (dur);
2364   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2365     {
2366       Music *m = unsmob_music (last_beam_start_);
2367       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2368     }
2369   last_beam_start_ = SCM_EOL;
2370 }
2371
2372
2373
2374
2375 /*
2376
2377 It is a little strange to have this function in this file, but
2378 otherwise, we have to import music classes into the lexer.
2379
2380 */
2381 int
2382 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2383 {
2384         if (gh_string_p (sid)) {
2385                 *destination = sid;
2386                 return STRING_IDENTIFIER;
2387         } else if (gh_number_p (sid)) {
2388                 *destination = sid;
2389                 return NUMBER_IDENTIFIER;
2390         } else if (unsmob_context_def (sid)) {
2391                 *destination = unsmob_context_def (sid)->clone_scm ();
2392                 return CONTEXT_DEF_IDENTIFIER;
2393         } else if (unsmob_score (sid)) {
2394                 Score *sc = new Score (*unsmob_score (sid));
2395                 *destination = sc->self_scm ();
2396                 return SCORE_IDENTIFIER;
2397         } else if (Music *mus = unsmob_music (sid)) {
2398                 mus = mus->clone ();
2399                 *destination = mus->self_scm ();
2400                 unsmob_music (*destination)->
2401                         set_property ("origin", make_input (last_input_));
2402                 return dynamic_cast<Event*> (mus)
2403                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2404         } else if (unsmob_duration (sid)) {
2405                 *destination = unsmob_duration (sid)->smobbed_copy ();
2406                 return DURATION_IDENTIFIER;
2407         } else if (unsmob_music_output_def (sid)) {
2408                 Music_output_def *p = unsmob_music_output_def (sid);
2409                 p = p->clone ();
2410
2411                 *destination = p->self_scm ();
2412                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2413         } else if (Text_item::markup_p (sid)) {
2414                 *destination = sid;
2415                 return MARKUP_IDENTIFIER;
2416         }
2417
2418         return -1;
2419 }
2420
2421 Music *
2422 property_op_to_music (SCM op)
2423 {
2424         Music *m = 0;
2425         SCM tag = gh_car (op);
2426         SCM symbol = gh_cadr (op);
2427         SCM args = gh_cddr (op);
2428         SCM grob_val = SCM_UNDEFINED;
2429         SCM grob_sym = SCM_UNDEFINED;
2430         SCM val = SCM_UNDEFINED;
2431
2432         if (tag == ly_symbol2scm ("assign"))
2433                 {
2434                 m = MY_MAKE_MUSIC ("PropertySet");
2435                 val = gh_car (args);
2436                 }
2437         else if (tag == ly_symbol2scm ("unset"))
2438                 m = MY_MAKE_MUSIC ("PropertyUnset");
2439         else if (tag == ly_symbol2scm ("poppush")
2440                  || tag == ly_symbol2scm ("push"))
2441                 {
2442                 m = MY_MAKE_MUSIC ("OverrideProperty");
2443                 grob_sym = gh_car (args);
2444                 grob_val = gh_cadr (args);
2445                 }
2446         else if (tag == ly_symbol2scm ("pop")) {
2447                 m = MY_MAKE_MUSIC ("RevertProperty");
2448                 grob_sym = gh_car (args);
2449                 }
2450
2451         m->set_property ("symbol", symbol);
2452
2453         if (val != SCM_UNDEFINED)
2454                 m->set_property ("value", val);
2455         if (grob_val != SCM_UNDEFINED)
2456                 m->set_property ("grob-value", grob_val);
2457
2458         if (grob_sym != SCM_UNDEFINED)
2459                 {
2460                 bool itc = internal_type_checking_global_b;
2461                 /* UGH.
2462                 */
2463                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2464                 if (autobeam)
2465                         internal_type_checking_global_b = false;
2466                 m->set_property ("grob-property", grob_sym);
2467                 if (autobeam)
2468                         internal_type_checking_global_b = itc;
2469                 }
2470
2471         if (op == ly_symbol2scm ("poppush"))
2472                 m->set_property ("pop-first", SCM_BOOL_T);
2473
2474
2475         return m;
2476 }
2477
2478 Music*
2479 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2480 {
2481         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2482
2483         csm->set_property ("element", m->self_scm ());
2484         scm_gc_unprotect_object (m->self_scm ());
2485
2486         csm->set_property ("context-type",
2487                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2488         csm->set_property ("property-operations", ops);
2489
2490         if (gh_string_p (id))
2491                 csm->set_property ("context-id", id);
2492         return csm;
2493 }
2494
2495
2496 SCM
2497 get_next_unique_context ()
2498 {
2499         static int new_context_count;
2500
2501         char s[1024];
2502         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2503
2504         return scm_makfrom0str (s);
2505 }
2506