aclocal.m4

   1 dnl WARNING WARNING WARNING WARNING
   2 dnl do not edit! this is aclocal.m4, generated from stepmake/stepmake/../aclocal.m4
   3 dnl aclocal.m4   -*-shell-script-*-
   4 dnl StepMake subroutines for configure.in
   5
   6 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   7     # -O is necessary to get inlining
   8     OPTIMIZE=""
   9     CXXFLAGS=${CXXFLAGS:-""}
  10     CFLAGS=${CFLAGS:-""}
  11     checking_b=yes
  12     optimise_b=no
  13     profile_b=no
  14     debug_b=yes
  15
  16     AC_ARG_ENABLE(checking,
  17     [  enable-checking         set runtime checks (assert calls). Default: on],
  18     [checking_b=$enableval] )
  19
  20     # actually, the default is: tja='-O' to get inlining...
  21     # off=''  --jcn
  22
  23     #actually, that sucks.
  24     #  tja looks like a typo.  Default is optimisation off. --hwn
  25
  26     AC_ARG_ENABLE(optimise,
  27     [  enable-optimise         use maximal speed optimisations. Default: off],
  28     [optimise_b=$enableval])
  29
  30     AC_ARG_ENABLE(profiling,
  31     [  enable-profiling        compile with gprof support. Default: off],
  32     [profile_b=$enableval])
  33
  34     AC_ARG_ENABLE(debugging,
  35     [  enable-debugging        set debug info. Default: on],
  36     [debug_b=$enableval])
  37
  38     AC_ARG_ENABLE(mingw-prefix,
  39     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  40     [MINGWPREFIX=$enableval],
  41     [MINGWPREFIX=no])
  42
  43     if test "$printing_b" = no; then
  44         # ugh
  45         AC_DEFINE(NPRINT)
  46         DEFINES="$DEFINES -DNPRINT"
  47     fi
  48
  49     if test "$checking_b" = no; then
  50         # ugh
  51         AC_DEFINE(NDEBUG)
  52         DEFINES="$DEFINES -DNDEBUG"
  53     fi
  54
  55     if test "$optimise_b" = yes; then
  56         OPTIMIZE="-O2 -finline-functions"
  57     fi
  58
  59     if test "$optimise_b" = no; then
  60         OPTIMIZE=""
  61     fi
  62
  63     if test $profile_b = yes; then
  64         EXTRA_LIBES="-pg"
  65         OPTIMIZE="$OPTIMIZE -pg"
  66     fi
  67
  68     if test $debug_b = yes; then
  69         OPTIMIZE="$OPTIMIZE -g"
  70     fi
  71
  72     # however, C++ support in mingw32 v 0.1.4 is still flaky
  73     if test x$MINGWPREFIX != xno; then
  74         ICFLAGS="-I$MINGWPREFIX/include"
  75         ILDFLAGS="-$MINGWPREFIX/lib"
  76     fi
  77
  78     AC_PROG_CC
  79     LD='$(CC)'
  80     AC_SUBST(LD)
  81
  82     CPPFLAGS=${CPPFLAGS:-""}
  83     AC_SUBST(CPPFLAGS)
  84     AC_SUBST(LDFLAGS)
  85     AC_SUBST(ICFLAGS)
  86     AC_SUBST(ILDFLAGS)
  87     AC_SUBST(DEFINES)
  88     AC_SUBST(EXTRA_LIBES)
  89 ])
  90
  91 AC_DEFUN(AC_STEPMAKE_CXX, [
  92     AC_LANG_CPLUSPLUS
  93     AC_PROG_CXX
  94
  95     AC_CHECK_HEADER(FlexLexer.h, true,
  96         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  97
  98     CPPFLAGS="$CPPFLAGS $DEFINES"
  99     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 100     LDFLAGS=$EXTRA_LIBES
 101
 102     AC_SUBST(CXXFLAGS)
 103     AC_SUBST(CXX)
 104     LD='$(CXX)'
 105     AC_SUBST(LD)
 106 ])
 107
 108 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 109     AC_CACHE_CHECK([whether explicit instantiation is needed],
 110         lily_cv_need_explicit_instantiation,
 111         AC_TRY_LINK([
 112     template <class T> struct foo { static int baz; };
 113     template <class T> int foo<T>::baz = 1;
 114     ], [ return foo<int>::baz; ],
 115             lily_cv_need_explicit_instantiation=no,
 116             lily_cv_need_explicit_instantiation=yes))
 117     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 118         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 119     fi
 120 ])
 121
 122 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 123     if test "$datadir" = "\${prefix}/share"; then
 124             datadir='${prefix}/share/'$package
 125     fi
 126     DIR_DATADIR=${datadir}
 127     presome=${prefix}
 128     if test "$prefix" = "NONE"; then
 129             presome=${ac_default_prefix}
 130     fi
 131     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 132     AC_SUBST(datadir)
 133     AC_SUBST(DIR_DATADIR)
 134     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 135 ])
 136
 137 AC_DEFUN(AC_STEPMAKE_END, [
 138     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 139
 140     rm -f GNUmakefile
 141     cp make/toplevel.make.in ./GNUmakefile
 142     chmod 444 GNUmakefile
 143 ])
 144
 145 AC_DEFUN(AC_STEPMAKE_GXX, [
 146     # ugh autoconf
 147     changequote(<<, >>)dnl
 148     if $CXX --version | grep '2\.[78]' > /dev/null ||
 149         $CXX --version | grep 'egcs' > /dev/null
 150     changequote([, ])dnl
 151     then
 152             true
 153     else
 154             AC_STEPMAKE_WARN(can\'t find g++ 2.7, 2.8 or egcs)
 155     fi
 156 ])
 157
 158 AC_DEFUN(AC_STEPMAKE_INIT, [
 159
 160     . $srcdir/VERSION
 161     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 162     if test x$MY_PATCH_LEVEL != x; then
 163         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 164     fi
 165
 166     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 167     changequote(<<, >>)dnl
 168     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 169     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 170     changequote([, ])dnl
 171
 172     if test "x$PACKAGE" = "xSTEPMAKE"; then
 173         echo Stepmake package!
 174         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 175         (cd stepmake; rm -f bin; ln -s ../bin .)
 176         AC_CONFIG_AUX_DIR(bin)
 177     else
 178         echo Package: $PACKAGE
 179         AC_CONFIG_AUX_DIR(stepmake/bin)
 180     fi
 181
 182     AC_SUBST(package)
 183     AC_SUBST(PACKAGE)
 184     AC_SUBST(PACKAGE_NAME)
 185     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 186     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 187
 188     package_depth=`dirname $cache_file`
 189     AC_SUBST(package_depth)
 190
 191     AUTOGENERATE="This file was automatically generated by configure"
 192     AC_SUBST(AUTOGENERATE)
 193     absolute_builddir="`pwd`"
 194     AC_SUBST(absolute_builddir)
 195
 196     # No versioning on directory names of sub-packages
 197     stepmake=stepmake
 198     AC_SUBST(stepmake)
 199
 200     STATE_VECTOR=`ls make/STATE-VECTOR 2>/dev/null`
 201     if test "x$STATE_VECTOR" != "x"; then
 202         STATE_VECTOR="\$(depth)/$STATE_VECTOR"
 203     fi
 204     AC_SUBST(STATE_VECTOR)
 205
 206     CONFIGSUFFIX=
 207     AC_ARG_ENABLE(config,
 208     [  enable-config=FILE      put configure settings in config-FILE.make],
 209     [CONFIGSUFFIX=$enableval])
 210
 211     if test "$CONFIGSUFFIX" != "" ; then
 212         CONFIGFILE=config-$CONFIGSUFFIX
 213     else
 214         CONFIGFILE=config
 215     fi
 216     AC_SUBST(CONFIGSUFFIX)
 217
 218     AC_CANONICAL_HOST
 219     AC_CHECK_PROGS(MAKE, make, error)
 220     AC_CHECK_PROGS(FIND, find, error)
 221
 222
 223 dnl system supplied INSTALL is unsafe; use our own install.
 224 dnl    AC_PROG_INSTALL
 225 dnl    if test "$INSTALL" = "bin/install-sh"; then
 226 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 227 dnl    fi
 228
 229     AC_CHECK_PROGS(TAR, tar, error)
 230     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 231
 232     AC_PATH_PROG(PYTHON, python, -echo no python)
 233     AC_SUBST(PYTHON)
 234
 235
 236     AC_CHECK_SEARCH_RESULT($MAKE, GNU make,  You should install GNU make)
 237     if test $MAKE != "error" ; then
 238         $MAKE -v| grep GNU > /dev/null
 239         if test "$?" = 1
 240         then
 241                 AC_STEPMAKE_WARN(Please install *GNU* make)
 242         fi
 243     fi
 244
 245     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 246
 247     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 248         LN=cp # hard link does not work under cygnus-nt
 249         LN_S=cp # symbolic link does not work for native nt
 250         ZIP="zip -r -9" #
 251         DOTEXE=.exe
 252        DIRSEP='\\'
 253         PATHSEP=';'
 254        INSTALL="\$(stepdir)/../bin/install-dot-exe.sh -c"
 255     else
 256         DIRSEP='/'
 257         PATHSEP=':'
 258         LN=ln
 259         LN_S='ln -s'
 260         ZIP="zip -r -9"
 261         INSTALL="\$(stepdir)/../bin/install-sh -c"
 262     fi
 263     AC_SUBST(DOTEXE)
 264     AC_SUBST(ZIP)
 265     AC_SUBST(LN)
 266     AC_SUBST(LN_S)
 267     AC_SUBST(INSTALL)
 268     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 269     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 270     AC_SUBST(PATHSEP)
 271     AC_SUBST(DIRSEP)
 272
 273
 274     AC_STEPMAKE_DATADIR
 275 ])
 276
 277 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 278     # ugh, automake: we want (and check for) bison
 279     AC_PROG_YACC
 280     # ugh, automake: we want (and check for) flex
 281     # AC_PROG_LEX
 282     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 283
 284     # AC_DECL_YYTEXT
 285     # ugh, ugh
 286     ac_cv_prog_lex_root=lex.yy
 287
 288     AC_CHECK_PROGS(BISON, bison, error)
 289     AC_CHECK_PROGS(FLEX, flex, error)
 290     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or better)
 291     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or better)
 292
 293     if test $BISON != "error"; then
 294         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 295         if test $bison_version -lt 25; then
 296             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 297         fi
 298     fi
 299
 300     AC_SUBST(BISON)
 301     AC_SUBST(FLEX)
 302 ])
 303
 304 AC_DEFUN(AC_STEPMAKE_LIB, [
 305     AC_CHECK_PROGS(AR, ar, error)
 306     AC_PROG_RANLIB
 307
 308     AC_SUBST(AR)
 309     AC_SUBST(RANLIB)
 310 ])
 311
 312 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 313     # libtool.info ...
 314     # **Never** try to set library version numbers so that they correspond
 315     # to the release number of your package.  This is an abuse that only
 316     # fosters misunderstanding of the purpose of library versions.
 317
 318     REVISION=$PATCH_LEVEL
 319     # CURRENT=$MINOR_VERSION
 320     CURRENT=`expr $MINOR_VERSION + 1`
 321     # AGE=$(expr $MAJOR_VERSION + 1)
 322     AGE=$MAJOR_VERSION
 323     AC_SUBST(CURRENT)
 324     AC_SUBST(REVISION)
 325     AC_SUBST(AGE)
 326 ])
 327
 328 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 329     lang=English
 330     ALL_LINGUAS="en nl"
 331
 332     # with/enable ??
 333     AC_ARG_WITH(localedir,
 334     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 335     localedir=$with_localedir,
 336     localedir='${prefix}/share/locale')
 337
 338     AC_ARG_WITH(lang,
 339     [  with-lang=LANG          use LANG as language to emit messages],
 340     language=$with_lang,
 341     language=English)
 342
 343     AC_MSG_CHECKING(language)
 344     case "$language" in
 345       En* | en* | Am* | am* | US* | us*)
 346             lang=English;;
 347       NL | nl | Du* | du* | Ned* | ned*)
 348             lang=Dutch;;
 349       "")
 350             lang=English;;
 351       *)
 352             lang=unknown;;
 353     esac
 354     AC_MSG_RESULT($lang)
 355
 356     if test "$lang" = "unknown" ; then
 357         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 358     fi
 359
 360 ])
 361
 362 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 363     DIR_LOCALEDIR=${localedir}
 364     presome=${prefix}
 365     if test "$prefix" = "NONE"; then
 366             presome=${ac_default_prefix}
 367     fi
 368     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 369     AC_SUBST(localedir)
 370     AC_SUBST(DIR_LOCALEDIR)
 371     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 372
 373     AC_CHECK_LIB(intl, gettext)
 374     AC_CHECK_FUNCS(gettext)
 375 ])
 376
 377 AC_DEFUN(AC_STEPMAKE_MAN, [
 378     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 379 ])
 380
 381 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 382     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 383     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 384     AC_MSG_CHECKING(whether msgfmt accepts -o)
 385     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 386     if test "$msgfmt_output" = ""; then
 387         AC_MSG_RESULT(yes)
 388     else
 389         # urg
 390         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 391         AC_MSG_RESULT(no)
 392         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 393     fi
 394     if test ! -n "$MSGFMT"; then
 395         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 396     fi
 397 ])
 398
 399 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 400     AC_ARG_ENABLE(tex-prefix,
 401     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 402     [TEXPREFIX=$enableval],
 403     [TEXPREFIX=auto] )
 404
 405     AC_ARG_ENABLE(tex-dir,
 406     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 407     [TEXDIR=$enableval],
 408     [TEXDIR=auto] )
 409
 410     AC_ARG_ENABLE(mf-dir,
 411     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 412     [MFDIR=$enableval],
 413     [MFDIR=auto])
 414
 415     if test "x$TEXPREFIX" = xauto ; then
 416         AC_TEX_PREFIX(TEXPREFIX)
 417     else
 418      find_texprefix=$TEXPREFIX
 419     fi
 420
 421     if test "x$MFDIR" = xauto; then
 422         AC_MF_SUBDIR(MFDIR)
 423     fi
 424
 425     if test "x$TEXDIR" = xauto ; then
 426         AC_TEX_SUBDIR(TEXDIR)
 427     fi
 428
 429     AC_SUBST(TEXPREFIX)
 430     AC_SUBST(TEXDIR)
 431     AC_SUBST(MFDIR)
 432 ])
 433
 434 AC_DEFUN(AC_STEPMAKE_WARN, [
 435     AC_MSG_WARN($1)
 436     warn_b=yes
 437 ])
 438
 439 AC_DEFUN(AC_STEPMAKE_YODL, [
 440     if test "x$YODL" = "x"; then
 441         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 442         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 443         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 444         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 445         AC_CHECK_PROGS(YODL2MSLESS, yodl2msless, -echo no yodl)
 446         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 447         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 448     else
 449         AC_SUBST(YODL)
 450         AC_SUBST(YODL2HTML)
 451         AC_SUBST(YODL2LATEX)
 452         AC_SUBST(YODL2MAN)
 453         AC_SUBST(YODL2MSLESS)
 454         AC_SUBST(YODL2TEXINFO)
 455         AC_SUBST(YODL2TXT)
 456         export YODL YODL2HTML YODL2LATEX YODL2MAN YODL2MSLESS YODL2TEXINFO YODL2TXT
 457     fi
 458     if test "x$YODL" = "-echo no yodl"; then
 459         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 460     fi
 461 ])
 462
 463 dnl should cache result.
 464 dnl should  look in $prefix first.
 465 dnl should probably assume TDS
 466
 467 AC_DEFUN(AC_TEX_PREFIX, [
 468
 469
 470     AC_MSG_CHECKING(TeX/MF root dir directory)
 471
 472     find_root_prefix="$prefix"
 473
 474
 475     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 476     find_texpostfix="";
 477     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 478         find_texprefix="$find_root_prefix$postfix"
 479         if test -d $find_texprefix; then
 480             find_texpostfix=$postfix
 481             break;
 482         fi
 483     done
 484
 485     if test "x$find_texpostfix" = x; then
 486         find_texpostfix='/lib/texmf/tex'
 487         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 488     fi
 489
 490     find_texprefix="$find_root_prefix/$find_texpostfix"
 491
 492     # only assign if variablename not empty
 493     if test x != "x[$]$1"; then
 494         $1='${prefix}'/"$find_texpostfix"
 495     fi
 496     AC_MSG_RESULT($find_texprefix)
 497
 498 ])
 499
 500
 501 # find a directory inside a prefix,
 502 # $1 the prefix (expanded version)
 503 # $2 variable to assign
 504 # $3 the directory name
 505 # $4 description
 506 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 507
 508     AC_MSG_CHECKING($4 directory)
 509     find_dirdir=`(cd $1;
 510       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 511
 512
 513     if test "x$find_dirdir" = x; then
 514        find_dirdir="/$3";
 515        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 516         true
 517     fi
 518     $2=$find_dirdir
 519     AC_MSG_RESULT($1/$find_dirdir)
 520 ])
 521
 522 # ugh.  this is hopeless
 523 AC_DEFUN(AC_KPSE_TEX_DIR, [
 524         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 525         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 526         echo $kpse_paths
 527         if test -w "$kpse_syspaths";
 528         then
 529                 dir=`echo $kpse_syspaths | head -1`
 530         else
 531                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 532         fi
 533         if test "$prefix" = "NONE"; then
 534                 local_prefix=$ac_default_prefix
 535                 local_prefix_quote='${prefix}'
 536
 537         else
 538                 local_prefix=$prefix
 539                 local_prefix_quote=$prefix
 540         fi
 541         echo $local_prefix_quote = $local_prefix
 542         echo $dir
 543         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 544 ])
 545
 546 AC_DEFUN(AC_TEX_SUBDIR, [
 547 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 548     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 549     $1="$TEXPREFIX/$$1"
 550 ])
 551
 552 AC_DEFUN(AC_MF_SUBDIR, [
 553 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 554     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 555     $1="$TEXPREFIX/$$1"
 556 ])
 557
 558 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 559         result="`echo \"$1\" | grep echo`"
 560         if test "x$1" = "xerror" -o "x$result" != "x"; then
 561                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 562         fi
 563 ])
 564
 565 # Configure paths for GTK+
 566 # Owen Taylor     97-11-3
 567
 568 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 569 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 570 dnl
 571 AC_DEFUN(AM_PATH_GTK,
 572 [dnl
 573 dnl Get the cflags and libraries from the gtk-config script
 574 dnl
 575   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 576   min_gtk_version=ifelse([$1], ,0.99.7,$1)
 577   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 578   no_gtk=""
 579   if test "$GTK_CONFIG" != "no" ; then
 580     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 581     GTK_LIBS=`$GTK_CONFIG --libs`
 582     ac_save_CFLAGS="$CFLAGS"
 583     ac_save_LIBS="$LIBS"
 584     ac_save_CXXFLAGS="$CXXFLAGS"
 585     CFLAGS="$CFLAGS $GTK_CFLAGS"
 586     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 587     LIBS="$LIBS $GTK_LIBS"
 588 dnl
 589 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 590 dnl checks the results of gtk-config to some extent
 591 dnl
 592     AC_TRY_RUN([
 593 #include <gtk/gtk.h>
 594 #include <stdio.h>
 595
 596 int
 597 main ()
 598 {
 599   int major, minor, micro;
 600
 601   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 602      printf("%s, bad version string\n", "$min_gtk_version");
 603      exit(1);
 604    }
 605
 606    return !((gtk_major_version > major) ||
 607             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 608             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 609 }
 610 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 611      CFLAGS="$ac_save_CFLAGS"
 612      CXXFLAGS="$ac_save_CXXFLAGS"
 613      LIBS="$ac_save_LIBS"
 614   else
 615      no_gtk=yes
 616   fi
 617   if test "x$no_gtk" = x ; then
 618      AC_MSG_RESULT(yes)
 619      ifelse([$2], , :, [$2])
 620   else
 621      AC_MSG_RESULT(no)
 622      GTK_CFLAGS=""
 623      GTK_LIBS=""
 624      ifelse([$3], , :, [$3])
 625   fi
 626   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 627   AC_SUBST(CXXFLAGS)
 628   AC_SUBST(GTK_CFLAGS)
 629   AC_SUBST(GTK_LIBS)
 630 ])
 631
 632
 633 # Configure paths for GTK--
 634 # Jan Nieuwenhuizen   98-06-3
 635
 636 dnl AM_PATH_GTK__([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 637 dnl Test for GTK--, and define GTK___CFLAGS and GTK___LIBS
 638 dnl
 639 AC_DEFUN(AM_PATH_GTK__,
 640 [dnl
 641 dnl Get the cflags and libraries from the gtk__-config script
 642 dnl
 643   min_gtk___version=ifelse([$1], ,0.9.4,$1)
 644   AC_MSG_CHECKING(for GTK-- - version >= $min_gtk___version)
 645   no_gtk__=""
 646   if test "$GTK_CONFIG" != "no" ; then
 647     GTK___CFLAGS=`$GTK_CONFIG --cflags`
 648     GTK_LIBS=`$GTK_CONFIG --libs`
 649     GTK___LIBS="$GTK_LIBS -lgtkmm"
 650     ac_save_CFLAGS="$CFLAGS"
 651     ac_save_LIBS="$LIBS"
 652     ac_save_CXXFLAGS="$CXXFLAGS"
 653     CFLAGS="$CFLAGS $GTK___CFLAGS"
 654     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 655     LIBS="$LIBS $GTK___LIBS"
 656 dnl
 657 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 658 dnl checks the results of gtk__-config to some extent
 659 dnl
 660     AC_TRY_RUN([
 661 #include <gtk--.h>
 662 #include <stdio.h>
 663
 664 int
 665 main ()
 666 {
 667   // urg
 668   return 0;
 669 }
 670 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 671      CFLAGS="$ac_save_CFLAGS"
 672      CXXFLAGS="$ac_save_CXXFLAGS"
 673      LIBS="$ac_save_LIBS"
 674   else
 675      no_gtk__=yes
 676   fi
 677   if test "x$no_gtk__" = x ; then
 678      AC_MSG_RESULT(yes)
 679      ifelse([$2], , :, [$2])
 680   else
 681      AC_MSG_RESULT(no)
 682      GTK___CFLAGS=""
 683      GTK___LIBS=""
 684      ifelse([$3], , :, [$3])
 685   fi
 686   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 687   AC_SUBST(CXXFLAGS)
 688   AC_SUBST(GTK___CFLAGS)
 689   AC_SUBST(GTK___LIBS)
 690 ])
 691