configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10 # For stepmake package:
  11 # AC_CONFIG_AUX_DIR(bin)
  12
  13
  14 STEPMAKE_INIT
  15
  16 # List a file that identifies your package.
  17 AC_CONFIG_SRCDIR([lily/main.cc])
  18
  19 # Move to aclocal.m4?
  20 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  21
  22 # Uncomment the configuration options your package needs.
  23
  24 DOCUMENTATION=yes
  25 AC_ARG_ENABLE(documentation,
  26     [  --enable-documentation  build Documentation.  Default: on],
  27     [DOCUMENTATION=$enableval])
  28 AC_SUBST(DOCUMENTATION)
  29
  30 gui_b=no
  31 AC_ARG_ENABLE(gui,
  32     [  --enable-gui            compile with experimental GNOME output module.  Default: off],
  33     [gui_b=$enableval])
  34
  35 reloc_b=no
  36 AC_ARG_ENABLE(relocation,
  37     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  38     [reloc_b=$enableval])
  39
  40 LINK_GXX_STATICALLY=no
  41 AC_ARG_ENABLE(static-gxx,
  42     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  43     [LINK_GXX_STATICALLY=$enableval])
  44 AC_SUBST(LINK_GXX_STATICALLY)
  45
  46 # must come before any header checks
  47 STEPMAKE_COMPILE
  48
  49 STEPMAKE_PYTHON(REQUIRED, 2.2)
  50 STEPMAKE_GCC(REQUIRED, 2.8)
  51 STEPMAKE_CXX(REQUIRED)
  52 STEPMAKE_GXX(REQUIRED, 3.0.5)
  53 STEPMAKE_CXXTEMPLATE
  54 STEPMAKE_LIB(REQUIRED)
  55 STEPMAKE_DLOPEN
  56 # Do not use bison 1.50 and 1.75.
  57 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
  58 STEPMAKE_BISON(OPTIONAL, 1.29)
  59 STEPMAKE_FLEX(REQUIRED)
  60 STEPMAKE_FLEXLEXER(REQUIRED)
  61 STEPMAKE_FLEXLEXER_LOCATION
  62 AC_LANG_C
  63 STEPMAKE_LOCALE
  64 STEPMAKE_GETTEXT
  65 STEPMAKE_MSGFMT(REQUIRED)
  66 STEPMAKE_TEXMF(REQUIRED)
  67 STEPMAKE_TEXMF_DIRS
  68 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.6.5)
  69 STEPMAKE_MAKEINFO(REQUIRED)
  70 STEPMAKE_PYTHON_DEVEL(REQUIRED)
  71
  72 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.15)
  73
  74 STEPMAKE_PROGS(MFTRACE, mftrace, REQUIRED, 1.1.9)
  75 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
  76
  77 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h])
  78 AC_LANG_PUSH(C++)
  79 AC_CHECK_HEADERS([sstream])
  80 AC_LANG_POP(C++)
  81 AC_HEADER_STAT
  82 AC_FUNC_MEMCMP
  83 AC_FUNC_VPRINTF
  84 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
  85 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
  86 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
  87
  88 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
  89
  90 if test "$gui_b" = "yes"; then
  91     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
  92 fi
  93
  94 if test "$reloc_b" = "yes"; then
  95     AC_DEFINE(ARGV0_RELOCATION)
  96 fi
  97
  98 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
  99 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
 100 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
 101 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 0)
 102
 103 STEPMAKE_WINDOWS
 104
 105 ## Optional tools for building documentation, website, extra fonts.
 106
 107 # guile executable for some scripts
 108 STEPMAKE_GUILE(OPTIONAL)
 109
 110 # perl for help2man.
 111 STEPMAKE_PERL(OPTIONAL)
 112
 113 # New makeinfo for multi-page website docs Simply always require new
 114 # makeinfo should avoid bug reports; if people want to build lily
 115 # without the docs, they can find this comment and use an older
 116 # makeinfo--but hopefully won't report makeinfo problems.
 117 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.7)
 118
 119 if test "$optimise_b" = yes; then
 120     DEFINES="$DEFINES -DSTRING_UTILS_INLINED"
 121     AC_DEFINE(STRINGS_UTILS_INLINED)
 122 fi
 123
 124 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 125
 126 # Gather requirements and generate output.
 127 STEPMAKE_END
 128
 129 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 130
 131 cat <<EOF
 132
 133 Type:
 134     make$mc all       to build LilyPond
 135     make$mc install   to install LilyPond
 136     make$mc help      to see all possible targets
 137
 138 EOF