modules/debian-org/manifests/init.pp

   1 define sysctl($key, $value, $ensure=present) {
   2     file {
   3         "/etc/sysctl.d/$name.conf":
   4             ensure  => $ensure,
   5             owner   => root,
   6             group   => root,
   7             mode    => 0644,
   8             content => "$key = $value\n",
   9             notify  => Exec["procps restart"],
  10     }
  11 }
  12
  13 define set_alternatives($linkto) {
  14     exec {
  15         "/usr/sbin/update-alternatives --set $name $linkto":
  16             unless => "/bin/sh -c '! [ -e $linkto ] || ! [ -e /etc/alternatives/$name ] || ([ -L /etc/alternatives/$name ] && [ /etc/alternatives/$name -ef $linkto ])'"
  17         }
  18 }
  19
  20 define linux_module ($ensure) {
  21     case $ensure {
  22         present: {
  23             exec { "append_module_${name}":
  24                 command => "echo '${name}' >> /etc/modules",
  25                 unless => "grep -q -F -x '${name}' /etc/modules",
  26             }
  27         }
  28         absent: {
  29             exec { "remove_module_${name}":
  30                 command => "sed -i -e'/^${name}\$/d' /etc/modules",
  31                 onlyif => "grep -q -F -x '${name}' /etc/modules",
  32             }
  33         }
  34         default: {
  35              err("invalid ensure value ${ensure}")
  36          }
  37     }
  38 }
  39
  40
  41 class debian-org {
  42     package {
  43         "apt-utils": ensure => installed;
  44         "bash-completion": ensure => installed;
  45         "bzip2": ensure => installed;
  46         "cron": ensure => installed;
  47         "csh": ensure => installed;
  48         "dnsutils": ensure => installed;
  49         "dsa-munin-plugins": ensure => installed;
  50         "ed": ensure => installed;
  51         "gnupg": ensure => installed;
  52         "klogd": ensure => purged;
  53         "ksh": ensure => installed;
  54         "less": ensure => installed;
  55         "libfilesystem-ruby1.8": ensure => installed;
  56         "libpam-pwdfile": ensure => installed;
  57         "locales-all": ensure => installed;
  58         "mtr-tiny": ensure => installed;
  59         "nload": ensure => installed;
  60         "pciutils": ensure => installed;
  61         "pdksh": ensure => installed;
  62         "rsyslog": ensure => purged;
  63         "sysklogd": ensure => purged;
  64         "syslog-ng": ensure => installed;
  65         "tcsh": ensure => installed;
  66         "userdir-ldap": ensure => installed;
  67         "vim": ensure => installed;
  68         "zsh": ensure => installed;
  69         "logrotate": ensure => installed;
  70     }
  71     file {
  72         "/etc/apt/preferences":
  73             source => "puppet:///modules/debian-org/apt.preferences";
  74         "/etc/apt/sources.list.d/backports.org.list":
  75             content => template("debian-org/etc/apt/sources.list.d/backports.org.list.erb"),
  76             notify  => Exec["apt-get update"];
  77         "/etc/apt/sources.list.d/debian.org.list":
  78             content => template("debian-org/etc/apt/sources.list.d/debian.org.list.erb"),
  79             notify  => Exec["apt-get update"];
  80         "/etc/apt/sources.list.d/security.list":
  81             content => template("debian-org/etc/apt/sources.list.d/security.list.erb"),
  82             notify  => Exec["apt-get update"];
  83         "/etc/apt/sources.list.d/volatile.list":
  84             content => template("debian-org/etc/apt/sources.list.d/volatile.list.erb"),
  85             notify  => Exec["apt-get update"];
  86         "/etc/apt/apt.conf.d/local-recommends":
  87             source => "puppet:///modules/debian-org/apt.conf.d/local-recommends";
  88         "/etc/apt/apt.conf.d/local-pdiffs":
  89             source => "puppet:///modules/debian-org/apt.conf.d/local-pdiffs";
  90         "/etc/timezone":
  91             source => "puppet:///modules/debian-org/timezone",
  92             notify => Exec["dpkg-reconfigure tzdata -pcritical -fnoninteractive"];
  93         "/etc/puppet/puppet.conf":
  94             # require => Package["puppet"],
  95             source => "puppet:///modules/debian-org/puppet.conf"
  96             ;
  97         "/etc/default/puppet":
  98             # require => Package["puppet"],
  99             source => "puppet:///modules/debian-org/puppet.default"
 100             ;
 101
 102         "/etc/cron.d/dsa-puppet-stuff":
 103             source => "puppet:///modules/debian-org/dsa-puppet-stuff.cron",
 104             require => Package["cron"]
 105             ;
 106         "/etc/ldap/ldap.conf":
 107             require => Package["userdir-ldap"],
 108             source => "puppet:///modules/debian-org/ldap.conf",
 109             ;
 110         "/etc/pam.d/common-session":
 111             require => Package["libpam-pwdfile"],
 112             content => template("debian-org/pam.common-session.erb"),
 113             ;
 114         "/etc/rc.local":
 115             mode   => 0755,
 116             source => "puppet:///modules/debian-org/rc.local",
 117             notify => Exec["rc.local start"],
 118             ;
 119     }
 120
 121     # set mmap_min_addr to 4096 to mitigate
 122     # Linux NULL-pointer dereference exploits
 123     sysctl {
 124         "mmap_min_addr" :
 125             key         => "vm.mmap_min_addr",
 126             value       => 4096,
 127     }
 128
 129     set_alternatives {
 130         "editor":
 131             linkto => "/usr/bin/vim.basic",
 132     }
 133
 134     exec {
 135         "dpkg-reconfigure tzdata -pcritical -fnoninteractive":
 136             path        => "/usr/bin:/usr/sbin:/bin:/sbin",
 137             refreshonly => true;
 138         "apt-get update":
 139             command => 'apt-get update',
 140             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 141             refreshonly => true;
 142         "puppetmaster restart":
 143             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 144             refreshonly => true;
 145         "rc.local start":
 146             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 147             refreshonly => true;
 148         "procps restart":
 149             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 150             refreshonly => true;
 151         "init q":
 152             refreshonly => true;
 153     }
 154 }
 155
 156 class debian-proliant inherits debian-org {
 157     package {
 158         "hpacucli": ensure => installed;
 159         "hp-health": ensure => installed;
 160         "arrayprobe": ensure => installed;
 161     }
 162     case getfromhash($nodeinfo, 'squeeze') {
 163         true: {}
 164         default: {
 165             package {
 166                 "cpqarrayd": ensure => installed;
 167             }
 168         }
 169     }
 170     case $debarchitecture {
 171         "amd64": {
 172             package { "lib32gcc1": ensure => installed; }
 173         }
 174     }
 175     file {
 176         "/etc/apt/sources.list.d/debian.restricted.list":
 177             content => template("debian-org/etc/apt/sources.list.d/debian.restricted.list.erb"),
 178             notify  => Exec["apt-get update"];
 179     }
 180 }
 181
 182 class debian-radvd inherits debian-org {
 183     sysctl {
 184         "dsa-accept-ra-default" :
 185             key         => "net.ipv6.conf.default.accept_ra",
 186             value       => 0,
 187     }
 188     sysctl {
 189         "dsa-accept-ra-all" :
 190             key         => "net.ipv6.conf.all.accept_ra",
 191             value       => 0,
 192     }
 193 }
 194 # vim:set et:
 195 # vim:set sts=4 ts=4:
 196 # vim:set shiftwidth=4: