configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10 # For stepmake package:
  11 # AC_CONFIG_AUX_DIR(bin)
  12
  13
  14 STEPMAKE_INIT
  15
  16 # List a file that identifies your package.
  17 AC_CONFIG_SRCDIR([lily/main.cc])
  18
  19 # Move to aclocal.m4?
  20 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  21
  22 # Uncomment the configuration options your package needs.
  23
  24
  25 gui_b=no
  26 AC_ARG_ENABLE(gui,
  27     [  --enable-gui            compile with experimental GNOME output module.  Default: off],
  28     [gui_b=$enableval])
  29
  30 # must come before any header checks
  31 STEPMAKE_COMPILE
  32
  33 STEPMAKE_PYTHON(REQUIRED,2.1)
  34 STEPMAKE_GCC(REQUIRED, 2.8)
  35 STEPMAKE_CXX(REQUIRED)
  36 STEPMAKE_GXX(REQUIRED, 3.0.5)
  37 STEPMAKE_CXXTEMPLATE
  38 STEPMAKE_LIB(REQUIRED)
  39 # Do not use bison 1.50 and 1.75.
  40 STEPMAKE_BISON(REQUIRED, 1.25)
  41 STEPMAKE_FLEX(REQUIRED)
  42 STEPMAKE_FLEXLEXER(REQUIRED)
  43 AC_LANG_C
  44 STEPMAKE_LOCALE
  45 STEPMAKE_GETTEXT
  46 STEPMAKE_MSGFMT(REQUIRED)
  47 STEPMAKE_TEXMF(REQUIRED)
  48 STEPMAKE_TEXMF_DIRS
  49 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.6)
  50 STEPMAKE_KPATHSEA
  51 STEPMAKE_MAKEINFO(REQUIRED)
  52 STEPMAKE_PYTHON_DEVEL(REQUIRED)
  53
  54 # mftrace for generating pfa's, pfb's
  55 STEPMAKE_PROGS(MFTRACE, mftrace, REQUIRED, 1.0.27)
  56
  57 # mftrace for generating pfa's, pfb's
  58 STEPMAKE_PROGS(FONTFORGE, fontforge, REQUIRED)
  59
  60 # version:  20041208)
  61
  62
  63 AC_CHECK_HEADERS([assert.h sys/stat.h])
  64 AC_LANG_PUSH(C++)
  65 AC_CHECK_HEADERS([sstream])
  66 AC_LANG_POP(C++)
  67 AC_HEADER_STAT
  68 AC_FUNC_MEMCMP
  69 AC_FUNC_VPRINTF
  70 AC_CHECK_FUNCS([gettext isinf memmem snprintf vsnprintf gettext])
  71
  72 AC_MSG_CHECKING([for ec-fonts-mftraced])
  73 ecb10=`kpsewhich ecb10.pfa 2>/dev/null`
  74 if test -n "$ecb10"; then
  75     AC_MSG_RESULT([$ecb10])
  76 else
  77     AC_MSG_RESULT(no)
  78     AC_MSG_CHECKING([for lmodern])
  79     lmr10=`kpsewhich lmr10.pfb 2>/dev/null`
  80     if test -n "$lmr10"; then
  81         AC_MSG_RESULT([$lmr10])
  82     else
  83         STEPMAKE_ADD_ENTRY(REQUIRED, 'package ec-fonts-mftraced >= 1.0.5')
  84         AC_MSG_CHECKING([for old version of ec-fonts-mftraced])
  85         ecrm10=`kpsewhich ecrm10.pfa 2>/dev/null`
  86         if test -n "$ecrm10"; then
  87             AC_MSG_RESULT([$ecrm10])
  88             AC_MSG_WARN([old version of ec-fonts-mftraced found, install 1.0.5 or newer])
  89         fi
  90     fi
  91 fi
  92
  93 # This is developer only anyway, help pkgconfig a bit
  94 export PKG_CONFIG_PATH
  95 PKG_CONFIG_PATH=/usr/lib/pkgconfig:$PKG_CONFIG_PATH
  96 PKG_CONFIG_PATH=/opt/gnome/lib/pkgconfig:$PKG_CONFIG_PATH
  97 PKG_CONFIG_PATH=$HOME/usr/pkg/gnome/lib/pkgconfig:$PKG_CONFIG_PATH
  98 PKG_CONFIG_PATH=$HOME/usr/pkg/pango/lib/pkgconfig:$PKG_CONFIG_PATH
  99
 100 if test "$gui_b" = "yes"; then
 101     STEPMAKE_GTK2
 102 fi
 103
 104 STEPMAKE_FREETYPE2
 105 STEPMAKE_PANGO
 106
 107 ## Optional tools for building documentation, website, extra fonts.
 108
 109 # guile executable for some scripts
 110 STEPMAKE_GUILE(OPTIONAL)
 111 # perl for help2man.
 112 STEPMAKE_PERL(OPTIONAL)
 113
 114
 115
 116 # New makeinfo for multi-page website docs Simply always require new
 117 # makeinfo should avoid bug reports; if people want to build lily
 118 # without the docs, they can find this comment and use an older
 119 # makeinfo -- but hopefully won't report makeinfo problems.
 120 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.7)
 121 AC_SUBST(MAKEINFO_VERSION)
 122
 123
 124 if test "$optimise_b" = yes; then
 125     DEFINES="$DEFINES -DSTRING_UTILS_INLINED"
 126     AC_DEFINE(STRINGS_UTILS_INLINED)
 127 fi
 128
 129 AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 130 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 131
 132 # Gather requirements and generate output.
 133 STEPMAKE_END
 134
 135
 136 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 137
 138 cat <<EOF
 139
 140 Type:
 141     make$mc all       to build LilyPond
 142     make$mc install   to install LilyPond
 143     make$mc help      to see all possible targets
 144
 145 EOF