scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77   (display music)
  78   (display ": { ")
  79   (let ((es (ly:music-property music 'elements))
  80         (e (ly:music-property music 'element)))
  81     (display (ly:music-mutable-properties music))
  82     (if (pair? es)
  83         (begin (display "\nElements: {\n")
  84                (map display-music es)
  85                (display "}\n")))
  86     (if (ly:music? e)
  87         (begin
  88           (display "\nChild:")
  89           (display-music e))))
  90   (display " }\n")
  91   music)
  92
  93 ;;;
  94 ;;; A scheme music pretty printer
  95 ;;;
  96 (define (markup-expression->make-markup markup-expression)
  97   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  98 For instance,
  99   \\markup \\bold \\italic hello
 100 ==>
 101   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 102   (define (proc->command-keyword proc)
 103     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 104     (let ((cmd-markup (symbol->string (procedure-name proc))))
 105       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 106                                                                   (string-length "-markup")))))))
 107   (define (transform-arg arg)
 108     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 109            (apply append (map inner-markup->make-markup arg)))
 110           ((and (not (string? arg)) (markup? arg)) ;; a markup
 111            (inner-markup->make-markup arg))
 112           (else                                  ;; scheme arg
 113            arg)))
 114   (define (inner-markup->make-markup mrkup)
 115     (let ((cmd (proc->command-keyword (car mrkup)))
 116           (args (map transform-arg (cdr mrkup))))
 117       `(,cmd ,@args)))
 118   ;; body:
 119   (if (string? markup-expression)
 120       markup-expression
 121       `(markup ,@(inner-markup->make-markup markup-expression))))
 122
 123 (define-public (music->make-music obj)
 124   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 125 that is, for a music expression, a (make-music ...) form."
 126   (cond (;; markup expression
 127          (markup? obj)
 128          (markup-expression->make-markup obj))
 129         (;; music expression
 130          (ly:music? obj)
 131          `(make-music
 132            ',(ly:music-property obj 'name)
 133            ,@(apply append (map (lambda (prop)
 134                                   `(',(car prop)
 135                                     ,(music->make-music (cdr prop))))
 136                                 (remove (lambda (prop)
 137                                           (eqv? (car prop) 'origin))
 138                                         (ly:music-mutable-properties obj))))))
 139         (;; moment
 140          (ly:moment? obj)
 141          `(ly:make-moment ,(ly:moment-main-numerator obj)
 142                           ,(ly:moment-main-denominator obj)
 143                           ,(ly:moment-grace-numerator obj)
 144                           ,(ly:moment-grace-denominator obj)))
 145         (;; note duration
 146          (ly:duration? obj)
 147          `(ly:make-duration ,(ly:duration-log obj)
 148                             ,(ly:duration-dot-count obj)
 149                             ,(car (ly:duration-factor obj))
 150                             ,(cdr (ly:duration-factor obj))))
 151         (;; note pitch
 152          (ly:pitch? obj)
 153          `(ly:make-pitch ,(ly:pitch-octave obj)
 154                          ,(ly:pitch-notename obj)
 155                          ,(ly:pitch-alteration obj)))
 156         (;; scheme procedure
 157          (procedure? obj)
 158          (or (procedure-name obj) obj))
 159         (;; a symbol (avoid having an unquoted symbol)
 160          (symbol? obj)
 161          `',obj)
 162         (;; an empty list (avoid having an unquoted empty list)
 163          (null? obj)
 164          `'())
 165         (;; a proper list
 166          (list? obj)
 167          `(list ,@(map music->make-music obj)))
 168         (;; a pair
 169          (pair? obj)
 170          `(cons ,(music->make-music (car obj))
 171                 ,(music->make-music (cdr obj))))
 172         (else
 173          obj)))
 174
 175 (use-modules (ice-9 pretty-print))
 176 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 177   "Displays `obj', typically a music expression, in a friendly fashion,
 178 which often can be read back in order to generate an equivalent expression.
 179
 180 Returns `obj'.
 181 "
 182   (pretty-print (music->make-music obj) port)
 183   (newline)
 184   obj)
 185
 186 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 187
 188 (define-public (shift-one-duration-log music shift dot)
 189   "  add SHIFT to duration-log of 'duration in music and optionally
 190   a dot to any note encountered. This scales the music up by a factor
 191   2^shift * (2 - (1/2)^dot)"
 192   (let ((d (ly:music-property music 'duration)))
 193     (if (ly:duration? d)
 194         (let* ((cp (ly:duration-factor d))
 195                (nd (ly:make-duration (+ shift (ly:duration-log d))
 196                                      (+ dot (ly:duration-dot-count d))
 197                                      (car cp)
 198                                      (cdr cp))))
 199           (set! (ly:music-property music 'duration) nd)))
 200     music))
 201
 202 (define-public (shift-duration-log music shift dot)
 203   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 204              music))
 205
 206 (define-public (make-repeat name times main alts)
 207   "create a repeat music expression, with all properties initialized properly"
 208   (let ((talts (if (< times (length alts))
 209                    (begin
 210                      (ly:warning (_ "More alternatives than repeats. Junking excess alternatives"))
 211                      (take alts times))
 212                    alts))
 213         (r (make-repeated-music name)))
 214     (set! (ly:music-property r 'element) main)
 215     (set! (ly:music-property r 'repeat-count) (max times 1))
 216     (set! (ly:music-property r 'elements) talts)
 217     (if (equal? name "tremolo")
 218         (let* ((dot? (zero? (modulo times 3)))
 219                (dots (if dot? 1 0))
 220                (mult (if dot?
 221                          (quotient (* times 2) 3)
 222                          times))
 223                (shift (- (ly:intlog2 mult))))
 224
 225           (if (memq 'sequential-music (ly:music-property main 'types))
 226               ;; \repeat "tremolo" { c4 d4 }
 227               (let ((children (length (ly:music-property main 'elements))))
 228                 (if (not (= children 2))
 229                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 230                 (ly:music-compress r (ly:make-moment 1 children))
 231                 (shift-duration-log r (1- shift) dots))
 232               ;; \repeat "tremolo" c4
 233               (shift-duration-log r shift dots)))
 234         r)))
 235
 236 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 237 ;; clusters.
 238
 239 (define-public (note-to-cluster music)
 240   "Replace NoteEvents by ClusterNoteEvents."
 241   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 242       (make-music 'ClusterNoteEvent
 243                   'pitch (ly:music-property music 'pitch)
 244                   'duration (ly:music-property music 'duration))
 245       music))
 246
 247 (define-public (notes-to-clusters music)
 248   (music-map note-to-cluster music))
 249
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251 ;; repeats.
 252
 253 (define-public (unfold-repeats music)
 254   "
 255 This function replaces all repeats  with unfold repeats. "
 256
 257   (let ((es (ly:music-property music 'elements))
 258         (e  (ly:music-property music 'element))
 259         )
 260     (if (memq 'repeated-music (ly:music-property music 'types))
 261         (let*
 262             ((props (ly:music-mutable-properties music))
 263              (old-name (ly:music-property music 'name))
 264              (flattened  (flatten-alist props)))
 265
 266           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 267                                               flattened)))
 268
 269           (if (equal? old-name 'TremoloRepeatedMusic)
 270               (let* ((seq-arg? (memq 'sequential-music
 271                                      (ly:music-property e 'types)))
 272                      (count  (ly:music-property music 'repeat-count))
 273                      (dot-shift (if (= 0 (remainder count 3))
 274                                     -1 0)))
 275
 276                 (if (= 0 -1)
 277                     (set! count (* 2 (quotient count 3))))
 278
 279                 (shift-duration-log music (+ (if seq-arg? 1 0)
 280                                              (ly:intlog2 count)) dot-shift)
 281
 282                 (if seq-arg?
 283                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 284                                                                   e 'elements)) 1)))))))
 285
 286
 287     (if (pair? es)
 288         (set! (ly:music-property music 'elements)
 289               (map unfold-repeats es)))
 290     (if (ly:music? e)
 291         (set! (ly:music-property music 'element)
 292               (unfold-repeats e)))
 293     music))
 294
 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 296 ;; property setting music objs.
 297
 298 (define-public (make-grob-property-set grob gprop val)
 299   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 300 i.e.  this is not an override"
 301   (make-music 'OverrideProperty
 302               'symbol grob
 303               'grob-property gprop
 304               'grob-value val
 305               'pop-first #t))
 306
 307 (define-public (make-grob-property-override grob gprop val)
 308   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 309 i.e.  this is not an override"
 310   (make-music 'OverrideProperty
 311               'symbol grob
 312               'grob-property gprop
 313               'grob-value val))
 314
 315 (define-public (make-grob-property-revert grob gprop)
 316   "Revert the grob property GPROP for GROB."
 317   (make-music 'RevertProperty
 318               'symbol grob
 319               'grob-property gprop))
 320
 321 (define direction-polyphonic-grobs
 322   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 323
 324 (define-safe-public (make-voice-props-set n)
 325   (make-sequential-music
 326    (append
 327     (map (lambda (x) (make-grob-property-set x 'direction
 328                                              (if (odd? n) -1 1)))
 329          direction-polyphonic-grobs)
 330     (list
 331      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 332      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 333
 334 (define-safe-public (make-voice-props-revert)
 335   (make-sequential-music
 336    (append
 337     (map (lambda (x) (make-grob-property-revert x 'direction))
 338          direction-polyphonic-grobs)
 339     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 340     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 341
 342
 343 (define-safe-public (context-spec-music m context #:optional id)
 344   "Add \\context CONTEXT = ID to M. "
 345   (let ((cm (make-music 'ContextSpeccedMusic
 346                         'element m
 347                         'context-type context)))
 348     (if (string? id)
 349         (set! (ly:music-property cm 'context-id) id))
 350     cm))
 351
 352 (define-public (descend-to-context m context)
 353   "Like context-spec-music, but only descending. "
 354   (let ((cm (context-spec-music m context)))
 355     (ly:music-set-property! cm 'descend-only #t)
 356     cm))
 357
 358 (define-public (make-non-relative-music mus)
 359   (make-music 'UnrelativableMusic
 360               'element mus))
 361
 362 (define-public (make-apply-context func)
 363   (make-music 'ApplyContext
 364               'procedure func))
 365
 366 (define-public (make-sequential-music elts)
 367   (make-music 'SequentialMusic
 368               'elements elts))
 369
 370 (define-public (make-simultaneous-music elts)
 371   (make-music 'SimultaneousMusic
 372               'elements elts))
 373
 374 (define-safe-public (make-event-chord elts)
 375   (make-music 'EventChord
 376               'elements elts))
 377
 378 (define-public (make-skip-music dur)
 379   (make-music 'SkipMusic
 380               'duration dur))
 381
 382 (define-public (make-grace-music music)
 383   (make-music 'GraceMusic
 384               'element music))
 385
 386 ;;;;;;;;;;;;;;;;
 387
 388 ;; mmrest
 389 (define-public (make-multi-measure-rest duration location)
 390   (make-music 'MultiMeasureRestMusic
 391               'origin location
 392               'duration duration))
 393
 394 (define-public (make-property-set sym val)
 395   (make-music 'PropertySet
 396               'symbol sym
 397               'value val))
 398
 399 (define-public (make-property-unset sym)
 400   (make-music 'PropertyUnset
 401               'symbol sym))
 402
 403 (define-public (make-ottava-set octavation)
 404   (let ((m (make-music 'ApplyContext)))
 405     (define (ottava-modify context)
 406       "Either reset middleCPosition to the stored original, or remember
 407 old middleCPosition, add OCTAVATION to middleCPosition, and set
 408 OTTAVATION to `8va', or whatever appropriate."
 409       (if (number? (ly:context-property  context 'middleCPosition))
 410           (if (= octavation 0)
 411               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 412                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 413                 (ly:context-set-property! context 'middleCPosition oc0)
 414                 (ly:context-unset-property where 'originalCentralCPosition)
 415                 (ly:context-unset-property where 'ottavation))
 416               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 417                      (c0 (ly:context-property context 'middleCPosition))
 418                      (new-c0 (+ c0 (* -7 octavation)))
 419                      (string (cdr (assoc octavation '((2 . "15ma")
 420                                                       (1 . "8va")
 421                                                       (0 . #f)
 422                                                       (-1 . "8va bassa")
 423                                                       (-2 . "15ma bassa"))))))
 424                 (ly:context-set-property! context 'middleCPosition new-c0)
 425                 (ly:context-set-property! context 'originalCentralCPosition c0)
 426                 (ly:context-set-property! context 'ottavation string)))))
 427     (set! (ly:music-property m 'procedure) ottava-modify)
 428     (context-spec-music m 'Staff)))
 429
 430 (define-public (set-octavation ottavation)
 431   (ly:export (make-ottava-set ottavation)))
 432
 433 (define-public (make-time-signature-set num den . rest)
 434   "Set properties for time signature NUM/DEN.  Rest can contain a list
 435 of beat groupings "
 436
 437   (define (standard-beat-grouping num den)
 438
 439     "Some standard subdivisions for time signatures."
 440     (let*
 441         ((key (cons num den))
 442          (entry (assoc key '(((6 . 8) . (3 3))
 443                          ((5 . 8) . (3 2))
 444                          ((9 . 8) . (3 3 3))
 445                          ((12 . 8) . (3 3 3 3))
 446                          ((8 . 8) . (3 3 2))
 447                          ))))
 448
 449       (if entry
 450           (cdr entry)
 451           '())))
 452
 453   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 454          (beat (ly:make-moment 1 den))
 455          (len  (ly:make-moment num den))
 456          (set2 (make-property-set 'beatLength beat))
 457          (set3 (make-property-set 'measureLength len))
 458          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 459                                                     (car rest)
 460                                                     (standard-beat-grouping num den))))
 461          (basic  (list set1 set2 set3 set4)))
 462     (descend-to-context
 463      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 464
 465 (define-public (make-mark-set label)
 466   "Make the music for the \\mark command."
 467   (let* ((set (if (integer? label)
 468                   (context-spec-music (make-property-set 'rehearsalMark label)
 469                                       'Score)
 470                   #f))
 471          (ev (make-music 'MarkEvent))
 472          (ch (make-event-chord (list ev))))
 473     (if set
 474         (make-sequential-music (list set ch))
 475         (begin
 476           (set! (ly:music-property ev 'label) label)
 477           ch))))
 478
 479 (define-public (set-time-signature num den . rest)
 480   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 481
 482 (define-safe-public (make-articulation name)
 483   (make-music 'ArticulationEvent
 484               'articulation-type name))
 485
 486 (define-public (make-lyric-event string duration)
 487   (make-music 'LyricEvent
 488               'duration duration
 489               'text string))
 490
 491 (define-safe-public (make-span-event type spandir)
 492   (make-music type
 493               'span-direction spandir))
 494
 495 (define-public (set-mus-properties! m alist)
 496   "Set all of ALIST as properties of M."
 497   (if (pair? alist)
 498       (begin
 499         (set! (ly:music-property m (caar alist)) (cdar alist))
 500         (set-mus-properties! m (cdr alist)))))
 501
 502 (define-public (music-separator? m)
 503   "Is M a separator?"
 504   (let ((ts (ly:music-property m 'types)))
 505     (memq 'separator ts)))
 506
 507 ;;; splitting chords into voices.
 508 (define (voicify-list lst number)
 509   "Make a list of Musics.
 510
 511    voicify-list :: [ [Music ] ] -> number -> [Music]
 512    LST is a list music-lists.
 513
 514    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 515 "
 516   (if (null? lst)
 517       '()
 518       (cons (context-spec-music
 519              (make-sequential-music
 520               (list (make-voice-props-set number)
 521                     (make-simultaneous-music (car lst))))
 522              'Voice  (number->string (1+ number)))
 523             (voicify-list (cdr lst) (1+ number)))))
 524
 525 (define (voicify-chord ch)
 526   "Split the parts of a chord into different Voices using separator"
 527   (let ((es (ly:music-property ch 'elements)))
 528     (set! (ly:music-property  ch 'elements)
 529           (voicify-list (split-list es music-separator?) 0))
 530     ch))
 531
 532 (define-public (voicify-music m)
 533   "Recursively split chords that are separated with \\ "
 534   (if (not (ly:music? m))
 535       (ly:error (_ "music expected: ~S") m))
 536   (let ((es (ly:music-property m 'elements))
 537         (e (ly:music-property m 'element)))
 538
 539     (if (pair? es)
 540         (set! (ly:music-property m 'elements) (map voicify-music es)))
 541     (if (ly:music? e)
 542         (set! (ly:music-property m 'element)  (voicify-music e)))
 543     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 544              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 545         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 546     m))
 547
 548 (define-public (empty-music)
 549   (ly:export (make-music 'Music)))
 550 ;;;
 551
 552                                         ; Make a function that checks score element for being of a specific type.
 553 (define-public (make-type-checker symbol)
 554   (lambda (elt)
 555     ;;(display  symbol)
 556     ;;(eq? #t (ly:grob-property elt symbol))
 557     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 558
 559 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 560   (if (func grob)
 561       (set! (ly:grob-property grob sym) val)))
 562
 563
 564 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 565   "Usage:
 566
 567 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 568
 569 "
 570   (let ((meta (ly:grob-property grob 'meta)))
 571     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 572         (set! (ly:grob-property grob symbol) val))))
 573
 574
 575 ;;
 576 (define-public (smart-bar-check n)
 577   "Make  a bar check that checks for a specific bar number.
 578 "
 579   (let ((m (make-music 'ApplyContext)))
 580     (define (checker tr)
 581       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 582         (if (= bn n)
 583             #t
 584             (ly:error
 585              ;; FIXME: uncomprehensable message
 586              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 587              n bn))))
 588     (set! (ly:music-property m 'procedure) checker)
 589     m))
 590
 591
 592 (define-public (skip->rest mus)
 593
 594   "Replace MUS by RestEvent of the same duration if it is a
 595 SkipEvent. Useful for extracting parts from crowded scores"
 596
 597   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 598    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 599    mus))
 600
 601
 602 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 603 ;; warn for bare chords at start.
 604
 605 (define (has-request-chord elts)
 606   (reduce (lambda (x y) (or x y)) #f
 607           (map (lambda (x)
 608                  (equal? (ly:music-property x 'name) 'RequestChord))
 609                elts)))
 610
 611 (define-public (ly:music-message music msg)
 612   (let ((ip (ly:music-property music 'origin)))
 613     (if (ly:input-location? ip)
 614         (ly:input-message ip msg)
 615         (ly:warning msg))))
 616
 617 (define (check-start-chords music)
 618   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 619 without context specification. Called  from parser."
 620   (let ((es (ly:music-property music 'elements))
 621         (e (ly:music-property music 'element))
 622         (name (ly:music-property music 'name)))
 623     (cond ((equal? name "Context_specced_music") #t)
 624           ((equal? name "Simultaneous_music")
 625            (if (has-request-chord es)
 626                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 627                (map check-start-chords es)))
 628           ((equal? name "SequentialMusic")
 629            (if (pair? es)
 630                (check-start-chords (car es))))
 631           (else (if (ly:music? e) (check-start-chords e)))))
 632   music)
 633
 634
 635
 636 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 637 ;;
 638 ;; setting stuff for grace context.
 639 ;;
 640
 641 (define (vector-extend v x)
 642   "Make a new vector consisting of V, with X added to the end."
 643   (let* ((n (vector-length v))
 644          (nv (make-vector (+ n 1) '())))
 645     (vector-move-left! v 0 n nv 0)
 646     (vector-set! nv n x)
 647     nv))
 648
 649 (define (vector-map f v)
 650   "Map  F over V. This function returns nothing."
 651   (do ((n (vector-length v))
 652        (i 0 (+ i 1)))
 653       ((>= i n))
 654     (f (vector-ref v i))))
 655
 656 (define (vector-reverse-map f v)
 657   "Map  F over V, N to 0 order. This function returns nothing."
 658   (do ((i (- (vector-length v) 1) (- i 1)))
 659       ((< i 0))
 660     (f (vector-ref v i))))
 661
 662 ;; TODO:  make a remove-grace-property too.
 663 (define-public (add-grace-property context-name grob sym val)
 664   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 665   (define (set-prop context)
 666     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 667            (current (ly:context-property where 'graceSettings))
 668            (new-settings (append current
 669                                  (list (list context-name grob sym val)))))
 670       (ly:context-set-property! where 'graceSettings new-settings)))
 671   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 672
 673
 674
 675 (defmacro-public def-grace-function (start stop)
 676   `(define-music-function (parser location music) (ly:music?)
 677      (make-music 'GraceMusic
 678                  'origin location
 679                  'element (make-music 'SequentialMusic
 680                                       'elements (list (ly:music-deep-copy ,start)
 681                                                       music
 682                                                       (ly:music-deep-copy ,stop))))))
 683
 684 (defmacro-public define-music-function (args signature . body)
 685   "Helper macro for `ly:make-music-function'.
 686 Syntax:
 687   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 688     ...function body...)
 689 "
 690   `(ly:make-music-function (list ,@signature)
 691                            (lambda (,@args)
 692                              ,@body)))
 693
 694
 695 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 696
 697 (define-public (cue-substitute quote-music)
 698   "Must happen after quote-substitute."
 699
 700   (if (vector? (ly:music-property quote-music 'quoted-events))
 701       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 702              (main-voice (if (eq? 1 dir) 1 0))
 703              (cue-voice (if (eq? 1 dir) 0 1))
 704              (main-music (ly:music-property quote-music 'element))
 705              (return-value quote-music))
 706
 707         (if (or (eq? 1 dir) (eq? -1 dir))
 708
 709             ;; if we have stem dirs, change both quoted and main music
 710             ;; to have opposite stems.
 711             (begin
 712               (set! return-value
 713
 714                     ;; cannot context-spec Quote-music, since context
 715                     ;; for the quotes is determined in the iterator.
 716                     (make-sequential-music
 717                      (list
 718                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 719                       quote-music
 720                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 721               (set! main-music
 722                     (make-sequential-music
 723                      (list
 724                       (make-voice-props-set main-voice)
 725                       main-music
 726                       (make-voice-props-revert))))
 727               (set! (ly:music-property quote-music 'element) main-music)))
 728
 729         return-value)
 730       quote-music))
 731
 732 (define-public ((quote-substitute quote-tab) music)
 733   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 734          (quoted-vector (if (string? quoted-name)
 735                             (hash-ref quote-tab quoted-name #f)
 736                             #f)))
 737
 738
 739     (if (string? quoted-name)
 740         (if (vector? quoted-vector)
 741             (begin
 742               (set! (ly:music-property music 'quoted-events) quoted-vector)
 743               (set! (ly:music-property music 'iterator-ctor)
 744                     ly:quote-iterator::constructor))
 745             (ly:warning (_ "can't find quoted music `~S'" quoted-name))))
 746     music))
 747
 748
 749 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 750 ;; switch it on here, so parsing and init isn't checked (too slow!)
 751 ;;
 752 ;; automatic music transformations.
 753
 754 (define (switch-on-debugging m)
 755   (if (defined? 'set-debug-cell-accesses!)
 756       (set-debug-cell-accesses! 15000))
 757   m)
 758
 759 (define (music-check-error music)
 760   (define found #f)
 761   (define (signal m)
 762     (if (and (ly:music? m)
 763              (eq? (ly:music-property m 'error-found) #t))
 764         (set! found #t)))
 765
 766   (for-each signal (ly:music-property music 'elements))
 767   (signal (ly:music-property music 'element))
 768
 769   (if found
 770       (set! (ly:music-property music 'error-found) #t))
 771   music)
 772
 773 (define (precompute-music-length music)
 774   (set! (ly:music-property music 'length)
 775         (ly:music-length music))
 776   music)
 777
 778 (define (skip-to-last music parser)
 779
 780   "Replace MUSIC by
 781
 782 << { \\set skipTypesetting = ##t
 783      LENGTHOF(\\showLastLength)
 784      \\set skipTypesetting = ##t  }
 785     MUSIC >>
 786
 787 if appropriate.
 788  "
 789   (let*
 790       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 791
 792     (if (ly:music? show-last)
 793         (let*
 794             ((orig-length (ly:music-length music))
 795              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 796
 797           (make-simultaneous-music
 798            (list
 799             (make-sequential-music
 800              (list
 801               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 802               (make-music 'SkipMusic 'duration
 803                           (ly:make-duration 0 0
 804                                             (ly:moment-main-numerator skip-length)
 805                                             (ly:moment-main-denominator skip-length)))
 806               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 807             music)))
 808         music)))
 809
 810
 811 (define-public toplevel-music-functions
 812   (list
 813    (lambda (music parser) (voicify-music music))
 814    (lambda (x parser) (music-map music-check-error x))
 815    (lambda (x parser) (music-map precompute-music-length x))
 816    (lambda (music parser)
 817
 818      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 819
 820    ;; switch-on-debugging
 821    (lambda (x parser) (music-map cue-substitute x))
 822
 823    (lambda (x parser)
 824      (skip-to-last x parser)
 825    )))
 826
 827
 828 ;;;;;;;;;;;;;;;;;
 829 ;; lyrics
 830
 831 (define (apply-durations lyric-music durations)
 832   (define (apply-duration music)
 833     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 834              (ly:duration?  (ly:music-property music 'duration)))
 835         (begin
 836           (set! (ly:music-property music 'duration) (car durations))
 837           (set! durations (cdr durations)))))
 838
 839   (music-map apply-duration lyric-music))
 840
 841
 842 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 843 ;;
 844
 845 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 846   "Usage: see input/regression/balloon.ly "
 847   (let* ((meta (ly:grob-property grob 'meta))
 848          (cb (ly:grob-property-data grob 'stencil))
 849          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant")))
 850     (if (and (equal? nm object-name)
 851              (procedure? cb))
 852         (begin
 853           (ly:grob-set-property! grob 'stencil  ly:balloon-interface::print)
 854           (set! (ly:grob-property grob 'original-stencil) cb)
 855           (set! (ly:grob-property grob 'balloon-text) text)
 856           (set! (ly:grob-property grob 'balloon-text-offset) off)
 857           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 858
 859 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 860 ;; accidentals
 861
 862 (define-public (set-accidentals-properties extra-natural
 863                                            auto-accs auto-cauts
 864                                            context)
 865   (context-spec-music
 866    (make-sequential-music
 867     (append (if (boolean? extra-natural)
 868                 (list (make-property-set 'extraNatural extra-natural))
 869                 '())
 870             (list (make-property-set 'autoAccidentals auto-accs)
 871                   (make-property-set 'autoCautionaries auto-cauts))))
 872    context))
 873
 874 (define-public (set-accidental-style style . rest)
 875   "Set accidental style to STYLE. Optionally takes a context argument,
 876 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 877 use GrandStaff as a context. "
 878   (let ((context (if (pair? rest)
 879                      (car rest) 'Staff))
 880         (pcontext (if (pair? rest)
 881                       (car rest) 'GrandStaff)))
 882     (ly:export
 883      (cond
 884       ;; accidentals as they were common in the 18th century.
 885       ((equal? style 'default)
 886        (set-accidentals-properties #t '(Staff (same-octave . 0))
 887                                    '() context))
 888       ;; accidentals from one voice do NOT get cancelled in other voices
 889       ((equal? style 'voice)
 890        (set-accidentals-properties #t '(Voice (same-octave . 0))
 891                                    '() context))
 892       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 893       ;; This includes all the default accidentals, but accidentals also needs cancelling
 894       ;; in other octaves and in the next measure.
 895       ((equal? style 'modern)
 896        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 897                                    '()  context))
 898       ;; the accidentals that Stone adds to the old standard as cautionaries
 899       ((equal? style 'modern-cautionary)
 900        (set-accidentals-properties #f '(Staff (same-octave . 0))
 901                                    '(Staff (any-octave . 0) (same-octave . 1))
 902                                    context))
 903       ;; Multivoice accidentals to be read both by musicians playing one voice
 904       ;; and musicians playing all voices.
 905       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 906       ((equal? style 'modern-voice)
 907        (set-accidentals-properties  #f
 908                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 909                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 910                                     '()
 911                                     context))
 912       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 913       ;; as cautionaries
 914       ((equal? style 'modern-voice-cautionary)
 915        (set-accidentals-properties #f
 916                                    '(Voice (same-octave . 0))
 917                                    '(Voice (any-octave . 0) (same-octave . 1)
 918                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 919                                    context))
 920       ;; stone's suggestions for accidentals on grand staff.
 921       ;; Accidentals are cancelled across the staves in the same grand staff as well
 922       ((equal? style 'piano)
 923        (set-accidentals-properties #f
 924                                    '(Staff (same-octave . 0)
 925                                            (any-octave . 0) (same-octave . 1)
 926                                            GrandStaff (any-octave . 0) (same-octave . 1))
 927                                    '()
 928                                    pcontext))
 929       ((equal? style 'piano-cautionary)
 930        (set-accidentals-properties #f
 931                                    '(Staff (same-octave . 0))
 932                                    '(Staff (any-octave . 0) (same-octave . 1)
 933                                            GrandStaff (any-octave . 0) (same-octave . 1))
 934                                    pcontext))
 935       ;; do not set localKeySignature when a note alterated differently from
 936       ;; localKeySignature is found.
 937       ;; Causes accidentals to be printed at every note instead of
 938       ;; remembered for the duration of a measure.
 939       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 940       ((equal? style 'forget)
 941        (set-accidentals-properties '()
 942                                    '(Staff (same-octave . -1))
 943                                    '() context))
 944       ;; Do not reset the key at the start of a measure.  Accidentals will be
 945       ;; printed only once and are in effect until overridden, possibly many
 946       ;; measures later.
 947       ((equal? style 'no-reset)
 948        (set-accidentals-properties '()
 949                                    '(Staff (same-octave . #t))
 950                                    '()
 951                                    context))
 952       (else
 953        (ly:warning (_ "unknown accidental style: ~S" style))
 954        (make-sequential-music '()))))))
 955
 956 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 957
 958 (define-public (skip-of-length mus)
 959   "Create a skip of exactly the same length as MUS."
 960   (let* ((skip
 961           (make-music
 962            'SkipEvent
 963            'duration (ly:make-duration 0 0))))
 964
 965     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 966
 967 (define-public (mmrest-of-length mus)
 968   "Create a mmrest of exactly the same length as MUS."
 969
 970   (let* ((skip
 971           (make-multi-measure-rest
 972            (ly:make-duration 0 0) '())))
 973     (ly:music-compress skip (ly:music-length mus))
 974     skip))
 975
 976 (define-public (pitch-of-note event-chord)
 977
 978   (let*
 979       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 980                     (ly:music-property event-chord 'elements))))
 981
 982     (if (pair? evs)
 983         (ly:music-property (car evs) 'pitch)
 984         #f)))
 985