modules/debian-org/manifests/init.pp

   1 define sysctl($key, $value, $ensure=present) {
   2     file {
   3         "/etc/sysctl.d/$name.conf":
   4             ensure  => $ensure,
   5             owner   => root,
   6             group   => root,
   7             mode    => 0644,
   8             content => "$key = $value\n",
   9             notify  => Exec["procps restart"],
  10     }
  11 }
  12
  13 define set_alternatives($linkto) {
  14     exec {
  15         "/usr/sbin/update-alternatives --set $name $linkto":
  16             unless => "/bin/sh -c '! [ -e $linkto ] || ! [ -e /etc/alternatives/$name ] || ([ -L /etc/alternatives/$name ] && [ /etc/alternatives/$name -ef $linkto ])'"
  17         }
  18 }
  19
  20 define linux_module ($ensure) {
  21     case $ensure {
  22         present: {
  23             exec { "append_module_${name}":
  24                 command => "echo '${name}' >> /etc/modules",
  25                 unless => "grep -q -F -x '${name}' /etc/modules",
  26             }
  27         }
  28         absent: {
  29             exec { "remove_module_${name}":
  30                 command => "sed -i -e'/^${name}\$/d' /etc/modules",
  31                 onlyif => "grep -q -F -x '${name}' /etc/modules",
  32             }
  33         }
  34         default: {
  35              err("invalid ensure value ${ensure}")
  36          }
  37     }
  38 }
  39
  40
  41 class debian-org {
  42     $debianadmin = [ "debian-archive-debian-samhain-reports@master.debian.org", "debian-admin@ftbfs.de", "weasel@debian.org", "steve@lobefin.net", "paravoid@debian.org" ]
  43     package {
  44         "apt-utils": ensure => installed;
  45         "bash-completion": ensure => installed;
  46         "debian.org": ensure => installed;
  47         "dnsutils": ensure => installed;
  48         "dsa-munin-plugins": ensure => installed;
  49         "klogd": ensure => purged;
  50         "less": ensure => installed;
  51         "libfilesystem-ruby1.8": ensure => installed;
  52         "mtr-tiny": ensure => installed;
  53         "nload": ensure => installed;
  54         "pciutils": ensure => installed;
  55         "rsyslog": ensure => purged;
  56         "sysklogd": ensure => purged;
  57     }
  58     case $debarchitecture {
  59         "armhf": {}
  60         default: {
  61             file {
  62                 "/etc/apt/sources.list.d/security.list":
  63                     content => template("debian-org/etc/apt/sources.list.d/security.list.erb"),
  64                     notify  => Exec["apt-get update"];
  65                 "/etc/apt/sources.list.d/backports.org.list":
  66                     content => template("debian-org/etc/apt/sources.list.d/backports.org.list.erb"),
  67                     notify  => Exec["apt-get update"];
  68                 "/etc/apt/sources.list.d/volatile.list":
  69                     content => template("debian-org/etc/apt/sources.list.d/volatile.list.erb"),
  70                     notify  => Exec["apt-get update"];
  71             }
  72         }
  73     }
  74     file {
  75         "/etc/apt/preferences":
  76             source => "puppet:///modules/debian-org/apt.preferences";
  77         "/etc/apt/sources.list.d/debian.org.list":
  78             content => template("debian-org/etc/apt/sources.list.d/debian.org.list.erb"),
  79             notify  => Exec["apt-get update"];
  80         "/etc/apt/apt.conf.d/local-recommends":
  81             source => "puppet:///modules/debian-org/apt.conf.d/local-recommends";
  82         "/etc/apt/apt.conf.d/local-pdiffs":
  83             source => "puppet:///modules/debian-org/apt.conf.d/local-pdiffs";
  84         "/etc/timezone":
  85             source => "puppet:///modules/debian-org/timezone",
  86             notify => Exec["dpkg-reconfigure tzdata -pcritical -fnoninteractive"];
  87         "/etc/puppet/puppet.conf":
  88             # require => Package["puppet"],
  89             source => "puppet:///modules/debian-org/puppet.conf"
  90             ;
  91         "/etc/default/puppet":
  92             # require => Package["puppet"],
  93             source => "puppet:///modules/debian-org/puppet.default"
  94             ;
  95
  96         "/etc/cron.d/dsa-puppet-stuff":
  97             source => "puppet:///modules/debian-org/dsa-puppet-stuff.cron",
  98             require => Package["debian.org"]
  99             ;
 100         "/etc/ldap/ldap.conf":
 101             require => Package["debian.org"],
 102             source => "puppet:///modules/debian-org/ldap.conf",
 103             ;
 104         "/etc/pam.d/common-session":
 105             require => Package["debian.org"],
 106             content => template("debian-org/pam.common-session.erb"),
 107             ;
 108         "/etc/rc.local":
 109             mode   => 0755,
 110             source => "puppet:///modules/debian-org/rc.local",
 111             notify => Exec["rc.local start"],
 112             ;
 113
 114         "/etc/dsa":
 115             mode   => 0755,
 116             ensure  => directory,
 117             ;
 118         "/etc/dsa/cron.ignore.dsa-puppet-stuff":
 119             source => "puppet:///modules/debian-org/dsa-puppet-stuff.cron.ignore",
 120             require => Package["debian.org"]
 121             ;
 122     }
 123
 124     # set mmap_min_addr to 4096 to mitigate
 125     # Linux NULL-pointer dereference exploits
 126     sysctl {
 127         "mmap_min_addr" :
 128             key         => "vm.mmap_min_addr",
 129             value       => 4096,
 130     }
 131
 132     set_alternatives {
 133         "editor":
 134             linkto => "/usr/bin/vim.basic",
 135     }
 136
 137     mailalias {
 138         "samhain-reports":
 139             recipient => $debianadmin,
 140             ensure => present;
 141     }
 142
 143     exec {
 144         "dpkg-reconfigure tzdata -pcritical -fnoninteractive":
 145             path        => "/usr/bin:/usr/sbin:/bin:/sbin",
 146             refreshonly => true;
 147         "apt-get update":
 148             command => 'apt-get update',
 149             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 150             refreshonly => true;
 151         "puppetmaster restart":
 152             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 153             refreshonly => true;
 154         "rc.local start":
 155             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 156             refreshonly => true;
 157         "procps restart":
 158             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 159             refreshonly => true;
 160         "init q":
 161             refreshonly => true;
 162     }
 163 }
 164
 165 class debian-proliant inherits debian-org {
 166     package {
 167         "hpacucli": ensure => installed;
 168         "hp-health": ensure => installed;
 169         "arrayprobe": ensure => installed;
 170     }
 171     case getfromhash($nodeinfo, 'squeeze') {
 172         true: {}
 173         default: {
 174             package {
 175                 "cpqarrayd": ensure => installed;
 176             }
 177         }
 178     }
 179     case $debarchitecture {
 180         "amd64": {
 181             package { "lib32gcc1": ensure => installed; }
 182         }
 183     }
 184     file {
 185         "/etc/apt/sources.list.d/debian.restricted.list":
 186             content => template("debian-org/etc/apt/sources.list.d/debian.restricted.list.erb"),
 187             notify  => Exec["apt-get update"];
 188     }
 189 }
 190
 191 class debian-radvd inherits debian-org {
 192     sysctl {
 193         "dsa-accept-ra-default" :
 194             key         => "net.ipv6.conf.default.accept_ra",
 195             value       => 0,
 196     }
 197     sysctl {
 198         "dsa-accept-ra-all" :
 199             key         => "net.ipv6.conf.all.accept_ra",
 200             value       => 0,
 201     }
 202 }
 203 # vim:set et:
 204 # vim:set sts=4 ts=4:
 205 # vim:set shiftwidth=4: