lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYDEBUG 1
  13 #define YYERROR_VERBOSE 1
  14 #define YYPARSE_PARAM my_lily_parser
  15 #define YYLEX_PARAM my_lily_parser
  16 #define PARSER ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror PARSER->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "file-path.hh"
  78 #include "input.hh"
  79 #include "international.hh"
  80 #include "lily-guile.hh"
  81 #include "lily-lexer.hh"
  82 #include "lily-parser.hh"
  83 #include "lilypond-input-version.hh"
  84 #include "main.hh"
  85 #include "misc.hh"
  86 #include "music.hh"
  87 #include "music.hh"
  88 #include "output-def.hh"
  89 #include "paper-book.hh"
  90 #include "program-option.hh"
  91 #include "scm-hash.hh"
  92 #include "score.hh"
  93 #include "text-interface.hh"
  94 #include "warn.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         std::string *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 /* ES TODO:
 114 - Don't use lily module, create a new module instead.
 115 - delay application of the function
 116 */
 117 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 118   scm_apply_0 (proc, args)
 119 /* Syntactic Sugar. */
 120 #define MAKE_SYNTAX(name, location, ...)        \
 121   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 122
 123 SCM get_next_unique_context_id ();
 124 SCM get_next_unique_lyrics_context_id ();
 125
 126 #undef _
 127 #if !HAVE_GETTEXT
 128 #define _(x) x
 129 #else
 130 #include <libintl.h>
 131 #define _(x) gettext (x)
 132 #endif
 133
 134
 135
 136 SCM make_music_relative (Pitch start, SCM music);
 137 SCM run_music_function (Lily_parser *, SCM expr);
 138 SCM get_first_context_id (SCM type, Music *m);
 139 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 140 SCM make_chord_step (int step, int alter);
 141 SCM make_simple_markup (SCM a);
 142 bool is_duration (int t);
 143 bool is_regular_identifier (SCM id);
 144 bool ly_input_procedure_p (SCM x);
 145 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 146 void set_music_properties (Music *p, SCM a);
 147
 148 %}
 149
 150 /* The third option is an alias that will be used to display the
 151    syntax error.  Bison CVS now correctly handles backslash escapes.
 152
 153    FIXME: Bison needs to translate some of these, eg, STRING.
 154
 155 */
 156
 157 /* Keyword tokens with plain escaped name.  */
 158 %token ACCEPTS "\\accepts"
 159 %token ADDLYRICS "\\addlyrics"
 160 %token ADDQUOTE "\\addquote"
 161 %token ALIAS "\\alias"
 162 %token ALTERNATIVE "\\alternative"
 163 %token BOOK "\\book"
 164 %token CHANGE "\\change"
 165 %token CHORDMODE "\\chordmode"
 166 %token CHORDS "\\chords"
 167 %token CONSISTS "\\consists"
 168 %token CONTEXT "\\context"
 169 %token DEFAULT "\\default"
 170 %token DEFAULTCHILD "\\defaultchild"
 171 %token DENIES "\\denies"
 172 %token DESCRIPTION "\\description"
 173 %token DRUMMODE "\\drummode"
 174 %token DRUMS "\\drums"
 175 %token FIGUREMODE "\\figuremode"
 176 %token FIGURES "\\figures"
 177 %token GROBDESCRIPTIONS "\\grobdescriptions"
 178 %token HEADER "\\header"
 179 %token INVALID "\\invalid"
 180 %token KEY "\\key"
 181 %token LAYOUT "\\layout"
 182 %token LYRICMODE "\\lyricmode"
 183 %token LYRICS "\\lyrics"
 184 %token LYRICSTO "\\lyricsto"
 185 %token MARK "\\mark"
 186 %token MARKUP "\\markup"
 187 %token MIDI "\\midi"
 188 %token NAME "\\name"
 189 %token NOTEMODE "\\notemode"
 190 %token OBJECTID "\\objectid"
 191 %token OCTAVE "\\octave"
 192 %token ONCE "\\once"
 193 %token OVERRIDE "\\override"
 194 %token PAPER "\\paper"
 195 %token PARTIAL "\\partial"
 196 %token RELATIVE "\\relative"
 197 %token REMOVE "\\remove"
 198 %token REPEAT "\\repeat"
 199 %token REST "\\rest"
 200 %token REVERT "\\revert"
 201 %token SCORE "\\score"
 202 %token SEQUENTIAL "\\sequential"
 203 %token SET "\\set"
 204 %token SIMULTANEOUS "\\simultaneous"
 205 %token SKIP "\\skip"
 206 %token TEMPO "\\tempo"
 207 %token TIMES "\\times"
 208 %token TRANSPOSE "\\transpose"
 209 %token TYPE "\\type"
 210 %token UNSET "\\unset"
 211 %token WITH "\\with"
 212
 213 /* Keyword token exceptions.  */
 214 %token TIME_T "\\time"
 215 %token NEWCONTEXT "\\new"
 216
 217
 218 /* Other string tokens.  */
 219
 220 %token CHORD_BASS "/+"
 221 %token CHORD_CARET "^"
 222 %token CHORD_COLON ":"
 223 %token CHORD_MINUS "-"
 224 %token CHORD_SLASH "/"
 225 %token ANGLE_OPEN "<"
 226 %token ANGLE_CLOSE ">"
 227 %token DOUBLE_ANGLE_OPEN "<<"
 228 %token DOUBLE_ANGLE_CLOSE ">>"
 229 %token E_BACKSLASH "\\"
 230 %token E_ANGLE_CLOSE "\\>"
 231 %token E_CHAR "\\C[haracter]"
 232 %token E_CLOSE "\\)"
 233 %token E_EXCLAMATION "\\!"
 234 %token E_BRACKET_OPEN "\\["
 235 %token E_OPEN "\\("
 236 %token E_BRACKET_CLOSE "\\]"
 237 %token E_ANGLE_OPEN "\\<"
 238 %token E_PLUS "\\+"
 239 %token E_TILDE "\\~"
 240 %token EXTENDER "__"
 241
 242 /*
 243 If we give names, Bison complains.
 244 */
 245 %token FIGURE_CLOSE /* "\\>" */
 246 %token FIGURE_OPEN /* "\\<" */
 247 %token FIGURE_SPACE "_"
 248 %token HYPHEN "--"
 249
 250 %token CHORDMODIFIERS
 251 %token LYRIC_MARKUP
 252 %token MULTI_MEASURE_REST
 253
 254
 255 %token <i> DIGIT
 256 %token <i> E_UNSIGNED
 257 %token <i> UNSIGNED
 258
 259 /* Artificial tokens, for more generic function syntax */
 260 %token <i> EXPECT_MARKUP;
 261 %token <i> EXPECT_MUSIC;
 262 %token <i> EXPECT_SCM;
 263 /* After the last argument. */
 264 %token <i> EXPECT_NO_MORE_ARGS;
 265
 266 %token <scm> BOOK_IDENTIFIER
 267 %token <scm> CHORDMODIFIER_PITCH
 268 %token <scm> CHORD_MODIFIER
 269 %token <scm> CONTEXT_DEF_IDENTIFIER
 270 %token <scm> DRUM_PITCH
 271 %token <scm> DURATION_IDENTIFIER
 272 %token <scm> EVENT_IDENTIFIER
 273 %token <scm> FRACTION
 274 %token <scm> LYRICS_STRING
 275 %token <scm> LYRIC_MARKUP_IDENTIFIER
 276 %token <scm> MARKUP_HEAD_EMPTY
 277 %token <scm> MARKUP_HEAD_LIST0
 278 %token <scm> MARKUP_HEAD_MARKUP0
 279 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 280 %token <scm> MARKUP_HEAD_SCM0
 281 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 282 %token <scm> MARKUP_HEAD_SCM0_SCM1
 283 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 284 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 285 %token <scm> MARKUP_IDENTIFIER
 286 %token <scm> MUSIC_FUNCTION
 287 %token <scm> MUSIC_IDENTIFIER
 288 %token <scm> NOTENAME_PITCH
 289 %token <scm> NUMBER_IDENTIFIER
 290 %token <scm> OUTPUT_DEF_IDENTIFIER
 291 %token <scm> REAL
 292 %token <scm> RESTNAME
 293 %token <scm> SCM_IDENTIFIER
 294 %token <scm> SCM_TOKEN
 295 %token <scm> SCORE_IDENTIFIER
 296 %token <scm> STRING
 297 %token <scm> STRING_IDENTIFIER
 298 %token <scm> TONICNAME_PITCH
 299
 300
 301 %type <book> book_block
 302 %type <book> book_body
 303
 304 %type <i> bare_unsigned
 305 %type <i> figured_bass_alteration
 306 %type <i> dots
 307 %type <i> exclamations
 308 %type <i> optional_rest
 309 %type <i> questions
 310 %type <i> script_dir
 311 %type <i> sub_quotes
 312 %type <i> sup_quotes
 313 %type <i> tremolo_type
 314
 315 /* Music */
 316 %type <scm> composite_music
 317 %type <scm> grouped_music_list
 318 %type <scm> music
 319 %type <scm> prefix_composite_music
 320 %type <scm> repeated_music
 321 %type <scm> sequential_music
 322 %type <scm> simple_music
 323 %type <scm> simultaneous_music
 324 %type <scm> chord_body
 325 %type <scm> chord_body_element
 326 %type <scm> command_element
 327 %type <scm> command_event
 328 %type <scm> context_change
 329 %type <scm> direction_less_event
 330 %type <scm> direction_reqd_event
 331 %type <scm> event_chord
 332 %type <scm> gen_text_def
 333 %type <scm> music_property_def
 334 %type <scm> note_chord_element
 335 %type <scm> post_event
 336 %type <scm> re_rhythmed_music
 337 %type <scm> relative_music
 338 %type <scm> simple_element
 339 %type <scm> simple_music_property_def
 340 %type <scm> string_number_event
 341 %type <scm> tempo_event
 342
 343 %type <outputdef> output_def_body
 344 %type <outputdef> output_def_head
 345 %type <outputdef> output_def_head_with_mode_switch
 346 %type <outputdef> output_def
 347 %type <outputdef> paper_block
 348
 349 %type <scm> alternative_music
 350 %type <scm> generic_prefix_music_scm
 351 %type <scm> music_list
 352 %type <scm> absolute_pitch
 353 %type <scm> assignment_id
 354 %type <scm> bare_number
 355 %type <scm> bass_figure
 356 %type <scm> figured_bass_modification
 357 %type <scm> br_bass_figure
 358 %type <scm> bass_number
 359 %type <scm> chord_body_elements
 360 %type <scm> chord_item
 361 %type <scm> chord_items
 362 %type <scm> chord_separator
 363 %type <scm> context_def_mod
 364 %type <scm> context_def_spec_block
 365 %type <scm> context_def_spec_body
 366 %type <scm> context_mod
 367 %type <scm> context_mod_list
 368 %type <scm> context_prop_spec
 369 %type <scm> direction_less_char
 370 %type <scm> duration_length
 371 %type <scm> embedded_scm
 372 %type <scm> figure_list
 373 %type <scm> figure_spec
 374 %type <scm> fraction
 375 %type <scm> full_markup
 376 %type <scm> function_scm_argument
 377 %type <scm> function_arglist
 378 %type <scm> function_arglist_music_last
 379 %type <scm> function_arglist_nonmusic_last
 380 %type <scm> function_arglist_nonmusic
 381 %type <scm> identifier_init
 382 %type <scm> lilypond_header
 383 %type <scm> lilypond_header_body
 384 %type <scm> lyric_element
 385 %type <scm> lyric_markup
 386 %type <scm> markup
 387 %type <scm> markup_braced_list
 388 %type <scm> markup_braced_list_body
 389 %type <scm> markup_composed_list
 390 %type <scm> markup_head_1_item
 391 %type <scm> markup_head_1_list
 392 %type <scm> markup_list
 393 %type <scm> markup_top
 394 %type <scm> mode_changing_head
 395 %type <scm> mode_changing_head_with_context
 396 %type <scm> multiplied_duration
 397 %type <scm> music_function_identifier_musicless_prefix
 398 %type <scm> music_function_event
 399 %type <scm> music_function_chord_body
 400 %type <scm> new_chord
 401 %type <scm> new_lyrics
 402 %type <scm> number_expression
 403 %type <scm> number_factor
 404 %type <scm> number_term
 405 %type <scm> object_id_setting
 406 %type <scm> octave_check
 407 %type <scm> optional_context_mod
 408 %type <scm> optional_id
 409 %type <scm> optional_notemode_duration
 410 %type <scm> pitch
 411 %type <scm> pitch_also_in_chords
 412 %type <scm> post_events
 413 %type <scm> property_operation
 414 %type <scm> scalar
 415 %type <scm> script_abbreviation
 416 %type <scm> simple_chord_elements
 417 %type <scm> simple_markup
 418 %type <scm> simple_string
 419 %type <scm> steno_duration
 420 %type <scm> steno_pitch
 421 %type <scm> steno_tonic_pitch
 422 %type <scm> step_number
 423 %type <scm> step_numbers
 424 %type <scm> string
 425
 426 %type <score> score_block
 427 %type <score> score_body
 428
 429
 430 %left '-' '+'
 431
 432 /* We don't assign precedence to / and *, because we might need varied
 433 prec levels in different prods */
 434
 435 %left UNARY_MINUS
 436
 437 %%
 438
 439 lilypond:       /* empty */
 440         | lilypond toplevel_expression {
 441         }
 442         | lilypond assignment {
 443         }
 444         | lilypond error {
 445                 PARSER->error_level_ = 1;
 446         }
 447         | lilypond INVALID      {
 448                 PARSER->error_level_ = 1;
 449         }
 450         ;
 451
 452
 453 object_id_setting:
 454         OBJECTID STRING { $$ = $2; }
 455         ;
 456
 457 toplevel_expression:
 458         lilypond_header {
 459                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 460         }
 461         | book_block {
 462                 Book *book = $1;
 463                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 464                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 465                 book->unprotect ();
 466         }
 467         | score_block {
 468                 Score *score = $1;
 469
 470                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 471                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 472                 score->unprotect ();
 473         }
 474         | composite_music {
 475                 Music *music = unsmob_music ($1);
 476                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 477                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 478         }
 479         | full_markup {
 480                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 481                 scm_call_2 (proc, PARSER->self_scm (), $1);
 482         }
 483         | output_def {
 484                 SCM id = SCM_EOL;
 485                 Output_def * od = $1;
 486
 487                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultpaper");
 489                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultmidi");
 491                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 492                         id = ly_symbol2scm ("$defaultlayout");
 493
 494                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 495                 od->unprotect();
 496         }
 497         ;
 498
 499 embedded_scm:
 500         SCM_TOKEN
 501         | SCM_IDENTIFIER
 502         ;
 503
 504
 505 lilypond_header_body:
 506         {
 507                 $$ = get_header(PARSER);
 508                 PARSER->lexer_->add_scope ($$);
 509         }
 510         | lilypond_header_body assignment  {
 511
 512         }
 513         ;
 514
 515 lilypond_header:
 516         HEADER '{' lilypond_header_body '}'     {
 517                 $$ = PARSER->lexer_->remove_scope ();
 518         }
 519         ;
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment_id:
 525         STRING          { $$ = $1; }
 526         | LYRICS_STRING { $$ = $1; }
 527         ;
 528
 529 assignment:
 530         assignment_id '=' identifier_init  {
 531                 PARSER->lexer_->set_identifier ($1, $3);
 532
 533 /*
 534  TODO: devise standard for protection in parser.
 535
 536   The parser stack lives on the C-stack, which means that
 537 all objects can be unprotected as soon as they're here.
 538
 539 */
 540         }
 541         | embedded_scm { }
 542         ;
 543
 544
 545 identifier_init:
 546         score_block {
 547                 $$ = $1->self_scm ();
 548                 $1->unprotect ();
 549         }
 550         | book_block {
 551                 $$ = $1->self_scm ();
 552                 $1->unprotect ();
 553         }
 554         | output_def {
 555                 $$ = $1->self_scm ();
 556                 $1->unprotect ();
 557         }
 558         | context_def_spec_block {
 559                 $$ = $1;
 560         }
 561         | music  {
 562                 /* Hack: Create event-chord around standalone events.
 563                    Prevents the identifier from being interpreted as a post-event. */
 564                 Music *mus = unsmob_music ($1);
 565                 bool is_event = mus &&
 566                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 567                                 != SCM_BOOL_F);
 568                 if (!is_event)
 569                         $$ = $1;
 570                 else
 571                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 572         }
 573         | post_event {
 574                 $$ = $1;
 575         }
 576         | number_expression {
 577                 $$ = $1;
 578         }
 579         | string {
 580                 $$ = $1;
 581         }
 582         | embedded_scm {
 583                 $$ = $1;
 584         }
 585         | full_markup {
 586                 $$ = $1;
 587         }
 588         | DIGIT {
 589                 $$ = scm_from_int ($1);
 590         }
 591         ;
 592
 593 context_def_spec_block:
 594         CONTEXT '{' context_def_spec_body '}'
 595                 {
 596                 $$ = $3;
 597         }
 598         ;
 599
 600 context_def_spec_body:
 601         /**/ {
 602                 $$ = Context_def::make_scm ();
 603                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 604         }
 605         | CONTEXT_DEF_IDENTIFIER {
 606                 $$ = $1;
 607                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 608         }
 609         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 610                 Context_def*td = unsmob_context_def ($$);
 611
 612                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 613                         SCM tag = scm_caar (p);
 614
 615                         /* TODO: should make new tag "grob-definition" ? */
 616                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 617                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 618                 }
 619         }
 620         | context_def_spec_body context_mod {
 621                 unsmob_context_def ($$)->add_context_mod ($2);
 622         }
 623         ;
 624
 625
 626
 627 book_block:
 628         BOOK '{' book_body '}'  {
 629                 $$ = $3;
 630         }
 631         ;
 632
 633 /* FIXME:
 634    * Use 'handlers' like for toplevel-* stuff?
 635    * grok \layout and \midi?  */
 636 book_body:
 637         {
 638                 $$ = new Book;
 639                 $$->origin ()->set_spot (@$);
 640                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 641                 $$->paper_->unprotect ();
 642                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 643         }
 644         | BOOK_IDENTIFIER {
 645                 $$ = unsmob_book ($1);
 646                 $$->protect ();
 647                 $$->origin ()->set_spot (@$);
 648         }
 649         | book_body paper_block {
 650                 $$->paper_ = $2;
 651                 $2->unprotect ();
 652         }
 653         | book_body score_block {
 654                 SCM s = $2->self_scm ();
 655                 $$->add_score (s);
 656                 $2->unprotect();
 657         }
 658         | book_body full_markup {
 659                 $$->add_score ($2);
 660         }
 661         | book_body lilypond_header {
 662                 $$->header_ = $2;
 663         }
 664         | book_body error {
 665                 $$->paper_ = 0;
 666                 $$->scores_ = SCM_EOL;
 667         }
 668         | book_body object_id_setting {
 669                 $$->user_key_ = ly_scm2string ($2);
 670         }
 671         ;
 672
 673 score_block:
 674         SCORE '{' score_body '}'        {
 675                 $$ = $3;
 676         }
 677         ;
 678
 679 score_body:
 680         music {
 681                 SCM m = $1;
 682                 SCM scorify = ly_lily_module_constant ("scorify-music");
 683                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 684
 685                 // pass ownernship to C++ again.
 686                 $$ = unsmob_score (score);
 687                 $$->protect ();
 688                 $$->origin ()->set_spot (@$);
 689         }
 690         | SCORE_IDENTIFIER {
 691                 $$ = unsmob_score ($1);
 692                 $$->protect ();
 693                 $$->origin ()->set_spot (@$);
 694         }
 695         | score_body object_id_setting {
 696                 $$->user_key_ = ly_scm2string ($2);
 697         }
 698         | score_body lilypond_header    {
 699                 $$->header_ = $2;
 700         }
 701         | score_body output_def {
 702                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 703                 {
 704                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 705
 706                 }
 707                 else
 708                 {
 709                         $$->add_output_def ($2);
 710                 }
 711                 $2->unprotect ();
 712         }
 713         | score_body error {
 714                 $$->error_found_ = true;
 715         }
 716         ;
 717
 718
 719 /*
 720         OUTPUT DEF
 721 */
 722
 723 paper_block:
 724         output_def {
 725                 $$ = $1;
 726                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 727                 {
 728                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 729                         $1->unprotect ();
 730                         $$ = get_paper (PARSER);
 731                 }
 732         }
 733         ;
 734
 735
 736 output_def:
 737         output_def_body '}' {
 738                 $$ = $1;
 739
 740                 PARSER->lexer_->remove_scope ();
 741                 PARSER->lexer_->pop_state ();
 742         }
 743         ;
 744
 745 output_def_head:
 746         PAPER {
 747                 $$ = get_paper (PARSER);
 748                 $$->input_origin_ = @$;
 749                 PARSER->lexer_->add_scope ($$->scope_);
 750         }
 751         | MIDI    {
 752                 Output_def *p = get_midi (PARSER);
 753                 $$ = p;
 754                 PARSER->lexer_->add_scope (p->scope_);
 755         }
 756         | LAYOUT        {
 757                 Output_def *p = get_layout (PARSER);
 758
 759                 PARSER->lexer_->add_scope (p->scope_);
 760                 $$ = p;
 761         }
 762         ;
 763
 764 output_def_head_with_mode_switch:
 765         output_def_head {
 766                 PARSER->lexer_->push_initial_state ();
 767                 $$ = $1;
 768         }
 769         ;
 770
 771 output_def_body:
 772         output_def_head_with_mode_switch '{' {
 773                 $$ = $1;
 774                 $$->input_origin_.set_spot (@$);
 775         }
 776         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 777                 $1->unprotect ();
 778
 779                 Output_def *o = unsmob_output_def ($3);
 780                 o->input_origin_.set_spot (@$);
 781                 $$ = o;
 782                 $$->protect ();
 783                 PARSER->lexer_->remove_scope ();
 784                 PARSER->lexer_->add_scope (o->scope_);
 785         }
 786         | output_def_body assignment  {
 787
 788         }
 789         | output_def_body context_def_spec_block        {
 790                 assign_context_def ($$, $2);
 791         }
 792         | output_def_body error {
 793
 794         }
 795         ;
 796
 797 tempo_event:
 798         TEMPO steno_duration '=' bare_unsigned  {
 799                 $$ = MAKE_SYNTAX ("tempo", @$, $2, scm_int2num ($4));
 800         }
 801         ;
 802
 803 /*
 804 The representation of a  list is the
 805
 806   (LIST . LAST-CONS)
 807
 808  to have efficient append.  */
 809
 810 music_list:
 811         /* empty */ {
 812                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 813         }
 814         | music_list music {
 815                 SCM s = $$;
 816                 SCM c = scm_cons ($2, SCM_EOL);
 817
 818                 if (scm_is_pair (scm_cdr (s)))
 819                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 820                 else
 821                         scm_set_car_x (s, c); /* set first cons */
 822                 scm_set_cdr_x (s, c);  /* remember last cell */
 823         }
 824         | music_list embedded_scm {
 825
 826         }
 827         | music_list error {
 828                 Music *m = MY_MAKE_MUSIC("Music");
 829                 // ugh. code dup
 830                 m->set_property ("error-found", SCM_BOOL_T);
 831                 SCM s = $$;
 832                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 833                 m->unprotect (); /* UGH */
 834
 835                 if (scm_is_pair (scm_cdr (s)))
 836                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 837                 else
 838                         scm_set_car_x (s, c); /* set first cons */
 839                 scm_set_cdr_x (s, c);  /* remember last cell */
 840         }
 841         ;
 842
 843 music:
 844         simple_music
 845         | composite_music
 846         ;
 847
 848 alternative_music:
 849         /* empty */ {
 850                 $$ = SCM_EOL;
 851         }
 852         | ALTERNATIVE '{' music_list '}' {
 853                 $$ = scm_car ($3);
 854         }
 855         ;
 856
 857
 858 repeated_music:
 859         REPEAT simple_string bare_unsigned music alternative_music
 860         {
 861                 $$ = MAKE_SYNTAX ("repeat", @$, $2, scm_int2num ($3), $4, $5);
 862         }
 863         ;
 864
 865 sequential_music:
 866         SEQUENTIAL '{' music_list '}'           {
 867                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 868         }
 869         | '{' music_list '}'            {
 870                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 871         }
 872         ;
 873
 874 simultaneous_music:
 875         SIMULTANEOUS '{' music_list '}'{
 876                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
 877         }
 878         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
 879                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
 880         }
 881         ;
 882
 883 simple_music:
 884         event_chord
 885         | MUSIC_IDENTIFIER
 886         | music_property_def
 887         | context_change
 888         ;
 889
 890 optional_context_mod:
 891         /**/ { $$ = SCM_EOL; }
 892         | WITH { PARSER->lexer_->push_initial_state (); }
 893         '{' context_mod_list '}'
 894         {
 895                 PARSER->lexer_->pop_state ();
 896                 $$ = $4;
 897         }
 898         ;
 899
 900 context_mod_list:
 901         /* */  { $$ = SCM_EOL; }
 902         | context_mod_list context_mod  {
 903                  $$ = scm_cons ($2, $1);
 904         }
 905         ;
 906
 907 composite_music:
 908         prefix_composite_music { $$ = $1; }
 909         | grouped_music_list { $$ = $1; }
 910         ;
 911
 912 grouped_music_list:
 913         simultaneous_music              { $$ = $1; }
 914         | sequential_music              { $$ = $1; }
 915         ;
 916
 917 function_scm_argument:
 918         embedded_scm
 919         | simple_string
 920         ;
 921
 922 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
 923  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM
 924 and this rule returns the reversed list of arguments. */
 925
 926 function_arglist_music_last:
 927         EXPECT_MUSIC function_arglist music {
 928                 $$ = scm_cons ($3, $2);
 929         }
 930         ;
 931
 932 function_arglist_nonmusic_last:
 933         EXPECT_MARKUP function_arglist full_markup {
 934                 $$ = scm_cons ($3, $2);
 935         }
 936         | EXPECT_SCM function_arglist function_scm_argument {
 937                 $$ = scm_cons ($3, $2);
 938         }
 939         ;
 940
 941 function_arglist_nonmusic: EXPECT_NO_MORE_ARGS {
 942                 $$ = SCM_EOL;
 943         }
 944         | EXPECT_MARKUP function_arglist_nonmusic full_markup {
 945                 $$ = scm_cons ($3, $2);
 946         }
 947         | EXPECT_SCM function_arglist_nonmusic function_scm_argument {
 948                 $$ = scm_cons ($3, $2);
 949         }
 950         ;
 951
 952 function_arglist: EXPECT_NO_MORE_ARGS {
 953                 /* This is for 0-ary functions, so they don't need to
 954                    read a lookahead token */
 955                 $$ = SCM_EOL;
 956         }
 957         | function_arglist_music_last
 958         | function_arglist_nonmusic_last
 959         ;
 960
 961 generic_prefix_music_scm:
 962         MUSIC_FUNCTION function_arglist {
 963                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
 964         }
 965         ;
 966
 967
 968 optional_id:
 969         /**/ { $$ = SCM_EOL; }
 970         | '=' simple_string {
 971                 $$ = $2;
 972         }
 973         ;
 974
 975
 976 prefix_composite_music:
 977         generic_prefix_music_scm {
 978                 $$ = run_music_function (PARSER, $1);
 979         }
 980         | CONTEXT    simple_string optional_id optional_context_mod music {
 981                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_F);
 982         }
 983         | NEWCONTEXT simple_string optional_id optional_context_mod music {
 984                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_T);
 985         }
 986
 987         | TIMES fraction music {
 988                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
 989         }
 990         | repeated_music                { $$ = $1; }
 991         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
 992                 Pitch from = *unsmob_pitch ($2);
 993                 Pitch to = *unsmob_pitch ($3);
 994                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
 995                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
 996         }
 997         | mode_changing_head grouped_music_list {
 998                 if ($1 == ly_symbol2scm ("chords"))
 999                 {
1000                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1001                 }
1002                 else
1003                 {
1004                   $$ = $2;
1005                 }
1006                 PARSER->lexer_->pop_state ();
1007         }
1008         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1009                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, $2, SCM_BOOL_T);
1010                 if ($1 == ly_symbol2scm ("ChordNames"))
1011                 {
1012                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1013                 }
1014                 PARSER->lexer_->pop_state ();
1015         }
1016         | relative_music        { $$ = $1; }
1017         | re_rhythmed_music     { $$ = $1; }
1018         ;
1019
1020 mode_changing_head:
1021         NOTEMODE {
1022                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1023                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1024
1025                 $$ = ly_symbol2scm ("notes");
1026         }
1027         | DRUMMODE
1028                 {
1029                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1030                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1031
1032                 $$ = ly_symbol2scm ("drums");
1033         }
1034         | FIGUREMODE {
1035                 PARSER->lexer_->push_figuredbass_state ();
1036
1037                 $$ = ly_symbol2scm ("figures");
1038         }
1039         | CHORDMODE {
1040                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1041                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1042                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1043                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1044                 $$ = ly_symbol2scm ("chords");
1045
1046         }
1047         | LYRICMODE
1048                 { PARSER->lexer_->push_lyric_state ();
1049                 $$ = ly_symbol2scm ("lyrics");
1050         }
1051         ;
1052
1053 mode_changing_head_with_context:
1054         DRUMS {
1055                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1056                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1057
1058                 $$ = ly_symbol2scm ("DrumStaff");
1059         }
1060         | FIGURES {
1061                 PARSER->lexer_->push_figuredbass_state ();
1062
1063                 $$ = ly_symbol2scm ("FiguredBass");
1064         }
1065         | CHORDS {
1066                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1067                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1068                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1069                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1070                 $$ = ly_symbol2scm ("ChordNames");
1071         }
1072         | LYRICS
1073                 { PARSER->lexer_->push_lyric_state ();
1074                 $$ = ly_symbol2scm ("Lyrics");
1075         }
1076         ;
1077
1078
1079 relative_music:
1080         RELATIVE absolute_pitch music {
1081                 Pitch start = *unsmob_pitch ($2);
1082                 $$ = make_music_relative (start, $3);
1083         }
1084         | RELATIVE composite_music {
1085                 Pitch middle_c (0, 0, 0);
1086                 $$ = make_music_relative (middle_c, $2);
1087         }
1088         ;
1089
1090 new_lyrics:
1091         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1092         /*cont */
1093         grouped_music_list {
1094         /* Can also use music at the expensive of two S/Rs similar to
1095            \repeat \alternative */
1096                 PARSER->lexer_->pop_state ();
1097
1098                 $$ = scm_cons ($3, SCM_EOL);
1099         }
1100         | new_lyrics ADDLYRICS {
1101                 PARSER->lexer_->push_lyric_state ();
1102         } grouped_music_list {
1103                 PARSER->lexer_->pop_state ();
1104                 $$ = scm_cons ($4, $1);
1105         }
1106         ;
1107
1108 re_rhythmed_music:
1109         grouped_music_list new_lyrics {
1110                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1111         }
1112         | LYRICSTO simple_string {
1113                 PARSER->lexer_->push_lyric_state ();
1114         } music {
1115                 PARSER->lexer_->pop_state ();
1116                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1117         }
1118         ;
1119
1120 context_change:
1121         CHANGE STRING '=' STRING  {
1122                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1123         }
1124         ;
1125
1126 property_operation:
1127         STRING '=' scalar {
1128                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1129                         scm_string_to_symbol ($1), $3);
1130         }
1131         | UNSET simple_string {
1132                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1133                         scm_string_to_symbol ($2));
1134         }
1135         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1136                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1137                         scm_string_to_symbol ($2), $5, $3);
1138         }
1139         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1140                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1141                                 scm_string_to_symbol ($2), $6, $4, $3);
1142         }
1143         | REVERT simple_string embedded_scm {
1144                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1145                         scm_string_to_symbol ($2), $3);
1146         }
1147         ;
1148
1149 context_def_mod:
1150         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1151         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1152
1153         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1154         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1155         | DENIES { $$ = ly_symbol2scm ("denies"); }
1156
1157         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1158         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1159         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1160         | NAME { $$ = ly_symbol2scm ("context-name"); }
1161         ;
1162
1163 context_mod:
1164         property_operation { $$ = $1; }
1165         | context_def_mod STRING {
1166                 $$ = scm_list_2 ($1, $2);
1167         }
1168         ;
1169
1170 context_prop_spec:
1171         simple_string {
1172                 if (!is_regular_identifier ($1))
1173                 {
1174                         @$.error (_("Grob name should be alphanumeric"));
1175                 }
1176
1177                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1178                         scm_string_to_symbol ($1));
1179         }
1180         | simple_string '.' simple_string {
1181                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1182                         scm_string_to_symbol ($3));
1183         }
1184         ;
1185
1186 simple_music_property_def:
1187         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1188                 $$ = scm_list_5 (scm_car ($2),
1189                         ly_symbol2scm ("OverrideProperty"),
1190                         scm_cadr ($2),
1191                         $5, $3);
1192         }
1193         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1194                 $$ = scm_list_n (scm_car ($2),
1195                         ly_symbol2scm ("OverrideProperty"),
1196                         scm_cadr ($2),
1197                         $6, $4, $3, SCM_UNDEFINED);
1198         }
1199         | REVERT context_prop_spec embedded_scm {
1200                 $$ = scm_list_4 (scm_car ($2),
1201                         ly_symbol2scm ("RevertProperty"),
1202                         scm_cadr ($2),
1203                         $3);
1204         }
1205         | SET context_prop_spec '=' scalar {
1206                 $$ = scm_list_4 (scm_car ($2),
1207                         ly_symbol2scm ("PropertySet"),
1208                         scm_cadr ($2),
1209                         $4);
1210         }
1211         | UNSET context_prop_spec {
1212                 $$ = scm_list_3 (scm_car ($2),
1213                         ly_symbol2scm ("PropertyUnset"),
1214                         scm_cadr ($2));
1215         }
1216         ;
1217
1218 music_property_def:
1219         simple_music_property_def {
1220                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1221         }
1222         | ONCE simple_music_property_def {
1223                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1224         }
1225         ;
1226
1227 string:
1228         STRING {
1229                 $$ = $1;
1230         }
1231         | STRING_IDENTIFIER {
1232                 $$ = $1;
1233         }
1234         | string '+' string {
1235                 $$ = scm_string_append (scm_list_2 ($1, $3));
1236         }
1237         ;
1238
1239 simple_string: STRING {
1240                 $$ = $1;
1241         }
1242         | LYRICS_STRING {
1243                 $$ = $1;
1244         }
1245         | STRING_IDENTIFIER {
1246                 $$ = $1;
1247         }
1248         ;
1249
1250 scalar: string {
1251                 $$ = $1;
1252         }
1253         | LYRICS_STRING {
1254                 $$ = $1;
1255         }
1256         | bare_number {
1257                 $$ = $1;
1258         }
1259         | embedded_scm {
1260                 $$ = $1;
1261         }
1262         | full_markup {
1263                 $$ = $1;
1264         }
1265         | DIGIT {
1266                 $$ = scm_from_int ($1);
1267         }
1268         ;
1269
1270 event_chord:
1271         /* TODO: Create a special case that avoids the creation of
1272            EventChords around simple_elements that have no post_events?
1273          */
1274         simple_chord_elements post_events       {
1275                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1276
1277                 Input i;
1278                 /* why is this giving wrong start location? -ns
1279                  * i = @$; */
1280                 i.set_location (@1, @2);
1281                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1282         }
1283         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1284                 Input i;
1285                 i.set_location (@1, @3);
1286                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2, $3);
1287         }
1288         | command_element
1289         | note_chord_element
1290         ;
1291
1292
1293 note_chord_element:
1294         chord_body optional_notemode_duration post_events
1295         {
1296                 Music *m = unsmob_music ($1);
1297                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1298                 SCM es = m->get_property ("elements");
1299                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1300
1301                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1302                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1303                 es = ly_append2 (es, postevs);
1304
1305                 m-> set_property ("elements", es);
1306                 m->set_spot (@$);
1307                 $$ = m->self_scm ();
1308         }
1309         ;
1310
1311 chord_body:
1312         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1313         {
1314                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1315         }
1316         ;
1317
1318 chord_body_elements:
1319         /* empty */             { $$ = SCM_EOL; }
1320         | chord_body_elements chord_body_element {
1321                 $$ = scm_cons ($2, $1);
1322         }
1323         ;
1324
1325 chord_body_element:
1326         pitch exclamations questions octave_check post_events
1327         {
1328                 int q = $3;
1329                 int ex = $2;
1330                 SCM check = $4;
1331                 SCM post = $5;
1332
1333                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1334                 n->set_property ("pitch", $1);
1335                 n->set_spot (@$);
1336                 if (q % 2)
1337                         n->set_property ("cautionary", SCM_BOOL_T);
1338                 if (ex % 2 || q % 2)
1339                         n->set_property ("force-accidental", SCM_BOOL_T);
1340
1341                 if (scm_is_pair (post)) {
1342                         SCM arts = scm_reverse_x (post, SCM_EOL);
1343                         n->set_property ("articulations", arts);
1344                 }
1345                 if (scm_is_number (check))
1346                 {
1347                         int q = scm_to_int (check);
1348                         n->set_property ("absolute-octave", scm_from_int (q-1));
1349                 }
1350
1351                 $$ = n->unprotect ();
1352         }
1353         | DRUM_PITCH post_events {
1354                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1355                 n->set_property ("duration", $2);
1356                 n->set_property ("drum-type", $1);
1357                 n->set_spot (@$);
1358
1359                 if (scm_is_pair ($2)) {
1360                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1361                         n->set_property ("articulations", arts);
1362                 }
1363                 $$ = n->unprotect ();
1364         }
1365         | music_function_chord_body {
1366                 $$ = run_music_function (PARSER, $1);
1367         }
1368         ;
1369
1370 music_function_identifier_musicless_prefix: MUSIC_FUNCTION {
1371                 SCM sig = scm_object_property (yylval.scm, ly_symbol2scm ("music-function-signature"));
1372                 if (scm_is_pair (sig) && to_boolean (scm_memq (ly_music_p_proc, scm_cdr (scm_reverse (sig)))))
1373                 {
1374                         PARSER->parser_error (@$, "Music function applied to event may not have a Music argument, except as the last argument.");
1375                 }
1376         }
1377         ;
1378
1379 music_function_chord_body:
1380         /* We could allow chord functions to have multiple music arguments,
1381            but it's more consistent with music_function_event if we
1382            prohibit it here too */
1383         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic chord_body_element {
1384                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1385         }
1386         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1387                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1388         }
1389         ;
1390
1391 music_function_event:
1392         /* Post-events can only have the last argument as music, without this
1393            restriction we get a shift/reduce conflict from e.g.
1394            c8-\partcombine c8 -. */
1395         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic post_event {
1396                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1397         }
1398         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1399                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1400         }
1401         ;
1402
1403 command_element:
1404         command_event {
1405                 $$ = $1;
1406         }
1407         | SKIP duration_length {
1408                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1409         }
1410         | E_BRACKET_OPEN {
1411                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1412                 m->set_property ("span-direction", scm_from_int (START));
1413                 m->set_spot (@$);
1414                 $$ = m->unprotect();
1415         }
1416         | E_BRACKET_CLOSE {
1417                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1418                 m->set_property ("span-direction", scm_from_int (STOP));
1419                 m->set_spot (@$);
1420                 $$ = m->unprotect ();
1421         }
1422         | E_BACKSLASH {
1423                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1424         }
1425         | '|'      {
1426                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1427
1428                 Music *m = unsmob_music (pipe);
1429                 if (m)
1430                 {
1431                         m = m->clone ();
1432                         m->set_spot (@$);
1433                         $$ = m->unprotect ();
1434                 }
1435                 else
1436                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1437
1438         }
1439         | PARTIAL duration_length       {
1440                 Moment m = - unsmob_duration ($2)->get_length ();
1441                 $$ = MAKE_SYNTAX ("property-operation", @$, SCM_BOOL_F, ly_symbol2scm ("Timing"), ly_symbol2scm ("PropertySet"), ly_symbol2scm ("measurePosition"), m.smobbed_copy ());
1442                 $$ = MAKE_SYNTAX ("context-specification", @$, ly_symbol2scm ("Score"), SCM_BOOL_F, $$, SCM_EOL, SCM_BOOL_F);
1443         }
1444
1445         | TIME_T fraction  {
1446                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1447
1448                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1449         }
1450         | MARK scalar {
1451                 SCM proc = ly_lily_module_constant ("make-mark-set");
1452
1453                 $$ = scm_call_1 (proc, $2);
1454         }
1455         ;
1456
1457 command_event:
1458         E_TILDE {
1459                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent")->unprotect ();
1460         }
1461         | MARK DEFAULT  {
1462                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1463                 $$ = m->unprotect ();
1464         }
1465         | tempo_event {
1466                 $$ = $1;
1467         }
1468         | KEY DEFAULT {
1469                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1470                 $$ = key->unprotect ();
1471         }
1472         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1473
1474                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1475                 if (scm_ilength ($3) > 0)
1476                 {
1477                         key->set_property ("pitch-alist", $3);
1478                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1479                         key->transpose (* unsmob_pitch ($2));
1480                 } else {
1481                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1482                 }
1483
1484                 $$ = key->unprotect ();
1485         }
1486         ;
1487
1488
1489 post_events:
1490         /* empty */ {
1491                 $$ = SCM_EOL;
1492         }
1493         | post_events post_event {
1494                 unsmob_music ($2)->set_spot (@2);
1495                 $$ = scm_cons ($2, $$);
1496         }
1497         ;
1498
1499 post_event:
1500         direction_less_event {
1501                 $$ = $1;
1502         }
1503         | '-' music_function_event {
1504                 $$ = run_music_function (PARSER, $2);
1505         }
1506         | HYPHEN {
1507                 if (!PARSER->lexer_->is_lyric_state ())
1508                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1509                 $$ = MY_MAKE_MUSIC ("HyphenEvent")->unprotect ();
1510         }
1511         | EXTENDER {
1512                 if (!PARSER->lexer_->is_lyric_state ())
1513                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1514                 $$ = MY_MAKE_MUSIC ("ExtenderEvent")->unprotect ();
1515         }
1516         | script_dir direction_reqd_event {
1517                 if ($1)
1518                 {
1519                         Music *m = unsmob_music ($2);
1520                         m->set_property ("direction", scm_from_int ($1));
1521                 }
1522                 $$ = $2;
1523         }
1524         | script_dir direction_less_event {
1525                 if ($1)
1526                 {
1527                         Music *m = unsmob_music ($2);
1528                         m->set_property ("direction", scm_from_int ($1));
1529                 }
1530                 $$ = $2;
1531         }
1532         | string_number_event
1533         ;
1534
1535 string_number_event:
1536         E_UNSIGNED {
1537                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1538                 s->set_property ("string-number", scm_from_int ($1));
1539                 s->set_spot (@$);
1540                 $$ = s->unprotect ();
1541         }
1542         ;
1543
1544 direction_less_char:
1545         '['  {
1546                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1547         }
1548         | ']'  {
1549                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1550         }
1551         | '~'  {
1552                 $$ = ly_symbol2scm ("tildeSymbol");
1553         }
1554         | '('  {
1555                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1556         }
1557         | ')'  {
1558                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1559         }
1560         | E_EXCLAMATION  {
1561                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1562         }
1563         | E_OPEN  {
1564                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1565         }
1566         | E_CLOSE  {
1567                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1568         }
1569         | E_ANGLE_CLOSE  {
1570                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1571         }
1572         | E_ANGLE_OPEN  {
1573                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1574         }
1575         ;
1576
1577 direction_less_event:
1578         direction_less_char {
1579                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1580                 Music *m = 0;
1581                 if (unsmob_music (predefd))
1582                 {
1583                         m = unsmob_music (predefd)->clone ();
1584                 }
1585                 else
1586                 {
1587                         m = MY_MAKE_MUSIC ("Music");
1588                 }
1589                 m->set_spot (@$);
1590                 $$ = m->unprotect ();
1591         }
1592         | EVENT_IDENTIFIER      {
1593                 $$ = $1;
1594         }
1595         | tremolo_type  {
1596                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1597                a->set_spot (@$);
1598                a->set_property ("tremolo-type", scm_from_int ($1));
1599                $$ = a->unprotect ();
1600         }
1601         ;
1602
1603 direction_reqd_event:
1604         gen_text_def {
1605                 $$ = $1;
1606         }
1607         | script_abbreviation {
1608                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1609                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1610                 if (scm_is_string (s))
1611                         a->set_property ("articulation-type", s);
1612                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1613                 $$ = a->unprotect ();
1614         }
1615         ;
1616
1617 octave_check:
1618         /**/ { $$ = SCM_EOL; }
1619         | '='  { $$ = scm_from_int (0); }
1620         | '=' sub_quotes { $$ = scm_from_int ($2); }
1621         | '=' sup_quotes { $$ = scm_from_int ($2); }
1622         ;
1623
1624 sup_quotes:
1625         '\'' {
1626                 $$ = 1;
1627         }
1628         | sup_quotes '\'' {
1629                 $$ ++;
1630         }
1631         ;
1632
1633 sub_quotes:
1634         ',' {
1635                 $$ = 1;
1636         }
1637         | sub_quotes ',' {
1638                 $$++;
1639         }
1640         ;
1641
1642 steno_pitch:
1643         NOTENAME_PITCH  {
1644                 $$ = $1;
1645         }
1646         | NOTENAME_PITCH sup_quotes     {
1647                 Pitch p = *unsmob_pitch ($1);
1648                 p = p.transposed (Pitch ($2,0,0));
1649                 $$ = p.smobbed_copy ();
1650         }
1651         | NOTENAME_PITCH sub_quotes      {
1652                 Pitch p =* unsmob_pitch ($1);
1653                 p = p.transposed (Pitch (-$2,0,0));
1654                 $$ = p.smobbed_copy ();
1655         }
1656         ;
1657
1658 /*
1659 ugh. duplication
1660 */
1661
1662 steno_tonic_pitch:
1663         TONICNAME_PITCH {
1664                 $$ = $1;
1665         }
1666         | TONICNAME_PITCH sup_quotes    {
1667                 Pitch p = *unsmob_pitch ($1);
1668                 p = p.transposed (Pitch ($2,0,0));
1669                 $$ = p.smobbed_copy ();
1670         }
1671         | TONICNAME_PITCH sub_quotes     {
1672                 Pitch p =* unsmob_pitch ($1);
1673
1674                 p = p.transposed (Pitch (-$2,0,0));
1675                 $$ = p.smobbed_copy ();
1676         }
1677         ;
1678
1679 pitch:
1680         steno_pitch {
1681                 $$ = $1;
1682         }
1683         ;
1684
1685 pitch_also_in_chords:
1686         pitch
1687         | steno_tonic_pitch
1688         ;
1689
1690 gen_text_def:
1691         full_markup {
1692                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1693                 t->set_property ("text", $1);
1694                 t->set_spot (@$);
1695                 $$ = t->unprotect ();
1696         }
1697         | string {
1698                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1699                 t->set_property ("text",
1700                         make_simple_markup ($1));
1701                 t->set_spot (@$);
1702                 $$ = t->unprotect ();
1703         }
1704         | DIGIT {
1705                 Music *t = MY_MAKE_MUSIC ("FingeringEvent");
1706                 t->set_property ("digit", scm_from_int ($1));
1707                 t->set_spot (@$);
1708                 $$ = t->unprotect ();
1709         }
1710         ;
1711
1712 script_abbreviation:
1713         '^'             {
1714                 $$ = scm_makfrom0str ("Hat");
1715         }
1716         | '+'           {
1717                 $$ = scm_makfrom0str ("Plus");
1718         }
1719         | '-'           {
1720                 $$ = scm_makfrom0str ("Dash");
1721         }
1722         | '|'           {
1723                 $$ = scm_makfrom0str ("Bar");
1724         }
1725         | ANGLE_CLOSE   {
1726                 $$ = scm_makfrom0str ("Larger");
1727         }
1728         | '.'           {
1729                 $$ = scm_makfrom0str ("Dot");
1730         }
1731         | '_' {
1732                 $$ = scm_makfrom0str ("Underscore");
1733         }
1734         ;
1735
1736 script_dir:
1737         '_'     { $$ = DOWN; }
1738         | '^'   { $$ = UP; }
1739         | '-'   { $$ = CENTER; }
1740         ;
1741
1742
1743 absolute_pitch:
1744         steno_pitch     {
1745                 $$ = $1;
1746         }
1747         ;
1748
1749 duration_length:
1750         multiplied_duration {
1751                 $$ = $1;
1752         }
1753         ;
1754
1755 optional_notemode_duration:
1756         {
1757                 Duration dd = PARSER->default_duration_;
1758                 $$ = dd.smobbed_copy ();
1759         }
1760         | multiplied_duration   {
1761                 $$ = $1;
1762                 PARSER->default_duration_ = *unsmob_duration ($$);
1763         }
1764         ;
1765
1766 steno_duration:
1767         bare_unsigned dots              {
1768                 int len = 0;
1769                 if (!is_duration ($1))
1770                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1771                 else
1772                         len = intlog2 ($1);
1773
1774                 $$ = Duration (len, $2).smobbed_copy ();
1775         }
1776         | DURATION_IDENTIFIER dots      {
1777                 Duration *d = unsmob_duration ($1);
1778                 Duration k (d->duration_log (), d->dot_count () + $2);
1779                 *d = k;
1780                 $$ = $1;
1781         }
1782         ;
1783
1784 multiplied_duration:
1785         steno_duration {
1786                 $$ = $1;
1787         }
1788         | multiplied_duration '*' bare_unsigned {
1789                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1790         }
1791         | multiplied_duration '*' FRACTION {
1792                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1793
1794                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1795         }
1796         ;
1797
1798 fraction:
1799         FRACTION { $$ = $1; }
1800         | UNSIGNED '/' UNSIGNED {
1801                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1802         }
1803         ;
1804
1805 dots:
1806         /* empty */     {
1807                 $$ = 0;
1808         }
1809         | dots '.' {
1810                 $$ ++;
1811         }
1812         ;
1813
1814 tremolo_type:
1815         ':'     {
1816                 $$ = 0;
1817         }
1818         | ':' bare_unsigned {
1819                 if (!is_duration ($2))
1820                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1821                 $$ = $2;
1822         }
1823         ;
1824
1825 bass_number:
1826         DIGIT   {
1827                 $$ = scm_from_int ($1);
1828         }
1829         | UNSIGNED {
1830                 $$ = scm_from_int ($1);
1831         }
1832         | STRING { $$ = $1; }
1833         | full_markup { $$ = $1; }
1834         ;
1835
1836 figured_bass_alteration:
1837         '-'     { $$ = -2; }
1838         | '+'   { $$ = 2; }
1839         | '!'   { $$ = 0; }
1840         ;
1841
1842 bass_figure:
1843         FIGURE_SPACE {
1844                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1845                 $$ = bfr->self_scm ();
1846                 bfr->unprotect ();
1847                 bfr->set_spot (@1);
1848         }
1849         | bass_number  {
1850                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1851                 $$ = bfr->self_scm ();
1852
1853                 if (scm_is_number ($1))
1854                         bfr->set_property ("figure", $1);
1855                 else if (Text_interface::is_markup ($1))
1856                         bfr->set_property ("text", $1);
1857
1858                 bfr->unprotect ();
1859                 bfr->set_spot (@1);
1860         }
1861         | bass_figure ']' {
1862                 $$ = $1;
1863                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1864         }
1865         | bass_figure figured_bass_alteration {
1866                 Music *m = unsmob_music ($1);
1867                 if ($2) {
1868                         SCM salter = m->get_property ("alteration");
1869                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
1870                         m->set_property ("alteration",
1871                                 scm_from_int (alter + $2));
1872                 } else {
1873                         m->set_property ("alteration", scm_from_int (0));
1874                 }
1875         }
1876         | bass_figure figured_bass_modification  {
1877                 Music *m = unsmob_music ($1);
1878                 if ($2 == ly_symbol2scm ("plus"))
1879                         {
1880                         m->set_property ("augmented", SCM_BOOL_T);
1881                         }
1882                 else if ($2 == ly_symbol2scm ("slash"))
1883                         {
1884                         m->set_property ("diminished", SCM_BOOL_T);
1885                         }
1886                 else if ($2 == ly_symbol2scm ("exclamation"))
1887                         {
1888                         m->set_property ("no-continuation", SCM_BOOL_T);
1889                         }
1890         }
1891         ;
1892
1893
1894 figured_bass_modification:
1895         E_PLUS          {
1896                 $$ = ly_symbol2scm ("plus");
1897         }
1898         | E_EXCLAMATION {
1899                 $$ = ly_symbol2scm ("exclamation");
1900         }
1901         | '/'           {
1902                 $$ = ly_symbol2scm ("slash");
1903         }
1904         ;
1905
1906 br_bass_figure:
1907         bass_figure {
1908                 $$ = $1;
1909         }
1910         | '[' bass_figure {
1911                 $$ = $2;
1912                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1913         }
1914         ;
1915
1916 figure_list:
1917         /**/            {
1918                 $$ = SCM_EOL;
1919         }
1920         | figure_list br_bass_figure {
1921                 $$ = scm_cons ($2, $1);
1922         }
1923         ;
1924
1925 figure_spec:
1926         FIGURE_OPEN figure_list FIGURE_CLOSE {
1927                 $$ = scm_reverse_x ($2, SCM_EOL);
1928         }
1929         ;
1930
1931
1932 optional_rest:
1933         /**/   { $$ = 0; }
1934         | REST { $$ = 1; }
1935         ;
1936
1937 simple_element:
1938         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
1939                 if (!PARSER->lexer_->is_note_state ())
1940                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
1941
1942                 Music *n = 0;
1943                 if ($6)
1944                         n = MY_MAKE_MUSIC ("RestEvent");
1945                 else
1946                         n = MY_MAKE_MUSIC ("NoteEvent");
1947
1948                 n->set_property ("pitch", $1);
1949                 n->set_property ("duration", $5);
1950
1951                 if (scm_is_number ($4))
1952                 {
1953                         int q = scm_to_int ($4);
1954                         n->set_property ("absolute-octave", scm_from_int (q-1));
1955                 }
1956
1957                 if ($3 % 2)
1958                         n->set_property ("cautionary", SCM_BOOL_T);
1959                 if ($2 % 2 || $3 % 2)
1960                         n->set_property ("force-accidental", SCM_BOOL_T);
1961
1962                 n->set_spot (@$);
1963                 $$ = n->unprotect ();
1964         }
1965         | DRUM_PITCH optional_notemode_duration {
1966                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1967                 n->set_property ("duration", $2);
1968                 n->set_property ("drum-type", $1);
1969
1970                 $$ = n->unprotect ();
1971         }
1972         | RESTNAME optional_notemode_duration           {
1973                 Music *ev = 0;
1974                 if (ly_scm2string ($1) == "s") {
1975                         /* Space */
1976                         ev = MY_MAKE_MUSIC ("SkipEvent");
1977                   }
1978                 else {
1979                         ev = MY_MAKE_MUSIC ("RestEvent");
1980
1981                     }
1982                 ev->set_property ("duration", $2);
1983                 ev->set_spot (@$);
1984                 $$ = ev->unprotect ();
1985         }
1986         | lyric_element optional_notemode_duration      {
1987                 if (!PARSER->lexer_->is_lyric_state ())
1988                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1989
1990                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
1991                 levent->set_property ("text", $1);
1992                 levent->set_property ("duration",$2);
1993                 levent->set_spot (@$);
1994                 $$= levent->unprotect ();
1995         }
1996         ;
1997
1998 simple_chord_elements:
1999         simple_element  {
2000                 $$ = scm_list_1 ($1);
2001         }
2002         | new_chord {
2003                 if (!PARSER->lexer_->is_chord_state ())
2004                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2005                 $$ = $1;
2006         }
2007         | figure_spec optional_notemode_duration {
2008                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2009                 {
2010                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2011                 }
2012                 $$ = $1;
2013         }
2014         ;
2015
2016 lyric_element:
2017         lyric_markup {
2018                 $$ = $1;
2019         }
2020         | LYRICS_STRING {
2021                 $$ = $1;
2022         }
2023         ;
2024
2025 new_chord:
2026         steno_tonic_pitch optional_notemode_duration   {
2027                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2028         }
2029         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2030                 SCM its = scm_reverse_x ($4, SCM_EOL);
2031                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2032         }
2033         ;
2034
2035 chord_items:
2036         /**/ {
2037                 $$ = SCM_EOL;
2038         }
2039         | chord_items chord_item {
2040                 $$ = scm_cons ($2, $$);
2041         }
2042         ;
2043
2044 chord_separator:
2045         CHORD_COLON {
2046                 $$ = ly_symbol2scm ("chord-colon");
2047         }
2048         | CHORD_CARET {
2049                 $$ = ly_symbol2scm ("chord-caret");
2050         }
2051         | CHORD_SLASH steno_tonic_pitch {
2052                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2053         }
2054         | CHORD_BASS steno_tonic_pitch {
2055                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2056         }
2057         ;
2058
2059 chord_item:
2060         chord_separator {
2061                 $$ = $1;
2062         }
2063         | step_numbers {
2064                 $$ = scm_reverse_x ($1, SCM_EOL);
2065         }
2066         | CHORD_MODIFIER  {
2067                 $$ = $1;
2068         }
2069         ;
2070
2071 step_numbers:
2072         step_number { $$ = scm_cons ($1, SCM_EOL); }
2073         | step_numbers '.' step_number {
2074                 $$ = scm_cons ($3, $$);
2075         }
2076         ;
2077
2078 step_number:
2079         bare_unsigned {
2080                 $$ = make_chord_step ($1, 0);
2081         }
2082         | bare_unsigned '+' {
2083                 $$ = make_chord_step ($1, SHARP);
2084         }
2085         | bare_unsigned CHORD_MINUS {
2086                 $$ = make_chord_step ($1, FLAT);
2087         }
2088         ;
2089
2090 /*
2091         UTILITIES
2092
2093 TODO: should deprecate in favor of Scheme?
2094
2095  */
2096 number_expression:
2097         number_expression '+' number_term {
2098                 $$ = scm_sum ($1, $3);
2099         }
2100         | number_expression '-' number_term {
2101                 $$ = scm_difference ($1, $3);
2102         }
2103         | number_term
2104         ;
2105
2106 number_term:
2107         number_factor {
2108                 $$ = $1;
2109         }
2110         | number_factor '*' number_factor {
2111                 $$ = scm_product ($1, $3);
2112         }
2113         | number_factor '/' number_factor {
2114                 $$ = scm_divide ($1, $3);
2115         }
2116         ;
2117
2118 number_factor:
2119         '-'  number_factor { /* %prec UNARY_MINUS */
2120                 $$ = scm_difference ($2, SCM_UNDEFINED);
2121         }
2122         | bare_number
2123         ;
2124
2125
2126 bare_number:
2127         UNSIGNED        {
2128                 $$ = scm_from_int ($1);
2129         }
2130         | REAL          {
2131                 $$ = $1;
2132         }
2133         | NUMBER_IDENTIFIER             {
2134                 $$ = $1;
2135         }
2136         | REAL NUMBER_IDENTIFIER        {
2137                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2138         }
2139         | UNSIGNED NUMBER_IDENTIFIER    {
2140                 $$ = scm_from_double ($1 *scm_to_double ($2));
2141         }
2142         ;
2143
2144
2145 bare_unsigned:
2146         UNSIGNED {
2147                         $$ = $1;
2148         }
2149         | DIGIT {
2150                 $$ = $1;
2151         }
2152         ;
2153
2154 exclamations:
2155                 { $$ = 0; }
2156         | exclamations '!'      { $$ ++; }
2157         ;
2158
2159 questions:
2160                 { $$ = 0; }
2161         | questions '?' { $$ ++; }
2162         ;
2163
2164 /*
2165 This should be done more dynamically if possible.
2166 */
2167
2168 lyric_markup:
2169         LYRIC_MARKUP_IDENTIFIER {
2170                 $$ = $1;
2171         }
2172         | LYRIC_MARKUP
2173                 { PARSER->lexer_->push_markup_state (); }
2174         markup_top {
2175                 $$ = $3;
2176                 PARSER->lexer_->pop_state ();
2177         }
2178         ;
2179
2180 full_markup:
2181         MARKUP_IDENTIFIER {
2182                 $$ = $1;
2183         }
2184         | MARKUP
2185                 { PARSER->lexer_->push_markup_state (); }
2186         markup_top {
2187                 $$ = $3;
2188                 PARSER->lexer_->pop_state ();
2189         }
2190         ;
2191
2192 markup_top:
2193         markup_list {
2194                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2195         }
2196         | markup_head_1_list simple_markup      {
2197                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2198         }
2199         | simple_markup {
2200                 $$ = $1;
2201         }
2202         ;
2203
2204 markup_list:
2205         markup_composed_list {
2206                 $$ = $1;
2207         }
2208         | markup_braced_list {
2209                 $$ = $1;
2210         }
2211         ;
2212
2213 markup_composed_list:
2214         markup_head_1_list markup_braced_list {
2215                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2216
2217         }
2218         ;
2219
2220 markup_braced_list:
2221         '{' markup_braced_list_body '}' {
2222                 $$ = scm_reverse_x ($2, SCM_EOL);
2223         }
2224         ;
2225
2226 markup_braced_list_body:
2227         /* empty */     {  $$ = SCM_EOL; }
2228         | markup_braced_list_body markup {
2229                 $$ = scm_cons ($2, $1);
2230         }
2231         | markup_braced_list_body markup_list {
2232                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2233         }
2234         ;
2235
2236 markup_head_1_item:
2237         MARKUP_HEAD_MARKUP0     {
2238                 $$ = scm_list_1 ($1);
2239         }
2240         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2241                 $$ = scm_list_2 ($1, $2);
2242         }
2243         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2244                 $$ = scm_list_3 ($1, $2, $3);
2245         }
2246         ;
2247
2248 markup_head_1_list:
2249         markup_head_1_item      {
2250                 $$ = scm_list_1 ($1);
2251         }
2252         | markup_head_1_list markup_head_1_item {
2253                 $$ = scm_cons ($2, $1);
2254         }
2255         ;
2256
2257 simple_markup:
2258         STRING {
2259                 $$ = make_simple_markup ($1);
2260         }
2261         | MARKUP_IDENTIFIER {
2262                 $$ = $1;
2263         }
2264         | LYRIC_MARKUP_IDENTIFIER {
2265                 $$ = $1;
2266         }
2267         | STRING_IDENTIFIER {
2268                 $$ = $1;
2269         }
2270         | SCORE {
2271                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2272                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2273         } '{' score_body '}' {
2274                 Score * sc = $4;
2275                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2276                 sc->unprotect ();
2277                 PARSER->lexer_->pop_state ();
2278         }
2279         | MARKUP_HEAD_SCM0 embedded_scm {
2280                 $$ = scm_list_2 ($1, $2);
2281         }
2282         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2283                 $$ = scm_list_4 ($1, $2, $3, $4);
2284         }
2285         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2286                 $$ = scm_list_3 ($1, $2, $3);
2287         }
2288         | MARKUP_HEAD_EMPTY {
2289                 $$ = scm_list_1 ($1);
2290         }
2291         | MARKUP_HEAD_LIST0 markup_list {
2292                 $$ = scm_list_2 ($1,$2);
2293         }
2294         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2295                 $$ = scm_list_3 ($1, $2, $3);
2296         }
2297         ;
2298
2299 markup:
2300         markup_head_1_list simple_markup        {
2301                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2302                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2303         }
2304         | simple_markup {
2305                 $$ = $1;
2306         }
2307         ;
2308
2309 %%
2310
2311 void
2312 Lily_parser::set_yydebug (bool x)
2313 {
2314         yydebug = x;
2315 }
2316
2317 void
2318 Lily_parser::do_yyparse ()
2319 {
2320         yyparse ((void*)this);
2321 }
2322
2323
2324
2325
2326
2327 /*
2328
2329 It is a little strange to have this function in this file, but
2330 otherwise, we have to import music classes into the lexer.
2331
2332 */
2333 int
2334 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2335 {
2336         if (scm_is_string (sid)) {
2337                 *destination = sid;
2338                 return STRING_IDENTIFIER;
2339         } else if (unsmob_book (sid)) {
2340                 Book *book =  unsmob_book (sid)->clone ();
2341                 *destination = book->self_scm ();
2342                 book->unprotect ();
2343
2344                 return BOOK_IDENTIFIER;
2345         } else if (scm_is_number (sid)) {
2346                 *destination = sid;
2347                 return NUMBER_IDENTIFIER;
2348         } else if (unsmob_context_def (sid)) {
2349                 Context_def *def= unsmob_context_def (sid)->clone ();
2350
2351                 *destination = def->self_scm ();
2352                 def->unprotect ();
2353
2354                 return CONTEXT_DEF_IDENTIFIER;
2355         } else if (unsmob_score (sid)) {
2356                 Score *score = new Score (*unsmob_score (sid));
2357                 *destination = score->self_scm ();
2358
2359                 score->unprotect ();
2360                 return SCORE_IDENTIFIER;
2361         } else if (Music *mus = unsmob_music (sid)) {
2362                 mus = mus->clone ();
2363                 *destination = mus->self_scm ();
2364                 unsmob_music (*destination)->
2365                         set_property ("origin", make_input (last_input_));
2366
2367                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2368                         != SCM_BOOL_F;
2369
2370                 mus->unprotect ();
2371                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2372         } else if (unsmob_duration (sid)) {
2373                 *destination = unsmob_duration (sid)->smobbed_copy ();
2374                 return DURATION_IDENTIFIER;
2375         } else if (unsmob_output_def (sid)) {
2376                 Output_def *p = unsmob_output_def (sid);
2377                 p = p->clone ();
2378
2379                 *destination = p->self_scm ();
2380                 p->unprotect ();
2381                 return OUTPUT_DEF_IDENTIFIER;
2382         } else if (Text_interface::is_markup (sid)) {
2383                 *destination = sid;
2384                 if (is_lyric_state ())
2385                         return LYRIC_MARKUP_IDENTIFIER;
2386                 return MARKUP_IDENTIFIER;
2387         }
2388
2389         return -1;
2390 }
2391
2392 SCM
2393 get_next_unique_context_id ()
2394 {
2395         return scm_makfrom0str ("$uniqueContextId");
2396 }
2397
2398
2399 SCM
2400 get_next_unique_lyrics_context_id ()
2401 {
2402         static int new_context_count;
2403         char s[128];
2404         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2405         return scm_makfrom0str (s);
2406 }
2407
2408
2409 SCM
2410 run_music_function (Lily_parser *parser, SCM expr)
2411 {
2412         SCM func = scm_car (expr);
2413         Input *loc = unsmob_input (scm_cadr (expr));
2414         SCM args = scm_cddr (expr);
2415         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2416
2417         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2418
2419         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2420         {
2421                 parser->error_level_ = 1;
2422                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2423         }
2424
2425         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2426         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2427 }
2428
2429 bool
2430 is_regular_identifier (SCM id)
2431 {
2432   string str = ly_scm2string (id);
2433   char const *s = str.c_str ();
2434
2435   bool v = true;
2436 #if 0
2437   isalpha (*s);
2438   s++;
2439 #endif
2440   while (*s && v)
2441    {
2442         v = v && isalnum (*s);
2443         s++;
2444    }
2445   return v;
2446 }
2447
2448
2449 SCM
2450 get_first_context_id (SCM type, Music *m)
2451 {
2452         SCM id = m->get_property ("context-id");
2453         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2454             && scm_is_string (m->get_property ("context-id"))
2455             && scm_c_string_length (id) > 0)
2456         {
2457                 return id;
2458         }
2459         return SCM_EOL;
2460 }
2461
2462 SCM
2463 make_simple_markup (SCM a)
2464 {
2465         return a;
2466 }
2467
2468 bool
2469 is_duration (int t)
2470 {
2471   return t && t == 1 << intlog2 (t);
2472 }
2473
2474 void
2475 set_music_properties (Music *p, SCM a)
2476 {
2477   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2478         p->set_property (scm_caar (k), scm_cdar (k));
2479 }
2480
2481
2482 SCM
2483 make_chord_step (int step, int alter)
2484 {
2485         if (step == 7)
2486                 alter += FLAT;
2487
2488         while (step < 0)
2489                 step += 7;
2490         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2491         return m.smobbed_copy ();
2492 }
2493
2494
2495 SCM
2496 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2497 {
2498         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2499         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2500 }
2501
2502
2503 /* Todo: actually also use apply iso. call too ...  */
2504 bool
2505 ly_input_procedure_p (SCM x)
2506 {
2507         return ly_is_procedure (x)
2508                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2509 }
2510
2511 SCM
2512 make_music_relative (Pitch start, SCM music)
2513 {
2514         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2515         relative->set_property ("element", music);
2516
2517         Music *m = unsmob_music (music);
2518         Pitch last = m->to_relative_octave (start);
2519         if (lily_1_8_relative)
2520                 m->set_property ("last-pitch", last.smobbed_copy ());
2521         return relative->unprotect ();
2522 }
2523
2524 int
2525 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2526 {
2527         Lily_parser *pars = (Lily_parser*) v;
2528         Lily_lexer *lex = pars->lexer_;
2529
2530         lex->lexval = (void*) s;
2531         lex->lexloc = loc;
2532         lex->prepare_for_next_token ();
2533         return lex->yylex ();
2534 }