lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "translator-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87
  88
  89 #define YYERROR_VERBOSE 1
  90
  91 My_lily_parser* my_lily_parser;
  92 #define YYPARSE_PARAM my_lily_parser
  93 #define YYLEX_PARAM my_lily_parser
  94 #define THIS\
  95         ((My_lily_parser *) my_lily_parser)
  96
  97 #define yyerror THIS->parser_error
  98
  99 /*
 100   Add symbols to the  TAGS field of a music object.
 101 */
 102
 103 void
 104 tag_music (Music*m,  SCM tag, Input ip)
 105 {
 106         SCM tags = m->get_mus_property ("tags");
 107         if (gh_symbol_p (tag))
 108                 tags = scm_cons (tag, tags);
 109         else if (gh_list_p (tag))
 110                 tags = gh_append2 (tag, tags);
 111         else
 112                 ip.warning (_("Tag must be symbol or list of symbols."));
 113
 114         m->set_mus_property ("tags", tags);
 115 }
 116
 117
 118
 119 bool
 120 regular_identifier_b (SCM id)
 121 {
 122   String str = ly_scm2string (id);
 123   char const *s = str.to_str0 () ;
 124
 125   bool v = true;
 126   while (*s && v)
 127    {
 128         v = v && isalpha (*s);
 129         s++;
 130    }
 131   return v;
 132 }
 133
 134 SCM
 135 make_simple_markup (SCM a)
 136 {
 137         static SCM simple;
 138         if (!simple)
 139         simple = scm_c_eval_string ("simple-markup");
 140
 141         return scm_list_n (simple, a, SCM_UNDEFINED);
 142 }
 143
 144
 145 bool
 146 is_duration_b (int t)
 147 {
 148   return t && t == 1 << intlog2 (t);
 149 }
 150
 151 void
 152 set_music_properties (Music *p, SCM a)
 153 {
 154   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 155         {
 156         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 157         }
 158 }
 159
 160 SCM
 161 make_chord_step (int step, int alter)
 162 {
 163         if (step == 7)
 164                 alter += FLAT;
 165
 166         while(step < 0)
 167                 step += 7;
 168         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 169         return m.smobbed_copy ();
 170 }
 171
 172
 173 SCM
 174 make_chord (SCM pitch, SCM dur, SCM modification_list)
 175 {
 176         static SCM chord_ctor;
 177         if (!chord_ctor)
 178                 chord_ctor= scm_c_eval_string ("construct-chord");
 179         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 180         scm_gc_protect_object (ch);
 181         return ch;
 182 }
 183
 184 /*
 185   Todo: actually also use apply iso. call too ...
 186 */
 187 bool
 188 ly_input_procedure_p (SCM x)
 189 {
 190         return gh_procedure_p (x)
 191                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 192 }
 193
 194 Music*
 195 set_property_music (SCM sym, SCM value)
 196 {
 197         Music * p = MY_MAKE_MUSIC("PropertySet");
 198         p->set_mus_property ("symbol", sym);
 199         p->set_mus_property ("value", value);
 200         return p;
 201 }
 202
 203 %}
 204
 205 /* We use SCMs to do strings, because it saves us the trouble of
 206 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 207 of the parse stack onto the heap. */
 208
 209
 210 %union {
 211         String * string;
 212     Music *music;
 213     Score *score;
 214     Music_output_def * outputdef;
 215     SCM scm;
 216     int i;
 217 }
 218 %{
 219
 220 int
 221 yylex (YYSTYPE *s,  void * v)
 222 {
 223         My_lily_parser   *pars = (My_lily_parser*) v;
 224         My_lily_lexer * lex = pars->lexer_;
 225
 226         lex->lexval = (void*) s;
 227         lex->prepare_for_next_token();
 228         return lex->yylex ();
 229 }
 230
 231
 232 %}
 233
 234 %pure_parser
 235
 236
 237 %token ACCEPTS
 238 %token ADDLYRICS
 239 %token ALIAS
 240 %token ALTERNATIVE
 241 %token APPLY
 242 %token APPLYCONTEXT
 243 %token APPLYOUTPUT
 244 %token AUTOCHANGE
 245 %token BAR
 246 %token BREATHE
 247 %token CHORDMODIFIERS
 248 %token CHORDS
 249 %token LESSLESS
 250 %token MOREMORE
 251 %token CLEF
 252 %token COMMANDSPANREQUEST
 253 %token CONSISTS
 254 %token CONSISTSEND
 255 %token CONTEXT
 256 %token DEFAULT
 257 %token DENIES
 258 %token DESCRIPTION
 259 %token EXTENDER
 260 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 261 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 262 %token GRACE
 263 %token ACCIACCATURA
 264 %token APPOGGIATURA
 265 %token GROBDESCRIPTIONS
 266 %token HEADER
 267 %token HYPHEN
 268 %token INVALID
 269 %token KEY
 270 %token LYRICS
 271 %token MARK
 272 %token MIDI
 273 %token MULTI_MEASURE_REST
 274 %token NAME
 275 %token NEWCONTEXT
 276 %token NOTES
 277 %token OCTAVE
 278 %token ONCE
 279 %token OVERRIDE SET REVERT
 280 %token PAPER
 281 %token PARTCOMBINE
 282 %token PARTIAL
 283 %token PITCHNAMES
 284 %token PROPERTY
 285 %token RELATIVE
 286 %token REMOVE
 287 %token REPEAT
 288 %token REST
 289 %token SCM_T
 290 %token SCORE
 291 %token SEQUENTIAL
 292 %token SIMULTANEOUS
 293 %token SKIP
 294 %token SPANREQUEST
 295 %token TAG
 296 %token TEMPO
 297 %token TIMES
 298 %token TIME_T
 299 %token TRANSLATOR
 300 %token TRANSPOSE
 301 %token TYPE
 302 %token UNSET
 303
 304
 305 /* escaped */
 306 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 307 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 308 %token E_BACKSLASH
 309 %token <i> E_UNSIGNED
 310 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 311 %token FIGURE_SPACE
 312
 313 %type <i>       exclamations questions dots optional_rest
 314 %type <i>        bass_mod
 315 %type <scm>     grace_head
 316 %type <scm>     lyric_element
 317 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 318 %token <i>      DIGIT
 319 %token <scm>    NOTENAME_PITCH
 320 %token <scm>    TONICNAME_PITCH
 321 %token <scm>    CHORDMODIFIER_PITCH
 322 %token <scm>    DURATION_IDENTIFIER
 323 %token <scm>    FRACTION
 324 %token <id>     IDENTIFIER
 325 %token <scm>    CHORDNAMES
 326
 327 %token <scm> CHORD_MODIFIER
 328
 329 %token <scm>    SCORE_IDENTIFIER
 330 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 331 %token <scm>    NUMBER_IDENTIFIER
 332 %token <scm>    EVENT_IDENTIFIER
 333 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 334 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 335 %token <scm>    RESTNAME
 336 %token <scm>    STRING
 337 %token <scm>    SCM_T
 338 %token <i>      UNSIGNED
 339 %token <scm>   REAL
 340
 341 %token MARKUP
 342 %token <scm> MARKUP_HEAD_MARKUP0
 343 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 344 %token <scm> MARKUP_HEAD_SCM0
 345 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0_SCM1
 347 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 349
 350 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 351 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 352
 353 %type <outputdef> output_def
 354 %type <scm>     lilypond_header lilypond_header_body
 355 %type <music>   open_event close_event
 356 %type <i>       sub_quotes sup_quotes
 357 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 358 %type <music>   Repeated_music
 359 %type <scm>     Alternative_music
 360 %type <i>       tremolo_type
 361 %type <i>       bare_int  bare_unsigned
 362 %type <i>       script_dir
 363 %type <scm>     identifier_init
 364
 365 %type <music> note_chord_element chord_body chord_body_element
 366 %type <scm>  chord_body_elements
 367 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 368
 369 %type <scm>   post_events
 370 %type <music> gen_text_def direction_less_event direction_reqd_event
 371 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 372 %type <scm>    steno_tonic_pitch
 373 %type <scm>     duration_length fraction
 374
 375 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 376
 377 %type <scm>  embedded_scm scalar
 378 %type <music>   Music Sequential_music Simultaneous_music
 379 %type <music>   relative_music re_rhythmed_music part_combined_music
 380 %type <music>   property_def translator_change  simple_property_def
 381 %type <scm> Music_list
 382 %type <outputdef>  music_output_def_body
 383 %type <music> shorthand_command_req
 384 %type <music>   post_event tagged_post_event
 385 %type <music> command_req verbose_command_req
 386 %type <music> hyphen_req
 387 %type <music> string_number_event
 388 %type <scm>     string bare_number number_expression number_term number_factor
 389 %type <score>   score_block score_body
 390
 391 %type <scm>     translator_spec_block translator_spec_body
 392 %type <music>   tempo_event
 393 %type <scm> notenames_body notenames_block chordmodifiers_block
 394 %type <scm>     script_abbreviation
 395
 396
 397
 398 %left '-' '+'
 399
 400 /* We don't assign precedence to / and *, because we might need varied
 401 prec levels in different prods */
 402
 403 %left UNARY_MINUS
 404
 405 %%
 406
 407 lilypond:       /* empty */
 408         | lilypond toplevel_expression {}
 409         | lilypond assignment  { }
 410         | lilypond error {
 411                 THIS->error_level_  = 1;
 412         }
 413         | lilypond INVALID      {
 414                 THIS->error_level_  = 1;
 415         }
 416         ;
 417
 418 toplevel_expression:
 419         notenames_block                 {
 420                 THIS->lexer_->pitchname_tab_ =  $1;
 421         }
 422         | chordmodifiers_block                  {
 423                 THIS->lexer_->chordmodifier_tab_  = $1;
 424         }
 425         | lilypond_header {
 426                 THIS->input_file_->header_ = $1;
 427         }
 428         | score_block {
 429                 Score * sc = $1;
 430
 431                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 432
 433                 Path p = split_path (THIS->output_basename_);
 434                 int *c =  &THIS->input_file_->score_count_;
 435                 if (*c)
 436                         {
 437                         p.base += "-" + to_string (*c);
 438                         }
 439
 440                 (*c)++;
 441                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 442
 443                 for (int i=0; i < sc->defs_.size (); i++)
 444                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 445
 446                 if (sc->defs_.empty ())
 447                 {
 448                    Music_output_def *id =
 449                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 450                                 ("$defaultpaper"));
 451
 452                    id = id ? id->clone () : new Paper_def;
 453
 454                    default_rendering (sc->music_, id->self_scm(), head, outname);
 455
 456                    scm_gc_unprotect_object (id->self_scm ());
 457                 }
 458                 scm_gc_unprotect_object (sc->self_scm());
 459         }
 460         | output_def {
 461                 if (dynamic_cast<Paper_def*> ($1))
 462                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 463                 else if (dynamic_cast<Midi_def*> ($1))
 464                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 465         }
 466         ;
 467
 468 embedded_scm:
 469         SCM_T
 470         | SCM_IDENTIFIER
 471         ;
 472
 473
 474 chordmodifiers_block:
 475         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 476         ;
 477
 478 notenames_block:
 479         PITCHNAMES notenames_body   {  $$ = $2; }
 480         ;
 481
 482 notenames_body:
 483         embedded_scm    {
 484           int i = scm_ilength ($1);
 485
 486           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 487           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 488                 SCM pt = ly_cdar (s);
 489                 scm_hashq_set_x (tab, ly_caar (s), pt);
 490           }
 491           $$ = tab;
 492         }
 493         ;
 494
 495 lilypond_header_body:
 496         {
 497                 $$ = ly_make_anonymous_module ();
 498                 THIS->lexer_->add_scope ($$);
 499         }
 500         | lilypond_header_body assignment  {
 501
 502         }
 503         ;
 504
 505 lilypond_header:
 506         HEADER '{' lilypond_header_body '}'     {
 507                 $$ = THIS->lexer_-> remove_scope();
 508         }
 509         ;
 510
 511
 512 /*
 513         DECLARATIONS
 514 */
 515 assignment:
 516         STRING {
 517                 THIS->push_spot ();
 518         }
 519         /* cont */ '=' identifier_init  {
 520
 521         /*
 522                 Should find generic way of associating input with objects.
 523         */
 524                 Input ip = THIS->pop_spot ();
 525
 526                 if (! regular_identifier_b ($1))
 527                 {
 528                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 529                 }
 530
 531                 THIS->lexer_->set_identifier ($1, $4);
 532
 533 /*
 534  TODO: devise standard for protection in parser.
 535
 536   The parser stack lives on the C-stack, which means that
 537 all objects can be unprotected as soon as they're here.
 538
 539 */
 540         }
 541         | embedded_scm { }
 542         ;
 543
 544
 545
 546 identifier_init:
 547         score_block {
 548                 $$ = $1->self_scm ();
 549                 scm_gc_unprotect_object ($$);
 550         }
 551         | full_markup {
 552                 $$ = $1;
 553         }
 554         | output_def {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | translator_spec_block {
 559                 $$ = $1;
 560         }
 561         | Music  {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | post_event {
 566                 $$ = $1->self_scm ();
 567                 scm_gc_unprotect_object ($$);
 568         }
 569         | number_expression {
 570                 $$ = $1;
 571         }
 572         | string {
 573                 $$ = $1;
 574         }
 575         | embedded_scm  {
 576                 $$ = $1;
 577         }
 578         ;
 579
 580 translator_spec_block:
 581         TRANSLATOR '{' translator_spec_body '}'
 582                 {
 583                 $$ = $3;
 584         }
 585         ;
 586
 587 translator_spec_body:
 588         /**/ {
 589                 $$ = Translator_def::make_scm ();
 590                 unsmob_translator_def ($$)->set_spot (THIS->here_input ());
 591         }
 592         | TRANSLATOR_IDENTIFIER {
 593                 $$ = $1;
 594                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 595         }
 596         | translator_spec_body TYPE STRING      {
 597                 unsmob_translator_def ($$)->translator_group_type_ = $3;
 598         }
 599         | translator_spec_body DESCRIPTION string  {
 600                 unsmob_translator_def ($$)->description_ = $3;
 601         }
 602         | translator_spec_body STRING '=' embedded_scm                  {
 603                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 604         }
 605         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 606                 unsmob_translator_def ($$)
 607                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 608         }
 609         | translator_spec_body STRING SET embedded_scm '=' embedded_scm {
 610                 unsmob_translator_def ($$)
 611                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 612         }
 613         | translator_spec_body STRING REVERT embedded_scm  {
 614           unsmob_translator_def ($$)->add_pop_property (
 615                 scm_string_to_symbol ($2), $4);
 616         }
 617         | translator_spec_body NAME STRING  {
 618                 unsmob_translator_def ($$)->type_name_ = scm_string_to_symbol ($3);
 619         }
 620         | translator_spec_body CONSISTS STRING  {
 621                 unsmob_translator_def ($$)->add_element ($3);
 622         }
 623         | translator_spec_body ALIAS STRING  {
 624                 Translator_def*td = unsmob_translator_def ($$);
 625                 td->type_aliases_ = scm_cons (scm_string_to_symbol ($3), td->type_aliases_);
 626         }
 627         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 628                 Translator_def*td = unsmob_translator_def($$);
 629                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 630                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 631                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 632         }
 633         | translator_spec_body CONSISTSEND STRING  {
 634                 unsmob_translator_def ($$)->add_last_element ( $3);
 635         }
 636         | translator_spec_body ACCEPTS STRING  {
 637                 unsmob_translator_def ($$)->set_acceptor (scm_string_to_symbol ($3), true);
 638         }
 639         | translator_spec_body DENIES STRING  {
 640                 unsmob_translator_def ($$)->set_acceptor (scm_string_to_symbol ($3), false);
 641         }
 642         | translator_spec_body REMOVE STRING  {
 643                 unsmob_translator_def ($$)->remove_element ($3);
 644         }
 645         ;
 646
 647 /*
 648         SCORE
 649 */
 650 score_block:
 651         SCORE {
 652                 THIS->push_spot ();
 653         }
 654         /*cont*/ '{' score_body '}'     {
 655                 THIS->pop_spot ();
 656                 $$ = $4;
 657
 658         }
 659         ;
 660
 661 score_body:
 662         Music   {
 663                 $$ = new Score;
 664
 665                 $$->set_spot (THIS->here_input ());
 666                 SCM m = $1->self_scm ();
 667                 scm_gc_unprotect_object (m);
 668
 669                 /*
 670                         guh.
 671                 */
 672                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 673                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 674                         m = gh_call1 (gh_car (check_funcs), m);
 675                 $$->music_ = m;
 676
 677         }
 678         | SCORE_IDENTIFIER {
 679                 $$ = unsmob_score ($1);
 680                 $$->set_spot (THIS->here_input ());
 681         }
 682         | score_body lilypond_header    {
 683                 $$->header_ = $2;
 684         }
 685         | score_body output_def {
 686                 $$->defs_.push ($2);
 687         }
 688         | score_body error {
 689
 690         }
 691         ;
 692
 693
 694 /*
 695         MIDI
 696 */
 697 output_def:
 698         music_output_def_body '}' {
 699                 $$ = $1;
 700                 THIS-> lexer_-> remove_scope ();
 701         }
 702         ;
 703
 704 music_output_def_body:
 705         MIDI '{'    {
 706                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 707
 708
 709                 Midi_def* p =0;
 710                 if (id)
 711                         p = dynamic_cast<Midi_def*> (id->clone ());
 712                 else
 713                         p = new Midi_def;
 714
 715                 $$ = p;
 716                 THIS->lexer_->add_scope (p->scope_);
 717         }
 718         | PAPER '{'     {
 719                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 720                   Paper_def *p = 0;
 721                 if (id)
 722                         p = dynamic_cast<Paper_def*> (id->clone ());
 723                 else
 724                         p = new Paper_def;
 725
 726                 THIS->lexer_->add_scope (p->scope_);
 727                 $$ = p;
 728         }
 729         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 730                 Music_output_def * o =  unsmob_music_output_def ($3);
 731                 $$ =o;
 732
 733                 THIS->lexer_->add_scope (o->scope_);
 734         }
 735         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 736                 Music_output_def * o =  unsmob_music_output_def ($3);
 737                 $$ = o;
 738
 739                 THIS->lexer_->add_scope (o->scope_);
 740         }
 741         | music_output_def_body assignment  {
 742
 743         }
 744         | music_output_def_body translator_spec_block   {
 745                 $$->assign_translator ($2);
 746
 747         }
 748         | music_output_def_body tempo_event  {
 749                 /*
 750                         junk this ? there already is tempo stuff in
 751                         music.
 752                 */
 753                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 754                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 755                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 756                 if (md)
 757                         md->set_tempo (d->get_length (), m);
 758         }
 759         | music_output_def_body error {
 760
 761         }
 762         ;
 763
 764 tempo_event:
 765         TEMPO steno_duration '=' bare_unsigned  {
 766                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 767                 $$->set_mus_property ("tempo-unit", $2);
 768                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 769         }
 770         ;
 771
 772 /*
 773 The representation of a  list is the
 774
 775   (LIST . LAST-CONS)
 776
 777  to have  efficient append.
 778 */
 779 Music_list:
 780         /* empty */ {
 781                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 782         }
 783         | Music_list Music {
 784                 SCM s = $$;
 785                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 786                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 787                 if (gh_pair_p (ly_cdr (s)))
 788                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 789                 else
 790                         gh_set_car_x (s, c); /* set first cons */
 791                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 792         }
 793         | Music_list error {
 794         }
 795         ;
 796
 797
 798 Music:
 799         Simple_music
 800         | Composite_music
 801         ;
 802
 803 Alternative_music:
 804         /* empty */ {
 805                 $$ = SCM_EOL;
 806         }
 807         | ALTERNATIVE '{' Music_list '}' {
 808                 $$ = $3;
 809         }
 810         ;
 811
 812 Repeated_music:
 813         REPEAT string bare_unsigned Music Alternative_music
 814         {
 815                 Music *beg = $4;
 816                 int times = $3;
 817                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 818                 if (times < scm_ilength (alts)) {
 819                   unsmob_music (gh_car (alts))
 820                     ->origin ()->warning (
 821                     _("More alternatives than repeats.  Junking excess alternatives."));
 822                   alts = ly_truncate_list (times, alts);
 823                 }
 824
 825
 826                 static SCM proc;
 827                 if (!proc)
 828                         proc = scm_c_eval_string ("make-repeated-music");
 829
 830                 SCM mus = scm_call_1 (proc, $2);
 831                 scm_gc_protect_object (mus); // UGH.
 832                 Music *r =unsmob_music (mus);
 833                 if (beg)
 834                         {
 835                         r-> set_mus_property ("element", beg->self_scm ());
 836                         scm_gc_unprotect_object (beg->self_scm ());
 837                         }
 838                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 839
 840                 r-> set_mus_property ("elements",alts);
 841                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 842                         /*
 843                         we can not get durations and other stuff correct down the line, so we have to
 844                         add to the duration log here.
 845                         */
 846                         static SCM func;
 847
 848                         if (!func)
 849                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 850
 851                         int dots = ($3 % 3) ? 0 : 1;
 852                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 853
 854                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 855
 856                         if (seq) {
 857                                 int list_len =scm_ilength (seq->music_list ());
 858                                 if (list_len != 2)
 859                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 860                                 shift -= 1;
 861                                 r->compress (Moment (Rational (1,list_len)));
 862                                 }
 863                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 864
 865                 }
 866                 r->set_spot (*$4->origin ());
 867
 868                 $$ = r;
 869         }
 870         ;
 871
 872 Sequential_music:
 873         SEQUENTIAL '{' Music_list '}'           {
 874                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 875                 $$->set_mus_property ("elements", ly_car ($3));
 876                 $$->set_spot(THIS->here_input());
 877         }
 878         | '{' Music_list '}'            {
 879                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 880                 $$->set_mus_property ("elements", ly_car ($2));
 881                 $$->set_spot(THIS->here_input());
 882         }
 883         ;
 884
 885 Simultaneous_music:
 886         SIMULTANEOUS '{' Music_list '}'{
 887                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 888                 $$->set_mus_property ("elements", ly_car ($3));
 889                 $$->set_spot(THIS->here_input());
 890
 891         }
 892         | simul_open Music_list simul_close     {
 893                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 894                 $$->set_mus_property ("elements", ly_car ($2));
 895                 $$->set_spot(THIS->here_input());
 896         }
 897         ;
 898
 899 Simple_music:
 900         event_chord             { $$ = $1; }
 901         | APPLYOUTPUT embedded_scm {
 902                 if (!ly_input_procedure_p ($2))
 903                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 904                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 905                 $$->set_mus_property ("procedure", $2);
 906                 $$->set_spot (THIS->here_input());
 907         }
 908         | APPLYCONTEXT embedded_scm {
 909                 if (!ly_input_procedure_p ($2))
 910                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 911                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 912                 $$->set_mus_property ("procedure", $2);
 913                 $$->set_spot (THIS->here_input());
 914         }
 915         | MUSIC_IDENTIFIER {
 916                 $$ = unsmob_music ($1);
 917         }
 918         | property_def
 919         | translator_change
 920         ;
 921
 922
 923 grace_head:
 924         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 925         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 926         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 927         ;
 928
 929
 930 Composite_music:
 931         CONTEXT STRING Music    {
 932                 Music*csm =MY_MAKE_MUSIC("ContextSpeccedMusic");
 933
 934                 csm->set_mus_property ("element", $3->self_scm ());
 935                 scm_gc_unprotect_object ($3->self_scm ());
 936
 937                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
 938                 csm->set_mus_property ("context-id", scm_makfrom0str (""));
 939
 940                 $$ = csm;
 941         }
 942         | AUTOCHANGE STRING Music       {
 943         Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 944                 chm->set_mus_property ("element", $3->self_scm ());
 945                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 946
 947                 scm_gc_unprotect_object ($3->self_scm ());
 948                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 949
 950                 $$ = chm;
 951                 chm->set_spot (*$3->origin ());
 952         }
 953         | grace_head Music {
 954 #if 1
 955         /*
 956                 The other version is for easier debugging  of
 957                 Sequential_music_iterator in combination with grace notes.
 958         */
 959
 960 /*
 961
 962 TODO: should distinguish between both grace types in the
 963 basic music objects too, since the meaning is different.
 964
 965 */
 966
 967                 String start_str = "start" + ly_scm2string ($1) + "Music";
 968                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 969
 970                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 971                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 972
 973                 Music *startm = unsmob_music (start);
 974                 Music *stopm = unsmob_music (stop);
 975
 976                 SCM ms = SCM_EOL;
 977                 if (stopm) {
 978                         stopm = stopm->clone ();
 979                         ms = scm_cons (stopm->self_scm (), ms);
 980                         scm_gc_unprotect_object (stopm->self_scm ());
 981                 }
 982                 ms = scm_cons ($2->self_scm (), ms);
 983                 scm_gc_unprotect_object ($2->self_scm());
 984                 if (startm) {
 985                         startm = startm->clone ();
 986                         ms = scm_cons (startm->self_scm () , ms);
 987                         scm_gc_unprotect_object (startm->self_scm ());
 988                 }
 989
 990
 991                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 992                 seq->set_mus_property ("elements", ms);
 993
 994
 995                 $$ = MY_MAKE_MUSIC("GraceMusic");
 996                 $$->set_mus_property ("element", seq->self_scm ());
 997                 scm_gc_unprotect_object (seq->self_scm ());
 998 #else
 999                 $$ = MY_MAKE_MUSIC("GraceMusic");
1000                 $$->set_mus_property ("element", $2->self_scm ());
1001                 scm_gc_unprotect_object ($2->self_scm ());
1002 #endif
1003         }
1004         | CONTEXT string '=' string Music {
1005                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1006
1007                 csm->set_mus_property ("element", $5->self_scm ());
1008                 scm_gc_unprotect_object ($5->self_scm ());
1009
1010                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
1011                 csm->set_mus_property ("context-id", $4);
1012
1013                 $$ = csm;
1014         }
1015         | NEWCONTEXT string Music {
1016                 static int new_context_count;
1017
1018                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1019
1020                 csm->set_mus_property ("element", $3->self_scm ());
1021                 scm_gc_unprotect_object ($3->self_scm ());
1022
1023                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
1024
1025                 char s[1024];
1026                 snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
1027
1028                 SCM new_id = scm_makfrom0str (s);
1029                 csm->set_mus_property ("context-id", new_id);
1030                 $$ = csm;
1031         }
1032         | TIMES {
1033                 THIS->push_spot ();
1034         }
1035         /* CONTINUED */
1036                 fraction Music
1037
1038         {
1039                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
1040                 Music *mp = $4;
1041
1042                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
1043                 $$->set_spot (THIS->pop_spot ());
1044
1045                 $$->set_mus_property ("element", mp->self_scm ());
1046                 scm_gc_unprotect_object (mp->self_scm ());
1047                 $$->set_mus_property ("numerator", gh_int2scm (n));
1048                 $$->set_mus_property ("denominator", gh_int2scm (d));
1049                 $$->compress (Moment (Rational (n,d)));
1050
1051         }
1052         | Repeated_music                { $$ = $1; }
1053         | Simultaneous_music            { $$ = $1; }
1054         | Sequential_music              { $$ = $1; }
1055         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1056                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1057                 Music *p = $4;
1058                 Pitch from = *unsmob_pitch ($2);
1059                 Pitch to = *unsmob_pitch ($3);
1060
1061                 p->transpose (interval (from, to));
1062                 $$->set_mus_property ("element", p->self_scm ());
1063                 scm_gc_unprotect_object (p->self_scm ());
1064         }
1065         | APPLY embedded_scm Music  {
1066                 if (!ly_input_procedure_p ($2))
1067                         {
1068                         THIS->parser_error (_ ("\\apply takes function argument"));
1069                         $$ = $3;
1070                         }
1071                 else
1072                         {
1073                         SCM ret = gh_call1 ($2, $3->self_scm ());
1074                         Music *m = unsmob_music (ret);
1075                         if (!m) {
1076                                 THIS->parser_error ("\\apply must return a Music");
1077                                 m = MY_MAKE_MUSIC("Music");
1078                                 }
1079                         $$ = m;
1080                         }
1081         }
1082         | NOTES
1083                 { THIS->lexer_->push_note_state (); }
1084         Music
1085                 { $$ = $3;
1086                   THIS->lexer_->pop_state ();
1087                 }
1088         | FIGURES
1089                 { THIS->lexer_->push_figuredbass_state (); }
1090         Music
1091                 {
1092                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1093                   chm->set_mus_property ("element", $3->self_scm ());
1094                   $$ = chm;
1095                   scm_gc_unprotect_object ($3->self_scm());
1096
1097                   THIS->lexer_->pop_state ();
1098         }
1099         | CHORDS
1100                 { THIS->lexer_->push_chord_state (); }
1101         Music
1102                 {
1103                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1104                   chm->set_mus_property ("element", $3->self_scm ());
1105                   scm_gc_unprotect_object ($3->self_scm());
1106                   $$ = chm;
1107
1108                   THIS->lexer_->pop_state ();
1109         }
1110         | LYRICS
1111                 { THIS->lexer_->push_lyric_state (); }
1112         Music
1113                 {
1114                   $$ = $3;
1115                   THIS->lexer_->pop_state ();
1116         }
1117         | relative_music        { $$ = $1; }
1118         | re_rhythmed_music     { $$ = $1; }
1119         | part_combined_music   { $$ = $1; }
1120         | TAG embedded_scm Music {
1121                 tag_music ($3, $2, THIS->here_input ());
1122                 $$ = $3;
1123         }
1124         ;
1125
1126 relative_music:
1127         RELATIVE absolute_pitch Music {
1128                 Music * p = $3;
1129                 Pitch pit = *unsmob_pitch ($2);
1130                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1131
1132                 $$->set_mus_property ("element", p->self_scm ());
1133                 scm_gc_unprotect_object (p->self_scm ());
1134
1135
1136                 Pitch retpitch = p->to_relative_octave (pit);
1137                 if (lily_1_8_relative)
1138                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1139         }
1140         ;
1141
1142 re_rhythmed_music:
1143         ADDLYRICS Music Music {
1144         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1145           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1146           scm_gc_unprotect_object ($3->self_scm ());
1147           scm_gc_unprotect_object ($2->self_scm ());
1148           $$ = l;
1149         }
1150         ;
1151
1152 part_combined_music:
1153         PARTCOMBINE STRING Music Music {
1154                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1155                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1156                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1157
1158                 scm_gc_unprotect_object ($3->self_scm ());
1159                 scm_gc_unprotect_object ($4->self_scm ());
1160
1161                 $$ = p;
1162         }
1163         ;
1164
1165 translator_change:
1166         TRANSLATOR STRING '=' STRING  {
1167                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1168                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1169                 t-> set_mus_property ("change-to-id", $4);
1170
1171                 $$ = t;
1172                 $$->set_spot (THIS->here_input ());
1173         }
1174         ;
1175
1176 property_def:
1177         simple_property_def
1178         | ONCE simple_property_def {
1179                 $$ = $2;
1180                 SCM e = $2->get_mus_property ("element");
1181                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1182         }
1183         ;
1184
1185 simple_property_def:
1186         PROPERTY STRING '.' STRING '='  scalar {
1187                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1188                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1189
1190                 csm->set_mus_property ("element", t->self_scm ());
1191                 scm_gc_unprotect_object (t->self_scm ());
1192
1193                 $$ = csm;
1194                 $$->set_spot (THIS->here_input ());
1195
1196                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1197         }
1198         | PROPERTY STRING '.' STRING UNSET {
1199
1200                 Music *t = MY_MAKE_MUSIC("PropertyUnset");
1201                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1202
1203                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1204                 csm->set_mus_property ("element", t->self_scm ());
1205                 scm_gc_unprotect_object (t->self_scm ());
1206
1207                 $$ = csm;
1208                 $$->set_spot (THIS->here_input ());
1209
1210                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1211         }
1212         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1213                 bool autobeam
1214                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1215                 bool itc = internal_type_checking_global_b;
1216                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1217                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1218                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1219                 if (autobeam)
1220                         internal_type_checking_global_b = false;
1221                 t->set_mus_property ("grob-property", $6);
1222                 if (autobeam)
1223                         internal_type_checking_global_b = itc;
1224                 t->set_mus_property ("grob-value", $8);
1225
1226                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1227                 csm->set_mus_property ("element", t->self_scm ());
1228                 scm_gc_unprotect_object (t->self_scm ());
1229                 $$ = csm;
1230                 $$->set_spot (THIS->here_input ());
1231
1232                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1233         }
1234         | PROPERTY STRING '.' STRING OVERRIDE
1235                 embedded_scm '=' embedded_scm
1236         {
1237                 /*
1238                         UGH UGH UGH UGH.
1239                 */
1240                 bool autobeam
1241                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1242                 bool itc = internal_type_checking_global_b;
1243
1244                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1245                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1246                 if (autobeam)
1247                         internal_type_checking_global_b = false;
1248                 t->set_mus_property ("grob-property", $6);
1249                 t->set_mus_property ("grob-value", $8);
1250                 if (autobeam)
1251                         internal_type_checking_global_b = itc;
1252
1253                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1254                 csm->set_mus_property ("element", t->self_scm ());
1255                 scm_gc_unprotect_object (t->self_scm ());
1256
1257                 $$ = csm;
1258                 $$->set_spot (THIS->here_input ());
1259
1260                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1261
1262         }
1263         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1264                 Music *t = MY_MAKE_MUSIC("RevertProperty");
1265                 bool autobeam
1266                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1267                 bool itc = internal_type_checking_global_b;
1268
1269                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1270                 if (autobeam)
1271                         internal_type_checking_global_b = false;
1272                 t->set_mus_property ("grob-property", $6);
1273                 if (autobeam)
1274                         internal_type_checking_global_b = itc;
1275
1276                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1277                 csm->set_mus_property ("element", t->self_scm ());
1278                 scm_gc_unprotect_object (t->self_scm ());
1279
1280                 $$ = csm;
1281                 $$->set_spot (THIS->here_input ());
1282
1283                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1284         }
1285         ;
1286
1287
1288 scalar:
1289         string          { $$ = $1; }
1290         | bare_int      { $$ = gh_int2scm ($1); }
1291         | embedded_scm  { $$ = $1; }
1292         | full_markup {  $$ = $1; }
1293         | DIGIT { $$ = gh_int2scm ($1); }
1294         ;
1295
1296
1297
1298 /*
1299 This is a trick:
1300
1301 Adding pre_events to the simple_element
1302 makes the choice between
1303
1304   string:  STRING
1305
1306 and
1307
1308   simple_element: STRING
1309
1310 a single shift/reduction conflict.
1311
1312 nevertheless, this is not very clean, and we should find a different
1313 solution.
1314
1315 */
1316 pre_events: {
1317                 THIS->push_spot ();
1318         }
1319         ;
1320
1321 event_chord:
1322         pre_events simple_element post_events   {
1323                 SCM elts = $2-> get_mus_property ("elements");
1324
1325                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1326
1327                 $2->set_mus_property ("elements", elts);
1328                 $$ = $2;
1329         }
1330         | command_element
1331         | note_chord_element
1332         ;
1333
1334
1335 note_chord_element:
1336         chord_body optional_notemode_duration post_events
1337         {
1338                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1339                 SCM es = $1->get_mus_property ("elements");
1340                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1341
1342                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1343                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1344                 es = gh_append2 (es, postevs);
1345
1346                 $1-> set_mus_property ("elements", es);
1347                 $$ = $1;
1348         }
1349         ;
1350
1351 chord_open: '<'
1352         ;
1353
1354 chord_close: '>'
1355         ;
1356
1357 simul_open: LESSLESS
1358         ;
1359
1360 simul_close: MOREMORE
1361         ;
1362
1363 chord_body:
1364         chord_open chord_body_elements chord_close
1365         {
1366                 $$ = MY_MAKE_MUSIC("EventChord");
1367                 $$->set_mus_property ("elements",
1368                         scm_reverse_x ($2, SCM_EOL));
1369         }
1370         ;
1371
1372 chord_body_elements:
1373         /* empty */             { $$ = SCM_EOL; }
1374         | chord_body_elements chord_body_element {
1375                 $$ = gh_cons ($2->self_scm(), $1);
1376                 scm_gc_unprotect_object ($2->self_scm());
1377         }
1378         ;
1379
1380 chord_body_element:
1381         pitch exclamations questions post_events
1382         {
1383                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1384                 n->set_mus_property ("pitch", $1);
1385                 if ($3 % 2)
1386                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1387                 if ($2 % 2 || $3 % 2)
1388                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1389
1390                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1391                 n->set_mus_property ("articulations", arts);
1392
1393                 $$ = n;
1394         }
1395         ;
1396
1397 command_element:
1398         command_req {
1399                 $$ = MY_MAKE_MUSIC("EventChord");
1400                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1401                 scm_gc_unprotect_object ($1->self_scm());
1402
1403                 $$-> set_spot (THIS->here_input ());
1404                 $1-> set_spot (THIS->here_input ());
1405         }
1406         | OCTAVE { THIS->push_spot (); }
1407           pitch {
1408                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1409                 $$ = l;
1410                 $$->set_spot (THIS->pop_spot ());
1411                 $$->set_mus_property ("pitch", $3);
1412         }
1413         | E_LEFTSQUARE {
1414                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1415                 l->set_mus_property ("span-direction", gh_int2scm (START));
1416                 l->set_spot (THIS->here_input ());
1417
1418                 $$ = MY_MAKE_MUSIC("EventChord");
1419                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1420                 scm_gc_unprotect_object (l->self_scm());
1421                 $$->set_spot (THIS->here_input ());
1422         }
1423         | E_RIGHTSQUARE {
1424                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1425                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1426                 l->set_spot (THIS->here_input ());
1427
1428                 $$ = MY_MAKE_MUSIC("EventChord");
1429                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1430                 $$->set_spot (THIS->here_input ());
1431                 scm_gc_unprotect_object (l->self_scm());
1432         }
1433         | E_BACKSLASH {
1434                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1435                 $$->set_spot (THIS->here_input ());
1436         }
1437         | '|'      {
1438
1439                 $$ = MY_MAKE_MUSIC("BarCheck");
1440                 $$->set_spot (THIS->here_input ());
1441         }
1442         | BAR STRING                    {
1443                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1444
1445                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1446                 csm->set_mus_property ("element", t->self_scm ());
1447                 scm_gc_unprotect_object (t->self_scm ());
1448
1449                 $$ = csm;
1450                 $$->set_spot (THIS->here_input ());
1451
1452                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1453         }
1454         | PARTIAL duration_length       {
1455                 Moment m = - unsmob_duration ($2)->get_length ();
1456                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1457
1458                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1459                 sp->set_mus_property ("element", p->self_scm ());
1460                 scm_gc_unprotect_object (p->self_scm ());
1461
1462                 $$ =sp ;
1463                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1464         }
1465         | CLEF STRING  {
1466                 static SCM proc ;
1467                 if (!proc)
1468                         proc = scm_c_eval_string ("make-clef-set");
1469
1470                 SCM result = scm_call_1 (proc, $2);
1471                 scm_gc_protect_object (result);
1472                 $$ = unsmob_music (result);
1473         }
1474         | TIME_T fraction  {
1475                 static SCM proc;
1476                 if (!proc)
1477                         proc = scm_c_eval_string ("make-time-signature-set");
1478
1479                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1480                 scm_gc_protect_object (result);
1481                 $$ = unsmob_music (result);
1482         }
1483         ;
1484
1485 command_req:
1486         shorthand_command_req   { $$ = $1; }
1487         | verbose_command_req   { $$ = $1; }
1488         ;
1489
1490 shorthand_command_req:
1491         hyphen_req {
1492                 $$ = $1;
1493         }
1494         | BREATHE {
1495                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1496         }
1497         | E_TILDE {
1498                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1499         }
1500         ;
1501
1502 verbose_command_req:
1503         MARK DEFAULT  {
1504                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1505                 $$ = m;
1506         }
1507         | MARK scalar {
1508                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1509                 m->set_mus_property ("label", $2);
1510                 $$ = m;
1511         }
1512         | SKIP duration_length {
1513                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1514                 skip->set_mus_property ("duration", $2);
1515
1516                 $$ = skip;
1517         }
1518         | tempo_event {
1519                 $$ = $1;
1520         }
1521         | KEY DEFAULT {
1522                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1523                 $$ = key;
1524         }
1525         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1526
1527                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1528                 if (scm_ilength ($3) > 0)
1529                 {
1530                         key->set_mus_property ("pitch-alist", $3);
1531                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1532                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1533                 } else {
1534                         THIS->parser_error (_("Second argument must be pitch list."));
1535                 }
1536
1537                 $$ = key;
1538         }
1539         ;
1540
1541 post_events:
1542         /* empty */ {
1543                 $$ = SCM_EOL;
1544         }
1545         | post_events post_event {
1546                 $2->set_spot (THIS->here_input ());
1547                 $$ = gh_cons ($2->self_scm(), $$);
1548                 scm_gc_unprotect_object ($2->self_scm());
1549         }
1550         | post_events tagged_post_event {
1551                 $2 -> set_spot (THIS->here_input ());
1552                 $$ = scm_cons ($2->self_scm(), $$);
1553                 scm_gc_unprotect_object ($2->self_scm());
1554         }
1555         ;
1556
1557
1558 tagged_post_event:
1559         '-' TAG embedded_scm post_event {
1560                 tag_music ($4, $3, THIS->here_input ());
1561                 $$ = $4;
1562         }
1563         ;
1564
1565 post_event:
1566         direction_less_event {
1567                 $$ = $1;
1568         }
1569         | EXTENDER {
1570                 if (!THIS->lexer_->lyric_state_b ())
1571                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1572                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1573         }
1574         | script_dir direction_reqd_event {
1575                 if ($1)
1576                         $2->set_mus_property ("direction", gh_int2scm ($1));
1577                 $$ = $2;
1578         }
1579         | script_dir direction_less_event {
1580                 if ($1)
1581                         $2->set_mus_property ("direction", gh_int2scm ($1));
1582                 $$ = $2;
1583         }
1584         | string_number_event
1585         ;
1586
1587 string_number_event:
1588         E_UNSIGNED {
1589                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1590                 s->set_mus_property ("string-number",  gh_int2scm($1));
1591                 s->set_spot (THIS->here_input ());
1592                 $$ = s;
1593         }
1594         ;
1595
1596
1597 direction_less_event:
1598         '['  {
1599
1600
1601 /*
1602
1603 TODO: should take all these defs out of the parser, adn make use
1604 configurable, i.e.
1605
1606
1607 (set-articulation '~ "trill")
1608
1609 */
1610                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1611                 m->set_spot (THIS->here_input());
1612                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1613                 $$ = m;
1614         }
1615         | ']'  {
1616                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1617                 m->set_spot (THIS->here_input());
1618                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1619                 $$ = m;
1620         }
1621         | '~' {
1622                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1623                 m->set_spot (THIS->here_input());
1624                 $$ = m;
1625         }
1626         | close_event {
1627                 $$ = $1;
1628                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (START));
1629         }
1630         | open_event {
1631                 $$ = $1;
1632                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (STOP));
1633         }
1634         | EVENT_IDENTIFIER      {
1635                 $$ = unsmob_music ($1);
1636         }
1637         | tremolo_type  {
1638                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1639                a->set_spot (THIS->here_input ());
1640                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1641                $$ = a;
1642         }
1643         ;
1644
1645 direction_reqd_event:
1646         gen_text_def {
1647                 $$ = $1;
1648         }
1649         | script_abbreviation {
1650                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1651                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1652                 if (gh_string_p (s))
1653                         a->set_mus_property ("articulation-type", s);
1654                 else THIS->parser_error (_ ("Expecting string as script definition"));
1655                 $$ = a;
1656         }
1657         ;
1658
1659 sup_quotes:
1660         '\'' {
1661                 $$ = 1;
1662         }
1663         | sup_quotes '\'' {
1664                 $$ ++;
1665         }
1666         ;
1667
1668 sub_quotes:
1669         ',' {
1670                 $$ = 1;
1671         }
1672         | sub_quotes ',' {
1673                 $$ ++ ;
1674         }
1675         ;
1676
1677 steno_pitch:
1678         NOTENAME_PITCH  {
1679                 $$ = $1;
1680         }
1681         | NOTENAME_PITCH sup_quotes     {
1682                 Pitch p = *unsmob_pitch ($1);
1683                 p = p.transposed (Pitch ($2,0,0));
1684                 $$ = p.smobbed_copy ();
1685         }
1686         | NOTENAME_PITCH sub_quotes      {
1687                 Pitch p =* unsmob_pitch ($1);
1688                 p = p.transposed (Pitch (-$2,0,0));
1689                 $$ = p.smobbed_copy ();
1690         }
1691         ;
1692
1693 /*
1694 ugh. duplication
1695 */
1696
1697 steno_tonic_pitch:
1698         TONICNAME_PITCH {
1699                 $$ = $1;
1700         }
1701         | TONICNAME_PITCH sup_quotes    {
1702                 Pitch p = *unsmob_pitch ($1);
1703                 p = p.transposed (Pitch ($2,0,0));
1704                 $$ = p.smobbed_copy ();
1705         }
1706         | TONICNAME_PITCH sub_quotes     {
1707                 Pitch p =* unsmob_pitch ($1);
1708
1709                 p = p.transposed (Pitch (-$2,0,0));
1710                 $$ = p.smobbed_copy ();
1711         }
1712         ;
1713
1714 pitch:
1715         steno_pitch {
1716                 $$ = $1;
1717         }
1718         ;
1719
1720 pitch_also_in_chords:
1721         pitch
1722         | steno_tonic_pitch
1723         ;
1724
1725
1726
1727
1728
1729 hyphen_req:
1730         HYPHEN {
1731                 if (!THIS->lexer_->lyric_state_b ())
1732                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1733                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1734         }
1735         ;
1736
1737 close_event:
1738         '('     {
1739                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1740                 $$ = s;
1741                 s->set_spot (THIS->here_input());
1742         }
1743         | E_OPEN        {
1744                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1745                 $$ = s;
1746                 s->set_spot (THIS->here_input());
1747         }
1748         | E_SMALLER {
1749                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1750                 $$ = s;
1751                 s->set_spot (THIS->here_input());
1752         }
1753         | E_BIGGER {
1754                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1755                 $$ = s;
1756                 s->set_spot (THIS->here_input());
1757         }
1758         ;
1759
1760
1761 open_event:
1762         E_EXCLAMATION   {
1763                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1764                 s->set_spot (THIS->here_input());
1765
1766                 $$ = s;
1767         }
1768         | ')'   {
1769                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1770                 $$ = s;
1771                 s->set_spot (THIS->here_input());
1772
1773         }
1774         | E_CLOSE       {
1775                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1776                 $$ = s;
1777                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1778                 s->set_spot (THIS->here_input());
1779         }
1780         ;
1781
1782 gen_text_def:
1783         full_markup {
1784                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1785                 t->set_mus_property ("text", $1);
1786                 t->set_spot (THIS->here_input ());
1787                 $$ = t;
1788         }
1789         | string {
1790                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1791                 t->set_mus_property ("text", make_simple_markup ($1));
1792                 t->set_spot (THIS->here_input ());
1793                 $$ = t;
1794
1795         }
1796         | DIGIT {
1797                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1798                 t->set_mus_property ("digit",  gh_int2scm ($1));
1799                 t->set_spot (THIS->here_input ());
1800                 $$ = t;
1801         }
1802         ;
1803
1804 script_abbreviation:
1805         '^'             {
1806                 $$ = scm_makfrom0str ("Hat");
1807         }
1808         | '+'           {
1809                 $$ = scm_makfrom0str ("Plus");
1810         }
1811         | '-'           {
1812                 $$ = scm_makfrom0str ("Dash");
1813         }
1814         | '|'           {
1815                 $$ = scm_makfrom0str ("Bar");
1816         }
1817         | '>'           {
1818                 $$ = scm_makfrom0str ("Larger");
1819         }
1820         | '.'           {
1821                 $$ = scm_makfrom0str ("Dot");
1822         }
1823         | '_' {
1824                 $$ = scm_makfrom0str ("Underscore");
1825         }
1826         ;
1827
1828 script_dir:
1829         '_'     { $$ = DOWN; }
1830         | '^'   { $$ = UP; }
1831         | '-'   { $$ = CENTER; }
1832         ;
1833
1834
1835 absolute_pitch:
1836         steno_pitch     {
1837                 $$ = $1;
1838         }
1839         ;
1840
1841 duration_length:
1842         multiplied_duration {
1843                 $$ = $1;
1844         }
1845         ;
1846
1847 optional_notemode_duration:
1848         {
1849                 Duration dd = THIS->default_duration_;
1850                 $$ = dd.smobbed_copy ();
1851
1852                 THIS->beam_check ($$);
1853         }
1854         | multiplied_duration   {
1855                 $$ = $1;
1856                 THIS->default_duration_ = *unsmob_duration ($$);
1857
1858                 THIS->beam_check ($$);
1859         }
1860         ;
1861
1862 steno_duration:
1863         bare_unsigned dots              {
1864                 int l = 0;
1865                 if (!is_duration_b ($1))
1866                         THIS->parser_error (_f ("not a duration: %d", $1));
1867                 else
1868                         l =  intlog2 ($1);
1869
1870                 $$ = Duration (l, $2).smobbed_copy ();
1871         }
1872         | DURATION_IDENTIFIER dots      {
1873                 Duration *d =unsmob_duration ($1);
1874                 Duration k (d->duration_log (),d->dot_count () + $2);
1875
1876                 *d = k;
1877                 $$ = $1;
1878         }
1879         ;
1880
1881
1882
1883
1884 multiplied_duration:
1885         steno_duration {
1886                 $$ = $1;
1887         }
1888         | multiplied_duration '*' bare_unsigned {
1889                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1890         }
1891         | multiplied_duration '*' FRACTION {
1892                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1893
1894                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1895         }
1896         ;
1897
1898 fraction:
1899         FRACTION { $$ = $1; }
1900         | UNSIGNED '/' UNSIGNED {
1901                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1902         }
1903         ;
1904
1905 dots:
1906         /* empty */     {
1907                 $$ = 0;
1908         }
1909         | dots '.' {
1910                 $$ ++;
1911         }
1912         ;
1913
1914
1915 tremolo_type:
1916         ':'     {
1917                 $$ =0;
1918         }
1919         | ':' bare_unsigned {
1920                 if (!is_duration_b ($2))
1921                         THIS->parser_error (_f ("not a duration: %d", $2));
1922                 $$ = $2;
1923         }
1924         ;
1925
1926
1927
1928 /*****************************************************************
1929                 BASS FIGURES
1930 *****************************************************************/
1931 bass_number:
1932         DIGIT   {
1933                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1934         }
1935         | UNSIGNED {
1936                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1937         }
1938         | STRING { $$ =  $1; }
1939         ;
1940
1941 bass_mod:
1942         '-'     { $$ = -2; }
1943         | '+'   { $$ = 2; }
1944         | '!'   { $$ = 0; }
1945         ;
1946
1947 bass_figure:
1948         FIGURE_SPACE {
1949                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1950                 $$ = bfr->self_scm();
1951                 scm_gc_unprotect_object ($$);
1952         }
1953         | bass_number  {
1954                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1955                 $$ = bfr->self_scm();
1956
1957                 bfr->set_mus_property ("figure", $1);
1958
1959                 scm_gc_unprotect_object ($$);
1960         }
1961         | bass_figure bass_mod {
1962                 Music *m = unsmob_music ($1);
1963                 if ($2) {
1964                         SCM salter =m->get_mus_property ("alteration");
1965                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1966                         m->set_mus_property ("alteration",
1967                                 gh_int2scm (alter + $2));
1968                 } else {
1969                         m->set_mus_property ("alteration", gh_int2scm (0));
1970                 }
1971         }
1972         ;
1973
1974 br_bass_figure:
1975         '[' bass_figure {
1976                 $$ = $2;
1977                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1978         }
1979         | bass_figure   {
1980                 $$ = $1;
1981         }
1982         | br_bass_figure ']' {
1983                 $$ = $1;
1984                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1985         }
1986         ;
1987
1988 figure_list:
1989         /**/            {
1990                 $$ = SCM_EOL;
1991         }
1992         | figure_list br_bass_figure {
1993                 $$ = scm_cons ($2, $1);
1994         }
1995         ;
1996
1997 figure_spec:
1998         FIGURE_OPEN figure_list FIGURE_CLOSE {
1999                 Music * m = MY_MAKE_MUSIC("EventChord");
2000                 $2 = scm_reverse_x ($2, SCM_EOL);
2001                 m->set_mus_property ("elements",  $2);
2002                 $$ = m->self_scm ();
2003         }
2004         ;
2005
2006
2007 optional_rest:
2008         /**/   { $$ = 0; }
2009         | REST { $$ = 1; }
2010         ;
2011
2012 simple_element:
2013         pitch exclamations questions optional_notemode_duration optional_rest {
2014
2015                 Input i = THIS->pop_spot ();
2016                 if (!THIS->lexer_->note_state_b ())
2017                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2018
2019                 Music *n = 0;
2020                 if ($5)
2021                         n =  MY_MAKE_MUSIC("RestEvent");
2022                 else
2023                         n =  MY_MAKE_MUSIC("NoteEvent");
2024
2025                 n->set_mus_property ("pitch", $1);
2026                 n->set_mus_property ("duration", $4);
2027
2028
2029                 if ($3 % 2)
2030                         n->set_mus_property ("cautionary", SCM_BOOL_T);
2031                 if ($2 % 2 || $3 % 2)
2032                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
2033
2034                 Music *v = MY_MAKE_MUSIC("EventChord");
2035                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
2036                 scm_gc_unprotect_object (n->self_scm());
2037
2038                 v->set_spot (i);
2039                 n->set_spot (i);
2040                 $$ = v;
2041         }
2042         | figure_spec optional_notemode_duration {
2043                 Music * m = unsmob_music ($1);
2044                 Input i = THIS->pop_spot ();
2045                 m->set_spot (i);
2046                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2047                 {
2048                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
2049                 }
2050                 $$ = m;
2051         }
2052         | RESTNAME optional_notemode_duration           {
2053
2054                 Input i = THIS->pop_spot ();
2055                 Music * ev = 0;
2056                 if (ly_scm2string ($1) =="s") {
2057                         /* Space */
2058                         ev = MY_MAKE_MUSIC("SkipEvent");
2059                   }
2060                 else {
2061                         ev = MY_MAKE_MUSIC("RestEvent");
2062
2063                     }
2064                 ev->set_mus_property ("duration" ,$2);
2065                 ev->set_spot (i);
2066                 Music * velt = MY_MAKE_MUSIC("EventChord");
2067                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2068                 velt->set_spot (i);
2069
2070                 $$ = velt;
2071         }
2072         | MULTI_MEASURE_REST optional_notemode_duration         {
2073                 THIS->pop_spot ();
2074
2075                 static SCM proc ;
2076                 if (!proc)
2077                         proc = scm_c_eval_string ("make-multi-measure-rest");
2078
2079                 SCM mus = scm_call_2 (proc, $2,
2080                         make_input (THIS->here_input()));
2081                 scm_gc_protect_object (mus);
2082                 $$ = unsmob_music (mus);
2083         }
2084
2085         | lyric_element optional_notemode_duration      {
2086                 Input i = THIS->pop_spot ();
2087                 if (!THIS->lexer_->lyric_state_b ())
2088                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2089
2090                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2091                 lreq->set_mus_property ("text", $1);
2092                 lreq->set_mus_property ("duration",$2);
2093                 lreq->set_spot (i);
2094                 Music * velt = MY_MAKE_MUSIC("EventChord");
2095                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2096
2097                 $$= velt;
2098         }
2099         | new_chord {
2100                 THIS->pop_spot ();
2101
2102                 if (!THIS->lexer_->chord_state_b ())
2103                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2104                 $$ = unsmob_music ($1);
2105         }
2106         ;
2107
2108 lyric_element:
2109         full_markup { $$ = $1; }
2110         | STRING {  $$ = $1 ; }
2111         ;
2112
2113 new_chord:
2114         steno_tonic_pitch optional_notemode_duration   {
2115                 $$ = make_chord ($1, $2, SCM_EOL);
2116         }
2117         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2118                 SCM its = scm_reverse_x ($4, SCM_EOL);
2119                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2120         }
2121         ;
2122
2123 chord_items:
2124         /**/ {
2125                 $$ = SCM_EOL;
2126         }
2127         | chord_items chord_item {
2128                 $$ = gh_cons ($2, $$);
2129         }
2130         ;
2131
2132 chord_separator:
2133         CHORD_COLON {
2134                 $$ = ly_symbol2scm ("chord-colon");
2135         }
2136         | CHORD_CARET {
2137                 $$ = ly_symbol2scm ("chord-caret");
2138         }
2139         | CHORD_SLASH steno_tonic_pitch {
2140                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2141         }
2142         | CHORD_BASS steno_tonic_pitch {
2143                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2144         }
2145         ;
2146
2147 chord_item:
2148         chord_separator {
2149                 $$ = $1;
2150         }
2151         | step_numbers {
2152                 $$ = scm_reverse_x ($1, SCM_EOL);
2153         }
2154         | CHORD_MODIFIER  {
2155                 $$ = $1;
2156         }
2157         ;
2158
2159 step_numbers:
2160         step_number { $$ = gh_cons ($1, SCM_EOL); }
2161         | step_numbers '.' step_number {
2162                 $$ = gh_cons ($3, $$);
2163         }
2164         ;
2165
2166 step_number:
2167         bare_unsigned {
2168                 $$ = make_chord_step ($1, 0);
2169         }
2170         | bare_unsigned '+' {
2171                 $$ = make_chord_step ($1, SHARP);
2172         }
2173         | bare_unsigned CHORD_MINUS {
2174                 $$ = make_chord_step ($1, FLAT);
2175         }
2176         ;
2177
2178 /*
2179         UTILITIES
2180
2181 TODO: should deprecate in favor of Scheme?
2182
2183  */
2184 number_expression:
2185         number_expression '+' number_term {
2186                 $$ = scm_sum ($1, $3);
2187         }
2188         | number_expression '-' number_term {
2189                 $$ = scm_difference ($1, $3);
2190         }
2191         | number_term
2192         ;
2193
2194 number_term:
2195         number_factor {
2196                 $$ = $1;
2197         }
2198         | number_factor '*' number_factor {
2199                 $$ = scm_product ($1, $3);
2200         }
2201         | number_factor '/' number_factor {
2202                 $$ = scm_divide ($1, $3);
2203         }
2204         ;
2205
2206 number_factor:
2207         '-'  number_factor { /* %prec UNARY_MINUS */
2208                 $$ = scm_difference ($2, SCM_UNDEFINED);
2209         }
2210         | bare_number
2211         ;
2212
2213
2214 bare_number:
2215         UNSIGNED        {
2216                 $$ = gh_int2scm ($1);
2217         }
2218         | REAL          {
2219                 $$ = $1;
2220         }
2221         | NUMBER_IDENTIFIER             {
2222                 $$ = $1;
2223         }
2224         | REAL NUMBER_IDENTIFIER        {
2225                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2226         }
2227         | UNSIGNED NUMBER_IDENTIFIER    {
2228                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2229         }
2230         ;
2231
2232
2233 bare_unsigned:
2234         UNSIGNED {
2235                         $$ = $1;
2236         }
2237         | DIGIT {
2238                 $$ = $1;
2239         }
2240         ;
2241
2242 bare_int:
2243         bare_number {
2244                 if (scm_integer_p ($1) == SCM_BOOL_T)
2245                 {
2246                         int k = gh_scm2int ($1);
2247                         $$ = k;
2248                 } else
2249                 {
2250                         THIS->parser_error (_ ("need integer number arg"));
2251                         $$ = 0;
2252                 }
2253         }
2254         | '-' bare_int {
2255                 $$ = -$2;
2256         }
2257         ;
2258
2259
2260 string:
2261         STRING          {
2262                 $$ = $1;
2263         }
2264         | STRING_IDENTIFIER     {
2265                 $$ = $1;
2266         }
2267         | string '+' string {
2268                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2269         }
2270         ;
2271
2272
2273 exclamations:
2274                 { $$ = 0; }
2275         | exclamations '!'      { $$ ++; }
2276         ;
2277
2278 questions:
2279                 { $$ = 0; }
2280         | questions '?' { $$ ++; }
2281         ;
2282
2283
2284
2285 full_markup:
2286         MARKUP_IDENTIFIER {
2287                 $$ = $1;
2288         }
2289         | MARKUP
2290                 { THIS->lexer_->push_markup_state (); }
2291         markup
2292                 { $$ = $3;
2293                   THIS->lexer_->pop_state ();
2294                 }
2295         ;
2296
2297
2298 /*
2299 This should be done more dynamically if possible.
2300 */
2301 markup:
2302         STRING {
2303                 $$ = make_simple_markup ($1);
2304         }
2305         | MARKUP_HEAD_MARKUP0 markup {
2306                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2307         }
2308         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2309                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2310         }
2311         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2312                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2313         }
2314         | markup_line {
2315                 $$ = $1;
2316         }
2317         | MARKUP_HEAD_LIST0 markup_list {
2318                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2319         }
2320         | MARKUP_HEAD_SCM0 embedded_scm {
2321                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2322         }
2323         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2324                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2325         }
2326         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2327                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2328         }
2329         | MARKUP_IDENTIFIER {
2330                 $$ = $1;
2331         }
2332
2333         ;
2334
2335 markup_list:
2336         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2337         ;
2338
2339 markup_line:
2340         '{' markup_list_body '}' {
2341                 static SCM line ;
2342                 if (!line)
2343                         line = scm_c_eval_string ("line-markup");
2344
2345                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2346         }
2347         ;
2348
2349 markup_list_body:
2350         /**/ {  $$ = SCM_EOL; }
2351         | markup_list_body markup {
2352                 $$ = gh_cons ($2, $1) ;
2353         }
2354         ;
2355
2356
2357 %%
2358
2359 void
2360 My_lily_parser::set_yydebug (bool )
2361 {
2362 #if 0
2363         yydebug = 1;
2364 #endif
2365 }
2366
2367 extern My_lily_parser * current_parser;
2368
2369 void
2370 My_lily_parser::do_yyparse ()
2371 {
2372         current_parser = this;;
2373         yyparse ((void*)this);
2374 }
2375
2376
2377 /*
2378 Should make this optional?    It will also complain when you do
2379
2380         [s4]
2381
2382 which is entirely legitimate.
2383
2384 Or we can scrap it. Barchecks should detect wrong durations, and
2385 skipTypesetting speeds it up a lot.
2386 */
2387
2388 void
2389 My_lily_parser::beam_check (SCM dur)
2390 {
2391   Duration *d = unsmob_duration (dur);
2392   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2393     {
2394       Music * m = unsmob_music (last_beam_start_);
2395       m->origin ()->warning (_("Suspect duration found following this beam"));
2396     }
2397   last_beam_start_ = SCM_EOL;
2398 }
2399
2400
2401
2402
2403 /*
2404
2405 It is a little strange to have this function in this file, but
2406 otherwise, we have to import music classes into the lexer.
2407
2408 */
2409 int
2410 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2411 {
2412         if (gh_string_p (sid)) {
2413                 *destination = sid;
2414                 return STRING_IDENTIFIER;
2415         } else if (gh_number_p (sid)) {
2416                 *destination = sid;
2417                 return NUMBER_IDENTIFIER;
2418         } else if (unsmob_translator_def (sid)) {
2419                 *destination = unsmob_translator_def (sid)->clone_scm();
2420                 return TRANSLATOR_IDENTIFIER;
2421         } else if (unsmob_score (sid)) {
2422                 Score *sc =  new Score (*unsmob_score (sid));
2423                 *destination =sc->self_scm ();
2424                 return SCORE_IDENTIFIER;
2425         } else if (Music * mus =unsmob_music (sid)) {
2426                 *destination = unsmob_music (sid)->clone ()->self_scm();
2427                 unsmob_music (*destination)->
2428                         set_mus_property ("origin", make_input (last_input_));
2429                 return dynamic_cast<Event*> (mus)
2430                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2431         } else if (unsmob_duration (sid)) {
2432                 *destination = unsmob_duration (sid)->smobbed_copy();
2433                 return DURATION_IDENTIFIER;
2434         } else if (unsmob_music_output_def (sid)) {
2435                 Music_output_def *p = unsmob_music_output_def (sid);
2436                 p = p->clone ();
2437
2438                 *destination = p->self_scm();
2439                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2440         } else if (Text_item::markup_p (sid)) {
2441                 *destination = sid;
2442                 return MARKUP_IDENTIFIER;
2443         }
2444
2445         return -1;
2446 }