bin/parse_genecard_results

   1 #! /usr/bin/perl
   2
   3 # parse_genecard_results retreives files of search results from ncbi,
   4 # and is released under the terms of the GPL version 2, or any later
   5 # version, at your option. See the file README and COPYING for more
   6 # information.
   7
   8 # Copyright 2004 by Don Armstrong <don@donarmstrong.com>.
   9
  10 # $Id: ss,v 1.1 2004/06/29 05:26:35 don Exp $
  11
  12
  13 use warnings;
  14 use strict;
  15
  16
  17 use Getopt::Long;
  18 use Pod::Usage;
  19
  20 =head1 NAME
  21
  22   parse_genecard_results [options]
  23
  24 =head1 SYNOPSIS
  25
  26
  27  Options:
  28   --dir, -D directory to stick results into [default .]
  29   --name, -n file naming scheme [default ${search}_results.$format]
  30   --terms, -t file of search terms [default -]
  31   --debug, -d debugging level [default 0]
  32   --help, -h display this help
  33   --man, -m display manual
  34
  35 =head1 OPTIONS
  36
  37 =over
  38
  39 =item B<--debug, -d>
  40
  41 Debug verbosity. (Default 0)
  42
  43 =item B<--help, -h>
  44
  45 Display brief useage information.
  46
  47 =item B<--man, -m>
  48
  49 Display this manual.
  50
  51 =back
  52
  53 =head1 EXAMPLES
  54
  55   parse_harvester_results -D ./harvester_results/ -n '${search}_name.html' < search_parameters
  56
  57 Will pretty much do what you want
  58
  59 =cut
  60
  61
  62
  63 use vars qw($DEBUG $REVISION);
  64
  65 BEGIN{
  66      ($REVISION) = q$LastChangedRevision: 1$ =~ /LastChangedRevision:\s+([^\s]+)/;
  67      $DEBUG = 0 unless defined $DEBUG;
  68 }
  69
  70 use IO::File;
  71 use IO::Dir;
  72
  73 # XXX parse config file
  74
  75 my %options = (debug    => 0,
  76                help     => 0,
  77                man      => 0,
  78                dir      => '.',
  79                keyword  => undef,
  80               );
  81
  82 GetOptions(\%options,'keyword|k=s','dir|D=s','debug|d+','help|h|?','man|m');
  83
  84
  85 pod2usage() if $options{help};
  86 pod2usage({verbose=>2}) if $options{man};
  87
  88 $DEBUG = $options{debug};
  89
  90 # CSV columns
  91 use constant {NAME        => 0,
  92               REFSEQ      => 1,
  93               LOCATION    => 2,
  94               ALIAS       => 3,
  95               FUNCTION    => 4,
  96               DESCRIPTION => 5,
  97               KEYWORD     => 6,
  98               DBNAME      => 7,
  99               FILENAME    => 8,
 100              };
 101
 102 if (not -d $options{dir}) {
 103      die "$options{dir} does not exist or is not a directory";
 104 }
 105
 106 my $dir = new IO::Dir $options{dir} or die "Unable to open dir $options{dir}: $!";
 107
 108 print join(",", map {qq("$_");} qw(Name RefSeq Location Alias Function Description Keyword DBName Filename)),qq(\n);
 109
 110 while ($_ = $dir->read) {
 111      my $file_name = $_;
 112      next if $file_name =~ /^\./;
 113      next unless -f "$options{dir}/$file_name" and -r "$options{dir}/$file_name";
 114
 115      my $file = new IO::File "$options{dir}/$file_name", 'r' or die "Unable to open file $file_name";
 116
 117      local $/;
 118      my $result = <$file>;
 119
 120      my @results;
 121
 122      # Find gene name
 123      ($results[NAME]) = $result =~ m&(?:Lean|Gene)Card\s+for\s+(?:(?:disorder\s+locus|uncategorized|
 124                                      hugo\s*reserved\s*symbol|cluster|
 125                                      potentially\s*expressed\s*sequence)|(?:predicted\s+|pseudo|rna\s+|)gene)
 126                                      \s*(?:with\s*support\s*|)<FONT\s+COLOR=\"[^\"]+\">\s*<FONT\s+SIZE=\+2>\s*([^\s]+)\s*&xis;
 127
 128      $results[NAME] ||= 'NO NAME';
 129      # Find REF SEQ number
 130      ($results[REFSEQ]) = $result =~ m|http://www.ncbi.nlm.nih.gov/entrez/query.fcgi\?
 131                                cmd=Search\&db=nucleotide\&doptcmdl=GenBank\&term=([^\"]+)\"|xis;
 132
 133      $results[REFSEQ] ||= 'NO REFSEQ';
 134
 135      # Find Gene Location
 136      ($results[LOCATION]) = $result =~ m&<I>LocusLink\s+cytogenetic\s+band:</I><b>\s+
 137                                          <a\s+href="[^\"]+"\s+target\s+=\s+"aaa">\s*([^\<]+?)\s*</a>&xis;
 138
 139      $results[LOCATION] ||= 'NO LOCATION';
 140
 141      # Find gene aliases
 142      my ($alias_table) = $result =~ m|<b>Aliases and Descriptions</b>(.+?)</TR>|is;
 143      $alias_table ||='';
 144
 145      my @gene_aliases = $alias_table =~ m|<li>\s*([^\(]{0,20}?)\s*\(<FONT|gis;
 146
 147      $results[ALIAS] = join('; ', @gene_aliases);
 148      $results[ALIAS] ||= 'NO ALIASES';
 149
 150      # Find gene function(s)
 151
 152      # Swiss prot functions
 153      my @functions = $result =~ m&<li><b>Function:</b>\s+(.+?)(?:<li>)|(?:</ul>)&gis;
 154
 155      # GO Functions
 156      push @functions, (map {s#\s*</a>\s*# #g; $_;} $result =~ m&(GO:\d+\s*</a>.+?)(?:<dd>|<p>)&gis);
 157      $results[FUNCTION] = join('; ', map {(defined $_)?($_):()} @functions);
 158      $results[FUNCTION] ||= 'NO FUNCTION';
 159
 160      # Figure out the keyword used
 161      ($results[KEYWORD]) = $file_name =~ /search=([^&]+)/;
 162
 163      $results[KEYWORD] ||= 'NO KEYWORD';
 164
 165      # Figure out what the description is
 166      $results[DESCRIPTION] = '';
 167
 168      # Database searched
 169      $results[DBNAME] = 'genecard';
 170      $results[FILENAME] = $file_name;
 171
 172      print join(',',map {qq("$_")} @results),qq(\n);
 173 }
 174
 175
 176
 177
 178
 179
 180 __END__