Bootloader/CMakeLists.txt

   1 ###| CMAKE Kiibohd Controller Bootloader |###
   2 #
   3 # Jacob Alexander 2011-2014
   4 # Due to this file's usefulness:
   5 #
   6 # Released into the Public Domain
   7 #
   8 # This bootloader is based upon the MCHCK dfu-usb bootloader.
   9 # DO NOT USE with Teensy based microcontrollers.
  10 #
  11 ###
  12
  13
  14
  15 ###
  16 # Chip Selection
  17 #
  18
  19 #| You _MUST_ set this to match the microcontroller you are trying to compile for
  20 #| You _MUST_ clean the build directory if you change this value
  21 #|
  22 set( CHIP
  23         #"mk20dx128vlf5"    # McHCK       mk20dx128vlf5
  24         "mk20dx256vlh7"    # Kiibohd-dfu mk20dx256vlh7
  25 )
  26
  27
  28
  29 ###
  30 # Compiler Selection
  31 #
  32
  33 #| *** EXPERIMENTAL ***
  34 #| Stick with gcc unless you know what you're doing
  35 #| Currently only arm is supported with clang
  36 set( COMPILER
  37         "gcc"   # arm-none-eabi-gcc / avr-gcc - Default
  38 #       "clang" # arm-none-eabi
  39         CACHE STRING "Compiler Type" )
  40
  41
  42
  43 ###
  44 # Bootloader Configuration
  45 #
  46 set ( BOOTLOADER 1 )
  47
  48
  49
  50 ###
  51 # Compiler Intialization
  52 #
  53 set ( CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_SOURCE_DIR}/../Lib/CMake )
  54 include( initialize )
  55
  56
  57
  58 ##
  59 # Source Defines
  60 #
  61 set( SRCS
  62         main.c
  63         dfu.c
  64         dfu.desc.c
  65         flash.c
  66         kinetis.c
  67         usb.c
  68 )
  69
  70 message( STATUS "Bootloader Source Files:" )
  71 message( "${SRCS}" )
  72
  73 #| Add Lib sources to main list
  74 foreach( SRC_FILE ${COMPILER_SRCS} )
  75         set( SRCS ${SRCS} ${CMAKE_SOURCE_DIR}/../${SRC_FILE} )
  76 endforeach()
  77
  78
  79
  80
  81 ###
  82 # Directory Includes
  83 #
  84 include_directories( ${CMAKE_SOURCE_DIR}/../Lib )
  85
  86
  87
  88 ###
  89 # Project Description
  90 #
  91
  92 #| Project
  93 project( kiibohd_bootloader )
  94
  95 #| Target Name (output name)
  96 set( TARGET kiibohd_bootloader )
  97
  98 #| General Settings
  99 cmake_minimum_required( VERSION 2.8 )
 100
 101
 102
 103 ###
 104 # Generate Header Files
 105 #
 106 configure_file( _buildvars.h buildvars.h )
 107 include_directories( ${CMAKE_BINARY_DIR} )
 108
 109
 110
 111 ###
 112 # CMake Module Checking
 113 #
 114 find_package( Git REQUIRED )
 115 find_package( Ctags ) # Optional
 116
 117
 118
 119 ###
 120 # ctag Generation
 121 #
 122 if( CTAGS_EXECUTABLE )
 123         # Generate the ctags
 124         execute_process( COMMAND ctags ${SRCS}
 125                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 126         )
 127 endif()
 128
 129
 130
 131 ###
 132 # Disable -Wl,-search_paths_first for OSX (not supported by arm-none-eabi-gcc)
 133 #
 134
 135 if ( APPLE )
 136         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_C_LINK_FLAGS ${CMAKE_C_LINK_FLAGS} )
 137         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_CXX_LINK_FLAGS ${CMAKE_CXX_LINK_FLAGS} )
 138
 139         message ( AUTHOR_WARNING "Bootloader binary may not fit on device (must be less than 4096 bytes). Macports arm-none-eabi-gcc 4.7.3 doesn't seem to work properly with -flto. However, even disabling it doesn't shrink the binary enough... 4.9.1 is known to work on Arch Linux." )
 140 endif ()
 141
 142
 143
 144 ###
 145 # Build Targets
 146 #
 147
 148 #| Create the .ELF file
 149 set( TARGET_ELF ${TARGET}.elf )
 150 add_executable( ${TARGET_ELF} ${SRCS} )
 151
 152
 153 #| .ELF Properties
 154 set_target_properties( ${TARGET_ELF} PROPERTIES
 155         LINK_FLAGS ${LINKER_FLAGS}
 156         SUFFIX ""                               # XXX Force Windows to keep the .exe off
 157 )
 158
 159
 160 #| Convert the .ELF into a .bin to load onto the McHCK
 161 set( TARGET_BIN ${TARGET}.bin )
 162 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 163         COMMAND ${CMAKE_OBJCOPY} ${BIN_FLAGS} ${TARGET_ELF} ${TARGET_BIN}
 164         COMMENT "Creating binary file to load:  ${TARGET_BIN}"
 165 )
 166
 167
 168 #| Generate the Extended .LSS
 169 set( TARGET_LSS ${TARGET}.lss )
 170 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 171         COMMAND ${CMAKE_OBJDUMP} ${LSS_FLAGS} ${TARGET_ELF} > ${TARGET_LSS}
 172         COMMENT "Creating Extended Listing:     ${TARGET_LSS}"
 173 )
 174
 175
 176 #| Generate the Symbol Table .SYM
 177 set( TARGET_SYM ${TARGET}.sym )
 178 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 179         COMMAND ${CMAKE_NM} -n ${TARGET_ELF} > ${TARGET_SYM}
 180         COMMENT "Creating Symbol Table:         ${TARGET_SYM}"
 181 )
 182
 183
 184 #| Compiler Selection Record
 185 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 186         COMMAND ${CMAKE_SOURCE_DIR}/../Lib/CMake/writer compiler ${COMPILER_FAMILY}
 187 )
 188
 189
 190
 191 ###
 192 # Size Information
 193 #
 194
 195 #| After Changes Size Information
 196 add_custom_target( SizeAfter ALL
 197         COMMAND ${CMAKE_SOURCE_DIR}/../Lib/CMake/sizeCalculator ${CMAKE_SIZE} ram   ${TARGET_ELF} ${SIZE_RAM}   " SRAM"
 198         COMMAND ${CMAKE_SOURCE_DIR}/../Lib/CMake/sizeCalculator ${CMAKE_SIZE} flash ${TARGET_ELF} ${SIZE_FLASH} "Flash"
 199         DEPENDS ${TARGET_ELF}
 200         COMMENT "Chip usage for ${CHIP}"
 201 )
 202