aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4 AC_DEFUN(AC_STEPMAKE_COMPILE, [
   5     # -O is necessary to get inlining
   6     OPTIMIZE="-O"
   7     checking_b=yes
   8     optimise_b=tja
   9     profile_b=no
  10     debug_b=yes
  11
  12     AC_ARG_ENABLE(checking,
  13     [  enable-checking         set runtime checks (assert calls). Default: on],
  14     [checking_b=$enableval] )
  15
  16     # actually, the default is: tja='-O' to get inlining...
  17     # off=''
  18     AC_ARG_ENABLE(optimise,
  19     [  enable-optimise         use maximal speed optimisations. Default: off],
  20     [optimise_b=$enableval])
  21
  22     AC_ARG_ENABLE(profiling,
  23     [  enable-profiling        compile with gprof support. Default: off],
  24     [profile_b=$enableval])
  25
  26     AC_ARG_ENABLE(debugging,
  27     [  enable-debugging        set debug info. Default: on],
  28     [debug_b=$enableval])
  29
  30     AC_ARG_ENABLE(mingw-prefix,
  31     [  enable-mingw-prefix=DIR set the mingw32 directory (standalone windows32 exes)],
  32     [MINGWPREFIX=$enableval],
  33     [MINGWPREFIX=no])
  34
  35     if test "$printing_b" = no; then
  36         # ugh
  37         AC_DEFINE(NPRINT)
  38         DEFINES="$DEFINES -DNPRINT"
  39     fi
  40
  41     if test "$checking_b" = no; then
  42         # ugh
  43         AC_DEFINE(NDEBUG)
  44         DEFINES="$DEFINES -DNDEBUG"
  45     fi
  46
  47     if test "$optimise_b" = yes; then
  48         DEFINES="$DEFINES -finline-functions"
  49         OPTIMIZE="-O2"
  50     fi
  51
  52     if test "$optimise_b" = no; then
  53         OPTIMIZE=""
  54     fi
  55
  56     if test $profile_b = yes; then
  57         EXTRA_LIBES="-pg"
  58         DEFINES="$DEFINES -pg"
  59     fi
  60
  61     if test $debug_b = yes; then
  62         DEFINES="$DEFINES -g"
  63     fi
  64
  65     # however, C++ support in mingw32 v 0.1.4 is still flaky
  66     if test x$MINGWPREFIX != xno; then
  67         ICFLAGS="-I$MINGWPREFIX/include"
  68         ILDFLAGS="-$MINGWPREFIX/lib"
  69     fi
  70
  71     AC_PROG_CC
  72     LD='$(CC)'
  73     AC_SUBST(LD)
  74
  75     CPPFLAGS=${CPPFLAGS:-""}
  76     AC_SUBST(CPPFLAGS)
  77     AC_SUBST(LDFLAGS)
  78     AC_SUBST(ICFLAGS)
  79     AC_SUBST(ILDFLAGS)
  80     AC_SUBST(DEFINES)
  81     AC_SUBST(EXTRA_LIBES)
  82 ])
  83
  84 AC_DEFUN(AC_STEPMAKE_CXX, [
  85     AC_LANG_CPLUSPLUS
  86     AC_PROG_CXX
  87
  88     AC_CHECK_HEADER(FlexLexer.h, true,
  89         AC_STEPMAKE_WARN(can"\'"t find flex header. Please install Flex headers correctly))
  90
  91     CXXFLAGS="$DEFINES $OPTIMIZE"
  92     LDFLAGS=$EXTRA_LIBES
  93
  94     AC_SUBST(CXXFLAGS)
  95     AC_SUBST(CXX)
  96     LD='$(CXX)'
  97     AC_SUBST(LD)
  98 ])
  99
 100 AC_DEFUN(AC_STEPMAKE_CXXTEMPLATE, [
 101     AC_CACHE_CHECK([whether explicit instantiation is needed],
 102         lily_cv_need_explicit_instantiation,
 103         AC_TRY_LINK([
 104     template <class T> struct foo { static int baz; };
 105     template <class T> int foo<T>::baz = 1;
 106     ], [ return foo<int>::baz; ],
 107             lily_cv_need_explicit_instantiation=no,
 108             lily_cv_need_explicit_instantiation=yes))
 109     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 110         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 111     fi
 112 ])
 113
 114 AC_DEFUN(AC_STEPMAKE_DATADIR, [
 115     if test "$datadir" = "\${prefix}/share"; then
 116             datadir='${prefix}/share/'$package
 117     fi
 118     DIR_DATADIR=${datadir}
 119     presome=${prefix}
 120     if test "$prefix" = "NONE"; then
 121             presome=${ac_default_prefix}
 122     fi
 123     DIR_DATADIR=`echo ${DIR_DATADIR} | sed "s!\\\${prefix}!$presome!"`
 124     AC_SUBST(datadir)
 125     AC_SUBST(DIR_DATADIR)
 126     AC_DEFINE_UNQUOTED(DIR_DATADIR, "${DIR_DATADIR}")
 127 ])
 128
 129 AC_DEFUN(AC_STEPMAKE_END, [
 130     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 131
 132     rm -f Makefile
 133     cp make/toplevel.make.in ./Makefile
 134     chmod 444 Makefile
 135 ])
 136
 137 AC_DEFUN(AC_STEPMAKE_GXX, [
 138     # ugh autoconf
 139     changequote(<<, >>)dnl
 140     if $CXX --version | grep '2\.[78]' > /dev/null ||
 141         $CXX --version | grep 'egcs' > /dev/null
 142     changequote([, ])dnl
 143     then
 144             true
 145     else
 146             AC_STEPMAKE_WARN(can\'t find g++ 2.7, 2.8 or egcs)
 147     fi
 148 ])
 149
 150 AC_DEFUN(AC_STEPMAKE_INIT, [
 151
 152     . $srcdir/VERSION
 153     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 154     if test x$MY_PATCH_LEVEL != x; then
 155         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 156     fi
 157
 158     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 159     changequote(<<, >>)dnl
 160     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 161     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 162     changequote([, ])dnl
 163
 164     if test "x$PACKAGE" = "xSTEPMAKE"; then
 165         echo Stepmake package!
 166         (cd stepmake; rm -f stepmake; ln -s ../stepmake .)
 167         (cd stepmake; rm -f bin; ln -s ../bin .)
 168         AC_CONFIG_AUX_DIR(bin)
 169     else
 170         echo Package: $PACKAGE
 171         AC_CONFIG_AUX_DIR(stepmake/bin)
 172     fi
 173
 174     AC_SUBST(package)
 175     AC_SUBST(PACKAGE)
 176     AC_SUBST(PACKAGE_NAME)
 177     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 178     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 179
 180     package_depth=`dirname $cache_file`
 181     AC_SUBST(package_depth)
 182
 183     AUTOGENERATE="This file was automatically generated by configure"
 184     AC_SUBST(AUTOGENERATE)
 185     absolute_builddir="`pwd`"
 186     AC_SUBST(absolute_builddir)
 187
 188     # No versioning on directory names of sub-packages
 189     stepmake=stepmake
 190     AC_SUBST(stepmake)
 191
 192     CONFIGSUFFIX=
 193     AC_ARG_ENABLE(config,
 194     [  enable-config=FILE      put configure settings in config-FILE.make],
 195     [CONFIGSUFFIX=$enableval])
 196
 197     if test "$CONFIGSUFFIX" != "" ; then
 198         CONFIGFILE=config-$CONFIGSUFFIX
 199     else
 200         CONFIGFILE=config
 201     fi
 202     AC_SUBST(CONFIGSUFFIX)
 203
 204     AC_CANONICAL_HOST
 205     AC_CHECK_PROGS(MAKE, make, error)
 206     AC_CHECK_PROGS(FIND, find, error)
 207
 208
 209 dnl system supplied INSTALL is unsafe; use our own install.
 210 dnl    AC_PROG_INSTALL
 211 dnl    if test "$INSTALL" = "bin/install-sh"; then
 212 dnl     export INSTALL="\$\(depth\)/bin/install-sh"
 213 dnl    fi
 214
 215     AC_CHECK_PROGS(TAR, tar, error)
 216     AC_CHECK_PROGS(BASH, bash, /bin/sh)
 217
 218     AC_PATH_PROG(PYTHON, python, -echo no python)
 219     AC_SUBST(PYTHON)
 220
 221
 222     AC_CHECK_SEARCH_RESULT($MAKE, GNU make,  You should install GNU make)
 223     if test $MAKE != "error" ; then
 224         $MAKE -v| grep GNU > /dev/null
 225         if test "$?" = 1
 226         then
 227                 AC_STEPMAKE_WARN(Please install *GNU* make)
 228         fi
 229     fi
 230
 231     AC_CHECK_SEARCH_RESULT($PYTHON, python, You should install Python)
 232
 233     if test "x$OSTYPE" = "xcygwin32" || test "x$OSTYPE" = "xWindows_NT"; then
 234         LN=cp # hard link does not work under cygnus-nt (yet?)
 235         ZIP="zip -r -9" #
 236         DOTEXE=.exe
 237         INSTALL="\$(stepdir)/../bin/install-dot-exe.sh -c"
 238     else
 239         LN=ln
 240         ZIP="zip -r -9"
 241         INSTALL="\$(stepdir)/../bin/install-sh -c"
 242     fi
 243     AC_SUBST(DOTEXE)
 244     AC_SUBST(ZIP)
 245     AC_SUBST(LN)
 246     AC_SUBST(INSTALL)
 247
 248     AC_STEPMAKE_DATADIR
 249 ])
 250
 251 AC_DEFUN(AC_STEPMAKE_LEXYACC, [
 252     # ugh, automake: we want (and check for) bison
 253     AC_PROG_YACC
 254     # ugh, automake: we want (and check for) flex
 255     # AC_PROG_LEX
 256     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 257
 258     # AC_DECL_YYTEXT
 259     # ugh, ugh
 260     ac_cv_prog_lex_root=lex.yy
 261
 262     AC_CHECK_PROGS(BISON, bison, error)
 263     AC_CHECK_PROGS(FLEX, flex, error)
 264     AC_CHECK_SEARCH_RESULT($BISON, bison,  Please install Bison, 1.25 or better)
 265     AC_CHECK_SEARCH_RESULT($FLEX,  flex, Please install Flex, 2.5 or better)
 266
 267     if test $BISON != "error"; then
 268         bison_version=`$BISON --version| sed 's/^.*version 1.//g' `
 269         if test $bison_version -lt 25; then
 270             AC_STEPMAKE_WARN(Your bison is a bit old (1.$bison_version). You might have to install 1.25)
 271         fi
 272     fi
 273
 274     AC_SUBST(BISON)
 275     AC_SUBST(FLEX)
 276 ])
 277
 278 AC_DEFUN(AC_STEPMAKE_LIB, [
 279     AC_CHECK_PROGS(AR, ar, error)
 280     AC_PROG_RANLIB
 281
 282     AC_SUBST(AR)
 283     AC_SUBST(RANLIB)
 284 ])
 285
 286 AC_DEFUN(AC_STEPMAKE_LIBTOOL, [
 287     # libtool.info ...
 288     # **Never** try to set library version numbers so that they correspond
 289     # to the release number of your package.  This is an abuse that only
 290     # fosters misunderstanding of the purpose of library versions.
 291
 292     REVISION=$PATCH_LEVEL
 293     # CURRENT=$MINOR_VERSION
 294     CURRENT=`expr $MINOR_VERSION + 1`
 295     # AGE=$(expr $MAJOR_VERSION + 1)
 296     AGE=$MAJOR_VERSION
 297     AC_SUBST(CURRENT)
 298     AC_SUBST(REVISION)
 299     AC_SUBST(AGE)
 300 ])
 301
 302 AC_DEFUN(AC_STEPMAKE_LOCALE, [
 303     lang=English
 304     ALL_LINGUAS="en nl"
 305
 306     # with/enable ??
 307     AC_ARG_WITH(localedir,
 308     [  with-localedir=LOCALE   use LOCALE as locale dir. Default: PREFIX/share/locale ],
 309     localedir=$with_localedir,
 310     localedir='${prefix}/share/locale')
 311
 312     AC_ARG_WITH(lang,
 313     [  with-lang=LANG          use LANG as language to emit messages],
 314     language=$with_lang,
 315     language=English)
 316
 317     AC_MSG_CHECKING(language)
 318     case "$language" in
 319       En* | en* | Am* | am* | US* | us*)
 320             lang=English;;
 321       NL | nl | Du* | du* | Ned* | ned*)
 322             lang=Dutch;;
 323       "")
 324             lang=English;;
 325       *)
 326             lang=unknown;;
 327     esac
 328     AC_MSG_RESULT($lang)
 329
 330     if test "$lang" = "unknown" ; then
 331         AC_STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 332     fi
 333
 334 ])
 335
 336 AC_DEFUN(AC_STEPMAKE_GETTEXT, [
 337     DIR_LOCALEDIR=${localedir}
 338     presome=${prefix}
 339     if test "$prefix" = "NONE"; then
 340             presome=${ac_default_prefix}
 341     fi
 342     DIR_LOCALEDIR=`echo ${DIR_LOCALEDIR} | sed "s!\\\${prefix}!$presome!"`
 343     AC_SUBST(localedir)
 344     AC_SUBST(DIR_LOCALEDIR)
 345     AC_DEFINE_UNQUOTED(DIR_LOCALEDIR, "${DIR_LOCALEDIR}")
 346
 347     AC_CHECK_LIB(intl, gettext)
 348     AC_CHECK_FUNCS(gettext)
 349 ])
 350
 351 AC_DEFUN(AC_STEPMAKE_MAN, [
 352     AC_CHECK_PROGS(TROFF, troff, -echo no troff)
 353 ])
 354
 355 AC_DEFUN(AC_STEPMAKE_MSGFMT, [
 356     # AC_CHECK_PROGS(MSGFMT, msgfmt, -echo no msgfmt)
 357     AC_CHECK_PROGS(MSGFMT, msgfmt, \$(SHELL) \$(step-bindir)/fake-msgfmt.sh )
 358     AC_MSG_CHECKING(whether msgfmt accepts -o)
 359     msgfmt_output="`msgfmt -o bla 2>&1 | grep usage`"
 360     if test "$msgfmt_output" = ""; then
 361         AC_MSG_RESULT(yes)
 362     else
 363         # urg
 364         MSGFMT="\$(SHELL) \$(step-bindir)/fake-msgfmt.sh"
 365         AC_MSG_RESULT(no)
 366         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 367     fi
 368     if test ! -n "$MSGFMT"; then
 369         AC_STEPMAKE_WARN(please install msgfmt from GNU gettext)
 370     fi
 371 ])
 372
 373 AC_DEFUN(AC_STEPMAKE_TEXMF, [
 374     AC_ARG_ENABLE(tex-prefix,
 375     [  enable-tex-prefix=DIR   set the tex-directory to find TeX subdirectories. (default: PREFIX)],
 376     [TEXPREFIX=$enableval],
 377     [TEXPREFIX=auto] )
 378
 379     AC_ARG_ENABLE(tex-dir,
 380     [  enable-tex-dir=DIR      set the directory to put $PACKAGE_NAME TeX files in. ],
 381     [TEXDIR=$enableval],
 382     [TEXDIR=auto] )
 383
 384     AC_ARG_ENABLE(mf-dir,
 385     [  enable-mf-dir=DIR       set the directory to put $PACKAGE_NAME MetaFont files in. ],
 386     [MFDIR=$enableval],
 387     [MFDIR=auto])
 388
 389     if test "x$TEXPREFIX" = xauto ; then
 390         AC_TEX_PREFIX(TEXPREFIX)
 391     else
 392      find_texprefix=$TEXPREFIX
 393     fi
 394
 395     if test "x$MFDIR" = xauto; then
 396         AC_MF_SUBDIR(MFDIR)
 397     fi
 398
 399     if test "x$TEXDIR" = xauto ; then
 400         AC_TEX_SUBDIR(TEXDIR)
 401     fi
 402
 403     AC_SUBST(TEXPREFIX)
 404     AC_SUBST(TEXDIR)
 405     AC_SUBST(MFDIR)
 406 ])
 407
 408 AC_DEFUN(AC_STEPMAKE_WARN, [
 409     AC_MSG_WARN($1)
 410     warn_b=yes
 411 ])
 412
 413 AC_DEFUN(AC_STEPMAKE_YODL, [
 414     if test "x$YODL" = "x"; then
 415         AC_CHECK_PROGS(YODL, yodl, -echo no yodl)
 416         AC_CHECK_PROGS(YODL2HTML, yodl2html, -echo no yodl)
 417         AC_CHECK_PROGS(YODL2LATEX, yodl2latex, )
 418         AC_CHECK_PROGS(YODL2MAN, yodl2man, -echo no yodl)
 419         AC_CHECK_PROGS(YODL2TEXINFO, yodl2texinfo, -echo no yodl)
 420         AC_CHECK_PROGS(YODL2TXT, yodl2txt, -echo no yodl)
 421     else
 422         AC_SUBST(YODL)
 423         AC_SUBST(YODL2HTML)
 424         AC_SUBST(YODL2LATEX)
 425         AC_SUBST(YODL2MAN)
 426         AC_SUBST(YODL2TEXINFO)
 427         AC_SUBST(YODL2TXT)
 428         export YODL YODL2HTML YODL2LATEX YODL2MAN YODL2TEXINFO YODL2TXT
 429     fi
 430     if test "x$YODL" = "-echo no yodl"; then
 431         AC_STEPMAKE_WARN(Did not find YODL (Yodl is Yet Oneother Document Language, see http://www.cs.uu.nl/~hanwen/yodl))
 432     fi
 433 ])
 434
 435 dnl should cache result.
 436 dnl should  look in $prefix first.
 437 dnl should probably assume TDS
 438
 439 AC_DEFUN(AC_TEX_PREFIX, [
 440
 441
 442     AC_MSG_CHECKING(TeX/MF root dir directory)
 443
 444     find_root_prefix="$prefix"
 445
 446
 447     test "x$find_root_prefix" = xNONE && find_root_prefix="$ac_default_prefix"
 448     find_texpostfix="";
 449     for postfix in "/lib/tex/" "/lib/texmf" "/lib" "/tex" "/texmf"; do
 450         find_texprefix="$find_root_prefix$postfix"
 451         if test -d $find_texprefix; then
 452             find_texpostfix=$postfix
 453             break;
 454         fi
 455     done
 456
 457     if test "x$find_texpostfix" = x; then
 458         find_texpostfix='/lib/texmf/tex'
 459         AC_STEPMAKE_WARN(Cannot determine the TeX-directory. Please use --enable-tex-prefix)
 460     fi
 461
 462     find_texprefix="$find_root_prefix/$find_texpostfix"
 463
 464     # only assign if variablename not empty
 465     if test x != "x[$]$1"; then
 466         $1='${prefix}'/"$find_texpostfix"
 467     fi
 468     AC_MSG_RESULT($find_texprefix)
 469
 470 ])
 471
 472
 473 # find a directory inside a prefix,
 474 # $1 the prefix (expanded version)
 475 # $2 variable to assign
 476 # $3 the directory name
 477 # $4 description
 478 AC_DEFUN(AC_FIND_DIR_IN_PREFIX, [
 479
 480     AC_MSG_CHECKING($4 directory)
 481     find_dirdir=`(cd $1;
 482       $FIND ./ -type d -a -name $3 -print |sort|head -1|sed 's#^\./##')`
 483
 484
 485     if test "x$find_dirdir" = x; then
 486        find_dirdir="/$3";
 487        AC_STEPMAKE_WARN(Cannot determine $4 subdirectory. Please set from command-line)
 488         true
 489     fi
 490     $2=$find_dirdir
 491     AC_MSG_RESULT($1/$find_dirdir)
 492 ])
 493
 494 # ugh.  this is hopeless
 495 AC_DEFUN(AC_KPSE_TEX_DIR, [
 496         kpse_paths=`(kpsepath -n latex tex; kpsepath -n tex tex) | sed 's/:/ /g' | tr ' ' '\012' |sort | uniq -d`
 497         kpse_syspaths=`echo $kpse_paths | grep '!'| sed 's/!//g'`
 498         echo $kpse_paths
 499         if test -w "$kpse_syspaths";
 500         then
 501                 dir=`echo $kpse_syspaths | head -1`
 502         else
 503                 dir=`echo $kpse_paths | grep -v '!'| head -1`
 504         fi
 505         if test "$prefix" = "NONE"; then
 506                 local_prefix=$ac_default_prefix
 507                 local_prefix_quote='${prefix}'
 508
 509         else
 510                 local_prefix=$prefix
 511                 local_prefix_quote=$prefix
 512         fi
 513         echo $local_prefix_quote = $local_prefix
 514         echo $dir
 515         echo $dir  | sed 's!'$local_prefix'!\$local_prefix_quote!g'
 516 ])
 517
 518 AC_DEFUN(AC_TEX_SUBDIR, [
 519 dnl    AC_REQUIRE([AC_TEX_PREFIX])
 520     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, tex,TeX input)
 521     $1="$TEXPREFIX/$$1"
 522 ])
 523
 524 AC_DEFUN(AC_MF_SUBDIR, [
 525 dnl     AC_REQUIRE([AC_TEX_PREFIX])
 526     AC_FIND_DIR_IN_PREFIX($find_texprefix, $1, source, MF input)
 527     $1="$TEXPREFIX/$$1"
 528 ])
 529
 530 AC_DEFUN(AC_CHECK_SEARCH_RESULT, [
 531         result="`echo \"$1\" | grep echo`"
 532         if test "x$1" = "xerror" -o "x$result" != "x"; then
 533                 AC_STEPMAKE_WARN(can\'t find $2. $3)
 534         fi
 535 ])
 536
 537 # Configure paths for GTK+
 538 # Owen Taylor     97-11-3
 539
 540 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 541 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
 542 dnl
 543 AC_DEFUN(AM_PATH_GTK,
 544 [dnl
 545 dnl Get the cflags and libraries from the gtk-config script
 546 dnl
 547   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 548   min_gtk_version=ifelse([$1], ,0.99.7,$1)
 549   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
 550   no_gtk=""
 551   if test "$GTK_CONFIG" != "no" ; then
 552     GTK_CFLAGS=`$GTK_CONFIG --cflags`
 553     GTK_LIBS=`$GTK_CONFIG --libs`
 554     ac_save_CFLAGS="$CFLAGS"
 555     ac_save_LIBS="$LIBS"
 556     ac_save_CXXFLAGS="$CXXFLAGS"
 557     CFLAGS="$CFLAGS $GTK_CFLAGS"
 558     CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 559     LIBS="$LIBS $GTK_LIBS"
 560 dnl
 561 dnl Now check if the installed GTK is sufficiently new. (Also sanity
 562 dnl checks the results of gtk-config to some extent
 563 dnl
 564     AC_TRY_RUN([
 565 #include <gtk/gtk.h>
 566 #include <stdio.h>
 567
 568 int
 569 main ()
 570 {
 571   int major, minor, micro;
 572
 573   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
 574      printf("%s, bad version string\n", "$min_gtk_version");
 575      exit(1);
 576    }
 577
 578    return !((gtk_major_version > major) ||
 579             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
 580             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
 581 }
 582 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 583      CFLAGS="$ac_save_CFLAGS"
 584      CXXFLAGS="$ac_save_CXXFLAGS"
 585      LIBS="$ac_save_LIBS"
 586   else
 587      no_gtk=yes
 588   fi
 589   if test "x$no_gtk" = x ; then
 590      AC_MSG_RESULT(yes)
 591      ifelse([$2], , :, [$2])
 592   else
 593      AC_MSG_RESULT(no)
 594      GTK_CFLAGS=""
 595      GTK_LIBS=""
 596      ifelse([$3], , :, [$3])
 597   fi
 598   CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
 599   AC_SUBST(CXXFLAGS)
 600   AC_SUBST(GTK_CFLAGS)
 601   AC_SUBST(GTK_LIBS)
 602 ])
 603
 604
 605 # Configure paths for GTK--
 606 # Jan Nieuwenhuizen   98-06-3
 607
 608 dnl AM_PATH_GTK__([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 609 dnl Test for GTK--, and define GTK___CFLAGS and GTK___LIBS
 610 dnl
 611 AC_DEFUN(AM_PATH_GTK__,
 612 [dnl
 613 dnl Get the cflags and libraries from the gtk__-config script
 614 dnl
 615   min_gtk___version=ifelse([$1], ,0.9.4,$1)
 616   AC_MSG_CHECKING(for GTK-- - version >= $min_gtk___version)
 617   no_gtk__=""
 618   if test "$GTK_CONFIG" != "no" ; then
 619     GTK___CFLAGS=`$GTK_CONFIG --cflags`
 620     GTK_LIBS=`$GTK_CONFIG --libs`
 621     GTK___LIBS="$GTK_LIBS -lgtkmm"
 622     ac_save_CFLAGS="$CFLAGS"
 623     ac_save_LIBS="$LIBS"
 624     ac_save_CXXFLAGS="$CXXFLAGS"
 625     CFLAGS="$CFLAGS $GTK___CFLAGS"
 626     CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 627     LIBS="$LIBS $GTK___LIBS"
 628 dnl
 629 dnl Now check if the installed GTK__ is sufficiently new. (Also sanity
 630 dnl checks the results of gtk__-config to some extent
 631 dnl
 632     AC_TRY_RUN([
 633 #include <gtk--.h>
 634 #include <stdio.h>
 635
 636 int
 637 main ()
 638 {
 639   // urg
 640   return 0;
 641 }
 642 ],, no_gtk__=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 643      CFLAGS="$ac_save_CFLAGS"
 644      CXXFLAGS="$ac_save_CXXFLAGS"
 645      LIBS="$ac_save_LIBS"
 646   else
 647      no_gtk__=yes
 648   fi
 649   if test "x$no_gtk__" = x ; then
 650      AC_MSG_RESULT(yes)
 651      ifelse([$2], , :, [$2])
 652   else
 653      AC_MSG_RESULT(no)
 654      GTK___CFLAGS=""
 655      GTK___LIBS=""
 656      ifelse([$3], , :, [$3])
 657   fi
 658   CXXFLAGS="$CXXFLAGS $GTK___CFLAGS"
 659   AC_SUBST(CXXFLAGS)
 660   AC_SUBST(GTK___CFLAGS)
 661   AC_SUBST(GTK___LIBS)
 662 ])
 663