configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10
  11 # For stepmake package:
  12 # AC_CONFIG_AUX_DIR(bin)
  13
  14
  15 STEPMAKE_INIT
  16
  17 # List a file that identifies your package.
  18 AC_CONFIG_SRCDIR([lily/main.cc])
  19
  20 # Move to aclocal.m4?
  21 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  22
  23 # Uncomment the configuration options your package needs.
  24
  25 DOCUMENTATION=yes
  26 AC_ARG_ENABLE(documentation,
  27     [  --enable-documentation  build Documentation.  Default: on],
  28     [DOCUMENTATION=$enableval])
  29 AC_SUBST(DOCUMENTATION)
  30
  31 gui_b=no
  32 AC_ARG_ENABLE(gui,
  33     [  --enable-gui            compile with experimental GNOME output.  Default: off],
  34     [gui_b=$enableval])
  35
  36 std_string=yes
  37 AC_ARG_ENABLE(std-string,
  38     [  --enable-std-string     compile with std::string.  Default: on],
  39     [std_string=$enableval])
  40 if test "$std_string" = "yes"; then
  41     # Store in config.make rather than in config.hh and have every
  42     # source file depend on that.
  43     DEFINES="$DEFINES -DSTD_STRING=1"
  44 fi
  45
  46 std_vector=yes
  47 AC_ARG_ENABLE(std-string,
  48     [  --enable-std-vector     compile with std::vector.  Default: on],
  49     [std_vector=$enableval])
  50 if test "$std_vector" = "yes"; then
  51     # Store in config.make rather than in config.hh and have every
  52     # source file depend on that.
  53     DEFINES="$DEFINES -DSTD_VECTOR=1"
  54 fi
  55
  56 NCSB_DIR=unknown
  57 AC_ARG_WITH(ncsb-dir,
  58 [  --with-ncsb-dir=DIR     location of Century Schoolbook fonts
  59                             Default: detect with locate(1)],
  60     [NCSB_DIR=$withval])
  61
  62
  63 reloc_b=no
  64 AC_ARG_ENABLE(relocation,
  65     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  66     [reloc_b=$enableval])
  67
  68 FRAMEWORKDIR=".."
  69 AC_ARG_WITH(framework-dir,
  70     [  --with-framework-dir=DIR
  71                           relative location of framework],[
  72         if test "$withval" = "yes" -o "$withval" = "no"; then
  73             AC_MSG_WARN(Usage: --with-framework-dir=../lib/FRAMEWORK/DIR)
  74         else
  75             FRAMEWORKDIR="${withval}"
  76             LDFLAGS="$LDFLAGS -Wl,--rpath,'\$\${ORIGIN}/$FRAMEWORKDIR/lib'"
  77         fi
  78         ])
  79 AC_DEFINE_UNQUOTED(FRAMEWORKDIR, ["${FRAMEWORKDIR}"])
  80
  81 LINK_GXX_STATICALLY=no
  82 AC_ARG_ENABLE(static-gxx,
  83     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  84     [LINK_GXX_STATICALLY=$enableval])
  85 AC_SUBST(LINK_GXX_STATICALLY)
  86
  87 # must come before any header checks
  88 STEPMAKE_COMPILE
  89
  90 STEPMAKE_PYTHON(REQUIRED, 2.2)
  91 STEPMAKE_GCC(REQUIRED, 2.8)
  92 STEPMAKE_CXX(REQUIRED)
  93 STEPMAKE_GXX(REQUIRED, 3.0.5)
  94 STEPMAKE_CXXTEMPLATE
  95 STEPMAKE_STL_DATA_METHOD
  96 STEPMAKE_LIB(REQUIRED)
  97 STEPMAKE_DLOPEN
  98 # Do not use bison 1.50 and 1.75.
  99 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 100 STEPMAKE_BISON(OPTIONAL, 1.29)
 101 STEPMAKE_FLEX(REQUIRED)
 102 STEPMAKE_FLEXLEXER(REQUIRED)
 103 STEPMAKE_FLEXLEXER_LOCATION
 104 AC_LANG_C
 105 STEPMAKE_LOCALE
 106 STEPMAKE_GETTEXT
 107 STEPMAKE_MSGFMT(REQUIRED)
 108 STEPMAKE_TEXMF(REQUIRED)
 109 STEPMAKE_TEXMF_DIRS
 110 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.6.5)
 111 STEPMAKE_MAKEINFO(REQUIRED)
 112 STEPMAKE_PYTHON_DEVEL(REQUIRED)
 113
 114 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.15)
 115
 116 STEPMAKE_PROGS(MFTRACE, mftrace, REQUIRED, 1.1.9)
 117 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
 118
 119 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h])
 120 AC_LANG_PUSH(C++)
 121 AC_CHECK_HEADERS([sstream])
 122 AC_LANG_POP(C++)
 123 AC_HEADER_STAT
 124 AC_FUNC_MEMCMP
 125 AC_FUNC_VPRINTF
 126 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
 127 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
 128 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
 129
 130 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 131
 132 if test "$gui_b" = "yes"; then
 133     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
 134 fi
 135
 136 if test "$reloc_b" = "yes"; then
 137     AC_DEFINE(ARGV0_RELOCATION)
 138 fi
 139
 140 AC_MSG_CHECKING([New Century Schoolbook PFB files])
 141 if test "$NCSB_DIR" = "unknown"; then
 142   # use `type' command rather than external program `which'
 143   type locate >& /dev/null
 144   if test "$?" = "0"; then
 145       for d in `locate c059033l.pfb `; do
 146           if test -f `dirname "$d"`/c059033l.afm ; then
 147               NCSB_DIR=`dirname "$d"`
 148               break
 149           fi
 150       done
 151       if test "$NCSB_DIR" = "unknown";  then
 152           AC_MSG_WARN(Could not find c059033l.pfb. Use --enable-ncsb-path to set path)
 153       fi
 154   else
 155      AC_MSG_WARN(Could not find locate(1). Use --enable-ncsb-path to set path to c059033l.pfb)
 156   fi
 157 fi
 158
 159 AC_MSG_RESULT($NCSB_DIR)
 160 AC_SUBST(NCSB_DIR)
 161
 162 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 163 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
 164 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
 165 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 0)
 166
 167 STEPMAKE_WINDOWS
 168
 169 ## Optional tools for building documentation, website, extra fonts.
 170
 171 # guile executable for some scripts
 172 STEPMAKE_GUILE(OPTIONAL)
 173
 174 # perl for help2man.
 175 STEPMAKE_PERL(OPTIONAL)
 176
 177 # New makeinfo for multi-page website docs Simply always require new
 178 # makeinfo should avoid bug reports; if people want to build lily
 179 # without the docs, they can find this comment and use an older
 180 # makeinfo--but hopefully won't report makeinfo problems.
 181 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.7)
 182
 183 if test "$optimise_b" = yes; then
 184     DEFINES="$DEFINES -DSTRING_UTILS_INLINED"
 185     AC_DEFINE(STRINGS_UTILS_INLINED)
 186 fi
 187
 188 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 189
 190 # Gather requirements and generate output.
 191 STEPMAKE_END
 192
 193 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 194
 195 cat <<EOF
 196
 197 Type:
 198     make$mc all       to build LilyPond
 199     make$mc install   to install LilyPond
 200     make$mc help      to see all possible targets
 201
 202 EOF