lily/lexer.ll

   1 %{ // -*-Fundamental-*-
   2 /*
   3   lexer.l -- implement the Flex lexer
   4
   5   source file of the LilyPond music typesetter
   6
   7   (c) 1996--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   8            Jan Nieuwenhuizen <janneke@gnu.org>
   9 */
  10
  11
  12 /*
  13   backup rules
  14
  15   after making a change to the lexer rules, run
  16       flex -b <this lexer file>
  17   and make sure that
  18       lex.backup
  19   contains no backup states, but only the reminder
  20       Compressed tables always back up.
  21  (don-t forget to rm lex.yy.cc :-)
  22  */
  23
  24
  25 #include <stdio.h>
  26 #include <ctype.h>
  27 #include <iostream.h> /* gcc 3.0 */
  28 #include <errno.h>
  29
  30
  31 #include "score.hh"
  32 #include "lily-guile.hh"
  33 #include "string.hh"
  34 #include "string-convert.hh"
  35 #include "my-lily-lexer.hh"
  36 #include "array.hh"
  37 #include "interval.hh"
  38 #include "lily-guile.hh"
  39 #include "parser.hh"
  40 #include "debug.hh"
  41 #include "main.hh"
  42 #include "musical-request.hh"
  43 #include "version.hh"
  44 #include "lilypond-input-version.hh"
  45 #include "translator-def.hh"
  46 #include "music-output-def.hh"
  47
  48 /*
  49 RH 7 fix (?)
  50 */
  51 #define isatty HORRIBLEKLUDGE
  52
  53 void strip_trailing_white (String&);
  54 void strip_leading_white (String&);
  55 String lyric_fudge (String s);
  56
  57
  58 bool
  59 valid_version_b (String s);
  60
  61
  62
  63 #define start_quote()   \
  64         yy_push_state (quote);\
  65         yylval.string = new String
  66
  67 #define yylval \
  68         (*(YYSTYPE*)lexval_l)
  69
  70 #define YY_USER_ACTION  add_lexed_char (YYLeng ());
  71 /*
  72
  73 LYRICS          ({AA}|{TEX})[^0-9 \t\n\f]*
  74
  75 */
  76
  77
  78 SCM scan_fraction (String);
  79
  80 %}
  81
  82 %option c++
  83 %option noyywrap
  84 %option nodefault
  85 %option debug
  86 %option yyclass="My_lily_lexer"
  87 %option stack
  88 %option never-interactive
  89 %option warn
  90
  91 %x version
  92 %x chords
  93 %x incl
  94 %x lyrics
  95 %x notes
  96 %x figures
  97 %x quote
  98 %x longcomment
  99
 100
 101 A               [a-zA-Z]
 102 AA              {A}|_
 103 N               [0-9]
 104 AN              {AA}|{N}
 105 PUNCT           [?!:'`]
 106 ACCENT          \\[`'"^]
 107 NATIONAL        [\001-\006\021-\027\031\036\200-\377]
 108 TEX             {AA}|-|{PUNCT}|{ACCENT}|{NATIONAL}
 109 WORD            {A}{AN}*
 110 ALPHAWORD       {A}+
 111 DIGIT           {N}
 112 UNSIGNED        {N}+
 113 FRACTION        {N}+\/{N}+
 114 INT             -?{UNSIGNED}
 115 REAL            ({INT}\.{N}*)|(-?\.{N}+)
 116 KEYWORD         \\{WORD}
 117 WHITE           [ \n\t\f\r]
 118 HORIZONTALWHITE         [ \t]
 119 BLACK           [^ \n\t\f\r]
 120 RESTNAME        [rs]
 121 NOTECOMMAND     \\{A}+
 122 LYRICS          ({AA}|{TEX})[^0-9 \t\n\f]*
 123 ESCAPED         [nt\\'"]
 124 EXTENDER        __
 125 HYPHEN          --
 126 %%
 127
 128
 129 <*>\r           {
 130         // windows-suck-suck-suck
 131 }
 132
 133 <INITIAL,chords,incl,lyrics,notes,figures>{
 134   "%{"  {
 135         yy_push_state (longcomment);
 136   }
 137   %[^{\n].*\n   {
 138   }
 139   %[^{\n]       { // backup rule
 140   }
 141   %\n   {
 142   }
 143   %[^{\n].*     {
 144   }
 145   {WHITE}+      {
 146
 147   }
 148 }
 149
 150 <INITIAL,chords,lyrics,notes,figures>\\version{WHITE}*  {
 151         yy_push_state (version);
 152 }
 153 <version>\"[^"]*\"     { /* got the version number */
 154         String s (YYText ()+1);
 155         s = s.left_str (s.index_last_i ('"'));
 156
 157         yy_pop_state ();
 158         if (!valid_version_b (s))
 159                 return INVALID;
 160 }
 161 <version>.      {
 162         LexerError ("No quoted string found after \\version");
 163         yy_pop_state ();
 164 }
 165 <longcomment>{
 166         [^\%]*          {
 167         }
 168         \%*[^}%]*               {
 169
 170         }
 171         "%"+"}"         {
 172                 yy_pop_state ();
 173         }
 174         <<EOF>>         {
 175                 LexerError (_ ("EOF found inside a comment").ch_C ());
 176                 if (! close_input ())
 177                   yyterminate (); // can't move this, since it actually rets a YY_NULL
 178         }
 179 }
 180
 181
 182 <INITIAL,chords,lyrics,notes,figures>\\maininput           {
 183         if (!main_input_b_)
 184         {
 185                 start_main_input ();
 186                 main_input_b_ = true;
 187         }
 188         else
 189                 error (_ ("\\maininput disallowed outside init files"));
 190 }
 191
 192 <INITIAL,chords,lyrics,figures,notes>\\include           {
 193         yy_push_state (incl);
 194 }
 195 <incl>\"[^"]*\";?   { /* got the include file name */
 196         String s (YYText ()+1);
 197         s = s.left_str (s.index_last_i ('"'));
 198
 199         new_input (s,source_global_l);
 200         yy_pop_state ();
 201 }
 202 <incl>\\{BLACK}*;?{WHITE} { /* got the include identifier */
 203         String s = YYText () + 1;
 204         strip_trailing_white (s);
 205         if (s.length_i () && (s[s.length_i () - 1] == ';'))
 206           s = s.left_str (s.length_i () - 1);
 207
 208         SCM sid = lookup_identifier (s);
 209         if (gh_string_p (sid)) {
 210                 new_input (ly_scm2string (sid), source_global_l);
 211                 yy_pop_state ();
 212         } else {
 213             String msg (_f ("wrong or undefined identifier: `%s'", s ));
 214
 215             LexerError (msg.ch_C ());
 216             SCM err = scm_current_error_port ();
 217             scm_puts ("This value was found in the table: ", err);
 218             scm_display (sid, err);
 219           }
 220 }
 221 <incl>\"[^"]*   { // backup rule
 222         error (_ ("Missing end quote"));
 223         exit (1);
 224 }
 225 <chords,notes,figures>{RESTNAME}        {
 226         const char *s = YYText ();
 227         yylval.scm = ly_str02scm (s);
 228         return RESTNAME;
 229 }
 230 <chords,notes,figures>R         {
 231         return MULTI_MEASURE_REST;
 232 }
 233 <INITIAL,chords,lyrics,notes,figures>\\\${BLACK}*{WHITE}        {
 234         String s=YYText () + 2;
 235         s=s.left_str (s.length_i () - 1);
 236         return scan_escaped_word (s);
 237 }
 238 <INITIAL,chords,lyrics,notes,figures>\${BLACK}*{WHITE}          {
 239         String s=YYText () + 1;
 240         s=s.left_str (s.length_i () - 1);
 241         return scan_bare_word (s);
 242 }
 243 <INITIAL,chords,lyrics,notes,figures>\\\${BLACK}*               { // backup rule
 244         error (_("white expected"));
 245         exit (1);
 246 }
 247 <INITIAL,chords,lyrics,notes,figures>\${BLACK}*         { // backup rule
 248         error (_("white expected"));
 249         exit (1);
 250 }
 251
 252 <INITIAL,chords,lyrics,notes,figures>#  { //embedded scm
 253         //char const* s = YYText () + 1;
 254         char const* s = here_ch_C ();
 255         int n = 0;
 256         if (main_input_b_ && safe_global_b) {
 257                 error (_ ("Can't evaluate Scheme in safe mode"));
 258                 yylval.scm =  SCM_EOL;
 259                 return SCM_T;
 260         }
 261         yylval.scm = ly_parse_scm (s, &n);
 262
 263         for (int i=0; i < n; i++)
 264         {
 265                 yyinput ();
 266         }
 267         char_count_stack_.top () += n;
 268
 269         return SCM_T;
 270 }
 271 <figures>{
 272         _       {
 273                 return FIGURE_SPACE;
 274         }
 275         \>              {
 276                 return FIGURE_CLOSE;
 277         }
 278         \<      {
 279                 return FIGURE_OPEN;
 280         }
 281 }
 282 <notes,figures>{
 283         {ALPHAWORD}     {
 284                 return scan_bare_word (YYText ());
 285         }
 286
 287         {NOTECOMMAND}   {
 288                 return scan_escaped_word (YYText () + 1);
 289         }
 290         {FRACTION}      {
 291                 yylval.scm =  scan_fraction (YYText ());
 292                 return FRACTION;
 293         }
 294
 295         {DIGIT}         {
 296                 yylval.i = String_convert::dec2_i (String (YYText ()));
 297                 return DIGIT;
 298         }
 299         {UNSIGNED}              {
 300                 yylval.i = String_convert::dec2_i (String (YYText ()));
 301                 return UNSIGNED;
 302         }
 303
 304         \" {
 305                 start_quote ();
 306         }
 307 }
 308
 309 \"              {
 310         start_quote ();
 311 }
 312 <quote>{
 313         \\{ESCAPED}     {
 314                 *yylval.string += to_str (escaped_char (YYText ()[1]));
 315         }
 316         [^\\"]+ {
 317                 *yylval.string += YYText ();
 318         }
 319         \"      {
 320
 321                 yy_pop_state ();
 322
 323                 /* yylval is union. Must remember STRING before setting SCM*/
 324                 String *sp = yylval.string;
 325                 yylval.scm = ly_str02scm (sp->ch_C ());
 326                 delete sp;
 327                 return STRING;
 328         }
 329         .       {
 330                 *yylval.string += YYText ();
 331         }
 332 }
 333
 334 <lyrics>{
 335         \" {
 336                 start_quote ();
 337         }
 338         {FRACTION}      {
 339                 yylval.scm =  scan_fraction (YYText ());
 340                 return FRACTION;
 341         }
 342         {UNSIGNED}              {
 343                 yylval.i = String_convert::dec2_i (String (YYText ()));
 344                 return UNSIGNED;
 345         }
 346         {NOTECOMMAND}   {
 347                 return scan_escaped_word (YYText () + 1);
 348         }
 349         {LYRICS} {
 350                 /* ugr. This sux. */
 351                 String s (YYText ());
 352                 if (s == "__")
 353                         return yylval.i = EXTENDER;
 354                 if (s == "--")
 355                         return yylval.i = HYPHEN;
 356                 s = lyric_fudge (s);
 357
 358                 char c = s[s.length_i () - 1];
 359                 if (c == '{' ||  c == '}') // brace open is for not confusing dumb tools.
 360                         here_input ().warning (
 361                                 _ ("Brace found at end of lyric. Did you forget a space?"));
 362                 yylval.scm = ly_str02scm (s.ch_C ());
 363
 364
 365                 return STRING;
 366         }
 367         . {
 368                 return YYText ()[0];
 369         }
 370 }
 371 <chords>{
 372         {ALPHAWORD}     {
 373                 return scan_bare_word (YYText ());
 374         }
 375         {NOTECOMMAND}   {
 376                 return scan_escaped_word (YYText () + 1);
 377         }
 378         {FRACTION}      {
 379                 yylval.scm =  scan_fraction (YYText ());
 380                 return FRACTION;
 381         }
 382         {UNSIGNED}              {
 383                 yylval.i = String_convert::dec2_i (String (YYText ()));
 384                 return UNSIGNED;
 385         }
 386         \" {
 387                 start_quote ();
 388         }
 389         -  {
 390                 return CHORD_MINUS;
 391         }
 392         :  {
 393                 return CHORD_COLON;
 394         }
 395         \/\+ {
 396                 return CHORD_BASS;
 397         }
 398         \^  {
 399                 return CHORD_CARET;
 400         }
 401         . {
 402                 return YYText ()[0];
 403         }
 404 }
 405
 406 <<EOF>> {
 407
 408
 409         if (! close_input ()) {
 410           yyterminate (); // can't move this, since it actually rets a YY_NULL
 411         }
 412 }
 413
 414
 415 {WORD}  {
 416         return scan_bare_word (YYText ());
 417 }
 418 {KEYWORD}       {
 419         return scan_escaped_word (YYText () + 1);
 420 }
 421 {REAL}          {
 422         Real r;
 423         int cnv=sscanf (YYText (), "%lf", &r);
 424         assert (cnv == 1);
 425
 426         yylval.scm = gh_double2scm (r);
 427         return REAL;
 428 }
 429
 430 {UNSIGNED}      {
 431         yylval.i = String_convert::dec2_i (String (YYText ()));
 432         return UNSIGNED;
 433 }
 434
 435 [{}]    {
 436
 437         return YYText ()[0];
 438 }
 439 [*:=]           {
 440         char c = YYText ()[0];
 441
 442         return c;
 443 }
 444
 445 <INITIAL,notes,figures>.        {
 446         return YYText ()[0];
 447 }
 448
 449 <INITIAL,lyrics,notes,figures>\\. {
 450     char c= YYText ()[1];
 451
 452     switch (c) {
 453     case '>':
 454         return E_BIGGER;
 455     case '<':
 456         return E_SMALLER;
 457     case '!':
 458         return E_EXCLAMATION;
 459     case '(':
 460         return E_OPEN;
 461     case ')':
 462         return E_CLOSE;
 463     case '[':
 464         return E_LEFTSQUARE;
 465     case ']':
 466         return E_RIGHTSQUARE;
 467     case '~':
 468         return E_TILDE;
 469     case '\\':
 470         return E_BACKSLASH;
 471     default:
 472         return E_CHAR;
 473     }
 474 }
 475
 476 <*>.            {
 477         String msg = _f ("invalid character: `%c'", YYText ()[0]);
 478         LexerError (msg.ch_C ());
 479         return YYText ()[0];
 480 }
 481
 482 %%
 483
 484 void
 485 My_lily_lexer::push_note_state ()
 486 {
 487         yy_push_state (notes);
 488 }
 489
 490 void
 491 My_lily_lexer::push_figuredbass_state()
 492 {
 493         yy_push_state (figures);
 494 }
 495 void
 496 My_lily_lexer::push_chord_state ()
 497 {
 498         yy_push_state (chords);
 499 }
 500
 501 void
 502 My_lily_lexer::push_lyric_state ()
 503 {
 504         yy_push_state (lyrics);
 505 }
 506
 507 void
 508 My_lily_lexer::pop_state ()
 509 {
 510         yy_pop_state ();
 511 }
 512
 513 int
 514 My_lily_lexer::scan_escaped_word (String str)
 515 {
 516         // use more SCM for this.
 517
 518         SCM sym = ly_symbol2scm (str.ch_C ());
 519
 520         int l = lookup_keyword (str);
 521         if (l != -1) {
 522                 return l;
 523         }
 524         SCM sid = lookup_identifier (str);
 525         if (gh_string_p (sid)) {
 526                 yylval.scm = sid;
 527                 return STRING_IDENTIFIER;
 528         } else if (gh_number_p (sid)) {
 529                 yylval.scm = sid;
 530                 return NUMBER_IDENTIFIER;
 531         } else if (unsmob_translator_def (sid)) {
 532                 yylval.scm = sid;
 533                 return TRANSLATOR_IDENTIFIER;
 534         } else if (unsmob_score (sid)) {
 535                 yylval.scm =sid;
 536                 return SCORE_IDENTIFIER;
 537         } else if (Music * mus =unsmob_music (sid)) {
 538                 yylval.scm = sid;
 539
 540                 return dynamic_cast<Request*> (mus) ? REQUEST_IDENTIFIER : MUSIC_IDENTIFIER;
 541         } else if (unsmob_duration (sid)) {
 542                 yylval.scm = sid;
 543                 return DURATION_IDENTIFIER;
 544         } else if (unsmob_music_output_def (sid)) {
 545                 yylval.scm = sid;
 546                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
 547         }
 548
 549         if (sid != SCM_UNDEFINED) {
 550                 yylval.scm = sid;
 551                 return SCM_IDENTIFIER;
 552         }
 553
 554         if ((YYSTATE != notes) && (YYSTATE != chords)) {
 555                 SCM pitch = scm_hashq_get_handle (pitchname_tab_, sym);
 556
 557                 if (gh_pair_p (pitch))
 558                 {
 559                         yylval.scm = ly_cdr (pitch);
 560                         return NOTENAME_PITCH;
 561                 }
 562         }
 563         String msg (_f ("unknown escaped string: `\\%s'", str));
 564         LexerError (msg.ch_C ());
 565
 566         yylval.scm = ly_str02scm (str.ch_C ());
 567
 568         return STRING;
 569 }
 570
 571 int
 572 My_lily_lexer::scan_bare_word (String str)
 573 {
 574         SCM sym = ly_symbol2scm (str.ch_C ());
 575         if ((YYSTATE == notes) || (YYSTATE == chords)) {
 576                 SCM pitch = scm_hashq_get_handle (pitchname_tab_, sym);
 577                 if (gh_pair_p (pitch)) {
 578                     yylval.scm = ly_cdr (pitch);
 579                     return (YYSTATE == notes) ? NOTENAME_PITCH : TONICNAME_PITCH;
 580                 } else if ((pitch = scm_hashq_get_handle (chordmodifier_tab_, sym))!= SCM_BOOL_F)
 581                 {
 582                     yylval.scm = ly_cdr (pitch);
 583                     return CHORDMODIFIER_PITCH;
 584                 }
 585         }
 586
 587         yylval.scm = ly_str02scm (str.ch_C ());
 588         return STRING;
 589 }
 590
 591 bool
 592 My_lily_lexer::note_state_b () const
 593 {
 594         return YY_START == notes;
 595 }
 596
 597 bool
 598 My_lily_lexer::chord_state_b () const
 599 {
 600         return YY_START == chords;
 601 }
 602
 603 bool
 604 My_lily_lexer::lyric_state_b () const
 605 {
 606         return YY_START == lyrics;
 607 }
 608
 609 bool
 610 My_lily_lexer::figure_state_b () const
 611 {
 612         return YY_START == figures;
 613 }
 614
 615 /*
 616  urg, belong to String (_convert)
 617  and should be generalised
 618  */
 619 void
 620 strip_leading_white (String&s)
 621 {
 622         int i=0;
 623         for (;  i < s.length_i (); i++)
 624                 if (!isspace (s[i]))
 625                         break;
 626
 627         s = s.nomid_str (0, i);
 628 }
 629
 630 void
 631 strip_trailing_white (String&s)
 632 {
 633         int i=s.length_i ();
 634         while (i--)
 635                 if (!isspace (s[i]))
 636                         break;
 637
 638         s = s.left_str (i+1);
 639 }
 640
 641
 642
 643 /* 1.3.146 == removal of ; */
 644 Lilypond_version oldest_version ("1.3.146");
 645
 646
 647 bool
 648 valid_version_b (String s)
 649 {
 650   Lilypond_version current ( MAJOR_VERSION "." MINOR_VERSION "." PATCH_LEVEL );
 651   Lilypond_version ver (s);
 652   if (! ((ver >= oldest_version) && (ver <= current)))
 653         {
 654                 non_fatal_error (_f ("incorrect lilypond version: %s (%s, %s)", ver.str (), oldest_version.str (), current.str ()));
 655                 non_fatal_error (_ ("Consider converting the input with the convert-ly script"));
 656                 return false;
 657     }
 658   return true;
 659 }
 660
 661
 662 String
 663 lyric_fudge (String s)
 664 {
 665   char  * chars  =s.copy_ch_p ();
 666
 667   for (char * p = chars; *p ; p++)
 668     {
 669       if (*p == '_' && (p == chars || *(p-1) != '\\'))
 670         *p = ' ';
 671     }
 672
 673   s = String (chars);
 674   delete[] chars;
 675
 676   int i =0;
 677   if ((i=s.index_i ("\\,")) != -1)   // change "\," to TeX's "\c "
 678     {
 679       * (s.ch_l () + i + 1) = 'c';
 680       s = s.left_str (i+2) + " " + s.right_str (s.length_i ()-i-2);
 681     }
 682
 683   return s;
 684 }
 685
 686 /*
 687 Convert "NUM/DEN" into a '(NUM . DEN) cons.
 688 */
 689 SCM
 690 scan_fraction (String frac)
 691 {
 692         int i = frac.index_i ('/');
 693         int l = frac.length_i ();
 694         String left = frac.left_str (i);
 695         String right = frac.right_str (l - i - 1);
 696
 697         int n = String_convert::dec2_i (left);
 698         int d = String_convert::dec2_i (right);
 699         return gh_cons (gh_int2scm (n), gh_int2scm (d));
 700 }
 701