modules/roles/manifests/static_mirror.pp

   1 class roles::static_mirror {
   2
   3         include roles::static_source
   4         include apache2::cache
   5
   6         package { 'libapache2-mod-macro': ensure => installed, }
   7         package { 'libapache2-mod-geoip': ensure => installed, }
   8         package { 'geoip-database': ensure => installed, }
   9
  10         apache2::module { 'macro': require => Package['libapache2-mod-macro']; }
  11         apache2::module { 'rewrite': }
  12         apache2::module { 'include': }
  13         apache2::module { 'geoip': require => [Package['libapache2-mod-geoip'], Package['geoip-database']]; }
  14
  15         file { '/usr/local/bin/static-mirror-run':
  16                 source => 'puppet:///modules/roles/static-mirroring/static-mirror-run',
  17                 mode   => '0555',
  18         }
  19
  20         file { '/srv/static.debian.org':
  21                 ensure => directory,
  22                 owner  => staticsync,
  23                 group  => staticsync,
  24                 mode   => '02755'
  25         }
  26
  27         file { '/etc/cron.d/puppet-static-mirror':
  28                         content => "PATH=/usr/local/bin:/usr/bin:/bin\n@reboot staticsync sleep 60; awk '!/^ *(#|$)/ {print \$1, \$2}' /etc/static-components.conf | while read master component; do static-mirror-run --one-stage /srv/static.debian.org/mirrors/\$component \"\$master:\$component/-live-\" > /dev/null; done\n",
  29         }
  30
  31         $vhost_listen = $::hostname ? {
  32                 klecker => '130.89.148.14:80 [2001:610:1908:b000::148:14]:80',
  33                 default => '*:80',
  34         }
  35
  36         apache2::config { 'local-static-vhost.conf':
  37                 content => template('roles/static-mirroring/static-vhost.conf.erb'),
  38         }
  39
  40         apache2::site { '010-planet.debian.org':
  41                 site    => 'planet.debian.org',
  42                 content => template('roles/static-mirroring/vhost/planet.debian.org.erb'),
  43         }
  44
  45         apache2::site { '010-static-vhosts-simple':
  46                 site => 'static-vhosts-simple',
  47                 content => template('roles/static-mirroring/vhost/static-vhosts-simple.erb'),
  48         }
  49
  50         $wwwdo_document_root = '/srv/static.debian.org/mirrors/www.debian.org/cur'
  51         apache2::site { '010-www.debian.org':
  52                 site   => 'www.debian.org',
  53                 content => template('roles/apache-www.debian.org.erb'),
  54         }
  55 }