scm/backend-library.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2005--2012 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  20 ;; backend helpers.
  21
  22 (use-modules (scm ps-to-png)
  23              (scm paper-system)
  24              (ice-9 optargs))
  25
  26 (define-public (ly:system command)
  27   (ly:debug (_ "Invoking `~a'...") (string-join command))
  28   (let ((status (apply ly:spawn command)))
  29     (if (> status 0)
  30         (begin
  31           (ly:warning (_ "`~a' failed (~a)\n") command status)
  32           ;; hmmm.  what's the best failure option?
  33           (throw 'ly-file-failed)))))
  34
  35 (define-public (sanitize-command-option str)
  36   "Kill dubious shell quoting."
  37
  38   (string-append
  39    "\""
  40    (regexp-substitute/global #f "[^-_ 0-9,.a-zA-Z'\"\\]" str 'pre 'post)
  41    "\""))
  42
  43 (define-public (search-executable names)
  44   (define (helper path lst)
  45     (if (null? (cdr lst))
  46         (car lst)
  47         (if (search-path path (car lst)) (car lst)
  48             (helper path (cdr lst)))))
  49
  50   (let ((path (parse-path (getenv "PATH"))))
  51     (helper path names)))
  52
  53 (define-public (search-gs)
  54
  55   ;; must be sure that we don't catch stuff from old GUBs.
  56   (search-executable '("gs")))
  57
  58 (define-public (postscript->pdf paper-width paper-height name)
  59   (let* ((pdf-name (string-append
  60                     (dir-basename name ".ps" ".eps")
  61                     ".pdf"))
  62          (is-eps (string-match "\\.eps$" name))
  63          (*unspecified* (if #f #f))
  64          (cmd
  65           (remove (lambda (x) (eq? x *unspecified*))
  66                   (list
  67                    (search-gs)
  68                    (if (ly:get-option 'verbose) *unspecified* "-q")
  69                    (if (or (ly:get-option 'gs-load-fonts)
  70                            (ly:get-option 'gs-load-lily-fonts)
  71                            (eq? PLATFORM 'windows))
  72                        "-dNOSAFER"
  73                        "-dSAFER")
  74
  75                    (if is-eps
  76                        "-dEPSCrop"
  77                        (ly:format "-dDEVICEWIDTHPOINTS=~$" paper-width))
  78                    (if is-eps
  79                        *unspecified*
  80                        (ly:format "-dDEVICEHEIGHTPOINTS=~$" paper-height))
  81                    "-dCompatibilityLevel=1.4"
  82                    "-dNOPAUSE"
  83                    "-dBATCH"
  84                    "-r1200"
  85                    "-sDEVICE=pdfwrite"
  86                    (string-append "-sOutputFile="
  87                                   (string-join
  88                                    (string-split pdf-name #\%)
  89                                    "%%"))
  90                    "-c.setpdfwrite"
  91                    (string-append "-f" name)))))
  92
  93     (ly:message (_ "Converting to `~a'...\n") pdf-name)
  94     (ly:system cmd)))
  95
  96 (define-public (postscript->png resolution paper-width paper-height name)
  97   (let* ((verbose (ly:get-option 'verbose))
  98          (rename-page-1 #f))
  99
 100     ;; Do not try to guess the name of the png file,
 101     ;; GS produces PNG files like BASE-page%d.png.
 102     (ly:message (_ "Converting to ~a...") "PNG")
 103     (make-ps-images name
 104                     #:resolution resolution
 105                     #:page-width paper-width
 106                     #:page-height paper-height
 107                     #:rename-page-1 rename-page-1
 108                     #:be-verbose verbose
 109                     #:anti-alias-factor (ly:get-option 'anti-alias-factor)
 110                     #:pixmap-format (ly:get-option 'pixmap-format))
 111     (ly:progress "\n")))
 112
 113 (define-public (postprocess-output paper-book module filename formats)
 114   (let* ((completed (completize-formats formats))
 115          (base (dir-basename filename ".ps" ".eps"))
 116          (intermediate (remove (lambda (x) (member x formats)) completed)))
 117     (for-each (lambda (f)
 118                 ((eval (string->symbol (format #f "convert-to-~a" f))
 119                        module) paper-book filename)) completed)
 120     (if (ly:get-option 'delete-intermediate-files)
 121         (for-each (lambda (f)
 122                     (if (file-exists? f) (delete-file f)))
 123                   (map (lambda (x) (string-append base "." x)) intermediate)))))
 124
 125 (define-public (completize-formats formats)
 126   (define new-fmts '())
 127   (if (member "png" formats)
 128       (set! formats (cons "ps" formats)))
 129   (if (member "pdf" formats)
 130       (set! formats (cons "ps" formats)))
 131   (for-each (lambda (x)
 132               (if (member x formats) (set! new-fmts (cons x new-fmts))))
 133             '("ps" "pdf" "png"))
 134   (uniq-list (reverse new-fmts)))
 135
 136 (define (header-to-file file-name key value)
 137   (set! key (symbol->string key))
 138   (if (not (equal? "-" file-name))
 139       (set! file-name (string-append file-name "." key)))
 140   (ly:message (_ "Writing header field `~a' to `~a'...")
 141               key
 142               (if (equal? "-" file-name) "<stdout>" file-name))
 143   (if (equal? file-name "-")
 144       (display value)
 145       (let ((port (open-file file-name "w")))
 146         (display value port)
 147         (close-port port)))
 148
 149   (ly:progress "\n")
 150   "")
 151
 152 (define-public (output-scopes scopes fields basename)
 153   (define (output-scope scope)
 154     (string-concatenate
 155      (module-map
 156       (lambda (sym var)
 157         (let ((val (if (variable-bound? var) (variable-ref var) "")))
 158           (if (and (memq sym fields) (string? val))
 159               (header-to-file basename sym val))
 160           ""))
 161       scope)))
 162   (string-concatenate (map output-scope scopes)))
 163
 164 (define-public (relevant-book-systems book)
 165   (let ((systems (ly:paper-book-systems book)))
 166     ;; skip booktitles.
 167     (if (and (not (ly:get-option 'include-book-title-preview))
 168              (pair? systems)
 169              (ly:prob-property (car systems) 'is-book-title #f))
 170         (cdr systems)
 171         systems)))
 172
 173 (define-public (relevant-dump-systems systems)
 174   (let ((to-dump-systems '()))
 175     (for-each
 176      (lambda (sys)
 177        (if (or (paper-system-title? sys)
 178                (not (pair? to-dump-systems))
 179                (paper-system-title? (car to-dump-systems)))
 180            (set! to-dump-systems (cons sys to-dump-systems))))
 181      systems)
 182     to-dump-systems))
 183
 184 (define missing-stencil-list '())
 185
 186 (define-public (backend-testing output-module)
 187   (define (missing-stencil-expression name)
 188     (begin
 189       (ly:warning (_ "missing stencil expression `~S'") name)
 190       ""))
 191
 192   (for-each (lambda (x)
 193               (if (not (module-defined? output-module x))
 194                   (begin
 195                     (module-define! output-module x
 196                                     (lambda* (#:optional y . z)
 197                                              (missing-stencil-expression x)))
 198                     (set! missing-stencil-list (cons x missing-stencil-list)))))
 199             (ly:all-stencil-commands)))
 200
 201 (define-public (remove-stencil-warnings output-module)
 202   (for-each
 203    (lambda (x)
 204      (module-remove! output-module x))
 205    missing-stencil-list))
 206
 207 (define (filter-out pred? lst)
 208   (filter (lambda (x) (not (pred? x))) lst))
 209
 210 (define-public (font-name-split font-name)
 211   "Return @code{(FONT-NAME . DESIGN-SIZE)} from @var{font-name} string
 212 or @code{#f}."
 213   (let ((match (regexp-exec (make-regexp "(.*)-([0-9]*)") font-name)))
 214     (if (regexp-match? match)
 215         (cons (match:substring match 1) (match:substring match 2))
 216         (cons font-name-designsize #f))))
 217
 218 ;; Example of a pango-physical-font
 219 ;; ("Emmentaler-11" "/home/janneke/vc/lilypond/out/share/lilypond/current/fonts/otf/emmentaler-11.otf" 0)
 220 (define-public (pango-pf-font-name pango-pf)
 221   "Return the font-name of the pango physical font @var{pango-pf}."
 222   (list-ref pango-pf 0))
 223 (define-public (pango-pf-file-name pango-pf)
 224   "Return the file-name of the pango physical font @var{pango-pf}."
 225   (list-ref pango-pf 1))
 226 (define-public (pango-pf-fontindex pango-pf)
 227   "Return the fontindex of the pango physical font @var{pango-pf}."
 228   (list-ref pango-pf 2))
 229
 230 (define (pango-font-name pango-font)
 231   (let ((pf-fonts (ly:pango-font-physical-fonts pango-font)))
 232     (if (pair? pf-fonts)
 233         (pango-pf-font-name (car pf-fonts))
 234         "")))
 235
 236 (define-public (define-fonts paper define-font define-pango-pf)
 237   "Return a string of all fonts used in @var{paper}, invoking the functions
 238 @var{define-font} and @var{define-pango-pf} for producing the actual font
 239 definition."
 240
 241   (let* ((font-list (ly:paper-fonts paper))
 242          (pango-fonts (filter ly:pango-font? font-list))
 243          (other-fonts (filter-out ly:pango-font? font-list))
 244          (other-font-names (map ly:font-name other-fonts))
 245          (pango-only-fonts
 246           (filter-out (lambda (x)
 247                         (member (pango-font-name x) other-font-names))
 248                       pango-fonts)))
 249
 250     (define (font-load-command font)
 251       (let* ((font-name (ly:font-name font))
 252              (designsize (ly:font-design-size font))
 253              (magnification (* (ly:font-magnification font)))
 254              (ops (ly:output-def-lookup paper 'output-scale))
 255              (scaling (* ops magnification designsize)))
 256         (if (equal? font-name "unknown")
 257             (display (list font font-name)))
 258         (define-font font font-name scaling)))
 259
 260     (define (pango-font-load-command pango-font)
 261       (let* ((pf-fonts (ly:pango-font-physical-fonts pango-font))
 262              (pango-pf (if (pair? pf-fonts) (car pf-fonts) '("" "" 0)))
 263              (font-name (pango-pf-font-name pango-pf))
 264              (scaling (ly:output-def-lookup paper 'output-scale)))
 265         (if (equal? font-name "unknown")
 266             (display (list pango-font font-name)))
 267         (define-pango-pf pango-pf font-name scaling)))
 268
 269     (string-append
 270      (string-concatenate (map font-load-command other-fonts))
 271      (string-concatenate (map pango-font-load-command pango-only-fonts)))))