mf/feta-klef.mf

   1 %
   2 % feta-klef.mf --  implement Clefs
   3 %
   4 % source file of the Feta (Font-En-Tja) music font
   5 %
   6 % (c) 1997 Han-Wen Nienhuys <hanwen@stack.nl>,
   7 % Jan Nieuwenhuizen <jan@digicash.com>
   8
   9
  10
  11
  12 fet_begingroup("clefs");
  13
  14 %
  15 % [Ross] says that clefs take 1 interline space on the left and right
  16 %
  17 def set_horizontal_spacing =
  18         save left_space ,right_space;
  19         left_space# = reduced_il#;
  20         right_space# = reduced_il#;
  21 enddef;
  22
  23 def draw_staff(expr first, last)=
  24         pickup pencircle scaled stafflinethickness;
  25         for i:= first step 1 until last:
  26                 draw (- interline, i* interline) .. (4 interline, i* interline);
  27         endfor
  28         enddef;
  29
  30 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  31 % "arrow"
  32 def draw_c_clef (expr reduction) =
  33         save hair, norm, reduced_il, right_edge;
  34         reduced_il#=interline#*reduction;
  35         norm#:=2/3reduced_il#;
  36         hair#:=1/6norm#;
  37
  38         set_horizontal_spacing;
  39         right_edge# = 15/4norm#+2hair#;
  40
  41         set_char_box (left_space#, right_edge# + right_space#,
  42                 2 reduced_il#, 2 reduced_il#);
  43         define_pixels (hair,norm,reduced_il, right_edge);
  44
  45         draw_block ((0,-d), (3/4norm+1/2hair,h));
  46         draw_block ((3/4norm+2hair,-d),
  47                 (3/4norm+7/2hair,h));
  48
  49         save xoff;
  50         xoff=3/4norm+7/2hair;
  51         penpos1(hair,-90);
  52         z1l=(xoff+norm+hair,h);
  53         penpos2(norm-3/2hair,180);
  54         z2l=(right_edge,h/2);
  55         penpos3(hair,90);
  56         z3=(((right_edge -xoff)/2)+xoff,2hair);
  57
  58         penpos4(hair,0);
  59         z4=(xoff+1/2norm+1/2hair,reduced_il-hair);
  60
  61         penpos5(4hair,0);
  62         z5=(xoff+5/4hair,0);
  63
  64         penpos6(norm-hair,90);
  65         z6=(xoff+3/4norm,0);
  66
  67         penpos7(hair,-90);
  68         z7r=(x1,-d);
  69
  70         save t; t=0.833;
  71         save p; path p;
  72         p = z5l..z4l{up}..z4r{down}..z3r{right}..tension t..z2r{up}
  73                 ..tension t..z1r{left}..z1l{right}..tension t..z2l{down}
  74                 ..z3l{left}..z6r..z5r{down};
  75         pickup pencircle scaled 1pt#;
  76         filldraw p..(reverse p yscaled -1)..cycle;
  77         penlabels (1,2,3,4,5,6);
  78
  79         % ugh, should be bulb, not flare?
  80         draw_flare(z1l,180,90,hair,norm-1/2hair);
  81         draw_flare(z7r,180,-90,hair,norm-1/2hair);
  82         enddef;
  83
  84 fet_beginchar ("C clef", "alto", "altoclef")
  85         if test = 1:
  86                 draw_staff (-2,2);
  87         fi;
  88         draw_c_clef (1.0);
  89 fet_endchar;
  90
  91 fet_beginchar ("C clef", "alto_change", "caltoclef")
  92         if test = 1:
  93                 draw_staff (-2,2);
  94         fi;
  95         draw_c_clef (.8);
  96 fet_endchar;
  97
  98 %
  99 % Inspired by Baerenreiter and Breitkopf
 100 %
 101 % FIXME: dims
 102 % FIXME: right vertical tangent seems to be lower than the F-line
 103 % FIXME: bulb curve smoothly into "long curve" on the  inside
 104 %
 105 %
 106 % [Wanske] says that the extreme x point should be exactly between
 107 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
 108
 109 def draw_bass_klef(expr exact_center, reduction) =
 110         save reduced_il, left_tilt, left_thick, ball_to_right;
 111         reduced_il# = interline# * reduction;
 112
 113         set_horizontal_spacing;
 114         ball_to_right# = 2.1 reduced_il#;
 115         set_char_box(left_space# +
 116                 - xpart exact_center,
 117                 right_space# +
 118                 xpart exact_center + ball_to_right#,
 119                 - ypart exact_center + 2.5 reduced_il#,
 120                 ypart exact_center +reduced_il#);
 121
 122         define_pixels(reduced_il, ball_to_right);
 123         left_tilt = 5;
 124         left_thick = .25  reduced_il;
 125
 126         x1r - x1l = left_thick;
 127         z1l = (hround_pixels(xpart exact_center),
 128                 vround_pixels(ypart exact_center));
 129
 130         y2 = reduced_il;
 131
 132         x3l - x1l =  ball_to_right;
 133         x2 = .5 [x1,x3];
 134         x3l - x3r = .48 reduced_il;
 135         y3l = -0.05 interline;
 136         x4 = x1l - stafflinethickness;
 137         y4 = -2.2  reduced_il;
 138         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
 139
 140         penpos1(whatever, left_tilt);
 141         penpos2(1.2 stafflinethickness, -90);
 142         penpos3(whatever,  185);
 143         penpos4(stafflinethickness, 135);
 144
 145         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
 146
 147
 148         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
 149                 simple_serif(z4r, z4l, 90) {curl 0}
 150                 .. z3l{up} .. tension 0.9 .. z2l{left}
 151                 .. z1l{dir (-90 + left_tilt)} -- cycle;
 152         labels(2,4);
 153         penlabels(1,2,3,4);
 154
 155         save dot_diam;
 156         2 dot_diam = reduction* (interline - stafflinethickness);
 157         pickup pencircle scaled dot_diam;
 158         draw z5;
 159         draw z5 yscaled -1;
 160 enddef;
 161
 162
 163
 164 fet_beginchar("F clef ", "bass", "bassclef")
 165         if test = 1:
 166                 draw_staff(-3,1);
 167         fi;
 168         draw_bass_klef((.5 interline#, 0), 1.0);
 169 fet_endchar;
 170 fet_beginchar("F clef (reduced)", "bass_change", "cbassclef")
 171         draw_bass_klef((.4 interline#, 0),0.8);
 172 fet_endchar;
 173
 174
 175
 176 %
 177 % Inspired by Baerenreiter
 178 %
 179 % FIXME bulb should curve (see bass clef)
 180 % FIXME start (inside) should be little thinner
 181 % FIXME parametrise.
 182 %
 183
 184 % Beste lezers, kijk,
 185 %
 186 % Een bolletje  hebben we bij toeval allemaal wel eens getekend, maar begint u
 187 % toch eenvoudig.   Eerst een eenvoudig kruis of herstellingsteken
 188 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 189 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 190 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 191 %
 192 def draw_gclef (expr exact_center, reduction)=
 193         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 194         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 195         save inner_start_angle, thinness, thinpen;
 196         reduced_il# = interline# * reduction;
 197         define_pixels(reduced_il);
 198         pair downstroke_dir, center;
 199
 200         center := (hround_pixels(xpart exact_center),
 201                 vround_pixels(ypart exact_center));
 202
 203         hair =  .3 stafflinethickness;
 204         thinness = 1.3 stafflinethickness;
 205         downstroke_dir = (14, -75);
 206         breapth_factor = 11/7;
 207         inner_thick_end = 45;
 208         inner_start_angle = downstroke_angle - 43;
 209         thickness = .4 reduced_il - hair;
 210
 211         thinnib = thinness - hair;
 212         thinpen = thinness;
 213         set_horizontal_spacing;
 214
 215         set_char_box(
 216                 left_space# +
 217                 -xpart exact_center + 1.0 * breapth_factor* reduced_il#,
 218                 right_space# +
 219                 xpart exact_center + .66 breapth_factor* reduced_il#,
 220                 -ypart exact_center + 3 * reduced_il#,
 221                 ypart exact_center + 5 * reduced_il#);
 222
 223         pickup pencircle scaled hair;
 224         downstroke_angle = angle downstroke_dir;
 225
 226         z1 = center + whatever * dir (inner_start_angle);
 227         x1 = xpart center -.28 reduced_il;
 228
 229         top z2r = center + (0,reduced_il + stafflinethickness/2);
 230
 231         x4 = xpart center - .1 reduced_il;
 232         bot y4r = -(reduced_il + .5 stafflinethickness);
 233
 234         z3 = (z4 - center) rotated inner_thick_end + center;
 235
 236         z5r = (- breapth_factor, .37)* reduced_il + center;
 237         penpos5(thickness, 135);
 238
 239         z6 = center + whatever * downstroke_dir;
 240         y6 = ypart center + 2 reduced_il;
 241
 242         z7l - z6 = whatever *(z5- z6) ;
 243         y7l = 3.5 reduced_il;
 244         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 245
 246         x9 = .7 [x10, x7r];
 247         top y9l = 5 reduced_il;
 248
 249         y10 = 3. reduced_il;
 250         y11 = -11/7 reduced_il;
 251
 252         y12 = ypart center - 18.5/7 reduced_il;
 253         x12 = x11 - 5 /7 reduced_il;
 254
 255         z13 = z12 + .6 reduced_il*(-1,1);
 256
 257         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 258                 thinnib;
 259
 260         center - z10= whatever * downstroke_dir;
 261         center - z11 =  whatever * downstroke_dir;
 262         center - z14 = .8 (center - z11);
 263         penpos1(thinnib, inner_start_angle);
 264         penpos2(thickness, 90);
 265         penpos3(thinnib, -90 + inner_thick_end);
 266         penpos4(thinnib, -90);
 267
 268
 269         penpos7(thickness, 135);
 270         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 271         penpos9(1.4 thickness, -80);  % ugh
 272         penpos10(whatever, downstroke_angle + 10);
 273         penpos11(thinnib, downstroke_angle + 90);
 274         penpos14(thinnib, downstroke_angle + 90);
 275         penpos12(thinnib, -90);
 276         penpos13(3 thinnib, 180);
 277
 278         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 279                 %.. z8l
 280                 .. tension 1.2
 281                 .. z9l & z9l ..
 282                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 283                 .. tension .8
 284                 .. z9r & z9r{dir (downstroke_angle+ 40)} % ugh
 285                 %.. z8r
 286                 .. z7r{down} .. z5r{down} .. z4r{right}
 287                 .. z3r .. z2r{left} ..
 288                 tension .95 ..
 289                 z1r -- z1l
 290                 .. tension 0.85 ..cycle;
 291
 292         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 293
 294         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 295
 296         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 297
 298         pickup pencircle scaled (thinpen);
 299         draw z10 --- z14 .. z11  .. tension 0.85 ..  z12{left};
 300
 301         penlabels(range 1 thru 15);
 302 enddef;
 303
 304
 305 fet_beginchar("G clef", "violin", "violinclef")
 306         if test = 1:
 307                 draw_staff(-1,3);
 308         fi;
 309         draw_gclef((1.7 interline#,0), 1.0);
 310 fet_endchar;
 311 fet_beginchar("G clef", "violin_change", "cviolinclef")
 312         draw_gclef((1.3 interline#,0), .8);
 313 fet_endchar;
 314
 315 fet_endgroup("clefs");