Lib/mk20dx256vlh7.bootloader.ld

   1 /* Teensyduino Core Library
   2  * http://www.pjrc.com/teensy/
   3  * Copyright (c) 2013 PJRC.COM, LLC.
   4  * Modifications by Jacob Alexander 2014-2015 for use with McHCK and Kiibohd-dfu
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining
   7  * a copy of this software and associated documentation files (the
   8  * "Software"), to deal in the Software without restriction, including
   9  * without limitation the rights to use, copy, modify, merge, publish,
  10  * distribute, sublicense, and/or sell copies of the Software, and to
  11  * permit persons to whom the Software is furnished to do so, subject to
  12  * the following conditions:
  13  *
  14  * 1. The above copyright notice and this permission notice shall be
  15  * included in all copies or substantial portions of the Software.
  16  *
  17  * 2. If the Software is incorporated into a build system that allows
  18  * selection among a list of target devices, then similar target
  19  * devices manufactured by PJRC.COM must be included in the list of
  20  * target devices and selectable in the same manner.
  21  *
  22  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  23  * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  24  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  25  * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
  26  * BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
  27  * ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  28  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  29  * SOFTWARE.
  30  */
  31
  32 MEMORY
  33 {
  34         FLASH (rx)     : ORIGIN = 0x0, LENGTH = 256K
  35         FLASH_APP (rx) : ORIGIN = 8K, LENGTH = 256K-8K
  36         RAM  (rwx)     : ORIGIN = 0x20000000 - 64K / 2, LENGTH = 64K
  37 }
  38
  39 /* Starting Address of the application ROM */
  40 _app_rom = ORIGIN( FLASH_APP );
  41
  42 FlexRAM = 0x14000000;
  43 FTFL = 0x40020000;
  44 SCB = 0xe000ed00;
  45 USB0 = 0x40072000;
  46 SIM = 0x40047000;
  47
  48 /* Section Definitions */
  49 SECTIONS
  50 {
  51         .text :
  52         {
  53                 . = 0; KEEP(* (.vectors)) /* MUST BE AT 0 */
  54                 *(.startup*)
  55                 . = 0x400; KEEP(* (.flashconfig)) /* MUST BE AT 0x400 */
  56                 *(.rodata*)
  57                 *(.text*)
  58                 . = ALIGN(4);
  59                 KEEP(*(.init))
  60         } > FLASH
  61
  62         .ARM.exidx :
  63         {
  64                 __exidx_start = .;
  65                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  66                 __exidx_end = .;
  67         } > FLASH
  68         _etext = .;
  69
  70         .usbdescriptortable (NOLOAD) : {
  71                 . = ALIGN(512);
  72                 *(.usbdescriptortable*)
  73         } > RAM
  74
  75         .dmabuffers (NOLOAD) : {
  76                 . = ALIGN(4);
  77                 *(.dmabuffers*)
  78         } > RAM
  79
  80         .usbbuffers (NOLOAD) : {
  81                 . = ALIGN(4);
  82                 *(.usbbuffers*)
  83         } > RAM
  84
  85         .data : AT (_etext) {
  86                 . = ALIGN(4);
  87                 _sdata = .;
  88                 *(SORT_BY_ALIGNMENT(.ramtext.*) SORT_BY_ALIGNMENT(.data*))
  89                 *(.data*)
  90                 . = ALIGN(4);
  91                 _edata = .;
  92         } > RAM
  93
  94         .noinit (NOLOAD) : {
  95                 *(.noinit*)
  96         } > RAM
  97
  98         .bss : {
  99                 . = ALIGN(4);
 100                 _sbss = .;
 101                 *(.bss*)
 102                 *(COMMON)
 103                 . = ALIGN(4);
 104                 _ebss = .;
 105                 __bss_end = .;
 106         } > RAM
 107
 108         _estack = ORIGIN(RAM) + LENGTH(RAM);
 109 }
 110