Lib/CMake/build.cmake

   1 ###| CMAKE Kiibohd Controller Source Configurator |###
   2 #
   3 # Written by Jacob Alexander in 2011-2014 for the Kiibohd Controller
   4 #
   5 # Released into the Public Domain
   6 #
   7 ###
   8
   9
  10 ###
  11 # Disable -Wl,-search_paths_first for OSX (not supported by avr-gcc or arm-none-eabi-gcc)
  12 #
  13
  14 if ( APPLE )
  15         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_C_LINK_FLAGS ${CMAKE_C_LINK_FLAGS} )
  16         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_CXX_LINK_FLAGS ${CMAKE_CXX_LINK_FLAGS} )
  17 endif ()
  18
  19
  20
  21 ###
  22 # Build Targets
  23 #
  24
  25 #| Create the .ELF file
  26 set( TARGET_ELF ${TARGET}.elf )
  27 add_executable( ${TARGET_ELF} ${SRCS} generatedKeymap.h )
  28
  29
  30 #| .ELF Properties
  31 set_target_properties( ${TARGET_ELF} PROPERTIES
  32         LINK_FLAGS ${LINKER_FLAGS}
  33         SUFFIX ""                               # XXX Force Windows to keep the .exe off
  34 )
  35
  36
  37 #| Convert the .ELF into a .bin to load onto the McHCK
  38 if( DEFINED DFU )
  39         set( TARGET_BIN ${TARGET}.dfu.bin )
  40         add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  41                 COMMAND ${CMAKE_OBJCOPY} ${BIN_FLAGS} ${TARGET_ELF} ${TARGET_BIN}
  42                 COMMENT "Creating dfu binary file:      ${TARGET_BIN}"
  43         )
  44 endif()
  45
  46
  47 #| Convert the .ELF into a .HEX to load onto the Teensy
  48 if ( DEFINED TEENSY )
  49         set( TARGET_HEX ${TARGET}.teensy.hex )
  50         add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  51                 COMMAND ${CMAKE_OBJCOPY} ${HEX_FLAGS} ${TARGET_ELF} ${TARGET_HEX}
  52                 COMMENT "Creating iHex file to load:    ${TARGET_HEX}"
  53         )
  54 endif()
  55
  56
  57 #| Generate the Extended .LSS
  58 set( TARGET_LSS ${TARGET}.lss )
  59 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  60         COMMAND ${CMAKE_OBJDUMP} ${LSS_FLAGS} ${TARGET_ELF} > ${TARGET_LSS}
  61         COMMENT "Creating Extended Listing:     ${TARGET_LSS}"
  62 )
  63
  64
  65 #| Generate the Symbol Table .SYM
  66 set( TARGET_SYM ${TARGET}.sym )
  67 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  68         COMMAND ${CMAKE_NM} -n ${TARGET_ELF} > ${TARGET_SYM}
  69         COMMENT "Creating Symbol Table:         ${TARGET_SYM}"
  70 )
  71
  72
  73 #| Compiler Selection Record
  74 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  75         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/writer compiler ${COMPILER_FAMILY}
  76 )
  77
  78
  79
  80 ###
  81 # Size Information
  82 #
  83
  84 #| After Changes Size Information
  85 add_custom_target( SizeAfter ALL
  86         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/sizeCalculator ${CMAKE_SIZE} ram   ${TARGET_ELF} ${SIZE_RAM}   " SRAM"
  87         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/sizeCalculator ${CMAKE_SIZE} flash ${TARGET_ELF} ${SIZE_FLASH} "Flash"
  88         DEPENDS ${TARGET_ELF}
  89         COMMENT "Chip usage for ${CHIP}"
  90 )
  91
  92
  93
  94 ###
  95 # Setup Loader Script and Program
  96 #
  97
  98 #| First check for DFU based controllers
  99 if( DEFINED DFU )
 100         configure_file( LoadFile/load.dfu load NEWLINE_STYLE UNIX )
 101
 102 #| Next check for Teensy based
 103 elseif ( DEFINED TEENSY )
 104         # Provides the user with the correct teensy-loader-cli command for the built .HEX file
 105         # Windows
 106         if( CMAKE_SYSTEM_NAME MATCHES "Windows" )
 107                 configure_file( LoadFile/winload.teensy load NEWLINE_STYLE UNIX )
 108         # Default
 109         else()
 110                 configure_file( LoadFile/load.teensy load NEWLINE_STYLE UNIX )
 111         endif()
 112 endif()
 113