scm/chord-ignatzek-names.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2000--2012  Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  22 ;;
  23 ;; jazz-part 2
  24 ;;
  25 ;; after Klaus Ignatzek,   Die Jazzmethode fuer Klavier 1.
  26 ;;
  27 ;; The idea is: split chords into
  28 ;;
  29 ;;  ROOT PREFIXES MAIN-NAME ALTERATIONS SUFFIXES ADDITIONS
  30 ;;
  31 ;; and put that through a layout routine.
  32 ;;
  33 ;; the split is a procedural process, with lots of set!.
  34 ;;
  35
  36
  37 ;; todo: naming is confusing: steps  (0 based) vs. steps (1 based).
  38 (define (pitch-step p)
  39   "Musicological notation for an interval.  Eg. C to D is 2."
  40   (+ 1 (ly:pitch-steps p)))
  41
  42 (define (get-step x ps)
  43   "Does PS have the X step? Return that step if it does."
  44   (if (null? ps)
  45       #f
  46       (if (= (- x 1) (ly:pitch-steps (car ps)))
  47           (car ps)
  48           (get-step x (cdr ps)))))
  49
  50 (define (replace-step p ps)
  51   "Copy PS, but replace the step of P in PS."
  52   (if (null? ps)
  53       '()
  54       (let* ((t (replace-step p (cdr ps))))
  55         (if (= (ly:pitch-steps p) (ly:pitch-steps (car ps)))
  56             (cons p t)
  57             (cons (car ps) t)))))
  58
  59 (define (remove-step x ps)
  60   "Copy PS, but leave out the Xth step."
  61   (if (null? ps)
  62       '()
  63       (let* ((t (remove-step x (cdr ps))))
  64         (if (= (- x 1) (ly:pitch-steps (car ps)))
  65             t
  66             (cons (car ps) t)))))
  67
  68
  69 (define-public (ignatzek-chord-names
  70                 in-pitches bass inversion
  71                 context)
  72
  73   (define (remove-uptil-step x ps)
  74     "Copy PS, but leave out everything below the Xth step."
  75     (if (null? ps)
  76         '()
  77         (if (< (ly:pitch-steps (car ps)) (- x 1))
  78             (remove-uptil-step x (cdr ps))
  79             ps)))
  80
  81   (define name-root (ly:context-property context 'chordRootNamer))
  82   (define name-note
  83     (let ((nn (ly:context-property context 'chordNoteNamer)))
  84       (if (eq? nn '())
  85           ;; replacing the next line with name-root gives guile-error...? -rz
  86
  87           ;; apparently sequence of defines is equivalent to let, not let* ? -hwn
  88           (ly:context-property context 'chordRootNamer)
  89           ;; name-root
  90           nn)))
  91
  92   (define (is-natural-alteration? p)
  93     (= (natural-chord-alteration p) (ly:pitch-alteration p)))
  94
  95   (define (ignatzek-format-chord-name
  96            root
  97            prefix-modifiers
  98            main-name
  99            alteration-pitches
 100            addition-pitches
 101            suffix-modifiers
 102            bass-pitch
 103            lowercase-root?)
 104
 105     "Format for the given (lists of) pitches.  This is actually more
 106 work than classifying the pitches."
 107
 108     (define (filter-main-name p)
 109       "The main name: don't print anything for natural 5 or 3."
 110       (if
 111        (or (not (ly:pitch? p))
 112            (and (is-natural-alteration? p)
 113                 (or (= (pitch-step p) 5)
 114                     (= (pitch-step p) 3))))
 115        '()
 116        (list (name-step p))))
 117
 118     (define (glue-word-to-step word x)
 119       (make-line-markup
 120        (list
 121         (make-simple-markup word)
 122         (name-step x))))
 123
 124     (define (suffix-modifier->markup mod)
 125       (if (or (= 4 (pitch-step mod))
 126               (= 2 (pitch-step mod)))
 127           (glue-word-to-step "sus" mod)
 128           (glue-word-to-step "huh" mod)))
 129
 130     (define (prefix-modifier->markup mod)
 131       (if (and (= 3 (pitch-step mod))
 132                (= FLAT (ly:pitch-alteration mod)))
 133           (if lowercase-root?
 134               empty-markup
 135               (ly:context-property context 'minorChordModifier))
 136           (make-simple-markup "huh")))
 137
 138     (define (filter-alterations alters)
 139       "Filter out uninteresting (natural) pitches from ALTERS."
 140
 141       (define (altered? p)
 142         (not (is-natural-alteration? p)))
 143
 144       (if
 145        (null? alters)
 146        '()
 147        (let* ((lst (filter altered? alters))
 148               (lp (last-pair alters)))
 149
 150          ;; we want the highest also if unaltered
 151          (if (and (not (altered? (car lp)))
 152                   (> (pitch-step (car lp)) 5))
 153              (append lst (last-pair alters))
 154              lst))))
 155
 156     (define (name-step pitch)
 157       (define (step-alteration pitch)
 158         (- (ly:pitch-alteration pitch)
 159            (natural-chord-alteration pitch)))
 160
 161       (let* ((num-markup (make-simple-markup
 162                           (number->string (pitch-step pitch))))
 163              (args (list num-markup))
 164              (total (if (= (ly:pitch-alteration pitch) 0)
 165                         (if (= (pitch-step pitch) 7)
 166                             (list (ly:context-property context 'majorSevenSymbol))
 167                             args)
 168                         (cons (accidental->markup (step-alteration pitch)) args))))
 169
 170         (make-line-markup total)))
 171
 172     (let* ((sep (ly:context-property context 'chordNameSeparator))
 173            (slashsep (ly:context-property context 'slashChordSeparator))
 174            (root-markup (name-root root lowercase-root?))
 175            (add-pitch-prefix (ly:context-property context 'additionalPitchPrefix))
 176            (add-markups (map (lambda (x) (glue-word-to-step add-pitch-prefix x))
 177                              addition-pitches))
 178            (filtered-alterations (filter-alterations alteration-pitches))
 179            (alterations (map name-step filtered-alterations))
 180            (suffixes (map suffix-modifier->markup suffix-modifiers))
 181            (prefixes (map prefix-modifier->markup prefix-modifiers))
 182            (main-markups (filter-main-name main-name))
 183            (to-be-raised-stuff (markup-join
 184                                 (append
 185                                  main-markups
 186                                  alterations
 187                                  suffixes
 188                                  add-markups) sep))
 189            (base-stuff (if (ly:pitch? bass-pitch)
 190                            (list slashsep (name-note bass-pitch #f))
 191                            '())))
 192
 193       (set! base-stuff
 194             (append
 195              (list root-markup
 196                    (conditional-kern-before (markup-join prefixes sep)
 197                                             (and (not (null? prefixes))
 198                                                  (= (ly:pitch-alteration root) NATURAL))
 199                                             (ly:context-property context 'chordPrefixSpacer))
 200                    (make-super-markup to-be-raised-stuff))
 201              base-stuff))
 202       (make-line-markup base-stuff)))
 203
 204   (define (ignatzek-format-exception
 205            root
 206            exception-markup
 207            bass-pitch
 208            lowercase-root?)
 209
 210     (make-line-markup
 211      `(
 212        ,(name-root root lowercase-root?)
 213        ,exception-markup
 214        .
 215        ,(if (ly:pitch? bass-pitch)
 216             (list (ly:context-property context 'slashChordSeparator)
 217                   (name-note bass-pitch #f))
 218             '()))))
 219
 220   (let* ((root (car in-pitches))
 221          (pitches (map (lambda (x) (ly:pitch-diff x root)) (cdr in-pitches)))
 222          (lowercase-root?
 223           (and (ly:context-property context 'chordNameLowercaseMinor)
 224                (let ((third (get-step 3 pitches)))
 225                  (and third (= (ly:pitch-alteration third) FLAT)))))
 226          (exceptions (ly:context-property context 'chordNameExceptions))
 227          (exception (assoc-get pitches exceptions))
 228          (prefixes '())
 229          (suffixes '())
 230          (add-steps '())
 231          (main-name #f)
 232          (bass-note
 233           (if (ly:pitch? inversion)
 234               inversion
 235               bass))
 236          (alterations '()))
 237
 238     (if exception
 239         (ignatzek-format-exception root exception bass-note lowercase-root?)
 240
 241         (begin
 242           ;; no exception.
 243           ;; handle sus4 and sus2 suffix: if there is a 3 together with
 244           ;; sus2 or sus4, then we explicitly say add3.
 245           (for-each
 246            (lambda (j)
 247              (if (get-step j pitches)
 248                  (begin
 249                    (if (get-step 3 pitches)
 250                        (begin
 251                          (set! add-steps (cons (get-step 3 pitches) add-steps))
 252                          (set! pitches (remove-step 3 pitches))))
 253                    (set! suffixes (cons (get-step j pitches) suffixes)))))
 254            '(2 4))
 255
 256           ;; do minor-3rd modifier.
 257           (if (and (get-step 3 pitches)
 258                    (= (ly:pitch-alteration (get-step 3 pitches)) FLAT))
 259               (set! prefixes (cons (get-step 3 pitches) prefixes)))
 260
 261           ;; lazy bum. Should write loop.
 262           (cond
 263            ((get-step 7 pitches) (set! main-name (get-step 7 pitches)))
 264            ((get-step 6 pitches) (set! main-name (get-step 6 pitches)))
 265            ((get-step 5 pitches) (set! main-name (get-step 5 pitches)))
 266            ((get-step 4 pitches) (set! main-name (get-step 4 pitches)))
 267            ((get-step 3 pitches) (set! main-name (get-step 3 pitches))))
 268
 269           (let* ((3-diff? (lambda (x y)
 270                             (= (- (pitch-step y) (pitch-step x)) 2)))
 271                  (split (split-at-predicate
 272                          3-diff? (remove-uptil-step 5 pitches))))
 273             (set! alterations (append alterations (car split)))
 274             (set! add-steps (append add-steps (cdr split)))
 275             (set! alterations (delq main-name alterations))
 276             (set! add-steps (delq main-name add-steps))
 277
 278
 279             ;; chords with natural (5 7 9 11 13) or leading subsequence.
 280             ;; etc. are named by the top pitch, without any further
 281             ;; alterations.
 282             (if (and
 283                  (ly:pitch? main-name)
 284                  (= 7 (pitch-step main-name))
 285                  (is-natural-alteration? main-name)
 286                  (pair? (remove-uptil-step 7 alterations))
 287                  (every is-natural-alteration? alterations))
 288                 (begin
 289                   (set! main-name (last alterations))
 290                   (set! alterations '())))
 291
 292             (ignatzek-format-chord-name
 293              root prefixes main-name alterations add-steps suffixes bass-note
 294              lowercase-root?))))))