lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "translator-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC("PropertySet");
 200         p->set_mus_property ("symbol", sym);
 201         p->set_mus_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token PARTIAL
 287 %token PITCHNAMES
 288 %token PROPERTY
 289 %token RELATIVE
 290 %token REMOVE
 291 %token REPEAT
 292 %token REST
 293 %token SCM_T
 294 %token SCORE
 295 %token SEQUENTIAL
 296 %token SIMULTANEOUS
 297 %token SKIP
 298 %token SPANREQUEST
 299 %token TAG
 300 %token TEMPO
 301 %token TIMES
 302 %token TIME_T
 303 %token TRANSLATOR
 304 %token TRANSPOSE
 305 %token TYPE
 306 %token UNSET
 307 %token WITH
 308
 309 /* escaped */
 310 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 311 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 312 %token E_BACKSLASH
 313 %token <i> E_UNSIGNED
 314 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 315 %token FIGURE_SPACE
 316
 317 %type <i>       exclamations questions dots optional_rest
 318 %type <i>        bass_mod
 319 %type <scm>     grace_head
 320 %type <scm>     oct_check
 321 %type <scm>     context_mod_list
 322 %type <scm>     lyric_element
 323 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 324 %token <i>      DIGIT
 325 %token <scm>    NOTENAME_PITCH
 326 %token <scm>    TONICNAME_PITCH
 327 %token <scm>    CHORDMODIFIER_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    FRACTION
 330 %token <id>     IDENTIFIER
 331 %token <scm>    CHORDNAMES
 332 %token <scm>    CHORD_MODIFIER
 333 %token <scm>    SCORE_IDENTIFIER
 334 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    RESTNAME
 340 %token <scm>    STRING
 341 %token <scm>    SCM_T
 342 %token <i>      UNSIGNED
 343 %token <scm>   REAL
 344
 345 %token MARKUP
 346 %token <scm> MARKUP_HEAD_MARKUP0
 347 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0
 349 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 353
 354 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 355 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 356
 357 %type <outputdef> output_def
 358 %type <scm>     lilypond_header lilypond_header_body
 359 %type <music>   open_event close_event
 360 %type <i>       sub_quotes sup_quotes
 361 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 362 %type <music>   Repeated_music
 363 %type <scm>     Alternative_music
 364 %type <i>       tremolo_type
 365 %type <i>       bare_int  bare_unsigned
 366 %type <i>       script_dir
 367 %type <scm>     identifier_init
 368
 369 %type <music> note_chord_element chord_body chord_body_element
 370 %type <scm>  chord_body_elements
 371 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 372
 373 %type <scm>   post_events
 374 %type <music> gen_text_def direction_less_event direction_reqd_event
 375 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 376 %type <scm>    steno_tonic_pitch
 377 %type <scm>     duration_length fraction
 378
 379 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 380
 381 %type <scm>  embedded_scm scalar
 382 %type <music>   Music Sequential_music Simultaneous_music
 383 %type <music>   relative_music re_rhythmed_music part_combined_music
 384 %type <music>   music_property_def context_change
 385 %type <scm> Music_list
 386 %type <scm> property_operation context_mod translator_mod optional_context_mod
 387 %type <outputdef>  music_output_def_body
 388 %type <music> shorthand_command_req
 389 %type <music>   post_event tagged_post_event
 390 %type <music> command_req verbose_command_req
 391 %type <music> hyphen_req
 392 %type <music> string_number_event
 393 %type <scm>     string bare_number number_expression number_term number_factor
 394 %type <score>   score_block score_body
 395
 396 %type <scm>     translator_spec_block translator_spec_body
 397 %type <music>   tempo_event
 398 %type <scm> notenames_body notenames_block chordmodifiers_block
 399 %type <scm>     script_abbreviation
 400
 401
 402
 403 %left '-' '+'
 404
 405 /* We don't assign precedence to / and *, because we might need varied
 406 prec levels in different prods */
 407
 408 %left UNARY_MINUS
 409
 410 %%
 411
 412 lilypond:       /* empty */
 413         | lilypond toplevel_expression {}
 414         | lilypond assignment  { }
 415         | lilypond error {
 416                 THIS->error_level_  = 1;
 417         }
 418         | lilypond INVALID      {
 419                 THIS->error_level_  = 1;
 420         }
 421         ;
 422
 423 toplevel_expression:
 424         notenames_block                 {
 425                 THIS->lexer_->pitchname_tab_ =  $1;
 426         }
 427         | chordmodifiers_block                  {
 428                 THIS->lexer_->chordmodifier_tab_  = $1;
 429         }
 430         | lilypond_header {
 431                 THIS->input_file_->header_ = $1;
 432         }
 433         | score_block {
 434                 Score * sc = $1;
 435
 436                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 437
 438                 Path p = split_path (THIS->output_basename_);
 439                 int *c =  &THIS->input_file_->score_count_;
 440                 if (*c)
 441                         {
 442                         p.base += "-" + to_string (*c);
 443                         }
 444
 445                 (*c)++;
 446                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 447
 448                 for (int i=0; i < sc->defs_.size (); i++)
 449                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 450
 451                 if (sc->defs_.empty ())
 452                 {
 453                    Music_output_def *id =
 454                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 455                                 ("$defaultpaper"));
 456
 457                    id = id ? id->clone () : new Paper_def;
 458
 459                    default_rendering (sc->music_, id->self_scm(), head, outname);
 460
 461                    scm_gc_unprotect_object (id->self_scm ());
 462                 }
 463                 scm_gc_unprotect_object (sc->self_scm());
 464         }
 465         | output_def {
 466                 if (dynamic_cast<Paper_def*> ($1))
 467                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 468                 else if (dynamic_cast<Midi_def*> ($1))
 469                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 470         }
 471         ;
 472
 473 embedded_scm:
 474         SCM_T
 475         | SCM_IDENTIFIER
 476         ;
 477
 478
 479 chordmodifiers_block:
 480         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 481         ;
 482
 483 notenames_block:
 484         PITCHNAMES notenames_body   {  $$ = $2; }
 485         ;
 486
 487 notenames_body:
 488         embedded_scm    {
 489           int i = scm_ilength ($1);
 490
 491           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 492           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 493                 SCM pt = ly_cdar (s);
 494                 scm_hashq_set_x (tab, ly_caar (s), pt);
 495           }
 496           $$ = tab;
 497         }
 498         ;
 499
 500 lilypond_header_body:
 501         {
 502                 $$ = ly_make_anonymous_module ();
 503                 THIS->lexer_->add_scope ($$);
 504         }
 505         | lilypond_header_body assignment  {
 506
 507         }
 508         ;
 509
 510 lilypond_header:
 511         HEADER '{' lilypond_header_body '}'     {
 512                 $$ = THIS->lexer_-> remove_scope();
 513         }
 514         ;
 515
 516
 517 /*
 518         DECLARATIONS
 519 */
 520 assignment:
 521         STRING {
 522                 THIS->push_spot ();
 523         }
 524         /* cont */ '=' identifier_init  {
 525
 526         /*
 527                 Should find generic way of associating input with objects.
 528         */
 529                 Input ip = THIS->pop_spot ();
 530
 531                 if (! regular_identifier_b ($1))
 532                 {
 533                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 534                 }
 535
 536                 THIS->lexer_->set_identifier ($1, $4);
 537
 538 /*
 539  TODO: devise standard for protection in parser.
 540
 541   The parser stack lives on the C-stack, which means that
 542 all objects can be unprotected as soon as they're here.
 543
 544 */
 545         }
 546         | embedded_scm { }
 547         ;
 548
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 scm_gc_unprotect_object ($$);
 555         }
 556         | full_markup {
 557                 $$ = $1;
 558         }
 559         | output_def {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | translator_spec_block {
 564                 $$ = $1;
 565         }
 566         | Music  {
 567                 $$ = $1->self_scm ();
 568                 scm_gc_unprotect_object ($$);
 569         }
 570         | post_event {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | number_expression {
 575                 $$ = $1;
 576         }
 577         | string {
 578                 $$ = $1;
 579         }
 580         | embedded_scm  {
 581                 $$ = $1;
 582         }
 583         ;
 584
 585 translator_spec_block:
 586         TRANSLATOR '{' translator_spec_body '}'
 587                 {
 588                 $$ = $3;
 589         }
 590         ;
 591
 592 translator_spec_body:
 593         /**/ {
 594                 $$ = Context_def::make_scm ();
 595                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 596         }
 597         | TRANSLATOR_IDENTIFIER {
 598                 $$ = $1;
 599                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 600         }
 601         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 602                 Context_def*td = unsmob_context_def($$);
 603
 604                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 605                         SCM tag = gh_caar (p);
 606                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 607                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 608                 }
 609         }
 610         | translator_spec_body context_mod {
 611                 unsmob_context_def ($$)->add_context_mod ($2);
 612         }
 613         ;
 614
 615 /*
 616         SCORE
 617 */
 618 score_block:
 619         SCORE {
 620                 THIS->push_spot ();
 621         }
 622         /*cont*/ '{' score_body '}'     {
 623                 THIS->pop_spot ();
 624                 $$ = $4;
 625
 626         }
 627         ;
 628
 629 score_body:
 630         Music   {
 631                 $$ = new Score;
 632
 633                 $$->set_spot (THIS->here_input ());
 634                 SCM m = $1->self_scm ();
 635                 scm_gc_unprotect_object (m);
 636
 637                 /*
 638                         guh.
 639                 */
 640                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 641                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 642                         m = gh_call1 (gh_car (check_funcs), m);
 643                 $$->music_ = m;
 644
 645         }
 646         | SCORE_IDENTIFIER {
 647                 $$ = unsmob_score ($1);
 648                 $$->set_spot (THIS->here_input ());
 649         }
 650         | score_body lilypond_header    {
 651                 $$->header_ = $2;
 652         }
 653         | score_body output_def {
 654                 $$->defs_.push ($2);
 655         }
 656         | score_body error {
 657
 658         }
 659         ;
 660
 661
 662 /*
 663         MIDI
 664 */
 665 output_def:
 666         music_output_def_body '}' {
 667                 $$ = $1;
 668                 THIS-> lexer_-> remove_scope ();
 669         }
 670         ;
 671
 672 music_output_def_body:
 673         MIDI '{'    {
 674                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 675
 676
 677                 Midi_def* p =0;
 678                 if (id)
 679                         p = dynamic_cast<Midi_def*> (id->clone ());
 680                 else
 681                         p = new Midi_def;
 682
 683                 $$ = p;
 684                 THIS->lexer_->add_scope (p->scope_);
 685         }
 686         | PAPER '{'     {
 687                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 688                   Paper_def *p = 0;
 689                 if (id)
 690                         p = dynamic_cast<Paper_def*> (id->clone ());
 691                 else
 692                         p = new Paper_def;
 693
 694                 THIS->lexer_->add_scope (p->scope_);
 695                 $$ = p;
 696         }
 697         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 698                 Music_output_def * o =  unsmob_music_output_def ($3);
 699                 $$ =o;
 700
 701                 THIS->lexer_->add_scope (o->scope_);
 702         }
 703         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 704                 Music_output_def * o =  unsmob_music_output_def ($3);
 705                 $$ = o;
 706
 707                 THIS->lexer_->add_scope (o->scope_);
 708         }
 709         | music_output_def_body assignment  {
 710
 711         }
 712         | music_output_def_body translator_spec_block   {
 713                 $$->assign_translator ($2);
 714
 715         }
 716         | music_output_def_body tempo_event  {
 717                 /*
 718                         junk this ? there already is tempo stuff in
 719                         music.
 720                 */
 721                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 722                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 723                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 724                 if (md)
 725                         md->set_tempo (d->get_length (), m);
 726         }
 727         | music_output_def_body error {
 728
 729         }
 730         ;
 731
 732 tempo_event:
 733         TEMPO steno_duration '=' bare_unsigned  {
 734                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 735                 $$->set_mus_property ("tempo-unit", $2);
 736                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 737         }
 738         ;
 739
 740 /*
 741 The representation of a  list is the
 742
 743   (LIST . LAST-CONS)
 744
 745  to have  efficient append.
 746 */
 747 Music_list:
 748         /* empty */ {
 749                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 750         }
 751         | Music_list Music {
 752                 SCM s = $$;
 753                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 754                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 755                 if (gh_pair_p (ly_cdr (s)))
 756                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 757                 else
 758                         gh_set_car_x (s, c); /* set first cons */
 759                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 760         }
 761         | Music_list error {
 762         }
 763         ;
 764
 765
 766 Music:
 767         Simple_music
 768         | Composite_music
 769         ;
 770
 771 Alternative_music:
 772         /* empty */ {
 773                 $$ = SCM_EOL;
 774         }
 775         | ALTERNATIVE '{' Music_list '}' {
 776                 $$ = $3;
 777         }
 778         ;
 779
 780 Repeated_music:
 781         REPEAT string bare_unsigned Music Alternative_music
 782         {
 783                 Music *beg = $4;
 784                 int times = $3;
 785                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 786                 if (times < scm_ilength (alts)) {
 787                   unsmob_music (gh_car (alts))
 788                     ->origin ()->warning (
 789                     _("More alternatives than repeats.  Junking excess alternatives."));
 790                   alts = ly_truncate_list (times, alts);
 791                 }
 792
 793
 794                 static SCM proc;
 795                 if (!proc)
 796                         proc = scm_c_eval_string ("make-repeated-music");
 797
 798                 SCM mus = scm_call_1 (proc, $2);
 799                 scm_gc_protect_object (mus); // UGH.
 800                 Music *r =unsmob_music (mus);
 801                 if (beg)
 802                         {
 803                         r-> set_mus_property ("element", beg->self_scm ());
 804                         scm_gc_unprotect_object (beg->self_scm ());
 805                         }
 806                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 807
 808                 r-> set_mus_property ("elements",alts);
 809                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 810                         /*
 811                         we can not get durations and other stuff correct down the line, so we have to
 812                         add to the duration log here.
 813                         */
 814                         static SCM func;
 815
 816                         if (!func)
 817                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 818
 819                         int dots = ($3 % 3) ? 0 : 1;
 820                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 821
 822                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 823
 824                         if (seq) {
 825                                 int list_len =scm_ilength (seq->music_list ());
 826                                 if (list_len != 2)
 827                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 828                                 shift -= 1;
 829                                 r->compress (Moment (Rational (1,list_len)));
 830                                 }
 831                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 832
 833                 }
 834                 r->set_spot (*$4->origin ());
 835
 836                 $$ = r;
 837         }
 838         ;
 839
 840 Sequential_music:
 841         SEQUENTIAL '{' Music_list '}'           {
 842                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 843                 $$->set_mus_property ("elements", ly_car ($3));
 844                 $$->set_spot(THIS->here_input());
 845         }
 846         | '{' Music_list '}'            {
 847                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 848                 $$->set_mus_property ("elements", ly_car ($2));
 849                 $$->set_spot(THIS->here_input());
 850         }
 851         ;
 852
 853 Simultaneous_music:
 854         SIMULTANEOUS '{' Music_list '}'{
 855                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 856                 $$->set_mus_property ("elements", ly_car ($3));
 857                 $$->set_spot(THIS->here_input());
 858
 859         }
 860         | simul_open Music_list simul_close     {
 861                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 862                 $$->set_mus_property ("elements", ly_car ($2));
 863                 $$->set_spot(THIS->here_input());
 864         }
 865         ;
 866
 867 Simple_music:
 868         event_chord             { $$ = $1; }
 869         | APPLYOUTPUT embedded_scm {
 870                 if (!ly_input_procedure_p ($2))
 871                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 872                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 873                 $$->set_mus_property ("procedure", $2);
 874                 $$->set_spot (THIS->here_input());
 875         }
 876         | APPLYCONTEXT embedded_scm {
 877                 if (!ly_input_procedure_p ($2))
 878                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 879                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 880                 $$->set_mus_property ("procedure", $2);
 881                 $$->set_spot (THIS->here_input());
 882         }
 883         | MUSIC_IDENTIFIER {
 884                 $$ = unsmob_music ($1);
 885         }
 886         | music_property_def
 887         | context_change
 888         ;
 889
 890
 891 optional_context_mod:
 892         /**/ { $$ = SCM_EOL; }
 893         | WITH '{' context_mod_list '}'  { $$ = $3; }
 894         ;
 895
 896 grace_head:
 897         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 898         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 899         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 900         ;
 901
 902 context_mod_list:
 903         /* */  { $$ = SCM_EOL; }
 904         | context_mod_list context_mod  {
 905                  $$ = gh_cons ($2, $1);
 906         }
 907         ;
 908
 909 Composite_music:
 910         AUTOCHANGE STRING Music {
 911                 Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 912                 chm->set_mus_property ("element", $3->self_scm ());
 913                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 914
 915                 scm_gc_unprotect_object ($3->self_scm ());
 916                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 917
 918                 $$ = chm;
 919                 chm->set_spot (*$3->origin ());
 920         }
 921         | grace_head Music {
 922 #if 1
 923         /*
 924                 The other version is for easier debugging  of
 925                 Sequential_music_iterator in combination with grace notes.
 926         */
 927
 928 /*
 929
 930 TODO: should distinguish between both grace types in the
 931 basic music objects too, since the meaning is different.
 932
 933 */
 934
 935                 String start_str = "start" + ly_scm2string ($1) + "Music";
 936                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 937
 938                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 939                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 940
 941                 Music *startm = unsmob_music (start);
 942                 Music *stopm = unsmob_music (stop);
 943
 944                 SCM ms = SCM_EOL;
 945                 if (stopm) {
 946                         stopm = stopm->clone ();
 947                         ms = scm_cons (stopm->self_scm (), ms);
 948                         scm_gc_unprotect_object (stopm->self_scm ());
 949                 }
 950                 ms = scm_cons ($2->self_scm (), ms);
 951                 scm_gc_unprotect_object ($2->self_scm());
 952                 if (startm) {
 953                         startm = startm->clone ();
 954                         ms = scm_cons (startm->self_scm () , ms);
 955                         scm_gc_unprotect_object (startm->self_scm ());
 956                 }
 957
 958
 959                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 960                 seq->set_mus_property ("elements", ms);
 961
 962
 963                 $$ = MY_MAKE_MUSIC("GraceMusic");
 964                 $$->set_mus_property ("element", seq->self_scm ());
 965                 scm_gc_unprotect_object (seq->self_scm ());
 966 #else
 967                 $$ = MY_MAKE_MUSIC("GraceMusic");
 968                 $$->set_mus_property ("element", $2->self_scm ());
 969                 scm_gc_unprotect_object ($2->self_scm ());
 970 #endif
 971         }
 972         | CONTEXT string '=' string optional_context_mod Music {
 973                 $$ = context_spec_music ($2, $4, $6, $5);
 974
 975         }
 976         | CONTEXT STRING optional_context_mod Music {
 977                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 978         }
 979         | NEWCONTEXT string optional_context_mod Music {
 980                 $$ = context_spec_music ($2, get_next_unique_context (),
 981                                          $4, $3);
 982         }
 983
 984         | TIMES {
 985                 THIS->push_spot ();
 986         }
 987         /* CONTINUED */
 988                 fraction Music
 989
 990         {
 991                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 992                 Music *mp = $4;
 993
 994                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 995                 $$->set_spot (THIS->pop_spot ());
 996
 997                 $$->set_mus_property ("element", mp->self_scm ());
 998                 scm_gc_unprotect_object (mp->self_scm ());
 999                 $$->set_mus_property ("numerator", gh_int2scm (n));
1000                 $$->set_mus_property ("denominator", gh_int2scm (d));
1001                 $$->compress (Moment (Rational (n,d)));
1002
1003         }
1004         | Repeated_music                { $$ = $1; }
1005         | Simultaneous_music            { $$ = $1; }
1006         | Sequential_music              { $$ = $1; }
1007         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1008                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1009                 Music *p = $4;
1010                 Pitch from = *unsmob_pitch ($2);
1011                 Pitch to = *unsmob_pitch ($3);
1012
1013                 p->transpose (interval (from, to));
1014                 $$->set_mus_property ("element", p->self_scm ());
1015                 scm_gc_unprotect_object (p->self_scm ());
1016         }
1017         | APPLY embedded_scm Music  {
1018                 if (!ly_input_procedure_p ($2))
1019                         {
1020                         THIS->parser_error (_ ("\\apply takes function argument"));
1021                         $$ = $3;
1022                         }
1023                 else
1024                         {
1025                         SCM ret = gh_call1 ($2, $3->self_scm ());
1026                         Music *m = unsmob_music (ret);
1027                         if (!m) {
1028                                 THIS->parser_error ("\\apply must return a Music");
1029                                 m = MY_MAKE_MUSIC("Music");
1030                                 }
1031                         $$ = m;
1032                         }
1033         }
1034         | NOTES
1035                 { THIS->lexer_->push_note_state (); }
1036         Music
1037                 { $$ = $3;
1038                   THIS->lexer_->pop_state ();
1039                 }
1040         | FIGURES
1041                 { THIS->lexer_->push_figuredbass_state (); }
1042         Music
1043                 {
1044                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1045                   chm->set_mus_property ("element", $3->self_scm ());
1046                   $$ = chm;
1047                   scm_gc_unprotect_object ($3->self_scm());
1048
1049                   THIS->lexer_->pop_state ();
1050         }
1051         | CHORDS
1052                 { THIS->lexer_->push_chord_state (); }
1053         Music
1054                 {
1055                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1056                   chm->set_mus_property ("element", $3->self_scm ());
1057                   scm_gc_unprotect_object ($3->self_scm());
1058                   $$ = chm;
1059
1060                   THIS->lexer_->pop_state ();
1061         }
1062         | LYRICS
1063                 { THIS->lexer_->push_lyric_state (); }
1064         Music
1065                 {
1066                   $$ = $3;
1067                   THIS->lexer_->pop_state ();
1068         }
1069         | relative_music        { $$ = $1; }
1070         | re_rhythmed_music     { $$ = $1; }
1071         | part_combined_music   { $$ = $1; }
1072         | TAG embedded_scm Music {
1073                 tag_music ($3, $2, THIS->here_input ());
1074                 $$ = $3;
1075         }
1076         ;
1077
1078 relative_music:
1079         RELATIVE absolute_pitch Music {
1080                 Music * p = $3;
1081                 Pitch pit = *unsmob_pitch ($2);
1082                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1083
1084                 $$->set_mus_property ("element", p->self_scm ());
1085                 scm_gc_unprotect_object (p->self_scm ());
1086
1087
1088                 Pitch retpitch = p->to_relative_octave (pit);
1089                 if (lily_1_8_relative)
1090                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1091         }
1092         ;
1093
1094 re_rhythmed_music:
1095         ADDLYRICS Music Music {
1096         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1097           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1098           scm_gc_unprotect_object ($3->self_scm ());
1099           scm_gc_unprotect_object ($2->self_scm ());
1100           $$ = l;
1101         }
1102         | NEWADDLYRICS string Music {
1103           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1104           l->set_mus_property ("element", $3->self_scm ());
1105           scm_gc_unprotect_object ($3->self_scm ());
1106           $$ = l;
1107           l->set_mus_property ("associated-context", $2);
1108         }
1109         ;
1110
1111 part_combined_music:
1112         PARTCOMBINE STRING Music Music {
1113                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1114                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1115                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1116
1117                 scm_gc_unprotect_object ($3->self_scm ());
1118                 scm_gc_unprotect_object ($4->self_scm ());
1119
1120                 $$ = p;
1121         }
1122         ;
1123
1124 context_change:
1125         CHANGE STRING '=' STRING  {
1126                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1127                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1128                 t-> set_mus_property ("change-to-id", $4);
1129
1130                 $$ = t;
1131                 $$->set_spot (THIS->here_input ());
1132         }
1133         ;
1134
1135 property_operation:
1136         STRING '='  scalar {
1137                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1138                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1139         }
1140         | STRING UNSET {
1141                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1142                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1143         }
1144         | STRING SET embedded_scm '=' embedded_scm {
1145                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1146                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1147         }
1148         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1149                 $$ = scm_list_n (ly_symbol2scm ("push"),
1150                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1151         }
1152         | STRING REVERT embedded_scm {
1153                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1154                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1155         }
1156         ;
1157
1158 translator_mod:
1159         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1160         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1161         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1162
1163         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1164         | DENIES { $$ = ly_symbol2scm ("denies"); }
1165
1166         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1167         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1168         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1169         | NAME { $$ = ly_symbol2scm ("context-name"); }
1170         ;
1171
1172 context_mod:
1173         property_operation { $$ = $1; }
1174         | translator_mod STRING {
1175                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1176         }
1177         ;
1178
1179 music_property_def:
1180         PROPERTY STRING '.' property_operation {
1181                 Music * t = property_op_to_music ($4);
1182                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1183
1184                 csm->set_mus_property ("element", t->self_scm ());
1185                 scm_gc_unprotect_object (t->self_scm ());
1186
1187                 $$ = csm;
1188                 $$->set_spot (THIS->here_input ());
1189
1190                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1191         }
1192         | ONCE music_property_def {
1193                 $$ = $2;
1194                 SCM e = $2->get_mus_property ("element");
1195                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1196         }
1197         ;
1198
1199
1200 scalar:
1201         string          { $$ = $1; }
1202         | bare_int      { $$ = gh_int2scm ($1); }
1203         | embedded_scm  { $$ = $1; }
1204         | full_markup {  $$ = $1; }
1205         | DIGIT { $$ = gh_int2scm ($1); }
1206         ;
1207
1208 /*
1209 This is a trick:
1210
1211 Adding pre_events to the simple_element
1212 makes the choice between
1213
1214   string:  STRING
1215
1216 and
1217
1218   simple_element: STRING
1219
1220 a single shift/reduction conflict.
1221
1222 nevertheless, this is not very clean, and we should find a different
1223 solution.
1224
1225 */
1226 pre_events: {
1227                 THIS->push_spot ();
1228         }
1229         ;
1230
1231 event_chord:
1232         pre_events simple_element post_events   {
1233                 SCM elts = $2-> get_mus_property ("elements");
1234
1235                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1236
1237                 $2->set_mus_property ("elements", elts);
1238                 $$ = $2;
1239         }
1240         | command_element
1241         | note_chord_element
1242         ;
1243
1244
1245 note_chord_element:
1246         chord_body optional_notemode_duration post_events
1247         {
1248                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1249                 SCM es = $1->get_mus_property ("elements");
1250                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1251
1252                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1253                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1254                 es = gh_append2 (es, postevs);
1255
1256                 $1-> set_mus_property ("elements", es);
1257                 $$ = $1;
1258         }
1259         ;
1260
1261 chord_open: '<'
1262         ;
1263
1264 chord_close: '>'
1265         ;
1266
1267 simul_open: LESSLESS
1268         ;
1269
1270 simul_close: MOREMORE
1271         ;
1272
1273 chord_body:
1274         chord_open chord_body_elements chord_close
1275         {
1276                 $$ = MY_MAKE_MUSIC("EventChord");
1277                 $$->set_mus_property ("elements",
1278                         scm_reverse_x ($2, SCM_EOL));
1279         }
1280         ;
1281
1282 chord_body_elements:
1283         /* empty */             { $$ = SCM_EOL; }
1284         | chord_body_elements chord_body_element {
1285                 $$ = gh_cons ($2->self_scm(), $1);
1286                 scm_gc_unprotect_object ($2->self_scm());
1287         }
1288         ;
1289
1290 chord_body_element:
1291         pitch exclamations questions post_events
1292         {
1293                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1294                 n->set_mus_property ("pitch", $1);
1295                 if ($3 % 2)
1296                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1297                 if ($2 % 2 || $3 % 2)
1298                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1299
1300                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1301                 n->set_mus_property ("articulations", arts);
1302
1303                 $$ = n;
1304         }
1305         ;
1306
1307 command_element:
1308         command_req {
1309                 $$ = MY_MAKE_MUSIC("EventChord");
1310                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1311                 scm_gc_unprotect_object ($1->self_scm());
1312
1313                 $$-> set_spot (THIS->here_input ());
1314                 $1-> set_spot (THIS->here_input ());
1315         }
1316         | OCTAVE { THIS->push_spot (); }
1317           pitch {
1318                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1319                 $$ = l;
1320                 $$->set_spot (THIS->pop_spot ());
1321                 $$->set_mus_property ("pitch", $3);
1322         }
1323         | E_LEFTSQUARE {
1324                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1325                 l->set_mus_property ("span-direction", gh_int2scm (START));
1326                 l->set_spot (THIS->here_input ());
1327
1328                 $$ = MY_MAKE_MUSIC("EventChord");
1329                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1330                 scm_gc_unprotect_object (l->self_scm());
1331                 $$->set_spot (THIS->here_input ());
1332         }
1333         | E_RIGHTSQUARE {
1334                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1335                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1336                 l->set_spot (THIS->here_input ());
1337
1338                 $$ = MY_MAKE_MUSIC("EventChord");
1339                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1340                 $$->set_spot (THIS->here_input ());
1341                 scm_gc_unprotect_object (l->self_scm());
1342         }
1343         | E_BACKSLASH {
1344                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1345                 $$->set_spot (THIS->here_input ());
1346         }
1347         | '|'      {
1348
1349                 $$ = MY_MAKE_MUSIC("BarCheck");
1350                 $$->set_spot (THIS->here_input ());
1351         }
1352         | BAR STRING                    {
1353                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1354
1355                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1356                 csm->set_mus_property ("element", t->self_scm ());
1357                 scm_gc_unprotect_object (t->self_scm ());
1358
1359                 $$ = csm;
1360                 $$->set_spot (THIS->here_input ());
1361
1362                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1363         }
1364         | PARTIAL duration_length       {
1365                 Moment m = - unsmob_duration ($2)->get_length ();
1366                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1367
1368                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1369                 sp->set_mus_property ("element", p->self_scm ());
1370                 scm_gc_unprotect_object (p->self_scm ());
1371
1372                 $$ =sp ;
1373                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1374         }
1375         | CLEF STRING  {
1376                 static SCM proc ;
1377                 if (!proc)
1378                         proc = scm_c_eval_string ("make-clef-set");
1379
1380                 SCM result = scm_call_1 (proc, $2);
1381                 scm_gc_protect_object (result);
1382                 $$ = unsmob_music (result);
1383         }
1384         | TIME_T fraction  {
1385                 static SCM proc;
1386                 if (!proc)
1387                         proc = scm_c_eval_string ("make-time-signature-set");
1388
1389                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1390                 scm_gc_protect_object (result);
1391                 $$ = unsmob_music (result);
1392         }
1393         ;
1394
1395 command_req:
1396         shorthand_command_req   { $$ = $1; }
1397         | verbose_command_req   { $$ = $1; }
1398         ;
1399
1400 shorthand_command_req:
1401         hyphen_req {
1402                 $$ = $1;
1403         }
1404         | BREATHE {
1405                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1406         }
1407         | E_TILDE {
1408                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1409         }
1410         ;
1411
1412 verbose_command_req:
1413         MARK DEFAULT  {
1414                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1415                 $$ = m;
1416         }
1417         | MARK scalar {
1418                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1419                 m->set_mus_property ("label", $2);
1420                 $$ = m;
1421         }
1422         | SKIP duration_length {
1423                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1424                 skip->set_mus_property ("duration", $2);
1425
1426                 $$ = skip;
1427         }
1428         | tempo_event {
1429                 $$ = $1;
1430         }
1431         | KEY DEFAULT {
1432                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1433                 $$ = key;
1434         }
1435         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1436
1437                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1438                 if (scm_ilength ($3) > 0)
1439                 {
1440                         key->set_mus_property ("pitch-alist", $3);
1441                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1442                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1443                 } else {
1444                         THIS->parser_error (_("Second argument must be pitch list."));
1445                 }
1446
1447                 $$ = key;
1448         }
1449         ;
1450
1451 post_events:
1452         /* empty */ {
1453                 $$ = SCM_EOL;
1454         }
1455         | post_events post_event {
1456                 $2->set_spot (THIS->here_input ());
1457                 $$ = gh_cons ($2->self_scm(), $$);
1458                 scm_gc_unprotect_object ($2->self_scm());
1459         }
1460         | post_events tagged_post_event {
1461                 $2 -> set_spot (THIS->here_input ());
1462                 $$ = scm_cons ($2->self_scm(), $$);
1463                 scm_gc_unprotect_object ($2->self_scm());
1464         }
1465         ;
1466
1467
1468 tagged_post_event:
1469         '-' TAG embedded_scm post_event {
1470                 tag_music ($4, $3, THIS->here_input ());
1471                 $$ = $4;
1472         }
1473         ;
1474
1475 post_event:
1476         direction_less_event {
1477                 $$ = $1;
1478         }
1479         | EXTENDER {
1480                 if (!THIS->lexer_->lyric_state_b ())
1481                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1482                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1483         }
1484         | script_dir direction_reqd_event {
1485                 if ($1)
1486                         $2->set_mus_property ("direction", gh_int2scm ($1));
1487                 $$ = $2;
1488         }
1489         | script_dir direction_less_event {
1490                 if ($1)
1491                         $2->set_mus_property ("direction", gh_int2scm ($1));
1492                 $$ = $2;
1493         }
1494         | string_number_event
1495         ;
1496
1497 string_number_event:
1498         E_UNSIGNED {
1499                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1500                 s->set_mus_property ("string-number",  gh_int2scm($1));
1501                 s->set_spot (THIS->here_input ());
1502                 $$ = s;
1503         }
1504         ;
1505
1506
1507 direction_less_event:
1508         '['  {
1509
1510
1511 /*
1512
1513 TODO: should take all these defs out of the parser, adn make use
1514 configurable, i.e.
1515
1516
1517 (set-articulation '~ "trill")
1518
1519 */
1520                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1521                 m->set_spot (THIS->here_input());
1522                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1523                 $$ = m;
1524         }
1525         | ']'  {
1526                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1527                 m->set_spot (THIS->here_input());
1528                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1529                 $$ = m;
1530         }
1531         | '~' {
1532                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1533                 m->set_spot (THIS->here_input());
1534                 $$ = m;
1535         }
1536         | close_event {
1537                 $$ = $1;
1538                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1539                         gh_int2scm (START));
1540         }
1541         | open_event {
1542                 $$ = $1;
1543                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1544                         gh_int2scm (STOP));
1545         }
1546         | EVENT_IDENTIFIER      {
1547                 $$ = unsmob_music ($1);
1548         }
1549         | tremolo_type  {
1550                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1551                a->set_spot (THIS->here_input ());
1552                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1553                $$ = a;
1554         }
1555         ;
1556
1557 direction_reqd_event:
1558         gen_text_def {
1559                 $$ = $1;
1560         }
1561         | script_abbreviation {
1562                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1563                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1564                 if (gh_string_p (s))
1565                         a->set_mus_property ("articulation-type", s);
1566                 else THIS->parser_error (_ ("Expecting string as script definition"));
1567                 $$ = a;
1568         }
1569         ;
1570
1571 oct_check:
1572         /**/ { $$ = SCM_EOL; }
1573         | '='  { $$ = gh_int2scm (0); }
1574         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1575         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1576         ;
1577
1578 sup_quotes:
1579         '\'' {
1580                 $$ = 1;
1581         }
1582         | sup_quotes '\'' {
1583                 $$ ++;
1584         }
1585         ;
1586
1587 sub_quotes:
1588         ',' {
1589                 $$ = 1;
1590         }
1591         | sub_quotes ',' {
1592                 $$ ++ ;
1593         }
1594         ;
1595
1596 steno_pitch:
1597         NOTENAME_PITCH  {
1598                 $$ = $1;
1599         }
1600         | NOTENAME_PITCH sup_quotes     {
1601                 Pitch p = *unsmob_pitch ($1);
1602                 p = p.transposed (Pitch ($2,0,0));
1603                 $$ = p.smobbed_copy ();
1604         }
1605         | NOTENAME_PITCH sub_quotes      {
1606                 Pitch p =* unsmob_pitch ($1);
1607                 p = p.transposed (Pitch (-$2,0,0));
1608                 $$ = p.smobbed_copy ();
1609         }
1610         ;
1611
1612 /*
1613 ugh. duplication
1614 */
1615
1616 steno_tonic_pitch:
1617         TONICNAME_PITCH {
1618                 $$ = $1;
1619         }
1620         | TONICNAME_PITCH sup_quotes    {
1621                 Pitch p = *unsmob_pitch ($1);
1622                 p = p.transposed (Pitch ($2,0,0));
1623                 $$ = p.smobbed_copy ();
1624         }
1625         | TONICNAME_PITCH sub_quotes     {
1626                 Pitch p =* unsmob_pitch ($1);
1627
1628                 p = p.transposed (Pitch (-$2,0,0));
1629                 $$ = p.smobbed_copy ();
1630         }
1631         ;
1632
1633 pitch:
1634         steno_pitch {
1635                 $$ = $1;
1636         }
1637         ;
1638
1639 pitch_also_in_chords:
1640         pitch
1641         | steno_tonic_pitch
1642         ;
1643
1644 hyphen_req:
1645         HYPHEN {
1646                 if (!THIS->lexer_->lyric_state_b ())
1647                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1648                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1649         }
1650         ;
1651
1652 close_event:
1653         '('     {
1654                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1655                 $$ = s;
1656                 s->set_spot (THIS->here_input());
1657         }
1658         | E_OPEN        {
1659                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1660                 $$ = s;
1661                 s->set_spot (THIS->here_input());
1662         }
1663         | E_SMALLER {
1664                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1665                 $$ = s;
1666                 s->set_spot (THIS->here_input());
1667         }
1668         | E_BIGGER {
1669                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1670                 $$ = s;
1671                 s->set_spot (THIS->here_input());
1672         }
1673         ;
1674
1675
1676 open_event:
1677         E_EXCLAMATION   {
1678                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1679                 s->set_spot (THIS->here_input());
1680
1681                 $$ = s;
1682         }
1683         | ')'   {
1684                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1685                 $$ = s;
1686                 s->set_spot (THIS->here_input());
1687
1688         }
1689         | E_CLOSE       {
1690                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1691                 $$ = s;
1692                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1693                 s->set_spot (THIS->here_input());
1694         }
1695         ;
1696
1697 gen_text_def:
1698         full_markup {
1699                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1700                 t->set_mus_property ("text", $1);
1701                 t->set_spot (THIS->here_input ());
1702                 $$ = t;
1703         }
1704         | string {
1705                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1706                 t->set_mus_property ("text", make_simple_markup ($1));
1707                 t->set_spot (THIS->here_input ());
1708                 $$ = t;
1709
1710         }
1711         | DIGIT {
1712                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1713                 t->set_mus_property ("digit",  gh_int2scm ($1));
1714                 t->set_spot (THIS->here_input ());
1715                 $$ = t;
1716         }
1717         ;
1718
1719 script_abbreviation:
1720         '^'             {
1721                 $$ = scm_makfrom0str ("Hat");
1722         }
1723         | '+'           {
1724                 $$ = scm_makfrom0str ("Plus");
1725         }
1726         | '-'           {
1727                 $$ = scm_makfrom0str ("Dash");
1728         }
1729         | '|'           {
1730                 $$ = scm_makfrom0str ("Bar");
1731         }
1732         | '>'           {
1733                 $$ = scm_makfrom0str ("Larger");
1734         }
1735         | '.'           {
1736                 $$ = scm_makfrom0str ("Dot");
1737         }
1738         | '_' {
1739                 $$ = scm_makfrom0str ("Underscore");
1740         }
1741         ;
1742
1743 script_dir:
1744         '_'     { $$ = DOWN; }
1745         | '^'   { $$ = UP; }
1746         | '-'   { $$ = CENTER; }
1747         ;
1748
1749
1750 absolute_pitch:
1751         steno_pitch     {
1752                 $$ = $1;
1753         }
1754         ;
1755
1756 duration_length:
1757         multiplied_duration {
1758                 $$ = $1;
1759         }
1760         ;
1761
1762 optional_notemode_duration:
1763         {
1764                 Duration dd = THIS->default_duration_;
1765                 $$ = dd.smobbed_copy ();
1766
1767                 THIS->beam_check ($$);
1768         }
1769         | multiplied_duration   {
1770                 $$ = $1;
1771                 THIS->default_duration_ = *unsmob_duration ($$);
1772
1773                 THIS->beam_check ($$);
1774         }
1775         ;
1776
1777 steno_duration:
1778         bare_unsigned dots              {
1779                 int l = 0;
1780                 if (!is_duration_b ($1))
1781                         THIS->parser_error (_f ("not a duration: %d", $1));
1782                 else
1783                         l =  intlog2 ($1);
1784
1785                 $$ = Duration (l, $2).smobbed_copy ();
1786         }
1787         | DURATION_IDENTIFIER dots      {
1788                 Duration *d =unsmob_duration ($1);
1789                 Duration k (d->duration_log (),d->dot_count () + $2);
1790
1791                 *d = k;
1792                 $$ = $1;
1793         }
1794         ;
1795
1796
1797
1798
1799 multiplied_duration:
1800         steno_duration {
1801                 $$ = $1;
1802         }
1803         | multiplied_duration '*' bare_unsigned {
1804                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1805         }
1806         | multiplied_duration '*' FRACTION {
1807                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1808
1809                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1810         }
1811         ;
1812
1813 fraction:
1814         FRACTION { $$ = $1; }
1815         | UNSIGNED '/' UNSIGNED {
1816                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1817         }
1818         ;
1819
1820 dots:
1821         /* empty */     {
1822                 $$ = 0;
1823         }
1824         | dots '.' {
1825                 $$ ++;
1826         }
1827         ;
1828
1829
1830 tremolo_type:
1831         ':'     {
1832                 $$ =0;
1833         }
1834         | ':' bare_unsigned {
1835                 if (!is_duration_b ($2))
1836                         THIS->parser_error (_f ("not a duration: %d", $2));
1837                 $$ = $2;
1838         }
1839         ;
1840
1841
1842
1843 /*****************************************************************
1844                 BASS FIGURES
1845 *****************************************************************/
1846 bass_number:
1847         DIGIT   {
1848                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1849         }
1850         | UNSIGNED {
1851                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1852         }
1853         | STRING { $$ =  $1; }
1854         ;
1855
1856 bass_mod:
1857         '-'     { $$ = -2; }
1858         | '+'   { $$ = 2; }
1859         | '!'   { $$ = 0; }
1860         ;
1861
1862 bass_figure:
1863         FIGURE_SPACE {
1864                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1865                 $$ = bfr->self_scm();
1866                 scm_gc_unprotect_object ($$);
1867         }
1868         | bass_number  {
1869                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1870                 $$ = bfr->self_scm();
1871
1872                 bfr->set_mus_property ("figure", $1);
1873
1874                 scm_gc_unprotect_object ($$);
1875         }
1876         | bass_figure bass_mod {
1877                 Music *m = unsmob_music ($1);
1878                 if ($2) {
1879                         SCM salter =m->get_mus_property ("alteration");
1880                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1881                         m->set_mus_property ("alteration",
1882                                 gh_int2scm (alter + $2));
1883                 } else {
1884                         m->set_mus_property ("alteration", gh_int2scm (0));
1885                 }
1886         }
1887         ;
1888
1889 br_bass_figure:
1890         '[' bass_figure {
1891                 $$ = $2;
1892                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1893         }
1894         | bass_figure   {
1895                 $$ = $1;
1896         }
1897         | br_bass_figure ']' {
1898                 $$ = $1;
1899                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1900         }
1901         ;
1902
1903 figure_list:
1904         /**/            {
1905                 $$ = SCM_EOL;
1906         }
1907         | figure_list br_bass_figure {
1908                 $$ = scm_cons ($2, $1);
1909         }
1910         ;
1911
1912 figure_spec:
1913         FIGURE_OPEN figure_list FIGURE_CLOSE {
1914                 Music * m = MY_MAKE_MUSIC("EventChord");
1915                 $2 = scm_reverse_x ($2, SCM_EOL);
1916                 m->set_mus_property ("elements",  $2);
1917                 $$ = m->self_scm ();
1918         }
1919         ;
1920
1921
1922 optional_rest:
1923         /**/   { $$ = 0; }
1924         | REST { $$ = 1; }
1925         ;
1926
1927 simple_element:
1928         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1929
1930                 Input i = THIS->pop_spot ();
1931                 if (!THIS->lexer_->note_state_b ())
1932                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1933
1934                 Music *n = 0;
1935                 if ($6)
1936                         n =  MY_MAKE_MUSIC("RestEvent");
1937                 else
1938                         n =  MY_MAKE_MUSIC("NoteEvent");
1939
1940                 n->set_mus_property ("pitch", $1);
1941                 n->set_mus_property ("duration", $5);
1942
1943                 if (gh_number_p ($4))
1944                 {
1945                         int q = gh_scm2int ($4);
1946                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1947                 }
1948
1949                 if ($3 % 2)
1950                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1951                 if ($2 % 2 || $3 % 2)
1952                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1953
1954                 Music *v = MY_MAKE_MUSIC("EventChord");
1955                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1956                 scm_gc_unprotect_object (n->self_scm());
1957
1958                 v->set_spot (i);
1959                 n->set_spot (i);
1960                 $$ = v;
1961         }
1962         | figure_spec optional_notemode_duration {
1963                 Music * m = unsmob_music ($1);
1964                 Input i = THIS->pop_spot ();
1965                 m->set_spot (i);
1966                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1967                 {
1968                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1969                 }
1970                 $$ = m;
1971         }
1972         | RESTNAME optional_notemode_duration           {
1973
1974                 Input i = THIS->pop_spot ();
1975                 Music * ev = 0;
1976                 if (ly_scm2string ($1) =="s") {
1977                         /* Space */
1978                         ev = MY_MAKE_MUSIC("SkipEvent");
1979                   }
1980                 else {
1981                         ev = MY_MAKE_MUSIC("RestEvent");
1982
1983                     }
1984                 ev->set_mus_property ("duration" ,$2);
1985                 ev->set_spot (i);
1986                 Music * velt = MY_MAKE_MUSIC("EventChord");
1987                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
1988                 velt->set_spot (i);
1989
1990                 $$ = velt;
1991         }
1992         | MULTI_MEASURE_REST optional_notemode_duration         {
1993                 THIS->pop_spot ();
1994
1995                 static SCM proc ;
1996                 if (!proc)
1997                         proc = scm_c_eval_string ("make-multi-measure-rest");
1998
1999                 SCM mus = scm_call_2 (proc, $2,
2000                         make_input (THIS->here_input()));
2001                 scm_gc_protect_object (mus);
2002                 $$ = unsmob_music (mus);
2003         }
2004
2005         | lyric_element optional_notemode_duration      {
2006                 Input i = THIS->pop_spot ();
2007                 if (!THIS->lexer_->lyric_state_b ())
2008                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2009
2010                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2011                 lreq->set_mus_property ("text", $1);
2012                 lreq->set_mus_property ("duration",$2);
2013                 lreq->set_spot (i);
2014                 Music * velt = MY_MAKE_MUSIC("EventChord");
2015                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2016
2017                 $$= velt;
2018         }
2019         | new_chord {
2020                 THIS->pop_spot ();
2021
2022                 if (!THIS->lexer_->chord_state_b ())
2023                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2024                 $$ = unsmob_music ($1);
2025         }
2026         ;
2027
2028 lyric_element:
2029         full_markup { $$ = $1; }
2030         | STRING {  $$ = $1 ; }
2031         ;
2032
2033 new_chord:
2034         steno_tonic_pitch optional_notemode_duration   {
2035                 $$ = make_chord ($1, $2, SCM_EOL);
2036         }
2037         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2038                 SCM its = scm_reverse_x ($4, SCM_EOL);
2039                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2040         }
2041         ;
2042
2043 chord_items:
2044         /**/ {
2045                 $$ = SCM_EOL;
2046         }
2047         | chord_items chord_item {
2048                 $$ = gh_cons ($2, $$);
2049         }
2050         ;
2051
2052 chord_separator:
2053         CHORD_COLON {
2054                 $$ = ly_symbol2scm ("chord-colon");
2055         }
2056         | CHORD_CARET {
2057                 $$ = ly_symbol2scm ("chord-caret");
2058         }
2059         | CHORD_SLASH steno_tonic_pitch {
2060                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2061         }
2062         | CHORD_BASS steno_tonic_pitch {
2063                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2064         }
2065         ;
2066
2067 chord_item:
2068         chord_separator {
2069                 $$ = $1;
2070         }
2071         | step_numbers {
2072                 $$ = scm_reverse_x ($1, SCM_EOL);
2073         }
2074         | CHORD_MODIFIER  {
2075                 $$ = $1;
2076         }
2077         ;
2078
2079 step_numbers:
2080         step_number { $$ = gh_cons ($1, SCM_EOL); }
2081         | step_numbers '.' step_number {
2082                 $$ = gh_cons ($3, $$);
2083         }
2084         ;
2085
2086 step_number:
2087         bare_unsigned {
2088                 $$ = make_chord_step ($1, 0);
2089         }
2090         | bare_unsigned '+' {
2091                 $$ = make_chord_step ($1, SHARP);
2092         }
2093         | bare_unsigned CHORD_MINUS {
2094                 $$ = make_chord_step ($1, FLAT);
2095         }
2096         ;
2097
2098 /*
2099         UTILITIES
2100
2101 TODO: should deprecate in favor of Scheme?
2102
2103  */
2104 number_expression:
2105         number_expression '+' number_term {
2106                 $$ = scm_sum ($1, $3);
2107         }
2108         | number_expression '-' number_term {
2109                 $$ = scm_difference ($1, $3);
2110         }
2111         | number_term
2112         ;
2113
2114 number_term:
2115         number_factor {
2116                 $$ = $1;
2117         }
2118         | number_factor '*' number_factor {
2119                 $$ = scm_product ($1, $3);
2120         }
2121         | number_factor '/' number_factor {
2122                 $$ = scm_divide ($1, $3);
2123         }
2124         ;
2125
2126 number_factor:
2127         '-'  number_factor { /* %prec UNARY_MINUS */
2128                 $$ = scm_difference ($2, SCM_UNDEFINED);
2129         }
2130         | bare_number
2131         ;
2132
2133
2134 bare_number:
2135         UNSIGNED        {
2136                 $$ = gh_int2scm ($1);
2137         }
2138         | REAL          {
2139                 $$ = $1;
2140         }
2141         | NUMBER_IDENTIFIER             {
2142                 $$ = $1;
2143         }
2144         | REAL NUMBER_IDENTIFIER        {
2145                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2146         }
2147         | UNSIGNED NUMBER_IDENTIFIER    {
2148                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2149         }
2150         ;
2151
2152
2153 bare_unsigned:
2154         UNSIGNED {
2155                         $$ = $1;
2156         }
2157         | DIGIT {
2158                 $$ = $1;
2159         }
2160         ;
2161
2162 bare_int:
2163         bare_number {
2164                 if (scm_integer_p ($1) == SCM_BOOL_T)
2165                 {
2166                         int k = gh_scm2int ($1);
2167                         $$ = k;
2168                 } else
2169                 {
2170                         THIS->parser_error (_ ("need integer number arg"));
2171                         $$ = 0;
2172                 }
2173         }
2174         | '-' bare_int {
2175                 $$ = -$2;
2176         }
2177         ;
2178
2179
2180 string:
2181         STRING          {
2182                 $$ = $1;
2183         }
2184         | STRING_IDENTIFIER     {
2185                 $$ = $1;
2186         }
2187         | string '+' string {
2188                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2189         }
2190         ;
2191
2192
2193 exclamations:
2194                 { $$ = 0; }
2195         | exclamations '!'      { $$ ++; }
2196         ;
2197
2198 questions:
2199                 { $$ = 0; }
2200         | questions '?' { $$ ++; }
2201         ;
2202
2203
2204
2205 full_markup:
2206         MARKUP_IDENTIFIER {
2207                 $$ = $1;
2208         }
2209         | MARKUP
2210                 { THIS->lexer_->push_markup_state (); }
2211         markup
2212                 { $$ = $3;
2213                   THIS->lexer_->pop_state ();
2214                 }
2215         ;
2216
2217
2218 /*
2219 This should be done more dynamically if possible.
2220 */
2221 markup:
2222         STRING {
2223                 $$ = make_simple_markup ($1);
2224         }
2225         | MARKUP_HEAD_MARKUP0 markup {
2226                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2227         }
2228         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2229                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2230         }
2231         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2232                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2233         }
2234         | markup_line {
2235                 $$ = $1;
2236         }
2237         | MARKUP_HEAD_LIST0 markup_list {
2238                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2239         }
2240         | MARKUP_HEAD_SCM0 embedded_scm {
2241                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2242         }
2243         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2244                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2245         }
2246         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2247                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2248         }
2249         | MARKUP_IDENTIFIER {
2250                 $$ = $1;
2251         }
2252
2253         ;
2254
2255 markup_list:
2256         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2257         ;
2258
2259 markup_line:
2260         '{' markup_list_body '}' {
2261                 static SCM line ;
2262                 if (!line)
2263                         line = scm_c_eval_string ("line-markup");
2264
2265                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2266         }
2267         ;
2268
2269 markup_list_body:
2270         /**/ {  $$ = SCM_EOL; }
2271         | markup_list_body markup {
2272                 $$ = gh_cons ($2, $1) ;
2273         }
2274         ;
2275
2276
2277 %%
2278
2279 void
2280 My_lily_parser::set_yydebug (bool )
2281 {
2282 #if 0
2283         yydebug = 1;
2284 #endif
2285 }
2286
2287 extern My_lily_parser * current_parser;
2288
2289 void
2290 My_lily_parser::do_yyparse ()
2291 {
2292         current_parser = this;;
2293         yyparse ((void*)this);
2294 }
2295
2296
2297 /*
2298 Should make this optional?    It will also complain when you do
2299
2300         [s4]
2301
2302 which is entirely legitimate.
2303
2304 Or we can scrap it. Barchecks should detect wrong durations, and
2305 skipTypesetting speeds it up a lot.
2306 */
2307
2308 void
2309 My_lily_parser::beam_check (SCM dur)
2310 {
2311   Duration *d = unsmob_duration (dur);
2312   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2313     {
2314       Music * m = unsmob_music (last_beam_start_);
2315       m->origin ()->warning (_("Suspect duration found following this beam"));
2316     }
2317   last_beam_start_ = SCM_EOL;
2318 }
2319
2320
2321
2322
2323 /*
2324
2325 It is a little strange to have this function in this file, but
2326 otherwise, we have to import music classes into the lexer.
2327
2328 */
2329 int
2330 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2331 {
2332         if (gh_string_p (sid)) {
2333                 *destination = sid;
2334                 return STRING_IDENTIFIER;
2335         } else if (gh_number_p (sid)) {
2336                 *destination = sid;
2337                 return NUMBER_IDENTIFIER;
2338         } else if (unsmob_context_def (sid)) {
2339                 *destination = unsmob_context_def (sid)->clone_scm();
2340                 return TRANSLATOR_IDENTIFIER;
2341         } else if (unsmob_score (sid)) {
2342                 Score *sc =  new Score (*unsmob_score (sid));
2343                 *destination =sc->self_scm ();
2344                 return SCORE_IDENTIFIER;
2345         } else if (Music * mus =unsmob_music (sid)) {
2346                 *destination = unsmob_music (sid)->clone ()->self_scm();
2347                 unsmob_music (*destination)->
2348                         set_mus_property ("origin", make_input (last_input_));
2349                 return dynamic_cast<Event*> (mus)
2350                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2351         } else if (unsmob_duration (sid)) {
2352                 *destination = unsmob_duration (sid)->smobbed_copy();
2353                 return DURATION_IDENTIFIER;
2354         } else if (unsmob_music_output_def (sid)) {
2355                 Music_output_def *p = unsmob_music_output_def (sid);
2356                 p = p->clone ();
2357
2358                 *destination = p->self_scm();
2359                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2360         } else if (Text_item::markup_p (sid)) {
2361                 *destination = sid;
2362                 return MARKUP_IDENTIFIER;
2363         }
2364
2365         return -1;
2366 }
2367
2368 Music *
2369 property_op_to_music (SCM op)
2370 {
2371         Music * m = 0;
2372         SCM tag = gh_car (op);
2373         SCM symbol  = gh_cadr (op);
2374         SCM args = gh_cddr (op);
2375         SCM grob_val = SCM_UNDEFINED;
2376         SCM grob_sym = SCM_UNDEFINED;
2377         SCM val = SCM_UNDEFINED;
2378
2379         if (tag == ly_symbol2scm ("assign"))
2380                 {
2381                 m =  MY_MAKE_MUSIC("PropertySet");
2382                 val = gh_car (args);
2383                 }
2384         else if (tag == ly_symbol2scm ("unset"))
2385                 m =  MY_MAKE_MUSIC("PropertyUnset");
2386         else if (tag == ly_symbol2scm ("poppush")
2387                  || tag == ly_symbol2scm ("push"))
2388                 {
2389                 m  = MY_MAKE_MUSIC("OverrideProperty");
2390                 grob_sym = gh_car (args);
2391                 grob_val = gh_cadr (args);
2392                 }
2393         else if (tag == ly_symbol2scm ("pop")) {
2394                 m = MY_MAKE_MUSIC("RevertProperty");
2395                 grob_sym = gh_car (args);
2396                 }
2397
2398         m->set_mus_property ("symbol", symbol);
2399
2400         if (val != SCM_UNDEFINED)
2401                 m->set_mus_property ("value", val);
2402         if (grob_val != SCM_UNDEFINED)
2403                 m->set_mus_property ("grob-value", grob_val);
2404
2405         if (grob_sym != SCM_UNDEFINED)
2406                 {
2407                 bool itc = internal_type_checking_global_b;
2408                 /* UGH.
2409                 */
2410                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2411                 if (autobeam)
2412                         internal_type_checking_global_b = false;
2413                 m->set_mus_property ("grob-property", grob_sym);
2414                 if (autobeam)
2415                         internal_type_checking_global_b = itc;
2416                 }
2417
2418         if (op == ly_symbol2scm ("poppush"))
2419                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2420
2421
2422         return m;
2423 }
2424
2425 Music*
2426 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2427 {
2428         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2429
2430         csm->set_mus_property ("element", m->self_scm ());
2431         scm_gc_unprotect_object (m->self_scm ());
2432
2433         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2434         csm->set_mus_property ("property-operations", ops);
2435
2436         if (gh_string_p (id))
2437                 csm->set_mus_property ("context-id", id);
2438         return csm;
2439 }
2440
2441
2442 SCM
2443 get_next_unique_context ()
2444 {
2445         static int new_context_count;
2446
2447         char s[1024];
2448         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2449
2450         return scm_makfrom0str (s);
2451 }