modules/debian-org/manifests/init.pp

   1 class debian-org {
   2
   3         $debianadmin = [
   4                 'debian-archive-debian-samhain-reports@master.debian.org',
   5                 'debian-admin@ftbfs.de',
   6                 'weasel@debian.org',
   7                 'steve@lobefin.net',
   8                 'paravoid@debian.org'
   9         ]
  10
  11         package { [
  12                         'klogd',
  13                         'sysklogd',
  14                         'rsyslog',
  15                 ]:
  16                 ensure => purged,
  17         }
  18         package { [
  19                         'debian.org',
  20                         'dsa-munin-plugins',
  21                 ]:
  22                 ensure => installed,
  23                 require => [
  24                         File['/etc/apt/sources.list.d/db.debian.org.list'],
  25                         Exec['apt-get update']
  26                 ]
  27         }
  28         package { [
  29                         'apt-utils',
  30                         'bash-completion',
  31                         'dnsutils',
  32                         'less',
  33                         'lsb-release',
  34                         'libfilesystem-ruby1.8',
  35                         'molly-guard',
  36                         'mtr-tiny',
  37                         'nload',
  38                         'pciutils',
  39                 ]:
  40                 ensure => installed,
  41         }
  42
  43         munin::check { [
  44                         'cpu',
  45                         'entropy',
  46                         'forks',
  47                         'interrupts',
  48                         'iostat',
  49                         'irqstats',
  50                         'load',
  51                         'memory',
  52                         'ntp_offset',
  53                         'ntp_states',
  54                         'open_files',
  55                         'open_inodes',
  56                         'processes',
  57                         'swap',
  58                         'uptime',
  59                         'vmstat',
  60                 ]:
  61         }
  62
  63         if getfromhash($site::nodeinfo, 'broken-rtc') {
  64                 package { 'fake-hwclock':
  65                         ensure => installed,
  66                         require => [
  67                                 File['/etc/apt/sources.list.d/db.debian.org.list'],
  68                                 Exec['apt-get update']
  69                         ]
  70                 }
  71         }
  72
  73         # This really means 'not wheezy'
  74
  75         if $::debarchitecture != 'armhf' {
  76                 site::aptrepo { 'security':
  77                         template => 'debian-org/etc/apt/sources.list.d/security.list.erb',
  78                 }
  79                 site::aptrepo { 'backports.debian.org':
  80                         template => 'debian-org/etc/apt/sources.list.d/backports.debian.org.list.erb',
  81                 }
  82                 site::aptrepo { 'volatile':
  83                         template => 'debian-org/etc/apt/sources.list.d/volatile.list.erb',
  84                 }
  85         }
  86         site::aptrepo { 'backports.org':
  87                 ensure => absent,
  88                 keyid => '16BA136C',
  89                 key => 'puppet:///modules/debian-org/backports.org.asc',
  90         }
  91
  92         site::aptrepo { 'debian.org':
  93                 ensure => absent,
  94         }
  95
  96         site::aptrepo { 'db.debian.org':
  97                 template => 'debian-org/etc/apt/sources.list.d/debian.org.list.erb',
  98                 key      => 'puppet:///modules/debian-org/db.debian.org.asc',
  99         }
 100
 101         file { '/etc/facter':
 102                 ensure  => directory,
 103                 purge   => true,
 104                 force   => true,
 105                 recurse => true,
 106                 source  => 'puppet:///files/empty/',
 107         }
 108         file { '/etc/facter/facts.d':
 109                 ensure => directory,
 110         }
 111         file { '/etc/facter/facts.d/debian_facts.yaml':
 112                 content => template('debian-org/debian_facts.yaml.erb')
 113         }
 114         file { '/etc/apt/preferences':
 115                 source => 'puppet:///modules/debian-org/apt.preferences',
 116         }
 117         file { '/etc/apt/trusted-keys.d/':
 118                 ensure => directory,
 119                 purge  => true,
 120         }
 121         file { '/etc/apt/apt.conf.d/local-compression':
 122                 source => 'puppet:///modules/debian-org/apt.conf.d/local-compression',
 123         }
 124         file { '/etc/apt/apt.conf.d/local-recommends':
 125                 source => 'puppet:///modules/debian-org/apt.conf.d/local-recommends',
 126         }
 127         file { '/etc/apt/apt.conf.d/local-pdiffs':
 128                 source => 'puppet:///modules/debian-org/apt.conf.d/local-pdiffs',
 129         }
 130         file { '/etc/timezone':
 131                 source => 'puppet:///modules/debian-org/timezone',
 132                 notify => Exec['dpkg-reconfigure tzdata -pcritical -fnoninteractive'],
 133         }
 134         file { '/etc/puppet/puppet.conf':
 135                 source => 'puppet:///modules/debian-org/puppet.conf',
 136         }
 137         file { '/etc/default/puppet':
 138                 source => 'puppet:///modules/debian-org/puppet.default',
 139         }
 140         file { '/etc/cron.d/dsa-puppet-stuff':
 141                 source => 'puppet:///modules/debian-org/dsa-puppet-stuff.cron',
 142                 require => Package['debian.org'],
 143         }
 144         file { '/etc/ldap/ldap.conf':
 145                 require => Package['debian.org'],
 146                 source => 'puppet:///modules/debian-org/ldap.conf',
 147         }
 148         file { '/etc/pam.d/common-session':
 149                 require => Package['debian.org'],
 150                 content => template('debian-org/pam.common-session.erb'),
 151         }
 152         file { '/etc/pam.d/common-session-noninteractive':
 153                 require => Package['debian.org'],
 154                 content => template('debian-org/pam.common-session-noninteractive.erb'),
 155         }
 156         file { '/etc/rc.local':
 157                 mode   => '0755',
 158                 source => 'puppet:///modules/debian-org/rc.local',
 159                 notify => Exec['rc.local start'],
 160         }
 161         file { '/etc/molly-guard/run.d/15-acquire-reboot-lock':
 162                 mode    => '0755',
 163                 source  => 'puppet:///modules/debian-org/molly-guard-acquire-reboot-lock',
 164                 require => Package['molly-guard'],
 165         }
 166         file { '/etc/dsa':
 167                 ensure => directory,
 168                 mode   => '0755',
 169         }
 170         file { '/etc/dsa/cron.ignore.dsa-puppet-stuff':
 171                 source  => 'puppet:///modules/debian-org/dsa-puppet-stuff.cron.ignore',
 172                 require => Package['debian.org']
 173         }
 174
 175         # set mmap_min_addr to 4096 to mitigate
 176         # Linux NULL-pointer dereference exploits
 177         site::sysctl { 'mmap_min_addr':
 178                 key   => 'vm.mmap_min_addr',
 179                 value => '4096',
 180         }
 181         site::alternative { 'editor':
 182                 linkto => '/usr/bin/vim.basic',
 183         }
 184         site::alternative { 'view':
 185                 linkto => '/usr/bin/vim.basic',
 186         }
 187         mailalias { 'samhain-reports':
 188                 ensure => present,
 189                 recipient => $debianadmin,
 190         }
 191
 192         exec { 'apt-get update':
 193                 path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 194                 refreshonly => true,
 195         }
 196
 197         exec { 'dpkg-reconfigure tzdata -pcritical -fnoninteractive':
 198                 path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 199                 refreshonly => true
 200         }
 201         exec { 'puppetmaster restart':
 202                 path        => '/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin',
 203                 refreshonly => true
 204         }
 205         exec { 'rc.local start':
 206                 path        => '/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin',
 207                 refreshonly => true
 208         }
 209         exec { 'init q':
 210                 refreshonly => true
 211         }
 212 }