scm/stencil.scm

   1 ;;;; stencil.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2003--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6
   7 (define-public (stack-stencils axis dir padding stils)
   8   "Stack stencils STILS in direction AXIS, DIR, using PADDING."
   9   (cond
  10    ((null? stils) empty-stencil)
  11    ((null? (cdr stils)) (car stils))
  12    (else (ly:stencil-combine-at-edge
  13           (car stils) axis dir (stack-stencils axis dir padding (cdr stils))
  14           padding))))
  15
  16 (define-public (stack-stencils-padding-list axis dir padding stils)
  17   "Stack stencils STILS in direction AXIS, DIR, using a list of PADDING."
  18   (cond
  19    ((null? stils) empty-stencil)
  20    ((null? (cdr stils)) (car stils))
  21    (else (ly:stencil-combine-at-edge
  22           (car stils)
  23           axis dir
  24           (stack-stencils-padding-list axis dir (cdr padding) (cdr stils))
  25           (car padding)))))
  26
  27 (define-public (centered-stencil stencil)
  28   "Center stencil @var{stencil} in both the X and Y directions"
  29   (ly:stencil-aligned-to (ly:stencil-aligned-to stencil X CENTER) Y CENTER))
  30
  31 (define-public (stack-lines dir padding baseline stils)
  32   "Stack vertically with a baseline-skip."
  33   (if (null? stils)
  34       empty-stencil
  35       (if (null? (cdr stils))
  36           (car stils)
  37           (ly:stencil-combine-at-edge
  38            (car stils) Y dir
  39            (stack-lines dir padding baseline (cdr stils))
  40            padding baseline))))
  41
  42 (define-public (bracketify-stencil stil axis thick protusion padding)
  43   "Add brackets around STIL, producing a new stencil."
  44
  45   (let* ((ext (ly:stencil-extent stil axis))
  46          (lb (ly:bracket axis ext thick (- protusion)))
  47          (rb (ly:bracket axis ext thick protusion)))
  48     (set! stil
  49           (ly:stencil-combine-at-edge stil (other-axis axis) 1 lb padding))
  50     (set! stil
  51           (ly:stencil-combine-at-edge stil (other-axis axis) -1 rb padding))
  52     stil))
  53
  54 (define-public (make-filled-box-stencil xext yext)
  55   "Make a filled box."
  56
  57   (ly:make-stencil
  58       (list 'round-filled-box (- (car xext)) (cdr xext)
  59                        (- (car yext)) (cdr yext) 0.0)
  60       xext yext))
  61
  62 (define-public (make-circle-stencil radius thickness fill)
  63   "Make a circle of radius @var{radius} and thickness @var{thickness}"
  64   (ly:make-stencil
  65    (list 'circle radius thickness fill)
  66    (cons (- radius) radius)
  67    (cons (- radius) radius)))
  68
  69 (define-public (box-grob-stencil grob)
  70   "Make a box of exactly the extents of the grob.  The box precisely
  71 encloses the contents.
  72 "
  73   (let* ((xext (ly:grob-extent grob grob 0))
  74          (yext (ly:grob-extent grob grob 1))
  75          (thick 0.1))
  76
  77     (ly:stencil-add
  78      (make-filled-box-stencil xext (cons (- (car yext) thick) (car yext)))
  79      (make-filled-box-stencil xext (cons (cdr yext) (+ (cdr yext) thick)))
  80      (make-filled-box-stencil (cons (cdr xext) (+ (cdr xext) thick)) yext)
  81      (make-filled-box-stencil (cons (- (car xext) thick) (car xext)) yext))))
  82
  83 ;; TODO merge this and prev function.
  84 (define-public (box-stencil stencil thickness padding)
  85   "Add a box around STENCIL, producing a new stencil."
  86   (let* ((x-ext (interval-widen (ly:stencil-extent stencil 0) padding))
  87          (y-ext (interval-widen (ly:stencil-extent stencil 1) padding))
  88          (y-rule (make-filled-box-stencil (cons 0 thickness) y-ext))
  89          (x-rule (make-filled-box-stencil
  90                   (interval-widen x-ext thickness) (cons 0 thickness))))
  91     (set! stencil (ly:stencil-combine-at-edge stencil X 1 y-rule padding))
  92     (set! stencil (ly:stencil-combine-at-edge stencil X -1 y-rule padding))
  93     (set! stencil (ly:stencil-combine-at-edge stencil Y 1 x-rule 0.0))
  94     (set! stencil (ly:stencil-combine-at-edge stencil Y -1 x-rule 0.0))
  95     stencil))
  96
  97 (define-public (circle-stencil stencil thickness padding)
  98   "Add a circle around STENCIL, producing a new stencil."
  99   (let* ((x-ext (ly:stencil-extent stencil 0))
 100          (y-ext (ly:stencil-extent stencil 1))
 101          (diameter (max (- (cdr x-ext) (car x-ext))
 102                         (- (cdr y-ext) (car y-ext))))
 103          (radius (+ (/ diameter 2) padding thickness)))
 104     (ly:stencil-add
 105      (centered-stencil stencil) (make-circle-stencil radius thickness #f))))
 106
 107 (define-public (fontify-text font-metric text)
 108   "Set TEXT with font FONT-METRIC, returning a stencil."
 109   (let* ((b (ly:text-dimension font-metric text)))
 110     (ly:make-stencil
 111      `(text ,font-metric ,text) (car b) (cdr b))))
 112
 113 (define-public (fontify-text-white scale font-metric text)
 114   "Set TEXT with scale factor s"
 115   (let* ((b (ly:text-dimension font-metric text))
 116          ;;urg -- workaround for using ps font
 117          (c `(white-text ,(* 2 scale) ,text)))
 118     ;;urg -- extent is not from ps font, but we hope it's close
 119     (ly:make-stencil c (car b) (cdr b))))
 120
 121 (define-public (dimension-arrows destination)
 122   "Draw twosided arrow from here to @var{destination}"
 123
 124   (let*
 125       ((e_x 1+0i)
 126        (e_y 0+1i)
 127        (rotate (lambda (z ang)
 128                  (* (make-polar 1 ang)
 129                     z)))
 130        (complex-to-offset (lambda (z)
 131                             (list (real-part z) (imag-part z))))
 132
 133        (z-dest (+ (* e_x (car destination)) (* e_y (cdr destination))))
 134        (e_z (/ z-dest (magnitude z-dest)))
 135        (triangle-points '(-1+0.25i
 136                           0
 137                           -1-0.25i))
 138        (p1s (map (lambda (z)
 139                    (+ z-dest (rotate z (angle z-dest))))
 140                  triangle-points))
 141        (p2s (map (lambda (z)
 142                    (rotate z (angle (- z-dest))))
 143                    triangle-points))
 144        (null (cons 0 0))
 145        (arrow-1
 146         (ly:make-stencil
 147          `(polygon (quote ,(concatenate (map complex-to-offset p1s)))
 148                    0.0
 149                    #t) null null))
 150        (arrow-2
 151         (ly:make-stencil
 152          `(polygon (quote ,(concatenate (map complex-to-offset p2s)))
 153                    0.0
 154                    #t) null null ) )
 155        (thickness 0.1)
 156        (shorten-line 0.5)
 157        (start (complex-to-offset (/ (* e_z shorten-line) 2)))
 158        (end (complex-to-offset (- z-dest (/ (* e_z shorten-line) 2))))
 159
 160        (line (ly:make-stencil
 161               `(draw-line ,thickness
 162                           ,(car start) ,(cadr start)
 163                           ,(car end) ,(cadr end)
 164                           )
 165               (cons (min 0 (car destination))
 166                     (min 0 (cdr destination)))
 167               (cons (max 0 (car destination))
 168                     (max 0 (cdr destination)))))
 169
 170        (result (ly:stencil-add arrow-2 arrow-1 line)))
 171
 172
 173     result))
 174
 175 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 176 ;; ANNOTATIONS
 177 ;;
 178 ;; annotations are arrows indicating the numerical value of
 179 ;; spacing variables
 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 181
 182 (define*-public (annotate-y-interval layout name extent is-length
 183                                      #:key (color darkblue))
 184   (let ((text-props (cons '((font-size . -3)
 185                             (font-family . typewriter))
 186                           (layout-extract-page-properties layout)))
 187         (annotation #f))
 188     (define (center-stencil-on-extent stil)
 189       (ly:stencil-translate (ly:stencil-aligned-to stil Y CENTER)
 190                             (cons 0 (interval-center extent))))
 191     ;; do something sensible for 0,0 intervals.
 192     (set! extent (interval-widen extent 0.001))
 193     (if (not (interval-sane? extent))
 194         (set! annotation (interpret-markup
 195                           layout text-props
 196                           (make-simple-markup (format "~a: NaN/inf" name))))
 197         (let ((text-stencil (interpret-markup
 198                              layout text-props
 199                              (markup #:whiteout #:simple name)))
 200               (dim-stencil (interpret-markup
 201                             layout text-props
 202                             (markup #:whiteout
 203                                     #:simple (cond
 204                                               ((interval-empty? extent)
 205                                                (format "empty"))
 206                                               (is-length
 207                                                (format "~$" (interval-length extent)))
 208                                               (else
 209                                                (format "(~$,~$)"
 210                                                        (car extent) (cdr extent)))))))
 211               (arrows (ly:stencil-translate-axis
 212                        (dimension-arrows (cons 0 (interval-length extent)))
 213                        (interval-start extent) Y)))
 214           (set! annotation
 215                 (center-stencil-on-extent text-stencil))
 216           (set! annotation
 217                 (ly:stencil-combine-at-edge arrows X RIGHT annotation 0.5 0))
 218           (set! annotation
 219                 (ly:stencil-combine-at-edge annotation X LEFT
 220                                             (center-stencil-on-extent dim-stencil)
 221                                             0.5 0))
 222           (set! annotation
 223                 (ly:make-stencil (list 'color color (ly:stencil-expr annotation))
 224                                  (ly:stencil-extent annotation X)
 225                                  (cons 10000 -10000)))))
 226     annotation))
 227
 228
 229 (define-public (eps-file->stencil axis size file-name)
 230   (let*
 231       ((contents (ly:gulp-file file-name))
 232        (bbox (get-postscript-bbox contents))
 233        (bbox-size (if (= axis X)
 234                       (- (list-ref bbox 2) (list-ref bbox 0))
 235                       (- (list-ref bbox 3) (list-ref bbox 1))
 236                       ))
 237        (factor (exact->inexact (/ size bbox-size)))
 238        (scaled-bbox
 239         (map (lambda (x) (* factor x)) bbox)))
 240
 241     (if bbox
 242         (ly:make-stencil
 243          (list
 244           'embedded-ps
 245           (string-append
 246            (format
 247            "
 248 gsave
 249 currentpoint translate
 250 BeginEPSF
 251 ~a ~a scale
 252 %%BeginDocument: ~a
 253 "          factor factor
 254            file-name
 255            )
 256            contents
 257            "%%EndDocument
 258 EndEPSF
 259 grestore
 260 "))
 261
 262          (cons (list-ref scaled-bbox 0) (list-ref scaled-bbox 2))
 263          (cons (list-ref scaled-bbox 1) (list-ref scaled-bbox 3)))
 264
 265         (ly:make-stencil "" '(0 . 0) '(0 . 0)))
 266     ))
 267
 268 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 269 ;; output signatures.
 270
 271 (define-public (write-system-signatures basename paper-systems count)
 272   (if (pair? paper-systems)
 273       (begin
 274         (let*
 275             ((outname (format "~a-~a.signature" basename count)) )
 276
 277           (ly:message "Writing ~a" outname)
 278           (write-system-signature outname (car paper-systems))
 279           (write-system-signatures basename (cdr paper-systems) (1+ count))))))
 280
 281
 282 (use-modules (scm paper-system))
 283 (define-public (write-system-signature filename paper-system)
 284   (define (float? x)
 285     (and (number? x) (inexact? x)))
 286
 287   (define system-grob
 288     (paper-system-system-grob paper-system))
 289
 290   (define output (open-output-file filename))
 291
 292   (define (strip-floats expr)
 293     "Replace floats by #f"
 294     (cond
 295      ((float? expr) #f)
 296      ((ly:font-metric? expr) (ly:font-name expr))
 297      ((pair? expr) (cons (strip-floats (car expr))
 298                          (strip-floats (cdr expr))))
 299      (else expr)))
 300
 301   (define (fold-false-pairs expr)
 302     "Try to remove lists of #f as much as possible."
 303     (if (pair? expr)
 304         (let*
 305             ((first (car expr))
 306              (rest (fold-false-pairs (cdr expr))))
 307
 308           (if first
 309               (cons (fold-false-pairs first) rest)
 310               rest))
 311         expr))
 312
 313
 314   (define (pythonic-string expr)
 315     "escape quotes and slashes for python consumption"
 316     (regexp-substitute/global #f "([\n\\\\'\"])" (format "~a" expr) 'pre "\\" 1 'post))
 317
 318   (define (pythonic-pair expr)
 319     (format "(~a,~a)"
 320             (car expr) (cdr expr)))
 321
 322
 323   (define (raw-string expr)
 324     "escape quotes and slashes for python consumption"
 325     (regexp-substitute/global #f "[@\n]" (format "~a" expr) 'pre " " 'post))
 326
 327   (define (raw-pair expr)
 328     (format "~a ~a"
 329             (car expr) (cdr expr)))
 330
 331   (define (found-grob expr)
 332     (let*
 333         ((grob (car expr))
 334          (rest (cdr expr))
 335          (collected '())
 336          (cause (event-cause grob))
 337          (input (if (ly:stream-event? cause) (ly:event-property cause 'origin) #f))
 338          (location (if (ly:input-location? input) (ly:input-file-line-char-column input) '()))
 339
 340          (x-ext (ly:grob-extent grob system-grob X))
 341          (y-ext (ly:grob-extent grob system-grob Y))
 342          )
 343
 344       (interpret-for-signature #f (lambda (e)
 345                                     (set! collected (cons e collected)))
 346                                rest)
 347
 348       (format output
 349               "~a@~a@~a@~a@~a\n"
 350               (cdr (assq 'name (ly:grob-property grob 'meta) ))
 351               (raw-string location)
 352               (raw-pair (if (interval-empty? x-ext) '(1 . -1) x-ext))
 353               (raw-pair (if (interval-empty? y-ext) '(1 . -1) y-ext))
 354               (raw-string collected))
 355       ))
 356
 357   (define (interpret-for-signature escape collect expr)
 358     (define (interpret expr)
 359       (let*
 360           ((head (if (pair? expr)
 361                      (car expr)
 362                      #f)))
 363
 364         (cond
 365          ((eq? head 'grob-cause) (escape (cdr expr)))
 366          ((eq? head 'color) (interpret (caddr expr)))
 367          ((eq? head 'rotate-stencil) (interpret (caddr expr)))
 368          ((eq? head 'translate-stencil) (interpret (caddr expr)))
 369          ((eq? head 'combine-stencil)
 370           (for-each (lambda (e) (interpret e))  (cdr expr)))
 371          (else
 372           (collect (fold-false-pairs (strip-floats expr))))
 373
 374          )))
 375
 376     (interpret expr))
 377
 378   (if (ly:grob? system-grob)
 379       (begin
 380         (display (format "# Output signature\n# Generated by LilyPond ~a\n" (lilypond-version))
 381                  output)
 382         (interpret-for-signature found-grob (lambda (x) #f)
 383                                  (ly:stencil-expr
 384                                   (paper-system-stencil paper-system)))))
 385
 386   ;; should be superfluous, but leaking "too many open files"?
 387   (close-port output))
 388