lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "scm-option.hh"
  29 #include "context-def.hh"
  30 #include "lily-guile.hh"
  31 #include "misc.hh"
  32 #include "my-lily-lexer.hh"
  33 #include "paper-def.hh"
  34 #include "midi-def.hh"
  35 #include "main.hh"
  36 #include "file-path.hh"
  37 #include "warn.hh"
  38 #include "dimensions.hh"
  39 #include "my-lily-parser.hh"
  40 #include "score.hh"
  41 #include "input-file-results.hh"
  42 #include "input.hh"
  43 #include "lilypond-input-version.hh"
  44 #include "scm-hash.hh"
  45 #include "ly-module.hh"
  46 #include "music-sequence.hh"
  47 #include "input-smob.hh"
  48 #include "event.hh"
  49 #include "text-item.hh"
  50 #include "music-list.hh"
  51 #include "paper-book.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84
  85
  86 bool
  87 is_regular_identifier (SCM id)
  88 {
  89   String str = ly_scm2string (id);
  90   char const *s = str.to_str0 ();
  91
  92   bool v = true;
  93 #if 0
  94   isalpha (*s);
  95   s++;
  96 #endif
  97   while (*s && v)
  98    {
  99         v = v && isalnum (*s);
 100         s++;
 101    }
 102   return v;
 103 }
 104
 105 SCM
 106 make_simple_markup (SCM a)
 107 {
 108         SCM simple = ly_scheme_function ("simple-markup");
 109         SCM markup = scm_list_2 (simple, a);
 110 #if 0
 111         if (THIS->lexer_->encoding_ != "")
 112                 return scm_list_2
 113                         (scm_cons (ly_scheme_function ("encoding"),
 114                          scm_makfrom0str (THIS->lexer_->encoding_.to_str0 ())),
 115                         markup);
 116 #endif
 117 return markup;
 118 }
 119
 120
 121 bool
 122 is_is_duration (int t)
 123 {
 124   return t && t == 1 << intlog2 (t);
 125 }
 126
 127 void
 128 set_music_properties (Music *p, SCM a)
 129 {
 130   for (SCM k = a; ly_pair_p (k); k = ly_cdr (k))
 131         p->internal_set_property (ly_caar (k), ly_cdar (k));
 132 }
 133
 134 SCM
 135 make_chord_step (int step, int alter)
 136 {
 137         if (step == 7)
 138                 alter += FLAT;
 139
 140         while (step < 0)
 141                 step += 7;
 142         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 143         return m.smobbed_copy ();
 144 }
 145
 146
 147 SCM
 148 make_chord (SCM pitch, SCM dur, SCM modification_list)
 149 {
 150         SCM chord_ctor = ly_scheme_function ("construct-chord");
 151         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 152         scm_gc_protect_object (ch);
 153         return ch;
 154 }
 155
 156 /* Todo: actually also use apply iso. call too ...  */
 157 bool
 158 ly_input_procedure_p (SCM x)
 159 {
 160         return ly_procedure_p (x)
 161                 || (ly_pair_p (x) && ly_procedure_p (ly_car (x)));
 162 }
 163
 164 Music*
 165 set_property_music (SCM sym, SCM value)
 166 {
 167         Music *p = MY_MAKE_MUSIC ("PropertySet");
 168         p->set_property ("symbol", sym);
 169         p->set_property ("value", value);
 170         return p;
 171 }
 172
 173 %}
 174
 175 /* We use SCMs to do strings, because it saves us the trouble of
 176 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 177 of the parse stack onto the heap. */
 178
 179
 180 %union {
 181         String *string;
 182     Music *music;
 183     Score *score;
 184     Music_output_def *outputdef;
 185     SCM scm;
 186     int i;
 187 }
 188 %{
 189
 190 int
 191 yylex (YYSTYPE *s, void *v)
 192 {
 193         My_lily_parser *pars = (My_lily_parser*) v;
 194         My_lily_lexer *lex = pars->lexer_;
 195
 196         lex->lexval = (void*) s;
 197         lex->prepare_for_next_token ();
 198         return lex->yylex ();
 199 }
 200
 201
 202 %}
 203
 204 %expect 4
 205
 206 /*
 207   Four shift/reduce problems:
 208
 209 1.      foo = bar.
 210
 211         "bar" -> String -> Lyric -> Music -> music-assignment
 212
 213         "bar" -> String -> string-assignment
 214
 215
 216 Similar problem for
 217
 218 2. \markup identifier.
 219
 220 3. \markup { }
 221
 222 4.  \repeat
 223         \repeat .. \alternative
 224
 225
 226     \repeat { \repeat .. \alternative }
 227
 228 or
 229
 230     \repeat { \repeat } \alternative
 231
 232 )
 233
 234 --hwn
 235
 236  */
 237
 238
 239 %pure_parser
 240
 241 %token ACCEPTS
 242 %token ADDLYRICS
 243 %token ADDQUOTE
 244 %token NEWADDLYRICS
 245 %token ALIAS
 246 %token ALTERNATIVE
 247 %token APPLY
 248 %token APPLYCONTEXT
 249 %token APPLYOUTPUT
 250 %token AUTOCHANGE
 251 %token BAR
 252 %token BREATHE
 253 %token CHANGE
 254 %token CHORDMODIFIERS
 255 %token CHORDS
 256 %token LESSLESS
 257 %token MOREMORE
 258 %token CLEF
 259 %token COMMANDSPANREQUEST
 260 %token CONSISTS
 261 %token CONSISTSEND
 262 %token CONTEXT
 263 %token DEFAULT
 264 %token DENIES
 265 %token DESCRIPTION
 266 %token EXTENDER
 267 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 268 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 269 %token GRACE
 270 %token ACCIACCATURA
 271 %token APPOGGIATURA
 272 %token GROBDESCRIPTIONS
 273 %token HEADER
 274 %token HYPHEN
 275 %token INVALID
 276 %token KEY
 277 %token LYRICS
 278 %token MARK
 279 %token MIDI
 280 %token MULTI_MEASURE_REST
 281 %token NAME
 282 %token NEWCONTEXT
 283 %token NOTES
 284 %token OCTAVE
 285 %token ONCE
 286 %token OVERRIDE SET REVERT
 287 %token PAPER
 288 %token PARTCOMBINE
 289 %token PARTIAL
 290 %token QUOTE
 291 %token RELATIVE
 292 %token REMOVE
 293 %token REPEAT
 294 %token REST
 295 %token SCM_T
 296 %token SCORE
 297 %token SEQUENTIAL
 298 %token SIMULTANEOUS
 299 %token SKIP
 300 %token SPANREQUEST
 301 %token TAG
 302 %token TEMPO
 303 %token TIMES
 304 %token TIME_T
 305 %token TRANSPOSE
 306 %token TRANSPOSITION
 307 %token TYPE
 308 %token UNSET
 309 %token WITH
 310
 311 /* escaped */
 312 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 313 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 314 %token E_BACKSLASH
 315 %token <i> E_UNSIGNED
 316 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 317 %token FIGURE_SPACE
 318
 319 %type <i>       exclamations questions dots optional_rest
 320 %type <i>        bass_mod
 321 %type <scm>     grace_head
 322 %type <scm>     oct_check
 323 %type <scm>     context_mod_list
 324 %type <scm>     lyric_element
 325 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 326 %token <i>      DIGIT
 327 %token <scm>    NOTENAME_PITCH
 328 %token <scm>    TONICNAME_PITCH
 329 %token <scm>    CHORDMODIFIER_PITCH
 330 %token <scm>    DURATION_IDENTIFIER
 331 %token <scm>    FRACTION
 332 %token <id>     IDENTIFIER
 333 %token DRUMS
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    CHORD_MODIFIER
 336 %token <scm>    SCORE_IDENTIFIER
 337 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 338 %token <scm>    NUMBER_IDENTIFIER
 339 %token <scm>    EVENT_IDENTIFIER
 340 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 341 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 342 %token <scm>    RESTNAME
 343 %token <scm>    STRING
 344 %token <scm>    SCM_T
 345 %token <i>      UNSIGNED
 346 %token <scm>   REAL
 347
 348 %token MARKUP
 349 %token <scm> MARKUP_HEAD_MARKUP0
 350 %token <scm> MARKUP_HEAD_EMPTY
 351 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0
 353 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1
 355 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 357
 358 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 359 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 360
 361 %type <outputdef> output_def
 362 %type <scm>     lilypond_header lilypond_header_body
 363 %type <music>   open_event close_event
 364 %type <i>       sub_quotes sup_quotes
 365 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 366 %type <music>   Repeated_music
 367 %type <scm>     Alternative_music
 368 %type <i>       tremolo_type
 369 %type <i>       bare_int  bare_unsigned
 370 %type <i>       script_dir
 371 %type <scm>     identifier_init
 372
 373 %type <music> note_chord_element chord_body chord_body_element
 374 %type <scm>  chord_body_elements
 375 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 376
 377 %type <scm>   post_events
 378 %type <music> gen_text_def direction_less_event direction_reqd_event
 379 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 380 %type <scm>    steno_tonic_pitch
 381 %type <scm>     duration_length fraction
 382
 383 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 384
 385 %type <scm>  embedded_scm scalar
 386 %type <music>   Music Sequential_music Simultaneous_music
 387 %type <music>   relative_music re_rhythmed_music
 388 %type <music>   music_property_def context_change
 389 %type <scm> context_prop_spec
 390 %type <scm> Music_list
 391 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 392 %type <outputdef>  music_output_def_body music_output_def_head
 393 %type <music>   post_event tagged_post_event
 394 %type <music> command_req
 395 %type <music> string_number_event
 396 %type <scm>     string bare_number number_expression number_term number_factor
 397 %type <score>   score_block score_body
 398
 399 %type <scm>     context_def_spec_block context_def_spec_body
 400 %type <music>   tempo_event
 401 %type <scm>     script_abbreviation
 402
 403
 404
 405 %left '-' '+'
 406
 407 /* We don't assign precedence to / and *, because we might need varied
 408 prec levels in different prods */
 409
 410 %left UNARY_MINUS
 411
 412 %%
 413
 414 lilypond:       /* empty */
 415         | lilypond toplevel_expression {}
 416         | lilypond assignment  { }
 417         | lilypond error {
 418                 THIS->error_level_ = 1;
 419         }
 420         | lilypond INVALID      {
 421                 THIS->error_level_ = 1;
 422         }
 423         ;
 424
 425 toplevel_expression:
 426         lilypond_header {
 427                 THIS->input_file_->header_ = $1;
 428         }
 429         | add_quote {
 430         }
 431         | score_block {
 432                 Score *sc = $1;
 433
 434                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 435
 436                 Path p = split_path (THIS->output_basename_);
 437                 int *c = &THIS->input_file_->score_count_;
 438                 if (*c)
 439                         {
 440                         p.base += "-" + to_string (*c);
 441                         }
 442
 443                 (*c)++;
 444                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 445
 446                 for (int i = 0; i < sc->defs_.size (); i++)
 447                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 448
 449                 if (sc->defs_.is_empty ())
 450                 {
 451                    Music_output_def *id = unsmob_music_output_def
 452                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 453                    id = id ? id->clone () : new Paper_def;
 454                    default_rendering (sc->music_, id->self_scm (), head,
 455                         outname);
 456                    scm_gc_unprotect_object (id->self_scm ());
 457                 }
 458                 scm_gc_unprotect_object (sc->self_scm ());
 459         }
 460         | output_def {
 461                 SCM id = SCM_EOL;
 462                 if (dynamic_cast<Paper_def*> ($1))
 463                         id = scm_makfrom0str ("$defaultpaper");
 464                 else if (dynamic_cast<Midi_def*> ($1))
 465                         id = scm_makfrom0str ("$defaultmidi");
 466                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 467                 scm_gc_unprotect_object ($1->self_scm ());
 468         }
 469         ;
 470
 471
 472 embedded_scm:
 473         SCM_T
 474         | SCM_IDENTIFIER
 475         ;
 476
 477
 478
 479
 480 lilypond_header_body:
 481         {
 482                 $$ = ly_make_anonymous_module ();
 483                 THIS->lexer_->add_scope ($$);
 484         }
 485         | lilypond_header_body assignment  {
 486
 487         }
 488         ;
 489
 490 lilypond_header:
 491         HEADER '{' lilypond_header_body '}'     {
 492                 $$ = THIS->lexer_->remove_scope ();
 493         }
 494         ;
 495
 496
 497 /*
 498         DECLARATIONS
 499 */
 500 assignment:
 501         STRING {
 502                 THIS->push_spot ();
 503         }
 504         /* cont */ '=' identifier_init  {
 505
 506         /*
 507                 Should find generic way of associating input with objects.
 508         */
 509                 Input ip = THIS->pop_spot ();
 510
 511                 if (! is_regular_identifier ($1))
 512                 {
 513                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 514                 }
 515
 516                 THIS->lexer_->set_identifier ($1, $4);
 517
 518 /*
 519  TODO: devise standard for protection in parser.
 520
 521   The parser stack lives on the C-stack, which means that
 522 all objects can be unprotected as soon as they're here.
 523
 524 */
 525         }
 526         | embedded_scm { }
 527         ;
 528
 529
 530 identifier_init:
 531         score_block {
 532                 $$ = $1->self_scm ();
 533                 scm_gc_unprotect_object ($$);
 534         }
 535         | full_markup {
 536                 $$ = $1;
 537         }
 538         | output_def {
 539                 $$ = $1->self_scm ();
 540                 scm_gc_unprotect_object ($$);
 541         }
 542         | context_def_spec_block {
 543                 $$ = $1;
 544         }
 545         | Music  {
 546                 $$ = $1->self_scm ();
 547                 scm_gc_unprotect_object ($$);
 548         }
 549         | post_event {
 550                 $$ = $1->self_scm ();
 551                 scm_gc_unprotect_object ($$);
 552         }
 553         | number_expression {
 554                 $$ = $1;
 555         }
 556         | string {
 557                 $$ = $1;
 558         }
 559         | embedded_scm  {
 560                 $$ = $1;
 561         }
 562         ;
 563
 564 context_def_spec_block:
 565         CONTEXT '{' context_def_spec_body '}'
 566                 {
 567                 $$ = $3;
 568         }
 569         ;
 570
 571 context_def_spec_body:
 572         /**/ {
 573                 $$ = Context_def::make_scm ();
 574                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 575         }
 576         | CONTEXT_DEF_IDENTIFIER        {
 577                 $$ = $1;
 578                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 579         }
 580         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 581                 Context_def*td = unsmob_context_def ($$);
 582
 583                 for (SCM p = $3; ly_pair_p (p); p = ly_cdr (p)) {
 584                         SCM tag = ly_caar (p);
 585
 586                         /* TODO: should make new tag "grob-definition" ? */
 587                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 588                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 589                 }
 590         }
 591         | context_def_spec_body context_mod {
 592                 unsmob_context_def ($$)->add_context_mod ($2);
 593         }
 594         ;
 595
 596 /*
 597         SCORE
 598 */
 599 score_block:
 600         SCORE {
 601                 THIS->push_spot ();
 602         }
 603         /*cont*/ '{' score_body '}'     {
 604                 THIS->pop_spot ();
 605                 $$ = $4;
 606
 607         }
 608         ;
 609
 610 score_body:
 611         Music   {
 612                 $$ = new Score;
 613
 614                 $$->set_spot (THIS->here_input ());
 615                 SCM m = $1->self_scm ();
 616                 scm_gc_unprotect_object (m);
 617
 618                 /*
 619                         guh.
 620                 */
 621                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 622                 for (; ly_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 623                         m = scm_call_1 (ly_car (check_funcs), m);
 624                 $$->music_ = m;
 625
 626         }
 627         | SCORE_IDENTIFIER {
 628                 $$ = new Score ( *unsmob_score ($1));
 629                 $$->set_spot (THIS->here_input ());
 630         }
 631         | score_body lilypond_header    {
 632                 $$->header_ = $2;
 633         }
 634         | score_body output_def {
 635                 $$->defs_.push ($2);
 636                 scm_gc_unprotect_object ($2->self_scm ());
 637         }
 638         | score_body error {
 639
 640         }
 641         ;
 642
 643
 644 /*
 645         MIDI
 646 */
 647 output_def:
 648         music_output_def_body '}' {
 649                 $$ = $1;
 650                 THIS-> lexer_-> remove_scope ();
 651         }
 652         ;
 653
 654 music_output_def_head:
 655         MIDI    {
 656                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 657
 658
 659                 Midi_def *p = 0;
 660                 if (id)
 661                         p = dynamic_cast<Midi_def*> (id->clone ());
 662                 else
 663                         p = new Midi_def;
 664
 665                 $$ = p;
 666                 THIS->lexer_->add_scope (p->scope_);
 667         }
 668         | PAPER         {
 669                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 670                   Paper_def *p = 0;
 671                 if (id)
 672                         p = dynamic_cast<Paper_def*> (id->clone ());
 673                 else
 674                         p = new Paper_def;
 675
 676                 THIS->lexer_->add_scope (p->scope_);
 677                 $$ = p;
 678         }
 679         ;
 680
 681
 682 music_output_def_body:
 683         music_output_def_head '{' {
 684                 $$ = $1;
 685                 $$->input_origin_. set_spot (THIS->here_input ());
 686
 687         }
 688         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 689                 scm_gc_unprotect_object ($1->self_scm ());
 690                 Music_output_def *o = unsmob_music_output_def ($3);
 691                 o->input_origin_.set_spot (THIS->here_input ());
 692                 $$ = o;
 693                 THIS->lexer_->remove_scope ();
 694                 THIS->lexer_->add_scope (o->scope_);
 695         }
 696         | music_output_def_body assignment  {
 697
 698         }
 699         | music_output_def_body context_def_spec_block  {
 700                 $$->assign_context_def ($2);
 701         }
 702         | music_output_def_body tempo_event  {
 703                 /*
 704                         junk this ? there already is tempo stuff in
 705                         music.
 706                 */
 707                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 708                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 709                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 710                 if (md)
 711                         md->set_tempo (d->get_length (), m);
 712                 scm_gc_unprotect_object ($2->self_scm ());
 713         }
 714         | music_output_def_body error {
 715
 716         }
 717         ;
 718
 719 tempo_event:
 720         TEMPO steno_duration '=' bare_unsigned  {
 721                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 722                 $$->set_property ("tempo-unit", $2);
 723                 $$->set_property ("metronome-count", scm_int2num ( $4));
 724         }
 725         ;
 726
 727 /*
 728 The representation of a  list is the
 729
 730   (LIST . LAST-CONS)
 731
 732  to have  efficient append.
 733 */
 734 Music_list:
 735         /* empty */ {
 736                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 737         }
 738         | Music_list Music {
 739                 SCM s = $$;
 740                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 741                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 742                 if (ly_pair_p (ly_cdr (s)))
 743                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 744                 else
 745                         scm_set_car_x (s, c); /* set first cons */
 746                 scm_set_cdr_x (s, c);  /* remember last cell */
 747         }
 748         | Music_list error {
 749         }
 750         ;
 751
 752
 753 Music:
 754         Simple_music
 755         | Composite_music
 756         ;
 757
 758 Alternative_music:
 759         /* empty */ {
 760                 $$ = SCM_EOL;
 761         }
 762         | ALTERNATIVE '{' Music_list '}' {
 763                 $$ = $3;
 764         }
 765         ;
 766
 767 Repeated_music:
 768         REPEAT string bare_unsigned Music Alternative_music
 769         {
 770                 Music *beg = $4;
 771                 int times = $3;
 772                 SCM alts = ly_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 773                 if (times < scm_ilength (alts)) {
 774                   unsmob_music (ly_car (alts))
 775                     ->origin ()->warning (
 776                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 777                   alts = ly_truncate_list (times, alts);
 778                 }
 779
 780
 781                 SCM proc = ly_scheme_function ("make-repeated-music");
 782
 783                 SCM mus = scm_call_1 (proc, $2);
 784                 scm_gc_protect_object (mus); // UGH.
 785                 Music *r = unsmob_music (mus);
 786                 if (beg)
 787                         {
 788                         r-> set_property ("element", beg->self_scm ());
 789                         scm_gc_unprotect_object (beg->self_scm ());
 790                         }
 791                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 792
 793                 r-> set_property ("elements",alts);
 794                 if (ly_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 795                         /*
 796                         TODO: move this code to Scheme.
 797                         */
 798
 799                         /*
 800                         we can not get durations and other stuff correct down the line, so we have to
 801                         add to the duration log here.
 802                         */
 803                         SCM func = ly_scheme_function ("shift-duration-log");
 804
 805                         int dots = ($3 % 3) ? 0 : 1;
 806                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 807
 808                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 809
 810                         if (seq) {
 811                                 int list_len = scm_ilength (seq->music_list ());
 812                                 if (list_len != 2)
 813                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 814                                 shift -= 1;
 815                                 r->compress (Moment (Rational (1, list_len)));
 816                                 }
 817                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 818
 819                 }
 820                 r->set_spot (*$4->origin ());
 821
 822                 $$ = r;
 823         }
 824         ;
 825
 826 Sequential_music:
 827         SEQUENTIAL '{' Music_list '}'           {
 828                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 829                 $$->set_property ("elements", ly_car ($3));
 830                 $$->set_spot (THIS->here_input ());
 831         }
 832         | '{' Music_list '}'            {
 833                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 834                 $$->set_property ("elements", ly_car ($2));
 835                 $$->set_spot (THIS->here_input ());
 836         }
 837         ;
 838
 839 Simultaneous_music:
 840         SIMULTANEOUS '{' Music_list '}'{
 841                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 842                 $$->set_property ("elements", ly_car ($3));
 843                 $$->set_spot (THIS->here_input ());
 844
 845         }
 846         | simul_open Music_list simul_close     {
 847                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 848                 $$->set_property ("elements", ly_car ($2));
 849                 $$->set_spot (THIS->here_input ());
 850         }
 851         ;
 852
 853 Simple_music:
 854         event_chord             { $$ = $1; }
 855         | APPLYOUTPUT embedded_scm {
 856                 if (!ly_input_procedure_p ($2))
 857                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 858                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 859                 $$->set_property ("procedure", $2);
 860                 $$->set_spot (THIS->here_input ());
 861         }
 862         | APPLYCONTEXT embedded_scm {
 863                 if (!ly_input_procedure_p ($2))
 864                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 865                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 866                 $$->set_property ("procedure", $2);
 867                 $$->set_spot (THIS->here_input ());
 868         }
 869         | MUSIC_IDENTIFIER {
 870                 $$ = unsmob_music ($1);
 871         }
 872         | music_property_def
 873         | context_change
 874         ;
 875
 876
 877 optional_context_mod:
 878         /**/ { $$ = SCM_EOL; }
 879         | WITH '{' context_mod_list '}'  { $$ = $3; }
 880         ;
 881
 882 grace_head:
 883         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 884         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 885         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 886         ;
 887
 888 context_mod_list:
 889         /* */  { $$ = SCM_EOL; }
 890         | context_mod_list context_mod  {
 891                  $$ = scm_cons ($2, $1);
 892         }
 893         ;
 894
 895 Composite_music:
 896         AUTOCHANGE Music        {
 897                 SCM proc = ly_scheme_function ("make-autochange-music");
 898
 899                 SCM res = scm_call_1 (proc, $2->self_scm ());
 900                 scm_gc_unprotect_object ($2->self_scm ());
 901                 $$ = unsmob_music (res);
 902                 scm_gc_protect_object (res);
 903                 $$->set_spot (THIS->here_input ());
 904         }
 905         | PARTCOMBINE Music Music {
 906                 SCM proc = ly_scheme_function ("make-part-combine-music");
 907
 908                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 909                         $3->self_scm (), SCM_UNDEFINED));
 910                 scm_gc_unprotect_object ($3->self_scm ());
 911                 scm_gc_unprotect_object ($2->self_scm ());
 912                 $$ = unsmob_music (res);
 913                 scm_gc_protect_object (res);
 914                 $$->set_spot (THIS->here_input ());
 915         }
 916         | grace_head Music {
 917 #if 1
 918         /*
 919                 The other version is for easier debugging  of
 920                 Sequential_music_iterator in combination with grace notes.
 921         */
 922
 923 /*
 924
 925 TODO: should distinguish between both grace types in the
 926 basic music objects too, since the meaning is different.
 927
 928 */
 929
 930                 String start_str = "start" + ly_scm2string ($1) + "Music";
 931                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 932
 933                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 934                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 935
 936                 Music *startm = unsmob_music (start);
 937                 Music *stopm = unsmob_music (stop);
 938
 939                 SCM ms = SCM_EOL;
 940                 if (stopm) {
 941                         stopm = stopm->clone ();
 942                         ms = scm_cons (stopm->self_scm (), ms);
 943                         scm_gc_unprotect_object (stopm->self_scm ());
 944                 }
 945                 ms = scm_cons ($2->self_scm (), ms);
 946                 scm_gc_unprotect_object ($2->self_scm ());
 947                 if (startm) {
 948                         startm = startm->clone ();
 949                         ms = scm_cons (startm->self_scm (), ms);
 950                         scm_gc_unprotect_object (startm->self_scm ());
 951                 }
 952
 953                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 954                 seq->set_property ("elements", ms);
 955
 956
 957                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 958                 $$->set_property ("element", seq->self_scm ());
 959                 scm_gc_unprotect_object (seq->self_scm ());
 960 #else
 961                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 962                 $$->set_property ("element", $2->self_scm ());
 963                 scm_gc_unprotect_object ($2->self_scm ());
 964 #endif
 965         }
 966         | CONTEXT string '=' string optional_context_mod Music {
 967                 $$ = context_spec_music ($2, $4, $6, $5);
 968
 969         }
 970         | CONTEXT STRING optional_context_mod Music {
 971                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 972         }
 973         | NEWCONTEXT string optional_context_mod Music {
 974                 $$ = context_spec_music ($2, get_next_unique_context (),
 975                                          $4, $3);
 976         }
 977
 978         | TIMES {
 979                 THIS->push_spot ();
 980         }
 981         /* CONTINUED */
 982                 fraction Music
 983
 984         {
 985                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
 986                 Music *mp = $4;
 987
 988                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 989                 $$->set_spot (THIS->pop_spot ());
 990
 991                 $$->set_property ("element", mp->self_scm ());
 992                 scm_gc_unprotect_object (mp->self_scm ());
 993                 $$->set_property ("numerator", scm_int2num (n));
 994                 $$->set_property ("denominator", scm_int2num (d));
 995                 $$->compress (Moment (Rational (n,d)));
 996
 997         }
 998         | Repeated_music                { $$ = $1; }
 999         | Simultaneous_music            { $$ = $1; }
1000         | Sequential_music              { $$ = $1; }
1001         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1002                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1003                 Music *p = $4;
1004                 Pitch from = *unsmob_pitch ($2);
1005                 Pitch to = *unsmob_pitch ($3);
1006
1007                 p->transpose (interval (from, to));
1008                 $$->set_property ("element", p->self_scm ());
1009                 scm_gc_unprotect_object (p->self_scm ());
1010         }
1011         | APPLY embedded_scm Music  {
1012                 if (!ly_input_procedure_p ($2))
1013                         {
1014                         THIS->parser_error (_ ("\\apply takes function argument"));
1015                         $$ = $3;
1016                         }
1017                 else
1018                         {
1019                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1020                         Music *m = unsmob_music (ret);
1021                         if (!m) {
1022                                 THIS->parser_error ("\\apply must return a Music");
1023                                 m = MY_MAKE_MUSIC ("Music");
1024                                 }
1025                         $$ = m;
1026                         }
1027         }
1028         | NOTES
1029                 {
1030                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1031                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1032         }
1033         Music
1034                 { $$ = $3;
1035                   THIS->lexer_->pop_state ();
1036                 }
1037         | DRUMS
1038                 {
1039                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1040                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1041         }
1042         Music
1043                 { $$ = $3;
1044                   THIS->lexer_->pop_state ();
1045                 }
1046         | FIGURES
1047                 { THIS->lexer_->push_figuredbass_state (); }
1048         Music
1049                 {
1050                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1051                   chm->set_property ("element", $3->self_scm ());
1052                   $$ = chm;
1053                   scm_gc_unprotect_object ($3->self_scm ());
1054
1055                   THIS->lexer_->pop_state ();
1056         }
1057         | CHORDS {
1058                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1059                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1060                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1061                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1062
1063         } Music {
1064                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1065                   chm->set_property ("element", $3->self_scm ());
1066                   scm_gc_unprotect_object ($3->self_scm ());
1067                   $$ = chm;
1068
1069                   THIS->lexer_->pop_state ();
1070         }
1071         | LYRICS
1072                 { THIS->lexer_->push_lyric_state (); }
1073         Music
1074                 {
1075                   $$ = $3;
1076                   THIS->lexer_->pop_state ();
1077         }
1078         | relative_music        { $$ = $1; }
1079         | re_rhythmed_music     { $$ = $1; }
1080         | TAG embedded_scm Music {
1081                 tag_music ($3, $2, THIS->here_input ());
1082                 $$ = $3;
1083         }
1084         ;
1085
1086 relative_music:
1087         RELATIVE absolute_pitch Music {
1088                 Music *p = $3;
1089                 Pitch pit = *unsmob_pitch ($2);
1090                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1091
1092                 $$->set_property ("element", p->self_scm ());
1093                 scm_gc_unprotect_object (p->self_scm ());
1094
1095
1096                 Pitch retpitch = p->to_relative_octave (pit);
1097                 if (lily_1_8_relative)
1098                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1099         }
1100         ;
1101
1102 re_rhythmed_music:
1103         ADDLYRICS Music Music {
1104         Music *l = MY_MAKE_MUSIC ("LyricCombineMusic");
1105           l->set_property ("elements", scm_listify ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1106           scm_gc_unprotect_object ($3->self_scm ());
1107           scm_gc_unprotect_object ($2->self_scm ());
1108           $$ = l;
1109         }
1110         | NEWADDLYRICS string Music {
1111           Music *l = MY_MAKE_MUSIC ("NewLyricCombineMusic");
1112           l->set_property ("element", $3->self_scm ());
1113           scm_gc_unprotect_object ($3->self_scm ());
1114           $$ = l;
1115           l->set_property ("associated-context", $2);
1116         }
1117         ;
1118
1119 context_change:
1120         CHANGE STRING '=' STRING  {
1121                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1122                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1123                 t-> set_property ("change-to-id", $4);
1124
1125                 $$ = t;
1126                 $$->set_spot (THIS->here_input ());
1127         }
1128         ;
1129
1130 property_operation:
1131         STRING '='  scalar {
1132                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1133                         scm_string_to_symbol ($1), $3);
1134         }
1135         | UNSET STRING {
1136                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1137                         scm_string_to_symbol ($2));
1138         }
1139         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1140                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1141                         scm_string_to_symbol ($2), $3, $5);
1142         }
1143         | REVERT STRING embedded_scm {
1144                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1145                         scm_string_to_symbol ($2), $3);
1146         }
1147         ;
1148
1149 context_def_mod:
1150         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1151         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1152         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1153
1154         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1155         | DENIES { $$ = ly_symbol2scm ("denies"); }
1156
1157         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1158         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1159         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1160         | NAME { $$ = ly_symbol2scm ("context-name"); }
1161         ;
1162
1163 context_mod:
1164         property_operation { $$ = $1; }
1165         | context_def_mod STRING {
1166                 $$ = scm_list_2 ($1, $2);
1167         }
1168         ;
1169
1170 context_prop_spec:
1171         STRING  {
1172                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1173         }
1174         | STRING '.' STRING {
1175                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1176         }
1177         ;
1178
1179 music_property_def:
1180         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1181                 $$ = property_op_to_music (scm_list_4 (
1182                         ly_symbol2scm ("poppush"),
1183                         ly_cadr ($2),
1184                         $3, $5));
1185                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1186         }
1187         | REVERT context_prop_spec embedded_scm {
1188                 $$ = property_op_to_music (scm_list_3 (
1189                         ly_symbol2scm ("pop"),
1190                         ly_cadr ($2),
1191                         $3));
1192
1193                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1194         }
1195         | SET context_prop_spec '=' scalar {
1196                 $$ = property_op_to_music (scm_list_3 (
1197                         ly_symbol2scm ("assign"),
1198                         ly_cadr ($2),
1199                         $4));
1200                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1201         }
1202         | UNSET context_prop_spec {
1203                 $$ = property_op_to_music (scm_list_2 (
1204                         ly_symbol2scm ("unset"),
1205                         ly_cadr ($2)));
1206                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1207         }
1208         | ONCE music_property_def {
1209                 SCM e = $2->get_property ("element");
1210                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1211                 $$ = $2;
1212
1213         }
1214         ;
1215
1216
1217
1218 scalar:
1219         string          { $$ = $1; }
1220         | bare_int      { $$ = scm_int2num ($1); }
1221         | embedded_scm  { $$ = $1; }
1222         | full_markup {  $$ = $1; }
1223         | DIGIT { $$ = scm_int2num ($1); }
1224         ;
1225
1226 /*
1227 This is a trick:
1228
1229 Adding pre_events to the simple_element
1230 makes the choice between
1231
1232   string:  STRING
1233
1234 and
1235
1236   simple_element: STRING
1237
1238 a single shift/reduction conflict.
1239
1240 nevertheless, this is not very clean, and we should find a different
1241 solution.
1242
1243 */
1244 pre_events: {
1245                 THIS->push_spot ();
1246         }
1247         ;
1248
1249 event_chord:
1250         pre_events simple_element post_events   {
1251                 SCM elts = $2-> get_property ("elements");
1252
1253                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1254
1255                 $2->set_property ("elements", elts);
1256                 $$ = $2;
1257         }
1258         | command_element
1259         | note_chord_element
1260         ;
1261
1262
1263 note_chord_element:
1264         chord_body optional_notemode_duration post_events
1265         {
1266                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1267                 SCM es = $1->get_property ("elements");
1268                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1269
1270                 for (SCM s = es; ly_pair_p (s); s = ly_cdr (s))
1271                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1272                 es = ly_append2 (es, postevs);
1273
1274                 $1-> set_property ("elements", es);
1275                 $$ = $1;
1276         }
1277         ;
1278
1279 chord_open: '<'
1280         ;
1281
1282 chord_close: '>'
1283         ;
1284
1285 simul_open: LESSLESS
1286         ;
1287
1288 simul_close: MOREMORE
1289         ;
1290
1291 chord_body:
1292         chord_open chord_body_elements chord_close
1293         {
1294                 $$ = MY_MAKE_MUSIC ("EventChord");
1295                 $$->set_property ("elements",
1296                         scm_reverse_x ($2, SCM_EOL));
1297         }
1298         ;
1299
1300 chord_body_elements:
1301         /* empty */             { $$ = SCM_EOL; }
1302         | chord_body_elements chord_body_element {
1303                 $$ = scm_cons ($2->self_scm (), $1);
1304                 scm_gc_unprotect_object ($2->self_scm ());
1305         }
1306         ;
1307
1308 chord_body_element:
1309         pitch exclamations questions post_events
1310         {
1311                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1312                 n->set_property ("pitch", $1);
1313                 if ($3 % 2)
1314                         n->set_property ("cautionary", SCM_BOOL_T);
1315                 if ($2 % 2 || $3 % 2)
1316                         n->set_property ("force-accidental", SCM_BOOL_T);
1317
1318                 if (ly_pair_p ($4)) {
1319                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1320                         n->set_property ("articulations", arts);
1321                 }
1322                 $$ = n;
1323         }
1324         | DRUM_PITCH post_events {
1325                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1326                 n->set_property ("duration", $2);
1327                 n->set_property ("drum-type", $1);
1328                 n->set_spot (THIS->here_input ());
1329
1330                 if (ly_pair_p ($2)) {
1331                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1332                         n->set_property ("articulations", arts);
1333                 }
1334                 $$ = n;
1335         }
1336         ;
1337
1338 add_quote:
1339         ADDQUOTE string Music {
1340                 SCM adder = ly_scheme_function ("add-quotable");
1341
1342                 scm_call_2 (adder, $2, $3->self_scm ());
1343                 scm_gc_unprotect_object ($3->self_scm ());
1344         }
1345         ;
1346
1347 command_element:
1348         command_req {
1349                 $$ = MY_MAKE_MUSIC ("EventChord");
1350                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1351                 scm_gc_unprotect_object ($1->self_scm ());
1352
1353                 $$-> set_spot (THIS->here_input ());
1354                 $1-> set_spot (THIS->here_input ());
1355         }
1356         | SKIP duration_length {
1357                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1358                 skip->set_property ("duration", $2);
1359
1360                 $$ = skip;
1361         }
1362         | QUOTE STRING duration_length {
1363                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1364                 SCM evs = SCM_EOL;
1365                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1366                 {
1367                         SCM key = $2; // use symbol?
1368                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1369                 }
1370                 Music *quote = 0;
1371                 if (ly_vector_p (evs))
1372                 {
1373                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1374                         quote->set_property ("duration", $3);
1375                         quote->set_property ("quoted-events", evs);
1376                 } else {
1377                         THIS->here_input ().warning (_f ("Can\'t find music"));
1378                         quote = MY_MAKE_MUSIC ("Event");
1379                 }
1380                 quote->set_spot (THIS->here_input ());
1381                 $$ = quote;
1382         }
1383         | OCTAVE { THIS->push_spot (); }
1384           pitch {
1385                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1386                 $$ = l;
1387                 $$->set_spot (THIS->pop_spot ());
1388                 $$->set_property ("pitch", $3);
1389         }
1390         | E_LEFTSQUARE {
1391                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1392                 l->set_property ("span-direction", scm_int2num (START));
1393                 l->set_spot (THIS->here_input ());
1394
1395                 $$ = MY_MAKE_MUSIC ("EventChord");
1396                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1397                 scm_gc_unprotect_object (l->self_scm ());
1398                 $$->set_spot (THIS->here_input ());
1399         }
1400         | E_RIGHTSQUARE {
1401                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1402                 l->set_property ("span-direction", scm_int2num (STOP));
1403                 l->set_spot (THIS->here_input ());
1404
1405                 $$ = MY_MAKE_MUSIC ("EventChord");
1406                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1407                 $$->set_spot (THIS->here_input ());
1408                 scm_gc_unprotect_object (l->self_scm ());
1409         }
1410         | E_BACKSLASH {
1411                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1412                 $$->set_spot (THIS->here_input ());
1413         }
1414         | '|'      {
1415                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1416
1417                 if (Music * m = unsmob_music (pipe))
1418                         $$ = m->clone ();
1419                 else
1420                         $$ = MY_MAKE_MUSIC ("BarCheck");
1421
1422                 $$->set_spot (THIS->here_input ());
1423         }
1424         | TRANSPOSITION pitch {
1425                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1426                                         $2);
1427                 $$->set_spot (THIS-> here_input ());
1428                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1429                         $$, SCM_EOL);
1430         }
1431         | BAR STRING                    {
1432                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1433
1434                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1435                                         t, SCM_EOL);
1436                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1437                 $$->set_spot (THIS->here_input ());
1438                 t->set_spot (THIS->here_input ());
1439         }
1440         | PARTIAL duration_length       {
1441                 Moment m = - unsmob_duration ($2)->get_length ();
1442                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1443                 p->set_spot (THIS->here_input ());
1444                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1445                                         p, SCM_EOL);
1446                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1447                                         p, SCM_EOL);
1448                 $$ = p;
1449         }
1450         | CLEF STRING  {
1451                 SCM proc = ly_scheme_function ("make-clef-set");
1452
1453                 SCM result = scm_call_1 (proc, $2);
1454                 scm_gc_protect_object (result);
1455                 $$ = unsmob_music (result);
1456         }
1457         | TIME_T fraction  {
1458                 SCM proc= ly_scheme_function ("make-time-signature-set");
1459
1460                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1461                 scm_gc_protect_object (result);
1462                 $$ = unsmob_music (result);
1463         }
1464         | MARK scalar {
1465                 SCM proc = ly_scheme_function ("make-mark-set");
1466
1467                 SCM result = scm_call_1 (proc, $2);
1468                 scm_gc_protect_object (result);
1469                 $$ = unsmob_music (result);
1470         }
1471         ;
1472
1473 command_req:
1474         BREATHE {
1475                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1476         }
1477         | E_TILDE {
1478                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1479         }
1480         | MARK DEFAULT  {
1481                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1482                 $$ = m;
1483         }
1484         | tempo_event {
1485                 $$ = $1;
1486         }
1487         | KEY DEFAULT {
1488                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1489                 $$ = key;
1490         }
1491         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1492
1493                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1494                 if (scm_ilength ($3) > 0)
1495                 {
1496                         key->set_property ("pitch-alist", $3);
1497                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1498                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1499                 } else {
1500                         THIS->parser_error (_ ("Second argument must be pitch list."));
1501                 }
1502
1503                 $$ = key;
1504         }
1505         ;
1506
1507 post_events:
1508         /* empty */ {
1509                 $$ = SCM_EOL;
1510         }
1511         | post_events post_event {
1512                 $2->set_spot (THIS->here_input ());
1513                 $$ = scm_cons ($2->self_scm (), $$);
1514                 scm_gc_unprotect_object ($2->self_scm ());
1515         }
1516         | post_events tagged_post_event {
1517                 $2 -> set_spot (THIS->here_input ());
1518                 $$ = scm_cons ($2->self_scm (), $$);
1519                 scm_gc_unprotect_object ($2->self_scm ());
1520         }
1521         ;
1522
1523
1524 tagged_post_event:
1525         '-' TAG embedded_scm post_event {
1526                 tag_music ($4, $3, THIS->here_input ());
1527                 $$ = $4;
1528         }
1529         ;
1530
1531 post_event:
1532         direction_less_event {
1533                 $$ = $1;
1534         }
1535         | HYPHEN {
1536                 if (!THIS->lexer_->is_lyric_state ())
1537                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1538                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1539         }
1540         | EXTENDER {
1541                 if (!THIS->lexer_->is_lyric_state ())
1542                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1543                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1544         }
1545         | script_dir direction_reqd_event {
1546                 if ($1)
1547                         $2->set_property ("direction", scm_int2num ($1));
1548                 $$ = $2;
1549         }
1550         | script_dir direction_less_event {
1551                 if ($1)
1552                         $2->set_property ("direction", scm_int2num ($1));
1553                 $$ = $2;
1554         }
1555         | string_number_event
1556         ;
1557
1558 string_number_event:
1559         E_UNSIGNED {
1560                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1561                 s->set_property ("string-number", scm_int2num ($1));
1562                 s->set_spot (THIS->here_input ());
1563                 $$ = s;
1564         }
1565         ;
1566
1567
1568 direction_less_event:
1569         '['  {
1570
1571
1572 /*
1573
1574 TODO: should take all these defs out of the parser, adn make use
1575 configurable, i.e.
1576
1577
1578 (set-articulation '~ "trill")
1579
1580 */
1581                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1582                 m->set_spot (THIS->here_input ());
1583                 m->set_property ("span-direction", scm_int2num (START));
1584                 $$ = m;
1585         }
1586         | ']'  {
1587                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1588                 m->set_spot (THIS->here_input ());
1589                 m->set_property ("span-direction", scm_int2num (STOP));
1590                 $$ = m;
1591         }
1592         | '~' {
1593                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1594                 m->set_spot (THIS->here_input ());
1595                 $$ = m;
1596         }
1597         | close_event {
1598                 $$ = $1;
1599                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1600                         scm_int2num (START));
1601         }
1602         | open_event {
1603                 $$ = $1;
1604                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1605                         scm_int2num (STOP));
1606         }
1607         | EVENT_IDENTIFIER      {
1608                 $$ = unsmob_music ($1);
1609         }
1610         | tremolo_type  {
1611                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1612                a->set_spot (THIS->here_input ());
1613                a->set_property ("tremolo-type", scm_int2num ($1));
1614                $$ = a;
1615         }
1616         ;
1617
1618 direction_reqd_event:
1619         gen_text_def {
1620                 $$ = $1;
1621         }
1622         | script_abbreviation {
1623                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1624                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1625                 if (ly_string_p (s))
1626                         a->set_property ("articulation-type", s);
1627                 else THIS->parser_error (_ ("Expecting string as script definition"));
1628                 $$ = a;
1629         }
1630         ;
1631
1632 oct_check:
1633         /**/ { $$ = SCM_EOL; }
1634         | '='  { $$ = scm_int2num (0); }
1635         | '=' sub_quotes { $$ = scm_int2num ($2); }
1636         | '=' sup_quotes { $$ = scm_int2num ($2); }
1637         ;
1638
1639 sup_quotes:
1640         '\'' {
1641                 $$ = 1;
1642         }
1643         | sup_quotes '\'' {
1644                 $$ ++;
1645         }
1646         ;
1647
1648 sub_quotes:
1649         ',' {
1650                 $$ = 1;
1651         }
1652         | sub_quotes ',' {
1653                 $$++;
1654         }
1655         ;
1656
1657 steno_pitch:
1658         NOTENAME_PITCH  {
1659                 $$ = $1;
1660         }
1661         | NOTENAME_PITCH sup_quotes     {
1662                 Pitch p = *unsmob_pitch ($1);
1663                 p = p.transposed (Pitch ($2,0,0));
1664                 $$ = p.smobbed_copy ();
1665         }
1666         | NOTENAME_PITCH sub_quotes      {
1667                 Pitch p =* unsmob_pitch ($1);
1668                 p = p.transposed (Pitch (-$2,0,0));
1669                 $$ = p.smobbed_copy ();
1670         }
1671         ;
1672
1673 /*
1674 ugh. duplication
1675 */
1676
1677 steno_tonic_pitch:
1678         TONICNAME_PITCH {
1679                 $$ = $1;
1680         }
1681         | TONICNAME_PITCH sup_quotes    {
1682                 Pitch p = *unsmob_pitch ($1);
1683                 p = p.transposed (Pitch ($2,0,0));
1684                 $$ = p.smobbed_copy ();
1685         }
1686         | TONICNAME_PITCH sub_quotes     {
1687                 Pitch p =* unsmob_pitch ($1);
1688
1689                 p = p.transposed (Pitch (-$2,0,0));
1690                 $$ = p.smobbed_copy ();
1691         }
1692         ;
1693
1694 pitch:
1695         steno_pitch {
1696                 $$ = $1;
1697         }
1698         ;
1699
1700 pitch_also_in_chords:
1701         pitch
1702         | steno_tonic_pitch
1703         ;
1704
1705 close_event:
1706         '('     {
1707                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1708                 $$ = s;
1709                 s->set_spot (THIS->here_input ());
1710         }
1711         | E_OPEN        {
1712                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1713                 $$ = s;
1714                 s->set_spot (THIS->here_input ());
1715         }
1716         | E_SMALLER {
1717                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1718                 $$ = s;
1719                 s->set_spot (THIS->here_input ());
1720         }
1721         | E_BIGGER {
1722                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1723                 $$ = s;
1724                 s->set_spot (THIS->here_input ());
1725         }
1726         ;
1727
1728
1729 open_event:
1730         E_EXCLAMATION   {
1731                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1732                 s->set_spot (THIS->here_input ());
1733
1734                 $$ = s;
1735         }
1736         | ')'   {
1737                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1738                 $$ = s;
1739                 s->set_spot (THIS->here_input ());
1740
1741         }
1742         | E_CLOSE       {
1743                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1744                 $$ = s;
1745                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1746                 s->set_spot (THIS->here_input ());
1747         }
1748         ;
1749
1750 gen_text_def:
1751         full_markup {
1752                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1753                 t->set_property ("text", $1);
1754                 t->set_spot (THIS->here_input ());
1755                 $$ = t;
1756         }
1757         | string {
1758                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1759                 t->set_property ("text", make_simple_markup ($1));
1760                 t->set_spot (THIS->here_input ());
1761                 $$ = t;
1762
1763         }
1764         | DIGIT {
1765                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1766                 t->set_property ("digit", scm_int2num ($1));
1767                 t->set_spot (THIS->here_input ());
1768                 $$ = t;
1769         }
1770         ;
1771
1772 script_abbreviation:
1773         '^'             {
1774                 $$ = scm_makfrom0str ("Hat");
1775         }
1776         | '+'           {
1777                 $$ = scm_makfrom0str ("Plus");
1778         }
1779         | '-'           {
1780                 $$ = scm_makfrom0str ("Dash");
1781         }
1782         | '|'           {
1783                 $$ = scm_makfrom0str ("Bar");
1784         }
1785         | '>'           {
1786                 $$ = scm_makfrom0str ("Larger");
1787         }
1788         | '.'           {
1789                 $$ = scm_makfrom0str ("Dot");
1790         }
1791         | '_' {
1792                 $$ = scm_makfrom0str ("Underscore");
1793         }
1794         ;
1795
1796 script_dir:
1797         '_'     { $$ = DOWN; }
1798         | '^'   { $$ = UP; }
1799         | '-'   { $$ = CENTER; }
1800         ;
1801
1802
1803 absolute_pitch:
1804         steno_pitch     {
1805                 $$ = $1;
1806         }
1807         ;
1808
1809 duration_length:
1810         multiplied_duration {
1811                 $$ = $1;
1812         }
1813         ;
1814
1815 optional_notemode_duration:
1816         {
1817                 Duration dd = THIS->default_duration_;
1818                 $$ = dd.smobbed_copy ();
1819
1820                 THIS->beam_check ($$);
1821         }
1822         | multiplied_duration   {
1823                 $$ = $1;
1824                 THIS->default_duration_ = *unsmob_duration ($$);
1825
1826                 THIS->beam_check ($$);
1827         }
1828         ;
1829
1830 steno_duration:
1831         bare_unsigned dots              {
1832                 int len = 0;
1833                 if (!is_is_duration ($1))
1834                         THIS->parser_error (_f ("not a duration: %d", $1));
1835                 else
1836                         len = intlog2 ($1);
1837
1838                 $$ = Duration (len, $2).smobbed_copy ();
1839         }
1840         | DURATION_IDENTIFIER dots      {
1841                 Duration *d = unsmob_duration ($1);
1842                 Duration k (d->duration_log (), d->dot_count () + $2);
1843                 *d = k;
1844                 $$ = $1;
1845         }
1846         ;
1847
1848
1849
1850
1851 multiplied_duration:
1852         steno_duration {
1853                 $$ = $1;
1854         }
1855         | multiplied_duration '*' bare_unsigned {
1856                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1857         }
1858         | multiplied_duration '*' FRACTION {
1859                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1860
1861                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1862         }
1863         ;
1864
1865 fraction:
1866         FRACTION { $$ = $1; }
1867         | UNSIGNED '/' UNSIGNED {
1868                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
1869         }
1870         ;
1871
1872 dots:
1873         /* empty */     {
1874                 $$ = 0;
1875         }
1876         | dots '.' {
1877                 $$ ++;
1878         }
1879         ;
1880
1881
1882 tremolo_type:
1883         ':'     {
1884                 $$ = 0;
1885         }
1886         | ':' bare_unsigned {
1887                 if (!is_is_duration ($2))
1888                         THIS->parser_error (_f ("not a duration: %d", $2));
1889                 $$ = $2;
1890         }
1891         ;
1892
1893
1894
1895 /*****************************************************************
1896                 BASS FIGURES
1897 *****************************************************************/
1898 bass_number:
1899         DIGIT   {
1900                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1901         }
1902         | UNSIGNED {
1903                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1904         }
1905         | STRING { $$ = $1; }
1906         ;
1907
1908 bass_mod:
1909         '-'     { $$ = -2; }
1910         | '+'   { $$ = 2; }
1911         | '!'   { $$ = 0; }
1912         ;
1913
1914 bass_figure:
1915         FIGURE_SPACE {
1916                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1917                 $$ = bfr->self_scm ();
1918                 scm_gc_unprotect_object ($$);
1919         }
1920         | bass_number  {
1921                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1922                 $$ = bfr->self_scm ();
1923
1924                 bfr->set_property ("figure", $1);
1925
1926                 scm_gc_unprotect_object ($$);
1927         }
1928         | bass_figure bass_mod {
1929                 Music *m = unsmob_music ($1);
1930                 if ($2) {
1931                         SCM salter = m->get_property ("alteration");
1932                         int alter = ly_number_p (salter) ? ly_scm2int (salter) : 0;
1933                         m->set_property ("alteration",
1934                                 scm_int2num (alter + $2));
1935                 } else {
1936                         m->set_property ("alteration", scm_int2num (0));
1937                 }
1938         }
1939         ;
1940
1941 br_bass_figure:
1942         '[' bass_figure {
1943                 $$ = $2;
1944                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1945         }
1946         | bass_figure   {
1947                 $$ = $1;
1948         }
1949         | br_bass_figure ']' {
1950                 $$ = $1;
1951                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1952         }
1953         ;
1954
1955 figure_list:
1956         /**/            {
1957                 $$ = SCM_EOL;
1958         }
1959         | figure_list br_bass_figure {
1960                 $$ = scm_cons ($2, $1);
1961         }
1962         ;
1963
1964 figure_spec:
1965         FIGURE_OPEN figure_list FIGURE_CLOSE {
1966                 Music *m = MY_MAKE_MUSIC ("EventChord");
1967                 $2 = scm_reverse_x ($2, SCM_EOL);
1968                 m->set_property ("elements", $2);
1969                 $$ = m->self_scm ();
1970         }
1971         ;
1972
1973
1974 optional_rest:
1975         /**/   { $$ = 0; }
1976         | REST { $$ = 1; }
1977         ;
1978
1979 simple_element:
1980         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1981
1982                 Input i = THIS->pop_spot ();
1983                 if (!THIS->lexer_->is_note_state ())
1984                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1985
1986                 Music *n = 0;
1987                 if ($6)
1988                         n = MY_MAKE_MUSIC ("RestEvent");
1989                 else
1990                         n = MY_MAKE_MUSIC ("NoteEvent");
1991
1992                 n->set_property ("pitch", $1);
1993                 n->set_property ("duration", $5);
1994
1995                 if (ly_number_p ($4))
1996                 {
1997                         int q = ly_scm2int ($4);
1998                         n->set_property ("absolute-octave", scm_int2num (q-1));
1999                 }
2000
2001                 if ($3 % 2)
2002                         n->set_property ("cautionary", SCM_BOOL_T);
2003                 if ($2 % 2 || $3 % 2)
2004                         n->set_property ("force-accidental", SCM_BOOL_T);
2005
2006                 Music *v = MY_MAKE_MUSIC ("EventChord");
2007                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2008                 scm_gc_unprotect_object (n->self_scm ());
2009
2010                 v->set_spot (i);
2011                 n->set_spot (i);
2012                 $$ = v;
2013         }
2014         | DRUM_PITCH optional_notemode_duration {
2015                 Input i = THIS->pop_spot ();
2016
2017                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2018                 n->set_property ("duration", $2);
2019                 n->set_property ("drum-type", $1);
2020
2021                 Music *v = MY_MAKE_MUSIC ("EventChord");
2022                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2023                 scm_gc_unprotect_object (n->self_scm ());
2024                 v->set_spot (i);
2025                 n->set_spot (i);
2026                 $$ = v;
2027
2028         }
2029         | figure_spec optional_notemode_duration {
2030                 Music *m = unsmob_music ($1);
2031                 Input i = THIS->pop_spot ();
2032                 m->set_spot (i);
2033                 for (SCM s = m->get_property ("elements"); ly_pair_p (s); s = ly_cdr (s))
2034                 {
2035                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2036                 }
2037                 $$ = m;
2038         }
2039         | RESTNAME optional_notemode_duration           {
2040
2041                 Input i = THIS->pop_spot ();
2042                 Music *ev = 0;
2043                 if (ly_scm2string ($1) == "s") {
2044                         /* Space */
2045                         ev = MY_MAKE_MUSIC ("SkipEvent");
2046                   }
2047                 else {
2048                         ev = MY_MAKE_MUSIC ("RestEvent");
2049
2050                     }
2051                 ev->set_property ("duration", $2);
2052                 ev->set_spot (i);
2053                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2054                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2055                 velt->set_spot (i);
2056
2057                 scm_gc_unprotect_object (ev->self_scm ());
2058
2059                 $$ = velt;
2060         }
2061         | MULTI_MEASURE_REST optional_notemode_duration         {
2062                 THIS->pop_spot ();
2063
2064                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2065                 SCM mus = scm_call_2 (proc, $2,
2066                         make_input (THIS->here_input ()));
2067                 scm_gc_protect_object (mus);
2068                 $$ = unsmob_music (mus);
2069         }
2070
2071         | lyric_element optional_notemode_duration      {
2072                 Input i = THIS->pop_spot ();
2073                 if (!THIS->lexer_->is_lyric_state ())
2074                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2075
2076                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2077                 lreq->set_property ("text", $1);
2078                 lreq->set_property ("duration",$2);
2079                 lreq->set_spot (i);
2080                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2081                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2082
2083                 $$= velt;
2084         }
2085         | new_chord {
2086                 THIS->pop_spot ();
2087
2088                 if (!THIS->lexer_->is_chord_state ())
2089                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2090                 $$ = unsmob_music ($1);
2091         }
2092         ;
2093
2094 lyric_element:
2095         full_markup { $$ = $1; }
2096         | STRING { $$ = $1; }
2097         ;
2098
2099 new_chord:
2100         steno_tonic_pitch optional_notemode_duration   {
2101                 $$ = make_chord ($1, $2, SCM_EOL);
2102         }
2103         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2104                 SCM its = scm_reverse_x ($4, SCM_EOL);
2105                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2106         }
2107         ;
2108
2109 chord_items:
2110         /**/ {
2111                 $$ = SCM_EOL;
2112         }
2113         | chord_items chord_item {
2114                 $$ = scm_cons ($2, $$);
2115         }
2116         ;
2117
2118 chord_separator:
2119         CHORD_COLON {
2120                 $$ = ly_symbol2scm ("chord-colon");
2121         }
2122         | CHORD_CARET {
2123                 $$ = ly_symbol2scm ("chord-caret");
2124         }
2125         | CHORD_SLASH steno_tonic_pitch {
2126                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2127         }
2128         | CHORD_BASS steno_tonic_pitch {
2129                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2130         }
2131         ;
2132
2133 chord_item:
2134         chord_separator {
2135                 $$ = $1;
2136         }
2137         | step_numbers {
2138                 $$ = scm_reverse_x ($1, SCM_EOL);
2139         }
2140         | CHORD_MODIFIER  {
2141                 $$ = $1;
2142         }
2143         ;
2144
2145 step_numbers:
2146         step_number { $$ = scm_cons ($1, SCM_EOL); }
2147         | step_numbers '.' step_number {
2148                 $$ = scm_cons ($3, $$);
2149         }
2150         ;
2151
2152 step_number:
2153         bare_unsigned {
2154                 $$ = make_chord_step ($1, 0);
2155         }
2156         | bare_unsigned '+' {
2157                 $$ = make_chord_step ($1, SHARP);
2158         }
2159         | bare_unsigned CHORD_MINUS {
2160                 $$ = make_chord_step ($1, FLAT);
2161         }
2162         ;
2163
2164 /*
2165         UTILITIES
2166
2167 TODO: should deprecate in favor of Scheme?
2168
2169  */
2170 number_expression:
2171         number_expression '+' number_term {
2172                 $$ = scm_sum ($1, $3);
2173         }
2174         | number_expression '-' number_term {
2175                 $$ = scm_difference ($1, $3);
2176         }
2177         | number_term
2178         ;
2179
2180 number_term:
2181         number_factor {
2182                 $$ = $1;
2183         }
2184         | number_factor '*' number_factor {
2185                 $$ = scm_product ($1, $3);
2186         }
2187         | number_factor '/' number_factor {
2188                 $$ = scm_divide ($1, $3);
2189         }
2190         ;
2191
2192 number_factor:
2193         '-'  number_factor { /* %prec UNARY_MINUS */
2194                 $$ = scm_difference ($2, SCM_UNDEFINED);
2195         }
2196         | bare_number
2197         ;
2198
2199
2200 bare_number:
2201         UNSIGNED        {
2202                 $$ = scm_int2num ($1);
2203         }
2204         | REAL          {
2205                 $$ = $1;
2206         }
2207         | NUMBER_IDENTIFIER             {
2208                 $$ = $1;
2209         }
2210         | REAL NUMBER_IDENTIFIER        {
2211                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2212         }
2213         | UNSIGNED NUMBER_IDENTIFIER    {
2214                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2215         }
2216         ;
2217
2218
2219 bare_unsigned:
2220         UNSIGNED {
2221                         $$ = $1;
2222         }
2223         | DIGIT {
2224                 $$ = $1;
2225         }
2226         ;
2227
2228 bare_int:
2229         bare_number {
2230                 if (scm_integer_p ($1) == SCM_BOOL_T)
2231                 {
2232                         int k = ly_scm2int ($1);
2233                         $$ = k;
2234                 } else
2235                 {
2236                         THIS->parser_error (_ ("need integer number arg"));
2237                         $$ = 0;
2238                 }
2239         }
2240         | '-' bare_int {
2241                 $$ = -$2;
2242         }
2243         ;
2244
2245
2246 string:
2247         STRING          {
2248                 $$ = $1;
2249         }
2250         | STRING_IDENTIFIER     {
2251                 $$ = $1;
2252         }
2253         | string '+' string {
2254                 $$ = scm_string_append (scm_list_2 ($1, $3));
2255         }
2256         ;
2257
2258
2259 exclamations:
2260                 { $$ = 0; }
2261         | exclamations '!'      { $$ ++; }
2262         ;
2263
2264 questions:
2265                 { $$ = 0; }
2266         | questions '?' { $$ ++; }
2267         ;
2268
2269
2270
2271 full_markup:
2272         MARKUP_IDENTIFIER {
2273                 $$ = $1;
2274         }
2275         | MARKUP
2276                 { THIS->lexer_->push_markup_state (); }
2277         markup
2278                 { $$ = $3;
2279                   THIS->lexer_->pop_state ();
2280                 }
2281         ;
2282
2283
2284 /*
2285 This should be done more dynamically if possible.
2286 */
2287 markup:
2288         STRING {
2289                 $$ = make_simple_markup ($1);
2290         }
2291         | MARKUP_HEAD_EMPTY {
2292                 $$ = scm_list_1 ($1);
2293         }
2294         | MARKUP_HEAD_MARKUP0 markup {
2295                 $$ = scm_list_2 ($1, $2);
2296         }
2297         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2298                 $$ = scm_list_3 ($1, $2, $3);
2299         }
2300         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2301                 $$ = scm_list_3 ($1, $2, $3);
2302         }
2303         | markup_line {
2304                 $$ = $1;
2305         }
2306         | MARKUP_HEAD_LIST0 markup_list {
2307                 $$ = scm_list_2 ($1,$2);
2308         }
2309         | MARKUP_HEAD_SCM0 embedded_scm {
2310                 $$ = scm_list_2 ($1, $2);
2311         }
2312         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2313                 $$ = scm_list_4 ($1, $2, $3, $4);
2314         }
2315         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2316                 $$ = scm_list_4 ($1, $2, $3, $4);
2317         }
2318         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2319                 $$ = scm_list_3 ($1, $2, $3);
2320         }
2321         | MARKUP_IDENTIFIER {
2322                 $$ = $1;
2323         }
2324         | STRING_IDENTIFIER {
2325                 $$ = $1;
2326         }
2327         ;
2328
2329 markup_list:
2330         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2331         ;
2332
2333 markup_line:
2334         '{' markup_list_body '}' {
2335                 SCM line = ly_scheme_function ("line-markup");
2336
2337                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2338         }
2339         ;
2340
2341 markup_list_body:
2342         /**/ {  $$ = SCM_EOL; }
2343         | markup_list_body markup {
2344                 $$ = scm_cons ($2, $1);
2345         }
2346         ;
2347
2348
2349 %%
2350
2351 void
2352 My_lily_parser::set_yydebug (bool )
2353 {
2354 #if 0
2355         yydebug = 1;
2356 #endif
2357 }
2358
2359 extern My_lily_parser *current_parser;
2360
2361 void
2362 My_lily_parser::do_yyparse ()
2363 {
2364         current_parser = this;;
2365         yyparse ((void*)this);
2366 }
2367
2368
2369 /*
2370 Should make this optional?    It will also complain when you do
2371
2372         [s4]
2373
2374 which is entirely legitimate.
2375
2376 Or we can scrap it. Barchecks should detect wrong durations, and
2377 skipTypesetting speeds it up a lot.
2378 */
2379
2380 void
2381 My_lily_parser::beam_check (SCM dur)
2382 {
2383   Duration *d = unsmob_duration (dur);
2384   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2385     {
2386       Music *m = unsmob_music (last_beam_start_);
2387       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2388     }
2389   last_beam_start_ = SCM_EOL;
2390 }
2391
2392
2393
2394
2395 /*
2396
2397 It is a little strange to have this function in this file, but
2398 otherwise, we have to import music classes into the lexer.
2399
2400 */
2401 int
2402 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2403 {
2404         if (ly_string_p (sid)) {
2405                 *destination = sid;
2406                 return STRING_IDENTIFIER;
2407         } else if (ly_number_p (sid)) {
2408                 *destination = sid;
2409                 return NUMBER_IDENTIFIER;
2410         } else if (unsmob_context_def (sid)) {
2411                 *destination = unsmob_context_def (sid)->clone_scm ();
2412                 return CONTEXT_DEF_IDENTIFIER;
2413         } else if (unsmob_score (sid)) {
2414                 Score *sc = new Score (*unsmob_score (sid));
2415                 *destination = sc->self_scm ();
2416                 return SCORE_IDENTIFIER;
2417         } else if (Music *mus = unsmob_music (sid)) {
2418                 mus = mus->clone ();
2419                 *destination = mus->self_scm ();
2420                 unsmob_music (*destination)->
2421                         set_property ("origin", make_input (last_input_));
2422                 return dynamic_cast<Event*> (mus)
2423                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2424         } else if (unsmob_duration (sid)) {
2425                 *destination = unsmob_duration (sid)->smobbed_copy ();
2426                 return DURATION_IDENTIFIER;
2427         } else if (unsmob_music_output_def (sid)) {
2428                 Music_output_def *p = unsmob_music_output_def (sid);
2429                 p = p->clone ();
2430
2431                 *destination = p->self_scm ();
2432                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2433         } else if (Text_item::markup_p (sid)) {
2434                 *destination = sid;
2435                 return MARKUP_IDENTIFIER;
2436         }
2437
2438         return -1;
2439 }
2440
2441 Music *
2442 property_op_to_music (SCM op)
2443 {
2444         Music *m = 0;
2445         SCM tag = ly_car (op);
2446         SCM symbol = ly_cadr (op);
2447         SCM args = ly_cddr (op);
2448         SCM grob_val = SCM_UNDEFINED;
2449         SCM grob_sym = SCM_UNDEFINED;
2450         SCM val = SCM_UNDEFINED;
2451
2452         if (tag == ly_symbol2scm ("assign"))
2453                 {
2454                 m = MY_MAKE_MUSIC ("PropertySet");
2455                 val = ly_car (args);
2456                 }
2457         else if (tag == ly_symbol2scm ("unset"))
2458                 m = MY_MAKE_MUSIC ("PropertyUnset");
2459         else if (tag == ly_symbol2scm ("poppush")
2460                  || tag == ly_symbol2scm ("push"))
2461                 {
2462                 m = MY_MAKE_MUSIC ("OverrideProperty");
2463                 grob_sym = ly_car (args);
2464                 grob_val = ly_cadr (args);
2465                 }
2466         else if (tag == ly_symbol2scm ("pop")) {
2467                 m = MY_MAKE_MUSIC ("RevertProperty");
2468                 grob_sym = ly_car (args);
2469                 }
2470
2471         m->set_property ("symbol", symbol);
2472
2473         if (val != SCM_UNDEFINED)
2474                 m->set_property ("value", val);
2475         if (grob_val != SCM_UNDEFINED)
2476                 m->set_property ("grob-value", grob_val);
2477
2478         if (grob_sym != SCM_UNDEFINED)
2479                 {
2480                 bool itc = internal_type_checking_global_b;
2481                 /* UGH.
2482                 */
2483                 bool autobeam = ly_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2484                 if (autobeam)
2485                         internal_type_checking_global_b = false;
2486                 m->set_property ("grob-property", grob_sym);
2487                 if (autobeam)
2488                         internal_type_checking_global_b = itc;
2489                 }
2490
2491         if (op == ly_symbol2scm ("poppush"))
2492                 m->set_property ("pop-first", SCM_BOOL_T);
2493
2494
2495         return m;
2496 }
2497
2498 Music*
2499 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2500 {
2501         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2502
2503         csm->set_property ("element", m->self_scm ());
2504         scm_gc_unprotect_object (m->self_scm ());
2505
2506         csm->set_property ("context-type",
2507                 ly_symbol_p (type) ? type : scm_string_to_symbol (type));
2508         csm->set_property ("property-operations", ops);
2509
2510         if (ly_string_p (id))
2511                 csm->set_property ("context-id", id);
2512         return csm;
2513 }
2514
2515
2516 SCM
2517 get_next_unique_context ()
2518 {
2519         static int new_context_count;
2520
2521         char s[1024];
2522         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2523
2524         return scm_makfrom0str (s);
2525 }
2526