scm/time-signature-settings.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2009--2012 Carl Sorensen <c_sorensen@byu.edu>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;;; specify time signature default settings
  19
  20 ;;; format:
  21 ;;;
  22 ;;; alist of
  23 ;;;   (time-signature . default-properties) entries.
  24 ;;;
  25 ;;; where default-properties is an alist containing information about the
  26 ;;; time signature.  Each default-properties set can contain the
  27 ;;; following entries:
  28 ;;;
  29 ;;;   (baseMoment . (/ numerator denominator))
  30 ;;;   (beatStructure . structure-list)
  31 ;;;   (beamExceptions . (alist of beam exceptions that don't follow beats))
  32 ;;;
  33 ;;; The alist of beam exceptions has the following entries:
  34 ;;;
  35 ;;;   (end . grouping-rules)
  36 ;;;   (subdivide . grouping-rules)  (not yet implemented, reserved for future use)
  37 ;;;
  38 ;;;   grouping-rules is an alist containing (beam-type . grouping-list) entries
  39 ;;;
  40 ;;;     beam-type is the length as a rational number
  41 ;;;     grouping-list is a list that specifies the
  42 ;;;     number of stems of the given duration that are grouped in a beamed unit.
  43 ;;;     For an exception, the duration used is beam-type.  For measureBeats,
  44 ;;;     the duration used is baseMoment.
  45 ;;;
  46 ;;;     If an exception is specified for a given beam-type, it will apply to all
  47 ;;;     beams of shorter durations that don't have an individual exception, so
  48 ;;;     (1/8 . (3 3 2))
  49 ;;;     will cause all primary beams to be broken at 3/8, 6/8, and 8/8.
  50 ;;;
  51 ;;;     (1/32 . (16 8 4 4))
  52 ;;;     will cause all 1/32, 1/64, and 1/128 beams to be broken at 1/2, 3/4,
  53 ;;;     7/8, and 8/8.
  54 ;;;
  55 ;;;     Tuplets are referenced using their actual (scaled) length, so
  56 ;;;     a 3/2 tuplet of the 1/8 kind would get exceptions looked up
  57 ;;;     under 1/12.
  58 ;;;
  59 ;;; If no values are given for baseMoment and measureBeats, default values
  60 ;;;   will be assigned:
  61 ;;;   baseMoment gets the value (/ time-signature-denominator)
  62 ;;;   beatStructure gets a list of (3 3 3 ...), where the number of entries is the
  63 ;;;     number of beats, each containing 3 base-moments, if the time
  64 ;;;     signature numerator is greater than 3 and divisible by 3, and
  65 ;;;     a list of (1 1 1 ...), where the number of entries is the
  66 ;;;     number of base moments in a measure otherwise.
  67
  68 (define-public default-time-signature-settings
  69   '(
  70     ;; in 2/2 time:
  71     ;;   use defaults, but end beams with 32nd notes each 1 4 beat
  72     ((2 . 2) .
  73      ((beamExceptions . ((end . ((1/32 . (8 8 8 8))))))))
  74
  75     ;; in 2/4, 2/8 and 2/16 time:
  76     ;;   use defaults, so no entries are necessary
  77
  78     ;; in 3 2 time:
  79     ;;   use defaults, but end beams with 32nd notes and higher each 1 4 beat
  80
  81     ((3 . 2) .
  82      ((beamExceptions . ((end .  ((1/32 . (8 8 8 8 8 8))))))))
  83
  84     ;; in 3 4 time:
  85     ;;   use defaults, but combine all beats into a unit if possible
  86     ;;
  87     ;;   set all beams to end on beats, but 1 8 to beam entire measure
  88     ;;   in order to avoid beaming every beam type for the entire measure, we set
  89     ;;   triplets back to every beat.
  90     ((3 . 4) .
  91      ((beamExceptions . ((end . ((1/8 . (6))            ;1/8 note whole measure
  92                                  (1/12 . (3 3 3)))))))) ;Anything shorter by beat
  93
  94     ;; in 3 8  time:
  95     ;;   beam entire measure together
  96     ((3 . 8) . ((beamExceptions . ((end . ((1/8 . (3))))))))
  97
  98     ;; in 3 16 time:
  99     ;;   use defaults -- no entries necessary
 100
 101     ;; in 4 2 time:
 102     ;;   use defaults, but end beams with 16th notes or finer each 1 4 beat
 103     ((4 . 2) .
 104      ((beamExceptions . ((end . ((1/16 . (4 4 4 4 4 4 4 4))))))))
 105
 106     ;; in 4 4 (common) time:
 107     ;;   use defaults, but combine beats 1,2 and 3,4 if only 8th notes
 108     ;;   NOTE: Any changes here need to be duplicated in
 109     ;;         ly/engraver-init.ly where the default time signature is set
 110     ;;         are set
 111     ((4 . 4) .
 112      ((beamExceptions . ((end . ((1/8 . (4 4))  ; 1/8 notes half measure
 113                                  (1/12 . (3 3 3 3)))))))) ;Anything shorter by beat
 114
 115     ;; in 4/8 time:
 116     ;;   combine beats 1 and 2, so beam in 2
 117     ((4 . 8) . ((beatStructure . (2 2))))
 118
 119     ;; in 4/16 time:
 120     ;;   use defaults, so no entries necessary
 121
 122     ;; in 6 4 time:
 123     ;;   use defaults, but end beams with 32nd or finer each 1/4 beat
 124     ((6 . 4) .
 125      ((beamExceptions . ((end .  ((1/16 . (4 4 4 4 4 4))))))))
 126
 127     ;; in 6 8 time:
 128     ;;   use defaults, so no entries necessary
 129
 130     ;; in 6 16 time:
 131     ;;   use defaults, so no entries necessary
 132
 133     ;; in 9 4 time:
 134     ;;   use defaults, but end beams with 32nd or finer each 1 4 beat
 135     ((9 . 4) .
 136      ((beamExceptions . ((end . ((1/32 . (8 8 8 8 8 8 8 8))))))))
 137
 138     ;; in 9 8 time
 139     ;;   use defaults, so no entries necessary
 140
 141     ;; in 9 16 time
 142     ;;   use defaults, so no entries necessary
 143
 144     ;; in 12 4 time:
 145     ;;   use defaults, but end beams with 32nd or finer notes each 1 4 beat
 146     ((12 . 4) .
 147      ((beamExceptions . ((end . ((1/32 . (8 8 8 8 8 8 8 8 8 8 8 8))))))))
 148
 149     ;; in 12 8 time:
 150     ;;   use defaults, so no entries necessary
 151
 152     ;; in 12 16 time:
 153     ;;   use defaults, so no entries necessary
 154
 155     ;; in 5 8 time:
 156     ;;   default: group (3 2)
 157     ((5 . 8) .
 158      ((beatStructure . (3 2))))
 159
 160     ;; in 8 8 time:
 161     ;;   default: group (3 3 2)
 162     ((8 . 8) .
 163      ((beatStructure . (3 3 2))))
 164
 165     ))  ; end of alist definition
 166
 167 ;;;
 168 ;;;  Accessor and constructor functions
 169 ;;;
 170
 171 (define (get-setting my-symbol time-signature time-signature-settings)
 172   "Get setting @code{my-symbol} for @code{time-signature} from
 173 @code{time-signature-settings}."
 174   (let ((my-time-signature-settings
 175          (assoc-get time-signature time-signature-settings '())))
 176     (assoc-get my-symbol my-time-signature-settings '())))
 177
 178 (define-public (make-setting base-fraction
 179                              beat-structure
 180                              beam-exceptions)
 181   (list
 182    (cons 'baseMoment (if (pair? base-fraction)
 183                          (/ (car base-fraction) (cdr base-fraction))
 184                          base-fraction))
 185    (cons 'beatStructure beat-structure)
 186    (cons 'beamExceptions beam-exceptions)))
 187
 188 (define-public (base-length time-signature time-signature-settings)
 189   "Get @code{baseMoment} rational value for @var{time-signature} from
 190 @var{time-signature-settings}."
 191   (let ((return-value (get-setting 'baseMoment
 192                                    time-signature
 193                                    time-signature-settings)))
 194     (if (null? return-value)
 195         (/ (cdr time-signature))
 196         return-value)))
 197
 198 (define-public (beat-structure base-length time-signature time-signature-settings)
 199   "Get @code{beatStructure} value in @var{base-length} units
 200 for @var{time-signature} from @var{time-signature-settings}."
 201
 202   (let ((return-value (get-setting 'beatStructure
 203                                    time-signature
 204                                    time-signature-settings)))
 205     (if (null? return-value)
 206         ;; calculate default beatStructure
 207         (let* ((numerator (car time-signature))
 208                (group-size (if (and (> numerator 3)
 209                                     (zero? (remainder numerator 3)))
 210                                3
 211                                1))
 212                (beat-count (/ (car time-signature)
 213                               (cdr time-signature)
 214                               base-length
 215                               group-size)))
 216           (if (integer? beat-count)
 217               (make-list beat-count group-size)
 218               '()))
 219         ;; use value obtained from time-signature-settings
 220         return-value)))
 221
 222 (define-public (beam-exceptions time-signature time-signature-settings)
 223   "Get @code{beamExceptions} value for @var{time-signature} from
 224 @var{time-signature-settings}."
 225   (get-setting 'beamExceptions time-signature time-signature-settings))
 226
 227
 228 ;;; Functions for overriding time-signature settings
 229 ;;;
 230
 231 (define (override-property-setting context property setting value)
 232   "Like the C++ code that executes \\override, but without type
 233 checking."
 234   (begin
 235     (ly:context-set-property!
 236      context
 237      property
 238      (cons (cons setting value) (ly:context-property context property)))))
 239
 240 (define (revert-property-setting context property setting)
 241   "Like the C++ code that executes \revert, but without type
 242 checking."
 243
 244   (define (entry-count alist entry-key)
 245     "Count the number of entries in alist with a key of
 246 ENTRY-KEY."
 247     (cond
 248      ((null? alist) 0)
 249      ((equal? (caar alist) entry-key)
 250       (+ 1 (entry-count (cdr alist) entry-key)))
 251      (else (entry-count (cdr alist) entry-key))))
 252
 253   (define (revert-member alist entry-key)
 254     "Return ALIST, with the first entry having a key of
 255 ENTRY-KEY removed.  ALIST is not modified, instead
 256 a fresh copy of the list-head is made."
 257     (cond
 258      ((null? alist) '())
 259      ((equal? (caar alist) entry-key) (cdr alist))
 260      (else (cons (car alist)
 261                  (revert-member (cdr alist) entry-key)))))
 262
 263   ;; body of revert-property-setting
 264   (let ((current-value (ly:context-property context property)))
 265     (if (> (entry-count current-value setting) 0)
 266         (ly:context-set-property!
 267          context
 268          property
 269          (revert-member current-value setting)))))
 270
 271 (define-public (override-time-signature-setting time-signature setting)
 272   "Override the time signature settings for the context in
 273 @var{time-signature}, with the new setting alist @var{setting}."
 274   (context-spec-music
 275    (make-apply-context
 276     (lambda (c) (override-property-setting
 277                  c
 278                  'timeSignatureSettings
 279                  time-signature
 280                  setting)))
 281    'Timing))
 282
 283 (define-public (revert-time-signature-setting time-signature)
 284   (context-spec-music
 285    (make-apply-context
 286     (lambda (c)
 287       (revert-property-setting
 288        c
 289        'timeSignatureSettings
 290        time-signature)))
 291    'Timing))
 292
 293
 294
 295
 296 ;;;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 297 ;;; Formatting of complex/compound time signatures
 298
 299 (define (insert-markups l m)
 300   (let ((ll (reverse l)))
 301     (let join-markups ((markups (list (car ll)))
 302                        (remaining (cdr ll)))
 303       (if (pair? remaining)
 304           (join-markups (cons (car remaining) (cons m markups)) (cdr remaining))
 305           markups))))
 306
 307 ;;; Use a centered-column inside a left-column, because the centered column
 308 ;;; moves its reference point to the center, which the left-column undoes.
 309 (define (format-time-fraction time-sig-fraction)
 310   (let* ((revargs (reverse (map number->string time-sig-fraction)))
 311          (den (car revargs))
 312          (nums (reverse (cdr revargs))))
 313     (make-override-markup '(baseline-skip . 0)
 314                           (make-number-markup
 315                            (make-left-column-markup
 316                             (list (make-center-column-markup
 317                                    (list (make-line-markup (insert-markups nums "+"))
 318                                          den))))))))
 319
 320 (define (format-complex-compound-time time-sig)
 321   (make-override-markup '(baseline-skip . 0)
 322                         (make-number-markup
 323                          (make-line-markup
 324                           (insert-markups (map format-time-fraction time-sig)
 325                                           (make-vcenter-markup "+"))))))
 326
 327 (define-public (format-compound-time time-sig)
 328   (cond
 329    ((not (pair? time-sig)) (null-markup))
 330    ((pair? (car time-sig)) (format-complex-compound-time time-sig))
 331    (else (format-time-fraction time-sig))))
 332
 333
 334 ;;;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 335 ;;; Measure length calculation of (possibly complex) compound time signatures
 336
 337 (define (calculate-time-fraction time-sig-fraction)
 338   (let* ((revargs (reverse time-sig-fraction))
 339          (den (car revargs))
 340          (num (apply + (cdr revargs))))
 341     (ly:make-moment num den)))
 342
 343 (define (calculate-complex-compound-time time-sig)
 344   (let add-moment ((moment ZERO-MOMENT)
 345                    (remaining (map calculate-time-fraction time-sig)))
 346     (if (pair? remaining)
 347         (add-moment (ly:moment-add moment (car remaining)) (cdr remaining))
 348         moment)))
 349
 350 (define-public (calculate-compound-measure-length time-sig)
 351   (cond
 352    ((not (pair? time-sig)) (ly:make-moment 4 4))
 353    ((pair? (car time-sig)) (calculate-complex-compound-time time-sig))
 354    (else (calculate-time-fraction time-sig))))
 355
 356
 357 ;;;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 358 ;;; Base beat length: Use the smallest denominator from all fraction
 359
 360 (define (calculate-compound-base-beat-full time-sig)
 361   (apply max (map last time-sig)))
 362
 363 (define-public (calculate-compound-base-beat time-sig)
 364   (ly:make-moment 1
 365                   (cond
 366                    ((not (pair? time-sig)) 4)
 367                    ((pair? (car time-sig)) (calculate-compound-base-beat-full time-sig))
 368                    (else (calculate-compound-base-beat-full (list time-sig))))))
 369
 370
 371 ;;;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 372 ;;; Beat Grouping
 373
 374 (define (normalize-fraction frac beat)
 375   (let* ((thisbeat (car (reverse frac)))
 376          (factor (/ beat thisbeat)))
 377     (map (lambda (f) (* factor f)) frac)))
 378
 379 (define (beat-grouping-internal time-sig)
 380   ;; Normalize to given beat, extract the beats and join them to one list
 381   (let* ((beat (calculate-compound-base-beat-full time-sig))
 382          (normalized (map (lambda (f) (normalize-fraction f beat)) time-sig))
 383          (beats (map (lambda (f) (drop-right f 1)) normalized)))
 384     (concatenate beats)))
 385
 386 (define-public (calculate-compound-beat-grouping time-sig)
 387   (cond
 388    ((not (pair? time-sig)) '(2 . 2))
 389    ((pair? (car time-sig)) (beat-grouping-internal time-sig))
 390    (else (beat-grouping-internal (list time-sig)))))