modules/roles/manifests/static_mirror.pp

   1 class roles::static_mirror {
   2
   3         include roles::static_source
   4
   5         package { 'libapache2-mod-macro': ensure => installed, }
   6         package { 'libapache2-mod-geoip': ensure => installed, }
   7         package { 'geoip-database': ensure => installed, }
   8
   9         apache2::module { 'macro': require => Package['libapache2-mod-macro']; }
  10         apache2::module { 'rewrite': }
  11         apache2::module { 'expires': }
  12         apache2::module { 'geoip': require => [Package['libapache2-mod-geoip'], Package['geoip-database']]; }
  13
  14         file { '/usr/local/bin/static-mirror-run':
  15                 source => 'puppet:///modules/roles/static-mirroring/static-mirror-run',
  16                 mode   => '0555',
  17         }
  18
  19         file { '/srv/static.debian.org':
  20                 ensure => directory,
  21                 owner  => staticsync,
  22                 group  => staticsync,
  23                 mode   => '02755'
  24         }
  25
  26         file { '/etc/cron.d/puppet-static-mirror':
  27                         content => "PATH=/usr/local/bin:/usr/bin:/bin\n@reboot staticsync sleep 60; static-mirror-run --one-stage /srv/static.debian.org bizet.debian.org:-live- > /dev/null\n",
  28         }
  29
  30         $vhost_listen = $::hostname ? {
  31                 klecker => '130.89.148.14:80 [2001:610:1908:b000::148:14]:80',
  32                 default => '*:80',
  33         }
  34
  35         apache2::config { "local-static-vhost.conf":
  36                 content => template('roles/static-mirroring/static-vhost.conf.erb'),
  37         }
  38
  39         apache2::site { '010-planet.debian.org':
  40                 site    => 'planet.debian.org',
  41                 content => template('roles/static-mirroring/vhost/planet.debian.org.erb'),
  42         }
  43
  44         apache2::site { '010-static-vhosts-simple':
  45                 site => "static-vhosts-simple",
  46                 content => template('roles/static-mirroring/vhost/static-vhosts-simple.erb'),
  47         }
  48 }