lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2011 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_BOT
  44 %nonassoc REPEAT
  45 %nonassoc ALTERNATIVE
  46
  47 /* The above precedences tackle the shift/reduce problem
  48
  49 1.  \repeat
  50         \repeat .. \alternative
  51
  52     \repeat { \repeat .. \alternative }
  53
  54 or
  55
  56     \repeat { \repeat } \alternative
  57 */
  58
  59 %right FUNCTION_ARGUMENTS
  60       MARKUP LYRICS_STRING MARKUP_IDENTIFIER STRING STRING_IDENTIFIER
  61       MARKUPLIST WITH CONTEXT_MOD_IDENTIFIER MARKUPLIST_IDENTIFIER
  62       SCORE BOOK BOOKPART PAPER LAYOUT MIDI
  63       SEQUENTIAL SIMULTANEOUS DOUBLE_ANGLE_OPEN MUSIC_IDENTIFIER '{'
  64       PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  65       SCM_FUNCTION SCM_IDENTIFIER SCM_TOKEN
  66       UNSIGNED DURATION_IDENTIFIER
  67       CHORDMODE CHORDS DRUMMODE DRUMS FIGUREMODE FIGURES LYRICMODE LYRICS
  68       NOTEMODE
  69       CONTEXT TIMES NEWCONTEXT
  70
  71  /* The above are the symbols that can start function arguments */
  72
  73 %left ADDLYRICS
  74 %left PREC_TOP
  75
  76
  77
  78
  79 %pure_parser
  80 %locations
  81
  82
  83
  84 %{ // -*-Fundamental-*-
  85
  86 /*
  87 FIXME:
  88
  89    * The rules for who is protecting what are very shady.  Uniformise
  90      this.
  91
  92    * There are too many lexical modes?
  93 */
  94
  95 #include "config.hh"
  96
  97 #include <cctype>
  98 #include <cstdlib>
  99 #include <cstdio>
 100 using namespace std;
 101
 102 #include "book.hh"
 103 #include "context-def.hh"
 104 #include "context-mod.hh"
 105 #include "dimensions.hh"
 106 #include "file-path.hh"
 107 #include "input.hh"
 108 #include "international.hh"
 109 #include "lily-guile.hh"
 110 #include "lily-lexer.hh"
 111 #include "lily-parser.hh"
 112 #include "main.hh"
 113 #include "misc.hh"
 114 #include "music.hh"
 115 #include "output-def.hh"
 116 #include "paper-book.hh"
 117 #include "scm-hash.hh"
 118 #include "score.hh"
 119 #include "text-interface.hh"
 120 #include "warn.hh"
 121
 122 #define MYBACKUP(Token, Value, Location)                                \
 123         do                                                              \
 124                 if (yychar == YYEMPTY)                                  \
 125                         PARSER->lexer_->push_extra_token (Token, Value); \
 126                 else                                                    \
 127                         PARSER->parser_error                            \
 128                                 (Location, _("cannot backup token"));   \
 129         while (0)
 130
 131 %}
 132
 133
 134 %union {
 135         Book *book;
 136         Output_def *outputdef;
 137         SCM scm;
 138         std::string *string;
 139         Music *music;
 140         Score *score;
 141         int i;
 142 }
 143
 144 %{
 145
 146 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 147
 148 /* ES TODO:
 149 - Don't use lily module, create a new module instead.
 150 - delay application of the function
 151 */
 152 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 153   scm_apply_0 (proc, args)
 154 /* Syntactic Sugar. */
 155 #define MAKE_SYNTAX(name, location, ...)        \
 156   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), ##__VA_ARGS__, SCM_UNDEFINED));
 157 #define START_MAKE_SYNTAX(name, ...)                                    \
 158         scm_list_n (ly_lily_module_constant (name), ##__VA_ARGS__, SCM_UNDEFINED)
 159 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 160         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (PARSER->self_scm (), make_input (location), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 161
 162 SCM get_next_unique_context_id ();
 163 SCM get_next_unique_lyrics_context_id ();
 164
 165 #undef _
 166 #if !HAVE_GETTEXT
 167 #define _(x) x
 168 #else
 169 #include <libintl.h>
 170 #define _(x) gettext (x)
 171 #endif
 172
 173
 174 static Music *make_music_with_input (SCM name, Input where);
 175 SCM check_scheme_arg (Lily_parser *parser, Input loc, SCM fallback,
 176                       SCM arg, SCM args, SCM pred);
 177 SCM loc_on_music (Input loc, SCM arg);
 178 SCM get_first_context_id (SCM type, Music *m);
 179 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 180 SCM make_chord_step (int step, Rational alter);
 181 SCM make_simple_markup (SCM a);
 182 SCM try_unpack_lyrics (SCM pred, SCM arg);
 183 bool is_duration (int t);
 184 bool is_regular_identifier (SCM id);
 185 bool ly_input_procedure_p (SCM x);
 186 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 187 void set_music_properties (Music *p, SCM a);
 188
 189 %}
 190
 191 /* The third option is an alias that will be used to display the
 192    syntax error.  Bison CVS now correctly handles backslash escapes.
 193
 194    FIXME: Bison needs to translate some of these, eg, STRING.
 195
 196 */
 197
 198 /* Keyword tokens with plain escaped name.  */
 199 %token ACCEPTS "\\accepts"
 200 %token ADDLYRICS "\\addlyrics"
 201 %token ALIAS "\\alias"
 202 %token ALTERNATIVE "\\alternative"
 203 %token BOOK "\\book"
 204 %token BOOKPART "\\bookpart"
 205 %token CHANGE "\\change"
 206 %token CHORDMODE "\\chordmode"
 207 %token CHORDS "\\chords"
 208 %token CONSISTS "\\consists"
 209 %token CONTEXT "\\context"
 210 %token DEFAULT "\\default"
 211 %token DEFAULTCHILD "\\defaultchild"
 212 %token DENIES "\\denies"
 213 %token DESCRIPTION "\\description"
 214 %token DRUMMODE "\\drummode"
 215 %token DRUMS "\\drums"
 216 %token FIGUREMODE "\\figuremode"
 217 %token FIGURES "\\figures"
 218 %token GROBDESCRIPTIONS "\\grobdescriptions"
 219 %token HEADER "\\header"
 220 %token INVALID "\\version-error"
 221 %token KEY "\\key"
 222 %token LAYOUT "\\layout"
 223 %token LYRICMODE "\\lyricmode"
 224 %token LYRICS "\\lyrics"
 225 %token LYRICSTO "\\lyricsto"
 226 %token MARK "\\mark"
 227 %token MARKUP "\\markup"
 228 %token MARKUPLIST "\\markuplist"
 229 %token MIDI "\\midi"
 230 %token NAME "\\name"
 231 %token NOTEMODE "\\notemode"
 232 %token ONCE "\\once"
 233 %token OVERRIDE "\\override"
 234 %token PAPER "\\paper"
 235 %token REMOVE "\\remove"
 236 %token REPEAT "\\repeat"
 237 %token REST "\\rest"
 238 %token REVERT "\\revert"
 239 %token SCORE "\\score"
 240 %token SEQUENTIAL "\\sequential"
 241 %token SET "\\set"
 242 %token SIMULTANEOUS "\\simultaneous"
 243 %token TEMPO "\\tempo"
 244 %token TIMES "\\times"
 245 %token TYPE "\\type"
 246 %token UNSET "\\unset"
 247 %token WITH "\\with"
 248
 249 /* Keyword token exceptions.  */
 250 %token TIME_T "\\time"
 251 %token NEWCONTEXT "\\new"
 252
 253
 254 /* Other string tokens.  */
 255
 256 %token CHORD_BASS "/+"
 257 %token CHORD_CARET "^"
 258 %token CHORD_COLON ":"
 259 %token CHORD_MINUS "-"
 260 %token CHORD_SLASH "/"
 261 %token ANGLE_OPEN "<"
 262 %token ANGLE_CLOSE ">"
 263 %token DOUBLE_ANGLE_OPEN "<<"
 264 %token DOUBLE_ANGLE_CLOSE ">>"
 265 %token E_BACKSLASH "\\"
 266 %token E_ANGLE_CLOSE "\\>"
 267 %token E_CHAR "\\C[haracter]"
 268 %token E_CLOSE "\\)"
 269 %token E_EXCLAMATION "\\!"
 270 %token E_BRACKET_OPEN "\\["
 271 %token E_OPEN "\\("
 272 %token E_BRACKET_CLOSE "\\]"
 273 %token E_ANGLE_OPEN "\\<"
 274 %token E_PLUS "\\+"
 275 %token E_TILDE "\\~"
 276 %token EXTENDER "__"
 277
 278 /*
 279 If we give names, Bison complains.
 280 */
 281 %token FIGURE_CLOSE /* "\\>" */
 282 %token FIGURE_OPEN /* "\\<" */
 283 %token FIGURE_SPACE "_"
 284 %token HYPHEN "--"
 285
 286 %token CHORDMODIFIERS
 287 %token LYRIC_MARKUP
 288 %token MULTI_MEASURE_REST
 289
 290
 291 %token <i> E_UNSIGNED
 292 %token <i> UNSIGNED
 293
 294 /* Artificial tokens, for more generic function syntax */
 295 %token <i> EXPECT_MARKUP "markup?"
 296 %token <i> EXPECT_PITCH "ly:pitch?"
 297 %token <i> EXPECT_DURATION "ly:duration?"
 298 %token <scm> EXPECT_SCM "scheme?"
 299 %token <scm> SKIPPED_SCM "(scheme?)"
 300 %token <i> EXPECT_MARKUP_LIST "markup-list?"
 301 %token <scm> EXPECT_OPTIONAL "optional?"
 302 /* After the last argument. */
 303 %token <i> EXPECT_NO_MORE_ARGS;
 304
 305 /* An artificial token for parsing embedded Lilypond */
 306 %token <i> EMBEDDED_LILY "#{"
 307
 308 %token <scm> BOOK_IDENTIFIER
 309 %token <scm> CHORDMODIFIER_PITCH
 310 %token <scm> CHORD_MODIFIER
 311 %token <scm> CHORD_REPETITION
 312 %token <scm> CONTEXT_DEF_IDENTIFIER
 313 %token <scm> CONTEXT_MOD_IDENTIFIER
 314 %token <scm> DRUM_PITCH
 315 %token <scm> PITCH_IDENTIFIER
 316 %token <scm> DURATION_IDENTIFIER
 317 %token <scm> EVENT_IDENTIFIER
 318 %token <scm> EVENT_FUNCTION
 319 %token <scm> FRACTION
 320 %token <scm> LYRICS_STRING
 321 %token <scm> LYRIC_MARKUP_IDENTIFIER
 322 %token <scm> MARKUP_FUNCTION
 323 %token <scm> MARKUP_LIST_FUNCTION
 324 %token <scm> MARKUP_IDENTIFIER
 325 %token <scm> MARKUPLIST_IDENTIFIER
 326 %token <scm> MUSIC_FUNCTION
 327 %token <scm> MUSIC_IDENTIFIER
 328 %token <scm> NOTENAME_PITCH
 329 %token <scm> NUMBER_IDENTIFIER
 330 %token <scm> OUTPUT_DEF_IDENTIFIER
 331 %token <scm> REAL
 332 %token <scm> RESTNAME
 333 %token <scm> SCM_FUNCTION
 334 %token <scm> SCM_IDENTIFIER
 335 %token <scm> SCM_TOKEN
 336 %token <scm> SCORE_IDENTIFIER
 337 %token <scm> STRING
 338 %token <scm> STRING_IDENTIFIER
 339 %token <scm> TONICNAME_PITCH
 340
 341
 342 %type <book> book_block
 343 %type <book> book_body
 344 %type <book> bookpart_block
 345 %type <book> bookpart_body
 346
 347 %type <i> bare_unsigned
 348 %type <scm> figured_bass_alteration
 349 %type <i> dots
 350 %type <i> exclamations
 351 %type <i> optional_rest
 352 %type <i> questions
 353 %type <i> script_dir
 354 %type <i> sub_quotes
 355 %type <i> sup_quotes
 356 %type <i> tremolo_type
 357
 358 /* Music */
 359 %type <scm> composite_music
 360 %type <scm> grouped_music_list
 361 %type <scm> braced_music_list
 362 %type <scm> closed_music
 363 %type <scm> music
 364 %type <scm> music_bare
 365 %type <scm> complex_music
 366 %type <scm> complex_music_prefix
 367 %type <scm> mode_changed_music
 368 %type <scm> repeated_music
 369 %type <scm> sequential_music
 370 %type <scm> simple_music
 371 %type <scm> simultaneous_music
 372 %type <scm> chord_body
 373 %type <scm> chord_body_element
 374 %type <scm> command_element
 375 %type <scm> command_event
 376 %type <scm> context_modification
 377 %type <scm> context_change
 378 %type <scm> direction_less_event
 379 %type <scm> direction_reqd_event
 380 %type <scm> embedded_lilypond
 381 %type <scm> event_chord
 382 %type <scm> fingering
 383 %type <scm> gen_text_def
 384 %type <scm> music_property_def
 385 %type <scm> note_chord_element
 386 %type <scm> post_event
 387 %type <scm> post_event_nofinger
 388 %type <scm> re_rhythmed_music
 389 %type <scm> simple_element
 390 %type <scm> simple_music_property_def
 391 %type <scm> start_symbol
 392 %type <scm> string_number_event
 393 %type <scm> tempo_event
 394
 395 %type <outputdef> output_def_body
 396 %type <outputdef> output_def_head
 397 %type <outputdef> output_def_head_with_mode_switch
 398 %type <outputdef> output_def
 399 %type <outputdef> paper_block
 400
 401 %type <scm> music_function_call
 402 %type <scm> music_list
 403 %type <scm> assignment_id
 404 %type <scm> bare_number
 405 %type <scm> unsigned_number
 406 %type <scm> bass_figure
 407 %type <scm> figured_bass_modification
 408 %type <scm> br_bass_figure
 409 %type <scm> bass_number
 410 %type <scm> chord_body_elements
 411 %type <scm> chord_item
 412 %type <scm> chord_items
 413 %type <scm> chord_separator
 414 %type <scm> context_def_mod
 415 %type <scm> context_def_spec_block
 416 %type <scm> context_def_spec_body
 417 %type <scm> context_mod
 418 %type <scm> context_mod_list
 419 %type <scm> context_prop_spec
 420 %type <scm> direction_less_char
 421 %type <scm> duration_length
 422 %type <scm> embedded_scm
 423 %type <scm> embedded_scm_arg
 424 %type <scm> embedded_scm_arg_closed
 425 %type <scm> embedded_scm_bare
 426 %type <scm> embedded_scm_bare_arg
 427 %type <scm> embedded_scm_closed
 428 %type <scm> embedded_scm_chord_body
 429 %type <scm> embedded_scm_event
 430 %type <scm> event_function_event
 431 %type <scm> figure_list
 432 %type <scm> figure_spec
 433 %type <scm> fraction
 434 %type <scm> full_markup
 435 %type <scm> full_markup_list
 436 %type <scm> function_arglist
 437 %type <scm> function_arglist_optional
 438 %type <scm> function_arglist_keep
 439 %type <scm> function_arglist_bare
 440 %type <scm> function_arglist_closed
 441 %type <scm> function_arglist_closed_optional
 442 %type <scm> function_arglist_closed_keep
 443 %type <scm> identifier_init
 444 %type <scm> lilypond
 445 %type <scm> lilypond_header
 446 %type <scm> lilypond_header_body
 447 %type <scm> lyric_element
 448 %type <scm> lyric_markup
 449 %type <scm> markup
 450 %type <scm> markup_braced_list
 451 %type <scm> markup_braced_list_body
 452 %type <scm> markup_composed_list
 453 %type <scm> markup_command_list
 454 %type <scm> markup_command_list_arguments
 455 %type <scm> markup_command_basic_arguments
 456 %type <scm> markup_head_1_item
 457 %type <scm> markup_head_1_list
 458 %type <scm> markup_list
 459 %type <scm> markup_top
 460 %type <scm> mode_changing_head
 461 %type <scm> mode_changing_head_with_context
 462 %type <scm> multiplied_duration
 463 %type <scm> music_function_event
 464 %type <scm> music_function_event_arglist
 465 %type <scm> music_function_chord_body
 466 %type <scm> music_function_chord_body_arglist
 467 %type <scm> new_chord
 468 %type <scm> new_lyrics
 469 %type <scm> number_expression
 470 %type <scm> number_factor
 471 %type <scm> number_term
 472 %type <scm> octave_check
 473 %type <scm> optional_context_mod
 474 %type <scm> optional_id
 475 %type <scm> optional_notemode_duration
 476 %type <scm> pitch
 477 %type <scm> pitch_also_in_chords
 478 %type <scm> post_events
 479 %type <scm> property_operation
 480 %type <scm> property_path property_path_revved
 481 %type <scm> scalar
 482 %type <scm> scalar_bare
 483 %type <scm> scalar_closed
 484 %type <scm> scm_function_call
 485 %type <scm> scm_function_call_closed
 486 %type <scm> script_abbreviation
 487 %type <scm> simple_chord_elements
 488 %type <scm> simple_markup
 489 %type <scm> simple_string
 490 %type <scm> steno_duration
 491 %type <scm> steno_pitch
 492 %type <scm> steno_tonic_pitch
 493 %type <scm> step_number
 494 %type <scm> step_numbers
 495 %type <scm> string
 496 %type <scm> tempo_range
 497
 498 %type <score> score_block
 499 %type <score> score_body
 500
 501
 502 %left '-' '+'
 503
 504 /* We don't assign precedence to / and *, because we might need varied
 505 prec levels in different prods */
 506
 507 %left UNARY_MINUS
 508
 509 %%
 510
 511 start_symbol:
 512         lilypond
 513         | EMBEDDED_LILY {
 514                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
 515                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
 516         } embedded_lilypond {
 517                 PARSER->lexer_->pop_state ();
 518                 PARSER->lexer_->set_identifier (ly_symbol2scm ("parseStringResult"), $3);
 519         }
 520         ;
 521
 522 lilypond:       /* empty */ { }
 523         | lilypond toplevel_expression {
 524         }
 525         | lilypond assignment {
 526         }
 527         | lilypond error {
 528                 PARSER->error_level_ = 1;
 529         }
 530         | lilypond INVALID      {
 531                 PARSER->error_level_ = 1;
 532         }
 533         ;
 534
 535
 536 toplevel_expression:
 537         lilypond_header {
 538                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 539         }
 540         | book_block {
 541                 Book *book = $1;
 542                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 543                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 544                 book->unprotect ();
 545         }
 546         | bookpart_block {
 547                 Book *bookpart = $1;
 548                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 549                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 550                 bookpart->unprotect ();
 551         }
 552         | score_block {
 553                 Score *score = $1;
 554
 555                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 556                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 557                 score->unprotect ();
 558         }
 559         | composite_music {
 560                 Music *music = unsmob_music ($1);
 561                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 562                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 563         }
 564         | full_markup {
 565                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 566                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 567         }
 568         | full_markup_list {
 569                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 570                 scm_call_2 (proc, PARSER->self_scm (), $1);
 571         }
 572         | output_def {
 573                 SCM id = SCM_EOL;
 574                 Output_def * od = $1;
 575
 576                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 577                         id = ly_symbol2scm ("$defaultpaper");
 578                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 579                         id = ly_symbol2scm ("$defaultmidi");
 580                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 581                         id = ly_symbol2scm ("$defaultlayout");
 582
 583                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 584                 od->unprotect();
 585         }
 586         ;
 587
 588 embedded_scm_bare:
 589         SCM_TOKEN
 590         | SCM_IDENTIFIER
 591         ;
 592
 593 embedded_scm_bare_arg:
 594         embedded_scm_bare
 595         | STRING
 596         | STRING_IDENTIFIER
 597         | full_markup
 598         | full_markup_list
 599         | context_modification
 600         | score_block
 601         {
 602                 $$ = $1->self_scm ();
 603                 $1->unprotect ();
 604         }
 605         | context_def_spec_block
 606         | book_block
 607         {
 608                 $$ = $1->self_scm ();
 609                 $1->unprotect ();
 610         }
 611         | bookpart_block
 612         {
 613                 $$ = $1->self_scm ();
 614                 $1->unprotect ();
 615         }
 616         | output_def
 617         {
 618                 $$ = $1->self_scm ();
 619                 $1->unprotect ();
 620         }
 621         ;
 622
 623 /* The generic version may end in music, or not */
 624
 625 embedded_scm:
 626         embedded_scm_bare
 627         | scm_function_call
 628         ;
 629
 630 embedded_scm_arg:
 631         embedded_scm_bare_arg
 632         | scm_function_call
 633         | music
 634         ;
 635
 636 scm_function_call:
 637         SCM_FUNCTION function_arglist {
 638                 $$ = MAKE_SYNTAX ("music-function", @$,
 639                                          $1, $2);
 640         }
 641         ;
 642
 643 embedded_lilypond:
 644         /* empty */
 645         {
 646                 $$ = MAKE_SYNTAX ("void-music", @$);
 647         }
 648         | identifier_init
 649         | music music music_list {
 650                 $$ = MAKE_SYNTAX ("sequential-music", @$,
 651                                   scm_cons2 ($1, $2, scm_reverse_x ($3, SCM_EOL)));
 652         }
 653         | error {
 654                 PARSER->error_level_ = 1;
 655         }
 656         | INVALID embedded_lilypond {
 657                 PARSER->error_level_ = 1;
 658         }
 659         ;
 660
 661
 662 lilypond_header_body:
 663         {
 664                 $$ = get_header (PARSER);
 665                 PARSER->lexer_->add_scope ($$);
 666         }
 667         | lilypond_header_body assignment  {
 668
 669         }
 670         ;
 671
 672 lilypond_header:
 673         HEADER '{' lilypond_header_body '}'     {
 674                 $$ = PARSER->lexer_->remove_scope ();
 675         }
 676         ;
 677
 678 /*
 679         DECLARATIONS
 680 */
 681 assignment_id:
 682         STRING          { $$ = $1; }
 683         | LYRICS_STRING { $$ = $1; }
 684         ;
 685
 686 assignment:
 687         assignment_id '=' identifier_init  {
 688                 PARSER->lexer_->set_identifier ($1, $3);
 689         }
 690         | assignment_id property_path '=' identifier_init {
 691                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 692                 PARSER->lexer_->set_identifier (path, $4);
 693         ;
 694 /*
 695  TODO: devise standard for protection in parser.
 696
 697   The parser stack lives on the C-stack, which means that
 698 all objects can be unprotected as soon as they're here.
 699
 700 */
 701         }
 702         | embedded_scm { }
 703         ;
 704
 705
 706 identifier_init:
 707         score_block {
 708                 $$ = $1->self_scm ();
 709                 $1->unprotect ();
 710         }
 711         | book_block {
 712                 $$ = $1->self_scm ();
 713                 $1->unprotect ();
 714         }
 715         | bookpart_block {
 716                 $$ = $1->self_scm ();
 717                 $1->unprotect ();
 718         }
 719         | output_def {
 720                 $$ = $1->self_scm ();
 721                 $1->unprotect ();
 722         }
 723         | context_def_spec_block {
 724                 $$ = $1;
 725         }
 726         | music  {
 727                 /* Hack: Create event-chord around standalone events.
 728                    Prevents the identifier from being interpreted as a post-event. */
 729                 Music *mus = unsmob_music ($1);
 730                 bool is_event = mus &&
 731                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 732                                 != SCM_BOOL_F);
 733                 if (!is_event)
 734                         $$ = $1;
 735                 else
 736                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 737         }
 738         | post_event_nofinger {
 739                 $$ = $1;
 740         }
 741         | number_expression {
 742                 $$ = $1;
 743         }
 744         | string {
 745                 $$ = $1;
 746         }
 747         | embedded_scm {
 748                 $$ = $1;
 749         }
 750         | full_markup {
 751                 $$ = $1;
 752         }
 753         | full_markup_list {
 754                 $$ = $1;
 755         }
 756         | context_modification {
 757                 $$ = $1;
 758         }
 759         ;
 760
 761 context_def_spec_block:
 762         CONTEXT '{' context_def_spec_body '}'
 763                 {
 764                 $$ = $3;
 765         }
 766         ;
 767
 768 context_def_spec_body:
 769         /**/ {
 770                 $$ = Context_def::make_scm ();
 771                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 772         }
 773         | CONTEXT_DEF_IDENTIFIER {
 774                 $$ = $1;
 775                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 776         }
 777         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 778                 Context_def*td = unsmob_context_def ($$);
 779
 780                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 781                         SCM tag = scm_caar (p);
 782
 783                         /* TODO: should make new tag "grob-definition" ? */
 784                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 785                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 786                 }
 787         }
 788         | context_def_spec_body context_mod {
 789                 unsmob_context_def ($$)->add_context_mod ($2);
 790         }
 791         | context_def_spec_body context_modification {
 792                 Context_def *td = unsmob_context_def ($$);
 793                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 794                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 795                     td->add_context_mod (scm_car (m));
 796                 }
 797         }
 798         ;
 799
 800
 801
 802 book_block:
 803         BOOK '{' book_body '}'  {
 804                 $$ = $3;
 805                 pop_paper (PARSER);
 806                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 807         }
 808         ;
 809
 810 /* FIXME:
 811    * Use 'handlers' like for toplevel-* stuff?
 812    * grok \layout and \midi?  */
 813 book_body:
 814         {
 815                 $$ = new Book;
 816                 init_papers (PARSER);
 817                 $$->origin ()->set_spot (@$);
 818                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 819                 $$->paper_->unprotect ();
 820                 push_paper (PARSER, $$->paper_);
 821                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 822                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 823                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 824                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 825         }
 826         | BOOK_IDENTIFIER {
 827                 $$ = unsmob_book ($1);
 828                 $$->protect ();
 829                 $$->origin ()->set_spot (@$);
 830                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 831         }
 832         | book_body paper_block {
 833                 $$->paper_ = $2;
 834                 $2->unprotect ();
 835                 set_paper (PARSER, $2);
 836         }
 837         | book_body bookpart_block {
 838                 Book *bookpart = $2;
 839                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 840                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 841                 bookpart->unprotect ();
 842         }
 843         | book_body score_block {
 844                 Score *score = $2;
 845                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 846                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 847                 score->unprotect ();
 848         }
 849         | book_body composite_music {
 850                 Music *music = unsmob_music ($2);
 851                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 852                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 853         }
 854         | book_body full_markup {
 855                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 856                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 857         }
 858         | book_body full_markup_list {
 859                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 860                 scm_call_2 (proc, $$->self_scm (), $2);
 861         }
 862         | book_body lilypond_header {
 863                 $$->header_ = $2;
 864         }
 865         | book_body embedded_scm { }
 866         | book_body error {
 867                 $$->paper_ = 0;
 868                 $$->scores_ = SCM_EOL;
 869                 $$->bookparts_ = SCM_EOL;
 870         }
 871         ;
 872
 873 bookpart_block:
 874         BOOKPART '{' bookpart_body '}' {
 875                 $$ = $3;
 876                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 877         }
 878         ;
 879
 880 bookpart_body:
 881         {
 882                 $$ = new Book;
 883                 $$->origin ()->set_spot (@$);
 884                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 885         }
 886         | BOOK_IDENTIFIER {
 887                 $$ = unsmob_book ($1);
 888                 $$->protect ();
 889                 $$->origin ()->set_spot (@$);
 890                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 891         }
 892         | bookpart_body paper_block {
 893                 $$->paper_ = $2;
 894                 $2->unprotect ();
 895         }
 896         | bookpart_body score_block {
 897                 Score *score = $2;
 898                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 899                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 900                 score->unprotect ();
 901         }
 902         | bookpart_body composite_music {
 903                 Music *music = unsmob_music ($2);
 904                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 905                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 906         }
 907         | bookpart_body full_markup {
 908                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 909                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 910         }
 911         | bookpart_body full_markup_list {
 912                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 913                 scm_call_2 (proc, $$->self_scm (), $2);
 914         }
 915         | bookpart_body lilypond_header {
 916                 $$->header_ = $2;
 917         }
 918         | bookpart_body embedded_scm { }
 919         | bookpart_body error {
 920                 $$->paper_ = 0;
 921                 $$->scores_ = SCM_EOL;
 922         }
 923         ;
 924
 925 score_block:
 926         SCORE '{' score_body '}'        {
 927                 $$ = $3;
 928         }
 929         ;
 930
 931 score_body:
 932         music {
 933                 SCM m = $1;
 934                 SCM scorify = ly_lily_module_constant ("scorify-music");
 935                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 936
 937                 // pass ownernship to C++ again.
 938                 $$ = unsmob_score (score);
 939                 $$->protect ();
 940                 $$->origin ()->set_spot (@$);
 941         }
 942         | SCORE_IDENTIFIER {
 943                 $$ = unsmob_score ($1);
 944                 $$->protect ();
 945                 $$->origin ()->set_spot (@$);
 946         }
 947         | score_body lilypond_header    {
 948                 $$->set_header ($2);
 949         }
 950         | score_body output_def {
 951                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 952                 {
 953                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 954
 955                 }
 956                 else
 957                 {
 958                         $$->add_output_def ($2);
 959                 }
 960                 $2->unprotect ();
 961         }
 962         | score_body error {
 963                 $$->error_found_ = true;
 964         }
 965         ;
 966
 967
 968 /*
 969         OUTPUT DEF
 970 */
 971
 972 paper_block:
 973         output_def {
 974                 $$ = $1;
 975                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 976                 {
 977                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 978                         $1->unprotect ();
 979                         $$ = get_paper (PARSER);
 980                 }
 981         }
 982         ;
 983
 984
 985 output_def:
 986         output_def_body '}' {
 987                 $$ = $1;
 988
 989                 PARSER->lexer_->remove_scope ();
 990                 PARSER->lexer_->pop_state ();
 991         }
 992         ;
 993
 994 output_def_head:
 995         PAPER {
 996                 $$ = get_paper (PARSER);
 997                 $$->input_origin_ = @$;
 998                 PARSER->lexer_->add_scope ($$->scope_);
 999         }
1000         | MIDI    {
1001                 Output_def *p = get_midi (PARSER);
1002                 $$ = p;
1003                 PARSER->lexer_->add_scope (p->scope_);
1004         }
1005         | LAYOUT        {
1006                 Output_def *p = get_layout (PARSER);
1007
1008                 PARSER->lexer_->add_scope (p->scope_);
1009                 $$ = p;
1010         }
1011         ;
1012
1013 output_def_head_with_mode_switch:
1014         output_def_head {
1015                 PARSER->lexer_->push_initial_state ();
1016                 $$ = $1;
1017         }
1018         ;
1019
1020 output_def_body:
1021         output_def_head_with_mode_switch '{' {
1022                 $$ = $1;
1023                 $$->input_origin_.set_spot (@$);
1024         }
1025         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
1026                 $1->unprotect ();
1027
1028                 Output_def *o = unsmob_output_def ($3);
1029                 o->input_origin_.set_spot (@$);
1030                 $$ = o;
1031                 $$->protect ();
1032                 PARSER->lexer_->remove_scope ();
1033                 PARSER->lexer_->add_scope (o->scope_);
1034         }
1035         | output_def_body assignment  {
1036
1037         }
1038         | output_def_body context_def_spec_block        {
1039                 assign_context_def ($$, $2);
1040         }
1041         | output_def_body error {
1042
1043         }
1044         ;
1045
1046 tempo_event:
1047         TEMPO steno_duration '=' tempo_range    {
1048                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1049         }
1050         | TEMPO scalar_closed steno_duration '=' tempo_range    {
1051                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1052         }
1053         | TEMPO scalar {
1054                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1055         }
1056         ;
1057
1058 /*
1059 The representation of a  list is reversed to have efficient append.  */
1060
1061 music_list:
1062         /* empty */ {
1063                 $$ = SCM_EOL;
1064         }
1065         | music_list music {
1066                 $$ = scm_cons ($2, $1);
1067         }
1068         | music_list embedded_scm {
1069
1070         }
1071         | music_list error {
1072                 Music *m = MY_MAKE_MUSIC("Music", @$);
1073                 // ugh. code dup
1074                 m->set_property ("error-found", SCM_BOOL_T);
1075                 $$ = scm_cons (m->self_scm (), $1);
1076                 m->unprotect (); /* UGH */
1077         }
1078         ;
1079
1080 braced_music_list:
1081         '{' music_list '}'
1082         {
1083                 $$ = scm_reverse_x ($2, SCM_EOL);
1084         }
1085         ;
1086
1087 music:
1088         simple_music
1089         | composite_music %prec FUNCTION_ARGUMENTS
1090         ;
1091
1092
1093 repeated_music:
1094         REPEAT simple_string unsigned_number music
1095         {
1096                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1097         }
1098         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1099         {
1100                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1101         }
1102         ;
1103
1104 sequential_music:
1105         SEQUENTIAL braced_music_list {
1106                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1107         }
1108         | braced_music_list {
1109                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1110         }
1111         ;
1112
1113 simultaneous_music:
1114         SIMULTANEOUS braced_music_list {
1115                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1116         }
1117         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1118                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1119         }
1120         ;
1121
1122 simple_music:
1123         event_chord
1124         | music_property_def
1125         | context_change
1126         ;
1127
1128 context_modification:
1129         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1130         {
1131                 PARSER->lexer_->pop_state ();
1132                 $$ = $4;
1133         }
1134         | WITH CONTEXT_MOD_IDENTIFIER
1135         {
1136                 $$ = $2;
1137         }
1138         | CONTEXT_MOD_IDENTIFIER
1139         {
1140                 $$ = $1;
1141         }
1142         ;
1143
1144 optional_context_mod:
1145         /**/ {
1146             $$ = SCM_EOL;
1147         }
1148         | context_modification
1149         {
1150               $$ = $1;
1151         }
1152         ;
1153
1154 context_mod_list:
1155         /**/ {
1156             $$ = Context_mod ().smobbed_copy ();
1157         }
1158         | context_mod_list context_mod  {
1159                  unsmob_context_mod ($1)->add_context_mod ($2);
1160         }
1161         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1162                  Context_mod *md = unsmob_context_mod ($2);
1163                  if (md)
1164                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1165         }
1166         ;
1167
1168 composite_music:
1169         complex_music
1170         | music_bare
1171         ;
1172
1173 /* Music that can be parsed without lookahead */
1174 closed_music:
1175         music_bare
1176         | complex_music_prefix closed_music
1177         {
1178                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1179         }
1180         ;
1181
1182 music_bare:
1183         mode_changed_music
1184         | MUSIC_IDENTIFIER
1185         | grouped_music_list
1186         ;
1187
1188 grouped_music_list:
1189         simultaneous_music              { $$ = $1; }
1190         | sequential_music              { $$ = $1; }
1191         ;
1192
1193 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1194  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1195 and this rule returns the reversed list of arguments. */
1196
1197
1198 function_arglist:
1199         function_arglist_bare
1200         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1201         {
1202                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1203                                        $3, $2, $1);
1204         }
1205         | EXPECT_SCM function_arglist_optional SKIPPED_SCM
1206         {
1207                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1208                                        $3, $2, $1);
1209         }
1210         ;
1211
1212 function_arglist_optional:
1213         function_arglist_keep %prec FUNCTION_ARGUMENTS
1214         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1215         {
1216                 $$ = scm_cons ($1, $3);
1217         }
1218         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1219         {
1220                 $$ = scm_cons ($1, $3);
1221         }
1222         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_optional
1223         {
1224                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1225         }
1226         ;
1227
1228 function_arglist_keep:
1229         EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords {
1230                 $$ = scm_cons ($4, $3);
1231         }
1232         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length {
1233                 $$ = scm_cons ($4, $3);
1234         }
1235         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1236         {
1237                 if (scm_is_true (scm_call_1 ($2, $4)))
1238                 {
1239                         $$ = scm_cons ($4, $3);
1240                 } else {
1241                         $$ = try_unpack_lyrics ($2, $4);
1242                         if (!SCM_UNBNDP ($$))
1243                                 $$ = scm_cons ($$, $3);
1244                         else {
1245                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1246                                 MYBACKUP (SKIPPED_SCM, $4, @4);
1247                         }
1248                 }
1249         }
1250         | function_arglist
1251         ;
1252
1253
1254 function_arglist_closed:
1255         function_arglist_bare
1256         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1257         {
1258                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1259                                        $3, $2, $1);
1260         }
1261         | EXPECT_SCM function_arglist_optional SKIPPED_SCM
1262         {
1263                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1264                                        $3, $2, $1);
1265         }
1266         ;
1267
1268 function_arglist_closed_optional:
1269         function_arglist_closed_keep %prec FUNCTION_ARGUMENTS
1270         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1271         {
1272                 $$ = scm_cons ($1, $3);
1273         }
1274         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1275         {
1276                 $$ = scm_cons ($1, $3);
1277         }
1278         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_optional
1279         {
1280                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1281         }
1282         ;
1283
1284 function_arglist_closed_keep:
1285         EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords {
1286                 $$ = scm_cons ($4, $3);
1287         }
1288         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length {
1289                 $$ = scm_cons ($4, $3);
1290         }
1291         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1292         {
1293                 if (scm_is_true (scm_call_1 ($2, $4)))
1294                 {
1295                         $$ = scm_cons ($4, $3);
1296                 } else {
1297                         $$ = try_unpack_lyrics ($2, $4);
1298                         if (!SCM_UNBNDP ($$))
1299                                 $$ = scm_cons ($$, $3);
1300                         else {
1301                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1302                                 MYBACKUP (SKIPPED_SCM, $4, @4);
1303                         }
1304                 }
1305         }
1306         | function_arglist_closed
1307         ;
1308
1309 embedded_scm_closed:
1310         embedded_scm_bare
1311         | scm_function_call_closed
1312         ;
1313
1314 embedded_scm_arg_closed:
1315         embedded_scm_bare_arg
1316         | scm_function_call_closed
1317         | closed_music
1318         ;
1319
1320 scm_function_call_closed:
1321         SCM_FUNCTION function_arglist_closed {
1322                 $$ = MAKE_SYNTAX ("music-function", @$,
1323                                          $1, $2);
1324         }
1325         ;
1326
1327 function_arglist_bare:
1328         EXPECT_NO_MORE_ARGS {
1329                 $$ = SCM_EOL;
1330         }
1331         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1332                 $$ = scm_cons ($3, $2);
1333         }
1334         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1335                 $$ = scm_cons ($3, $2);
1336         }
1337         ;
1338
1339 music_function_call:
1340         MUSIC_FUNCTION function_arglist {
1341                 $$ = MAKE_SYNTAX ("music-function", @$,
1342                                          $1, $2);
1343         }
1344         ;
1345
1346
1347 optional_id:
1348         /**/ { $$ = SCM_EOL; }
1349         | '=' simple_string {
1350                 $$ = $2;
1351         }
1352         ;
1353
1354 complex_music:
1355         music_function_call
1356         | repeated_music                { $$ = $1; }
1357         | re_rhythmed_music     { $$ = $1; }
1358         | complex_music_prefix music
1359         {
1360                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1361         }
1362         ;
1363
1364 complex_music_prefix:
1365         CONTEXT simple_string optional_id optional_context_mod {
1366                 Context_mod *ctxmod = unsmob_context_mod ($4);
1367                 SCM mods = SCM_EOL;
1368                 if (ctxmod)
1369                         mods = ctxmod->get_mods ();
1370                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1371         }
1372         | NEWCONTEXT simple_string optional_id optional_context_mod {
1373                 Context_mod *ctxmod = unsmob_context_mod ($4);
1374                 SCM mods = SCM_EOL;
1375                 if (ctxmod)
1376                         mods = ctxmod->get_mods ();
1377                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1378         }
1379         | TIMES fraction {
1380                 $$ = START_MAKE_SYNTAX ("time-scaled-music", $2);
1381         }
1382         ;
1383
1384 mode_changed_music:
1385         mode_changing_head grouped_music_list {
1386                 if ($1 == ly_symbol2scm ("chords"))
1387                 {
1388                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1389                 }
1390                 else
1391                 {
1392                   $$ = $2;
1393                 }
1394                 PARSER->lexer_->pop_state ();
1395         }
1396         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1397                 Context_mod *ctxmod = unsmob_context_mod ($2);
1398                 SCM mods = SCM_EOL;
1399                 if (ctxmod)
1400                         mods = ctxmod->get_mods ();
1401                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1402                 if ($1 == ly_symbol2scm ("ChordNames"))
1403                 {
1404                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1405                 }
1406                 PARSER->lexer_->pop_state ();
1407         }
1408         ;
1409
1410 mode_changing_head:
1411         NOTEMODE {
1412                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1413                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1414
1415                 $$ = ly_symbol2scm ("notes");
1416         }
1417         | DRUMMODE
1418                 {
1419                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1420                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1421
1422                 $$ = ly_symbol2scm ("drums");
1423         }
1424         | FIGUREMODE {
1425                 PARSER->lexer_->push_figuredbass_state ();
1426
1427                 $$ = ly_symbol2scm ("figures");
1428         }
1429         | CHORDMODE {
1430                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1431                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1432                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1433                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1434                 $$ = ly_symbol2scm ("chords");
1435
1436         }
1437         | LYRICMODE
1438                 { PARSER->lexer_->push_lyric_state ();
1439                 $$ = ly_symbol2scm ("lyrics");
1440         }
1441         ;
1442
1443 mode_changing_head_with_context:
1444         DRUMS {
1445                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1446                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1447
1448                 $$ = ly_symbol2scm ("DrumStaff");
1449         }
1450         | FIGURES {
1451                 PARSER->lexer_->push_figuredbass_state ();
1452
1453                 $$ = ly_symbol2scm ("FiguredBass");
1454         }
1455         | CHORDS {
1456                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1457                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1458                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1459                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1460                 $$ = ly_symbol2scm ("ChordNames");
1461         }
1462         | LYRICS
1463                 { PARSER->lexer_->push_lyric_state ();
1464                 $$ = ly_symbol2scm ("Lyrics");
1465         }
1466         ;
1467
1468 new_lyrics:
1469         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1470         /*cont */
1471         composite_music {
1472         /* Can also use music at the expensive of two S/Rs similar to
1473            \repeat \alternative */
1474                 PARSER->lexer_->pop_state ();
1475
1476                 $$ = scm_cons ($3, SCM_EOL);
1477         }
1478         | new_lyrics ADDLYRICS {
1479                 PARSER->lexer_->push_lyric_state ();
1480         } composite_music {
1481                 PARSER->lexer_->pop_state ();
1482                 $$ = scm_cons ($4, $1);
1483         }
1484         ;
1485
1486 re_rhythmed_music:
1487         composite_music new_lyrics {
1488                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1489         } %prec FUNCTION_ARGUMENTS
1490         | LYRICSTO simple_string {
1491                 PARSER->lexer_->push_lyric_state ();
1492         } music {
1493                 PARSER->lexer_->pop_state ();
1494                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1495         }
1496         ;
1497
1498 context_change:
1499         CHANGE STRING '=' STRING  {
1500                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1501         }
1502         ;
1503
1504
1505 property_path_revved:
1506         embedded_scm_closed {
1507                 $$ = scm_cons ($1, SCM_EOL);
1508         }
1509         | property_path_revved embedded_scm_closed {
1510                 $$ = scm_cons ($2, $1);
1511         }
1512         ;
1513
1514 property_path:
1515         property_path_revved  {
1516                 $$ = scm_reverse_x ($1, SCM_EOL);
1517         }
1518         ;
1519
1520 property_operation:
1521         STRING '=' scalar {
1522                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1523                         scm_string_to_symbol ($1), $3);
1524         }
1525         | UNSET simple_string {
1526                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1527                         scm_string_to_symbol ($2));
1528         }
1529         | OVERRIDE simple_string property_path '=' scalar {
1530                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1531                                                         scm_string_to_symbol ($2), $5),
1532                                              $3));
1533         }
1534         | REVERT simple_string embedded_scm {
1535                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1536                         scm_string_to_symbol ($2), $3);
1537         }
1538         ;
1539
1540 context_def_mod:
1541         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1542         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1543
1544         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1545         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1546         | DENIES { $$ = ly_symbol2scm ("denies"); }
1547
1548         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1549         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1550         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1551         | NAME { $$ = ly_symbol2scm ("context-name"); }
1552         ;
1553
1554 context_mod:
1555         property_operation { $$ = $1; }
1556         | context_def_mod STRING {
1557                 $$ = scm_list_2 ($1, $2);
1558         }
1559         | context_def_mod embedded_scm {
1560            if (ly_symbol2scm ("consists") != $1)
1561            {
1562              $$ = SCM_EOL;
1563              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1564            }
1565            else
1566            {
1567              $$ = scm_list_2 ($1, $2);
1568            }
1569         }
1570         ;
1571
1572 context_prop_spec:
1573         simple_string {
1574                 if (!is_regular_identifier ($1))
1575                 {
1576                         @$.error (_("Grob name should be alphanumeric"));
1577                 }
1578
1579                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1580                         scm_string_to_symbol ($1));
1581         }
1582         | simple_string '.' simple_string {
1583                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1584                         scm_string_to_symbol ($3));
1585         }
1586         ;
1587
1588 simple_music_property_def:
1589         OVERRIDE context_prop_spec property_path '=' scalar {
1590                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1591                                 ly_symbol2scm ("OverrideProperty"),
1592                                 scm_cadr ($2),
1593                                 $5, SCM_UNDEFINED),
1594                                 $3));
1595         }
1596         | REVERT context_prop_spec embedded_scm {
1597                 $$ = scm_list_4 (scm_car ($2),
1598                         ly_symbol2scm ("RevertProperty"),
1599                         scm_cadr ($2),
1600                         $3);
1601         }
1602         | SET context_prop_spec '=' scalar {
1603                 $$ = scm_list_4 (scm_car ($2),
1604                         ly_symbol2scm ("PropertySet"),
1605                         scm_cadr ($2),
1606                         $4);
1607         }
1608         | UNSET context_prop_spec {
1609                 $$ = scm_list_3 (scm_car ($2),
1610                         ly_symbol2scm ("PropertyUnset"),
1611                         scm_cadr ($2));
1612         }
1613         ;
1614
1615 music_property_def:
1616         simple_music_property_def {
1617                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1618         }
1619         | ONCE simple_music_property_def {
1620                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1621         }
1622         ;
1623
1624 string:
1625         STRING {
1626                 $$ = $1;
1627         }
1628         | STRING_IDENTIFIER {
1629                 $$ = $1;
1630         }
1631         | string '+' string {
1632                 $$ = scm_string_append (scm_list_2 ($1, $3));
1633         }
1634         ;
1635
1636 simple_string: STRING {
1637                 $$ = $1;
1638         }
1639         | LYRICS_STRING {
1640                 $$ = $1;
1641         }
1642         | STRING_IDENTIFIER {
1643                 $$ = $1;
1644         }
1645         ;
1646
1647 scalar_bare:
1648         string {
1649                 $$ = $1;
1650         }
1651         | lyric_element {
1652                 $$ = $1;
1653         }
1654         | bare_number {
1655                 $$ = $1;
1656         }
1657         | embedded_scm_bare {
1658                 $$ = $1;
1659         }
1660         | full_markup {
1661                 $$ = $1;
1662         }
1663         | full_markup_list
1664         {
1665                 $$ = $1;
1666         }
1667         ;
1668
1669 scalar:
1670         scalar_bare |
1671         scm_function_call
1672         ;
1673
1674 scalar_closed:
1675         scalar_bare |
1676         scm_function_call_closed
1677         ;
1678
1679
1680 event_chord:
1681         /* TODO: Create a special case that avoids the creation of
1682            EventChords around simple_elements that have no post_events?
1683          */
1684         simple_chord_elements post_events       {
1685                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1686
1687                 Input i;
1688                 /* why is this giving wrong start location? -ns
1689                  * i = @$; */
1690                 i.set_location (@1, @2);
1691                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1692         }
1693         | CHORD_REPETITION optional_notemode_duration post_events {
1694                 Input i;
1695                 i.set_location (@1, @3);
1696                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1697                                   PARSER->lexer_->chord_repetition_.last_chord_,
1698                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1699                                   $2, scm_reverse_x ($3, SCM_EOL));
1700         }
1701         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1702                 Input i;
1703                 i.set_location (@1, @3);
1704                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1705                                   scm_reverse_x ($3, SCM_EOL));
1706         }
1707         | command_element
1708         /* note chord elements are memorized into
1709            PARSER->lexer_->chord_repetition_ so that the chord repetition
1710            mechanism copy them when a chord repetition symbol is found
1711         */
1712         | note_chord_element    {
1713                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1714         }
1715         ;
1716
1717
1718 note_chord_element:
1719         chord_body optional_notemode_duration post_events
1720         {
1721                 Music *m = unsmob_music ($1);
1722                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1723                 SCM es = m->get_property ("elements");
1724                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1725
1726                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1727                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1728                 es = ly_append2 (es, postevs);
1729
1730                 m-> set_property ("elements", es);
1731                 m->set_spot (@$);
1732                 $$ = m->self_scm ();
1733         }
1734         ;
1735
1736 chord_body:
1737         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1738         {
1739                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1740         }
1741         ;
1742
1743 chord_body_elements:
1744         /* empty */             { $$ = SCM_EOL; }
1745         | chord_body_elements chord_body_element {
1746                 $$ = scm_cons ($2, $1);
1747         }
1748         ;
1749
1750 chord_body_element:
1751         pitch exclamations questions octave_check post_events
1752         {
1753                 int q = $3;
1754                 int ex = $2;
1755                 SCM check = $4;
1756                 SCM post = $5;
1757
1758                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1759                 n->set_property ("pitch", $1);
1760                 if (q % 2)
1761                         n->set_property ("cautionary", SCM_BOOL_T);
1762                 if (ex % 2 || q % 2)
1763                         n->set_property ("force-accidental", SCM_BOOL_T);
1764
1765                 if (scm_is_pair (post)) {
1766                         SCM arts = scm_reverse_x (post, SCM_EOL);
1767                         n->set_property ("articulations", arts);
1768                 }
1769                 if (scm_is_number (check))
1770                 {
1771                         int q = scm_to_int (check);
1772                         n->set_property ("absolute-octave", scm_from_int (q-1));
1773                 }
1774
1775                 $$ = n->unprotect ();
1776         }
1777         | DRUM_PITCH post_events {
1778                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1779                 n->set_property ("drum-type", $1);
1780
1781                 if (scm_is_pair ($2)) {
1782                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1783                         n->set_property ("articulations", arts);
1784                 }
1785                 $$ = n->unprotect ();
1786         }
1787         | music_function_chord_body
1788         ;
1789
1790 /* We can't accept a music argument, not even a closed one,
1791  * immediately before chord_body_elements, otherwise a function \fun
1792  * with a signature of two music arguments can't be sorted out
1793  * properly in a construct like
1794  * <\fun { c } \fun { c } c>
1795  * The second call could be interpreted either as a chord constituent
1796  * or a music expression.
1797  */
1798
1799 music_function_chord_body_arglist:
1800         function_arglist_bare
1801         | EXPECT_SCM music_function_chord_body_arglist embedded_scm_chord_body
1802         {
1803                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1804                                        $3, $2, $1);
1805         }
1806         ;
1807
1808 embedded_scm_chord_body:
1809         embedded_scm_bare_arg
1810         | SCM_FUNCTION music_function_chord_body_arglist {
1811                 $$ = MAKE_SYNTAX ("music-function", @$,
1812                                          $1, $2);
1813         }
1814         | chord_body_element
1815         | SKIPPED_SCM
1816         ;
1817
1818 music_function_chord_body:
1819         MUSIC_FUNCTION music_function_chord_body_arglist {
1820                 $$ = MAKE_SYNTAX ("music-function", @$,
1821                                          $1, $2);
1822         }
1823         ;
1824
1825 /* We could accept a closed music argument before the post events
1826  * indicated by a trailing argument list.  For symmetry with chord
1827  * bodies and in order to avoid too tricky and complex behavior, we
1828  * refrain from doing so.
1829  */
1830 music_function_event_arglist:
1831         function_arglist_bare
1832         | EXPECT_SCM music_function_event_arglist embedded_scm_event
1833         {
1834                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1835                                        $3, $2, $1);
1836         }
1837         ;
1838
1839 embedded_scm_event:
1840         embedded_scm_bare_arg
1841         | SCM_FUNCTION music_function_event_arglist {
1842                 $$ = MAKE_SYNTAX ("music-function", @$,
1843                                          $1, $2);
1844         }
1845         | post_event
1846         | SKIPPED_SCM
1847         ;
1848
1849 music_function_event:
1850         MUSIC_FUNCTION music_function_event_arglist {
1851                 $$ = MAKE_SYNTAX ("music-function", @$,
1852                                          $1, $2);
1853         }
1854         ;
1855
1856 event_function_event:
1857         EVENT_FUNCTION music_function_event_arglist {
1858                 $$ = MAKE_SYNTAX ("music-function", @$,
1859                                          $1, $2);
1860         }
1861         ;
1862
1863 command_element:
1864         command_event {
1865                 $$ = $1;
1866         }
1867         | E_BRACKET_OPEN {
1868                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1869                 m->set_property ("span-direction", scm_from_int (START));
1870                 $$ = m->unprotect();
1871         }
1872         | E_BRACKET_CLOSE {
1873                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1874                 m->set_property ("span-direction", scm_from_int (STOP));
1875                 $$ = m->unprotect ();
1876         }
1877         | E_BACKSLASH {
1878                 $$ = MAKE_SYNTAX ("voice-separator", @$);
1879         }
1880         | '|'      {
1881                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1882
1883                 Music *m = unsmob_music (pipe);
1884                 if (m)
1885                 {
1886                         m = m->clone ();
1887                         m->set_spot (@$);
1888                         $$ = m->unprotect ();
1889                 }
1890                 else
1891                         $$ = MAKE_SYNTAX ("bar-check", @$);
1892
1893         }
1894         | TIME_T fraction  {
1895                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1896
1897                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1898         }
1899         | MARK scalar {
1900                 $$ = MAKE_SYNTAX ("make-mark-set", @$, $2);
1901         }
1902         ;
1903
1904 command_event:
1905         E_TILDE {
1906                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1907         }
1908         | MARK DEFAULT  {
1909                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1910                 $$ = m->unprotect ();
1911         }
1912         | tempo_event {
1913                 $$ = $1;
1914         }
1915         | KEY DEFAULT {
1916                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1917                 $$ = key->unprotect ();
1918         }
1919         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1920
1921                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1922                 if (scm_ilength ($3) > 0)
1923                 {
1924                         key->set_property ("pitch-alist", $3);
1925                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1926                         key->transpose (* unsmob_pitch ($2));
1927                 } else {
1928                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1929                 }
1930
1931                 $$ = key->unprotect ();
1932         }
1933         ;
1934
1935
1936 post_events:
1937         /* empty */ {
1938                 $$ = SCM_EOL;
1939         }
1940         | post_events post_event {
1941                 unsmob_music ($2)->set_spot (@2);
1942                 $$ = scm_cons ($2, $$);
1943         }
1944         ;
1945
1946 post_event_nofinger:
1947         direction_less_event {
1948                 $$ = $1;
1949         }
1950         | script_dir music_function_event {
1951                 $$ = $2;
1952                 if ($1)
1953                 {
1954                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
1955                 }
1956         }
1957         | HYPHEN {
1958                 if (!PARSER->lexer_->is_lyric_state ())
1959                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1960                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1961         }
1962         | EXTENDER {
1963                 if (!PARSER->lexer_->is_lyric_state ())
1964                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1965                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1966         }
1967         | script_dir direction_reqd_event {
1968                 if ($1)
1969                 {
1970                         Music *m = unsmob_music ($2);
1971                         m->set_property ("direction", scm_from_int ($1));
1972                 }
1973                 $$ = $2;
1974         }
1975         | script_dir direction_less_event {
1976                 if ($1)
1977                 {
1978                         Music *m = unsmob_music ($2);
1979                         m->set_property ("direction", scm_from_int ($1));
1980                 }
1981                 $$ = $2;
1982         }
1983         | string_number_event
1984         ;
1985
1986 post_event:
1987         post_event_nofinger
1988         | script_dir fingering {
1989                 if ($1)
1990                 {
1991                         Music *m = unsmob_music ($2);
1992                         m->set_property ("direction", scm_from_int ($1));
1993                 }
1994                 $$ = $2;
1995         }
1996         ;
1997
1998 string_number_event:
1999         E_UNSIGNED {
2000                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2001                 s->set_property ("string-number", scm_from_int ($1));
2002                 $$ = s->unprotect ();
2003         }
2004         ;
2005
2006 direction_less_char:
2007         '['  {
2008                 $$ = ly_symbol2scm ("bracketOpenSymbol");
2009         }
2010         | ']'  {
2011                 $$ = ly_symbol2scm ("bracketCloseSymbol");
2012         }
2013         | '~'  {
2014                 $$ = ly_symbol2scm ("tildeSymbol");
2015         }
2016         | '('  {
2017                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
2018         }
2019         | ')'  {
2020                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
2021         }
2022         | E_EXCLAMATION  {
2023                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
2024         }
2025         | E_OPEN  {
2026                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
2027         }
2028         | E_CLOSE  {
2029                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
2030         }
2031         | E_ANGLE_CLOSE  {
2032                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
2033         }
2034         | E_ANGLE_OPEN  {
2035                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
2036         }
2037         ;
2038
2039 direction_less_event:
2040         direction_less_char {
2041                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
2042                 Music *m = 0;
2043                 if (unsmob_music (predefd))
2044                 {
2045                         m = unsmob_music (predefd)->clone ();
2046                         m->set_spot (@$);
2047                 }
2048                 else
2049                 {
2050                         m = MY_MAKE_MUSIC ("Music", @$);
2051                 }
2052                 $$ = m->unprotect ();
2053         }
2054         | EVENT_IDENTIFIER      {
2055                 $$ = $1;
2056         }
2057         | tremolo_type  {
2058                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2059                a->set_property ("tremolo-type", scm_from_int ($1));
2060                $$ = a->unprotect ();
2061         }
2062         | event_function_event
2063         ;
2064
2065 direction_reqd_event:
2066         gen_text_def {
2067                 $$ = $1;
2068         }
2069         | script_abbreviation {
2070                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2071                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2072                 if (scm_is_string (s))
2073                         a->set_property ("articulation-type", s);
2074                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
2075                 $$ = a->unprotect ();
2076         }
2077         ;
2078
2079 octave_check:
2080         /**/ { $$ = SCM_EOL; }
2081         | '='  { $$ = scm_from_int (0); }
2082         | '=' sub_quotes { $$ = scm_from_int (-$2); }
2083         | '=' sup_quotes { $$ = scm_from_int ($2); }
2084         ;
2085
2086 sup_quotes:
2087         '\'' {
2088                 $$ = 1;
2089         }
2090         | sup_quotes '\'' {
2091                 $$ ++;
2092         }
2093         ;
2094
2095 sub_quotes:
2096         ',' {
2097                 $$ = 1;
2098         }
2099         | sub_quotes ',' {
2100                 $$++;
2101         }
2102         ;
2103
2104 steno_pitch:
2105         NOTENAME_PITCH  {
2106                 $$ = $1;
2107         }
2108         | NOTENAME_PITCH sup_quotes     {
2109                 Pitch p = *unsmob_pitch ($1);
2110                 p = p.transposed (Pitch ($2,0,0));
2111                 $$ = p.smobbed_copy ();
2112         }
2113         | NOTENAME_PITCH sub_quotes      {
2114                 Pitch p =* unsmob_pitch ($1);
2115                 p = p.transposed (Pitch (-$2,0,0));
2116                 $$ = p.smobbed_copy ();
2117         }
2118         ;
2119
2120 /*
2121 ugh. duplication
2122 */
2123
2124 steno_tonic_pitch:
2125         TONICNAME_PITCH {
2126                 $$ = $1;
2127         }
2128         | TONICNAME_PITCH sup_quotes    {
2129                 Pitch p = *unsmob_pitch ($1);
2130                 p = p.transposed (Pitch ($2,0,0));
2131                 $$ = p.smobbed_copy ();
2132         }
2133         | TONICNAME_PITCH sub_quotes     {
2134                 Pitch p = *unsmob_pitch ($1);
2135
2136                 p = p.transposed (Pitch (-$2,0,0));
2137                 $$ = p.smobbed_copy ();
2138         }
2139         ;
2140
2141 pitch:
2142         steno_pitch {
2143                 $$ = $1;
2144         }
2145         | PITCH_IDENTIFIER
2146         ;
2147
2148 pitch_also_in_chords:
2149         pitch
2150         | steno_tonic_pitch
2151         ;
2152
2153 gen_text_def:
2154         full_markup {
2155                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2156                 t->set_property ("text", $1);
2157                 $$ = t->unprotect ();
2158         }
2159         | string {
2160                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2161                 t->set_property ("text",
2162                         make_simple_markup ($1));
2163                 $$ = t->unprotect ();
2164         }
2165         ;
2166
2167 fingering:
2168         UNSIGNED {
2169                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2170                 t->set_property ("digit", scm_from_int ($1));
2171                 $$ = t->unprotect ();
2172         }
2173         ;
2174
2175 script_abbreviation:
2176         '^'             {
2177                 $$ = scm_from_locale_string ("Hat");
2178         }
2179         | '+'           {
2180                 $$ = scm_from_locale_string ("Plus");
2181         }
2182         | '-'           {
2183                 $$ = scm_from_locale_string ("Dash");
2184         }
2185         | '|'           {
2186                 $$ = scm_from_locale_string ("Bar");
2187         }
2188         | ANGLE_CLOSE   {
2189                 $$ = scm_from_locale_string ("Larger");
2190         }
2191         | '.'           {
2192                 $$ = scm_from_locale_string ("Dot");
2193         }
2194         | '_' {
2195                 $$ = scm_from_locale_string ("Underscore");
2196         }
2197         ;
2198
2199 script_dir:
2200         '_'     { $$ = DOWN; }
2201         | '^'   { $$ = UP; }
2202         | '-'   { $$ = CENTER; }
2203         ;
2204
2205 duration_length:
2206         multiplied_duration {
2207                 $$ = $1;
2208         }
2209         ;
2210
2211 optional_notemode_duration:
2212         {
2213                 Duration dd = PARSER->default_duration_;
2214                 $$ = dd.smobbed_copy ();
2215         }
2216         | multiplied_duration   {
2217                 $$ = $1;
2218                 PARSER->default_duration_ = *unsmob_duration ($$);
2219         }
2220         ;
2221
2222 steno_duration:
2223         bare_unsigned dots              {
2224                 int len = 0;
2225                 if (!is_duration ($1))
2226                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
2227                 else
2228                         len = intlog2 ($1);
2229
2230                 $$ = Duration (len, $2).smobbed_copy ();
2231         }
2232         | DURATION_IDENTIFIER dots      {
2233                 Duration *d = unsmob_duration ($1);
2234                 Duration k (d->duration_log (), d->dot_count () + $2);
2235                 k = k.compressed (d->factor ());
2236                 *d = k;
2237                 $$ = $1;
2238         }
2239         ;
2240
2241 multiplied_duration:
2242         steno_duration {
2243                 $$ = $1;
2244         }
2245         | multiplied_duration '*' bare_unsigned {
2246                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2247         }
2248         | multiplied_duration '*' FRACTION {
2249                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2250
2251                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2252         }
2253         ;
2254
2255 fraction:
2256         FRACTION { $$ = $1; }
2257         | UNSIGNED '/' UNSIGNED {
2258                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2259         }
2260         ;
2261
2262 dots:
2263         /* empty */     {
2264                 $$ = 0;
2265         }
2266         | dots '.' {
2267                 $$ ++;
2268         }
2269         ;
2270
2271 tremolo_type:
2272         ':'     {
2273                 $$ = 0;
2274         }
2275         | ':' bare_unsigned {
2276                 if (!is_duration ($2))
2277                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2278                 $$ = $2;
2279         }
2280         ;
2281
2282 bass_number:
2283         UNSIGNED {
2284                 $$ = scm_from_int ($1);
2285         }
2286         | STRING { $$ = $1; }
2287         | full_markup { $$ = $1; }
2288         ;
2289
2290 figured_bass_alteration:
2291         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2292         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2293         | '!'   { $$ = scm_from_int (0); }
2294         ;
2295
2296 bass_figure:
2297         FIGURE_SPACE {
2298                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2299                 $$ = bfr->unprotect ();
2300         }
2301         | bass_number  {
2302                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2303                 $$ = bfr->self_scm ();
2304
2305                 if (scm_is_number ($1))
2306                         bfr->set_property ("figure", $1);
2307                 else if (Text_interface::is_markup ($1))
2308                         bfr->set_property ("text", $1);
2309
2310                 bfr->unprotect ();
2311         }
2312         | bass_figure ']' {
2313                 $$ = $1;
2314                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2315         }
2316         | bass_figure figured_bass_alteration {
2317                 Music *m = unsmob_music ($1);
2318                 if (scm_to_double ($2)) {
2319                         SCM salter = m->get_property ("alteration");
2320                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2321                         m->set_property ("alteration",
2322                                          scm_sum (alter, $2));
2323                 } else {
2324                         m->set_property ("alteration", scm_from_int (0));
2325                 }
2326         }
2327         | bass_figure figured_bass_modification  {
2328                 Music *m = unsmob_music ($1);
2329                 if ($2 == ly_symbol2scm ("plus"))
2330                         {
2331                         m->set_property ("augmented", SCM_BOOL_T);
2332                         }
2333                 else if ($2 == ly_symbol2scm ("slash"))
2334                         {
2335                         m->set_property ("diminished", SCM_BOOL_T);
2336                         }
2337                 else if ($2 == ly_symbol2scm ("exclamation"))
2338                         {
2339                         m->set_property ("no-continuation", SCM_BOOL_T);
2340                         }
2341                 else if ($2 == ly_symbol2scm ("backslash"))
2342                         {
2343                         m->set_property ("augmented-slash", SCM_BOOL_T);
2344                         }
2345         }
2346         ;
2347
2348
2349 figured_bass_modification:
2350         E_PLUS          {
2351                 $$ = ly_symbol2scm ("plus");
2352         }
2353         | E_EXCLAMATION {
2354                 $$ = ly_symbol2scm ("exclamation");
2355         }
2356         | '/'           {
2357                 $$ = ly_symbol2scm ("slash");
2358         }
2359         | E_BACKSLASH {
2360                 $$ = ly_symbol2scm ("backslash");
2361         }
2362         ;
2363
2364 br_bass_figure:
2365         bass_figure {
2366                 $$ = $1;
2367         }
2368         | '[' bass_figure {
2369                 $$ = $2;
2370                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2371         }
2372         ;
2373
2374 figure_list:
2375         /**/            {
2376                 $$ = SCM_EOL;
2377         }
2378         | figure_list br_bass_figure {
2379                 $$ = scm_cons ($2, $1);
2380         }
2381         ;
2382
2383 figure_spec:
2384         FIGURE_OPEN figure_list FIGURE_CLOSE {
2385                 $$ = scm_reverse_x ($2, SCM_EOL);
2386         }
2387         ;
2388
2389
2390 optional_rest:
2391         /**/   { $$ = 0; }
2392         | REST { $$ = 1; }
2393         ;
2394
2395 simple_element:
2396         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2397                 if (!PARSER->lexer_->is_note_state ())
2398                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2399
2400                 Music *n = 0;
2401                 if ($6)
2402                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2403                 else
2404                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2405
2406                 n->set_property ("pitch", $1);
2407                 n->set_property ("duration", $5);
2408
2409                 if (scm_is_number ($4))
2410                 {
2411                         int q = scm_to_int ($4);
2412                         n->set_property ("absolute-octave", scm_from_int (q-1));
2413                 }
2414
2415                 if ($3 % 2)
2416                         n->set_property ("cautionary", SCM_BOOL_T);
2417                 if ($2 % 2 || $3 % 2)
2418                         n->set_property ("force-accidental", SCM_BOOL_T);
2419
2420                 $$ = n->unprotect ();
2421         }
2422         | DRUM_PITCH optional_notemode_duration {
2423                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2424                 n->set_property ("duration", $2);
2425                 n->set_property ("drum-type", $1);
2426
2427                 $$ = n->unprotect ();
2428         }
2429         | RESTNAME optional_notemode_duration           {
2430                 Music *ev = 0;
2431                 if (ly_scm2string ($1) == "s") {
2432                         /* Space */
2433                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2434                   }
2435                 else {
2436                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2437
2438                     }
2439                 ev->set_property ("duration", $2);
2440                 $$ = ev->unprotect ();
2441         }
2442         | lyric_element optional_notemode_duration      {
2443                 if (!PARSER->lexer_->is_lyric_state ())
2444                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2445
2446                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2447                 levent->set_property ("text", $1);
2448                 levent->set_property ("duration",$2);
2449                 $$= levent->unprotect ();
2450         }
2451         ;
2452
2453 simple_chord_elements:
2454         simple_element  {
2455                 $$ = scm_list_1 ($1);
2456         }
2457         | new_chord {
2458                 if (!PARSER->lexer_->is_chord_state ())
2459                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2460                 $$ = $1;
2461         }
2462         | figure_spec optional_notemode_duration {
2463                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2464                 {
2465                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2466                 }
2467                 $$ = $1;
2468         }
2469         ;
2470
2471 lyric_element:
2472         lyric_markup {
2473                 $$ = $1;
2474         }
2475         | LYRICS_STRING {
2476                 $$ = $1;
2477         }
2478         ;
2479
2480 new_chord:
2481         steno_tonic_pitch optional_notemode_duration   {
2482                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2483         }
2484         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2485                 SCM its = scm_reverse_x ($4, SCM_EOL);
2486                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2487         }
2488         ;
2489
2490 chord_items:
2491         /**/ {
2492                 $$ = SCM_EOL;
2493         }
2494         | chord_items chord_item {
2495                 $$ = scm_cons ($2, $$);
2496         }
2497         ;
2498
2499 chord_separator:
2500         CHORD_COLON {
2501                 $$ = ly_symbol2scm ("chord-colon");
2502         }
2503         | CHORD_CARET {
2504                 $$ = ly_symbol2scm ("chord-caret");
2505         }
2506         | CHORD_SLASH steno_tonic_pitch {
2507                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2508         }
2509         | CHORD_BASS steno_tonic_pitch {
2510                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2511         }
2512         ;
2513
2514 chord_item:
2515         chord_separator {
2516                 $$ = $1;
2517         }
2518         | step_numbers {
2519                 $$ = scm_reverse_x ($1, SCM_EOL);
2520         }
2521         | CHORD_MODIFIER  {
2522                 $$ = $1;
2523         }
2524         ;
2525
2526 step_numbers:
2527         step_number { $$ = scm_cons ($1, SCM_EOL); }
2528         | step_numbers '.' step_number {
2529                 $$ = scm_cons ($3, $$);
2530         }
2531         ;
2532
2533 step_number:
2534         bare_unsigned {
2535                 $$ = make_chord_step ($1, 0);
2536         }
2537         | bare_unsigned '+' {
2538                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2539         }
2540         | bare_unsigned CHORD_MINUS {
2541                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2542         }
2543         ;
2544
2545 tempo_range:
2546         bare_unsigned {
2547                 $$ = scm_from_int ($1);
2548         }
2549         | bare_unsigned '~' bare_unsigned {
2550                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2551         }
2552         ;
2553
2554 /*
2555         UTILITIES
2556
2557 TODO: should deprecate in favor of Scheme?
2558
2559  */
2560 number_expression:
2561         number_expression '+' number_term {
2562                 $$ = scm_sum ($1, $3);
2563         }
2564         | number_expression '-' number_term {
2565                 $$ = scm_difference ($1, $3);
2566         }
2567         | number_term
2568         ;
2569
2570 number_term:
2571         number_factor {
2572                 $$ = $1;
2573         }
2574         | number_factor '*' number_factor {
2575                 $$ = scm_product ($1, $3);
2576         }
2577         | number_factor '/' number_factor {
2578                 $$ = scm_divide ($1, $3);
2579         }
2580         ;
2581
2582 number_factor:
2583         '-'  number_factor { /* %prec UNARY_MINUS */
2584                 $$ = scm_difference ($2, SCM_UNDEFINED);
2585         }
2586         | bare_number
2587         ;
2588
2589
2590 bare_number:
2591         UNSIGNED        {
2592                 $$ = scm_from_int ($1);
2593         }
2594         | REAL          {
2595                 $$ = $1;
2596         }
2597         | NUMBER_IDENTIFIER             {
2598                 $$ = $1;
2599         }
2600         | REAL NUMBER_IDENTIFIER        {
2601                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2602         }
2603         | UNSIGNED NUMBER_IDENTIFIER    {
2604                 $$ = scm_from_double ($1 *scm_to_double ($2));
2605         }
2606         ;
2607
2608
2609 bare_unsigned:
2610         UNSIGNED {
2611                         $$ = $1;
2612         }
2613         ;
2614
2615 unsigned_number:
2616         bare_unsigned  { $$ = scm_from_int ($1); }
2617         | NUMBER_IDENTIFIER {
2618                 $$ = $1;
2619         }
2620         ;
2621
2622 exclamations:
2623                 { $$ = 0; }
2624         | exclamations '!'      { $$ ++; }
2625         ;
2626
2627 questions:
2628                 { $$ = 0; }
2629         | questions '?' { $$ ++; }
2630         ;
2631
2632 /*
2633 This should be done more dynamically if possible.
2634 */
2635
2636 lyric_markup:
2637         LYRIC_MARKUP_IDENTIFIER {
2638                 $$ = $1;
2639         }
2640         | LYRIC_MARKUP
2641                 { PARSER->lexer_->push_markup_state (); }
2642         markup_top {
2643                 $$ = $3;
2644                 PARSER->lexer_->pop_state ();
2645         }
2646         ;
2647
2648 full_markup_list:
2649         MARKUPLIST_IDENTIFIER {
2650                 $$ = $1;
2651         }
2652         | MARKUPLIST
2653                 { PARSER->lexer_->push_markup_state (); }
2654         markup_list {
2655                 $$ = $3;
2656                 PARSER->lexer_->pop_state ();
2657         }
2658         ;
2659
2660 full_markup:
2661         MARKUP_IDENTIFIER {
2662                 $$ = $1;
2663         }
2664         | MARKUP
2665                 { PARSER->lexer_->push_markup_state (); }
2666         markup_top {
2667                 $$ = $3;
2668                 PARSER->lexer_->pop_state ();
2669         }
2670         ;
2671
2672 markup_top:
2673         markup_list {
2674                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2675         }
2676         | markup_head_1_list simple_markup      {
2677                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2678         }
2679         | simple_markup {
2680                 $$ = $1;
2681         }
2682         ;
2683
2684 markup_list:
2685         MARKUPLIST_IDENTIFIER {
2686                 $$ = $1;
2687         }
2688         | markup_composed_list {
2689                 $$ = $1;
2690         }
2691         | markup_braced_list {
2692                 $$ = $1;
2693         }
2694         | markup_command_list {
2695                 $$ = scm_list_1 ($1);
2696         }
2697         ;
2698
2699 markup_composed_list:
2700         markup_head_1_list markup_braced_list {
2701                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2702
2703         }
2704         ;
2705
2706 markup_braced_list:
2707         '{' markup_braced_list_body '}' {
2708                 $$ = scm_reverse_x ($2, SCM_EOL);
2709         }
2710         ;
2711
2712 markup_braced_list_body:
2713         /* empty */     {  $$ = SCM_EOL; }
2714         | markup_braced_list_body markup {
2715                 $$ = scm_cons ($2, $1);
2716         }
2717         | markup_braced_list_body markup_list {
2718                 $$ = scm_reverse_x ($2, $1);
2719         }
2720         ;
2721
2722 markup_command_list:
2723         MARKUP_LIST_FUNCTION markup_command_list_arguments {
2724           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2725         }
2726         ;
2727
2728 markup_command_basic_arguments:
2729         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2730           $$ = scm_cons ($3, $2);
2731         }
2732         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
2733           $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED, $3, $2, $1);
2734         }
2735         | EXPECT_NO_MORE_ARGS {
2736           $$ = SCM_EOL;
2737         }
2738         ;
2739
2740 markup_command_list_arguments:
2741         markup_command_basic_arguments { $$ = $1; }
2742         | EXPECT_MARKUP markup_command_list_arguments markup {
2743           $$ = scm_cons ($3, $2);
2744         }
2745         ;
2746
2747 markup_head_1_item:
2748         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2749           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2750         }
2751         ;
2752
2753 markup_head_1_list:
2754         markup_head_1_item      {
2755                 $$ = scm_list_1 ($1);
2756         }
2757         | markup_head_1_list markup_head_1_item {
2758                 $$ = scm_cons ($2, $1);
2759         }
2760         ;
2761
2762 simple_markup:
2763         STRING {
2764                 $$ = make_simple_markup ($1);
2765         }
2766         | MARKUP_IDENTIFIER {
2767                 $$ = $1;
2768         }
2769         | LYRIC_MARKUP_IDENTIFIER {
2770                 $$ = $1;
2771         }
2772         | STRING_IDENTIFIER {
2773                 $$ = $1;
2774         }
2775         | SCORE {
2776                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2777                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2778         } '{' score_body '}' {
2779                 Score * sc = $4;
2780                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2781                 sc->unprotect ();
2782                 PARSER->lexer_->pop_state ();
2783         }
2784         | MARKUP_FUNCTION markup_command_basic_arguments {
2785                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2786         }
2787         ;
2788
2789 markup:
2790         markup_head_1_list simple_markup        {
2791                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2792                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2793         }
2794         | simple_markup {
2795                 $$ = $1;
2796         }
2797         ;
2798
2799 %%
2800
2801 void
2802 Lily_parser::set_yydebug (bool x)
2803 {
2804         yydebug = x;
2805 }
2806
2807 void
2808 Lily_parser::do_yyparse ()
2809 {
2810         yyparse ((void*)this);
2811 }
2812
2813
2814
2815
2816
2817 /*
2818
2819 It is a little strange to have this function in this file, but
2820 otherwise, we have to import music classes into the lexer.
2821
2822 */
2823 int
2824 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2825 {
2826         if (scm_is_string (sid)) {
2827                 *destination = sid;
2828                 return STRING_IDENTIFIER;
2829         } else if (unsmob_book (sid)) {
2830                 Book *book =  unsmob_book (sid)->clone ();
2831                 *destination = book->self_scm ();
2832                 book->unprotect ();
2833
2834                 return BOOK_IDENTIFIER;
2835         } else if (scm_is_number (sid)) {
2836                 *destination = sid;
2837                 return NUMBER_IDENTIFIER;
2838         } else if (unsmob_context_def (sid)) {
2839                 Context_def *def= unsmob_context_def (sid)->clone ();
2840
2841                 *destination = def->self_scm ();
2842                 def->unprotect ();
2843
2844                 return CONTEXT_DEF_IDENTIFIER;
2845         } else if (unsmob_context_mod (sid)) {
2846                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
2847
2848                 return CONTEXT_MOD_IDENTIFIER;
2849         } else if (unsmob_score (sid)) {
2850                 Score *score = new Score (*unsmob_score (sid));
2851                 *destination = score->self_scm ();
2852
2853                 score->unprotect ();
2854                 return SCORE_IDENTIFIER;
2855         } else if (Music *mus = unsmob_music (sid)) {
2856                 mus = mus->clone ();
2857                 *destination = mus->self_scm ();
2858                 unsmob_music (*destination)->
2859                         set_property ("origin", make_input (last_input_));
2860
2861                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2862                         != SCM_BOOL_F;
2863
2864                 mus->unprotect ();
2865                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2866         } else if (unsmob_pitch (sid)) {
2867                 *destination = unsmob_pitch (sid)->smobbed_copy ();
2868                 return PITCH_IDENTIFIER;
2869         } else if (unsmob_duration (sid)) {
2870                 *destination = unsmob_duration (sid)->smobbed_copy ();
2871                 return DURATION_IDENTIFIER;
2872         } else if (unsmob_output_def (sid)) {
2873                 Output_def *p = unsmob_output_def (sid);
2874                 p = p->clone ();
2875
2876                 *destination = p->self_scm ();
2877                 p->unprotect ();
2878                 return OUTPUT_DEF_IDENTIFIER;
2879         } else if (Text_interface::is_markup (sid)) {
2880                 *destination = sid;
2881                 if (is_lyric_state ())
2882                         return LYRIC_MARKUP_IDENTIFIER;
2883                 return MARKUP_IDENTIFIER;
2884         } else if (Text_interface::is_markup_list (sid)) {
2885                 *destination = sid;
2886                 return MARKUPLIST_IDENTIFIER;
2887         }
2888
2889         return -1;
2890 }
2891
2892 SCM
2893 get_next_unique_context_id ()
2894 {
2895         return scm_from_locale_string ("$uniqueContextId");
2896 }
2897
2898
2899 SCM
2900 get_next_unique_lyrics_context_id ()
2901 {
2902         static int new_context_count;
2903         char s[128];
2904         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2905         return scm_from_locale_string (s);
2906 }
2907
2908 SCM check_scheme_arg (Lily_parser *my_lily_parser, Input loc, SCM fallback,
2909                       SCM arg, SCM args, SCM pred)
2910 {
2911         SCM unwrap = SCM_UNDEFINED;
2912         if (scm_is_true (scm_call_1 (pred, arg)))
2913                 return scm_cons (arg, args);
2914         unwrap = try_unpack_lyrics (pred, arg);
2915         if (!SCM_UNBNDP (unwrap))
2916                 return scm_cons (unwrap, args);
2917         if (SCM_UNBNDP (fallback)) {
2918                 args = scm_cons (SCM_BOOL_F, args);
2919                 fallback = SCM_BOOL_F;
2920         } else {
2921                 args = scm_cons (loc_on_music (loc, fallback), args);
2922                 fallback = SCM_CDR (scm_last_pair (args));
2923         }
2924         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
2925         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred, arg);
2926         scm_set_cdr_x (scm_last_pair (args), fallback);
2927         return args;
2928 }
2929
2930 SCM loc_on_music (Input loc, SCM arg)
2931 {
2932         if (Music *m = unsmob_music (arg))
2933         {
2934                 m = m->clone ();
2935                 m->set_spot (loc);
2936                 return m->unprotect ();
2937         }
2938         return arg;
2939 }
2940
2941 bool
2942 is_regular_identifier (SCM id)
2943 {
2944   string str = ly_scm2string (id);
2945   char const *s = str.c_str ();
2946
2947   bool v = true;
2948 #if 0
2949   isalpha (*s);
2950   s++;
2951 #endif
2952   while (*s && v)
2953    {
2954         v = v && isalnum (*s);
2955         s++;
2956    }
2957   return v;
2958 }
2959
2960 Music *
2961 make_music_with_input (SCM name, Input where)
2962 {
2963        Music *m = make_music_by_name (name);
2964        m->set_spot (where);
2965        return m;
2966 }
2967
2968 SCM
2969 get_first_context_id (SCM type, Music *m)
2970 {
2971         SCM id = m->get_property ("context-id");
2972         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2973             && scm_is_string (m->get_property ("context-id"))
2974             && scm_c_string_length (id) > 0)
2975         {
2976                 return id;
2977         }
2978         return SCM_EOL;
2979 }
2980
2981 SCM
2982 make_simple_markup (SCM a)
2983 {
2984         return a;
2985 }
2986
2987 bool
2988 is_duration (int t)
2989 {
2990   return t && t == 1 << intlog2 (t);
2991 }
2992
2993 void
2994 set_music_properties (Music *p, SCM a)
2995 {
2996   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2997         p->set_property (scm_caar (k), scm_cdar (k));
2998 }
2999
3000
3001 SCM
3002 make_chord_step (int step, Rational alter)
3003 {
3004         if (step == 7)
3005                 alter += FLAT_ALTERATION;
3006
3007         while (step < 0)
3008                 step += 7;
3009         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3010         return m.smobbed_copy ();
3011 }
3012
3013
3014 SCM
3015 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
3016 {
3017         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3018         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
3019 }
3020
3021 SCM
3022 try_unpack_lyrics (SCM pred, SCM arg)
3023 {
3024         if (Music *m = unsmob_music (arg))
3025                 if (m->is_mus_type ("lyric-event")) {
3026                         SCM text = m->get_property ("text");
3027                         if (scm_is_true (scm_call_1 (pred, text)))
3028                                         return text;
3029                         }
3030         return SCM_UNDEFINED;
3031 }
3032
3033 /* Todo: actually also use apply iso. call too ...  */
3034 bool
3035 ly_input_procedure_p (SCM x)
3036 {
3037         return ly_is_procedure (x)
3038                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
3039 }
3040
3041 int
3042 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
3043 {
3044         Lily_parser *pars = (Lily_parser*) v;
3045         Lily_lexer *lex = pars->lexer_;
3046
3047         lex->lexval_ = (void*) s;
3048         lex->lexloc_ = loc;
3049         lex->prepare_for_next_token ();
3050         return lex->yylex ();
3051 }