modules/debian-org/manifests/init.pp

   1 class debian-org {
   2
   3         $debianadmin = [
   4                 'debian-archive-debian-samhain-reports@master.debian.org',
   5                 'debian-admin@ftbfs.de',
   6                 'weasel@debian.org',
   7                 'steve@lobefin.net',
   8                 'paravoid@debian.org'
   9         ]
  10
  11         package { [
  12                         'klogd',
  13                         'sysklogd',
  14                         'rsyslog',
  15                 ]:
  16                 ensure => purged,
  17         }
  18         package { [
  19                         'debian.org',
  20                         'dsa-munin-plugins',
  21                 ]:
  22                 ensure => installed,
  23                 require => [
  24                         File['/etc/apt/sources.list.d/db.debian.org.list'],
  25                         Exec['apt-get update']
  26                 ]
  27         }
  28         package { [
  29                         'apt-utils',
  30                         'bash-completion',
  31                         'dnsutils',
  32                         'less',
  33                         'lsb-release',
  34                         'libfilesystem-ruby1.8',
  35                         'mtr-tiny',
  36                         'nload',
  37                         'pciutils',
  38                 ]:
  39                 ensure => installed,
  40         }
  41
  42         munin::check { [
  43                         'cpu',
  44                         'entropy',
  45                         'forks',
  46                         'interrupts',
  47                         'iostat',
  48                         'irqstats',
  49                         'load',
  50                         'memory',
  51                         'ntp_offset',
  52                         'ntp_states',
  53                         'open_files',
  54                         'open_inodes',
  55                         'processes',
  56                         'swap',
  57                         'uptime',
  58                         'vmstat',
  59                 ]:
  60         }
  61
  62         if getfromhash($site::nodeinfo, 'broken-rtc') {
  63                 package { 'fake-hwclock':
  64                         ensure => installed,
  65                         require => [
  66                                 File['/etc/apt/sources.list.d/db.debian.org.list'],
  67                                 Exec['apt-get update']
  68                         ]
  69                 }
  70         }
  71
  72         package { 'molly-guard':
  73                 ensure => installed,
  74         }
  75         file { '/etc/molly-guard/run.d/10-check-kvm':
  76                 mode    => '0755',
  77                 source  => 'puppet:///modules/debian-org/molly-guard/10-check-kvm',
  78                 require => Package['molly-guard'],
  79         }
  80         file { '/etc/molly-guard/run.d/15-acquire-reboot-lock':
  81                 mode    => '0755',
  82                 source  => 'puppet:///modules/debian-org/molly-guard/15-acquire-reboot-lock',
  83                 require => Package['molly-guard'],
  84         }
  85
  86         # This really means 'not wheezy'
  87
  88         if $::debarchitecture != 'armhf' {
  89                 site::aptrepo { 'security':
  90                         url        => 'http://security.debian.org/',
  91                         suite      => "${::lsbdistcodename}/updates",
  92                         components => ['main','contrib','non-free']
  93                 }
  94
  95                 site::aptrepo { 'backports.debian.org':
  96                         url        => 'http://backports.debian.org/debian-backports/',
  97                         suite      => "${::lsbdistcodename}-backports",
  98                         components => ['main','contrib','non-free']
  99                 }
 100
 101                 site::aptrepo { 'volatile':
 102                         url        => 'http://ftp.debian.org/debian',
 103                         suite      => "${::lsbdistcodename}-updates",
 104                         components => ['main','contrib','non-free']
 105                 }
 106         }
 107         site::aptrepo { 'backports.org':
 108                 ensure => absent,
 109                 keyid => '16BA136C',
 110                 key => 'puppet:///modules/debian-org/backports.org.asc',
 111         }
 112
 113         site::aptrepo { 'debian.org':
 114                 ensure => absent,
 115         }
 116
 117         site::aptrepo { 'db.debian.org':
 118                 url        => 'http://db.debian.org/debian-admin',
 119                 suite      => 'lenny',
 120                 components => 'main',
 121                 key        => 'puppet:///modules/debian-org/db.debian.org.asc',
 122         }
 123
 124         file { '/etc/facter':
 125                 ensure  => directory,
 126                 purge   => true,
 127                 force   => true,
 128                 recurse => true,
 129                 source  => 'puppet:///files/empty/',
 130         }
 131         file { '/etc/facter/facts.d':
 132                 ensure => directory,
 133         }
 134         file { '/etc/facter/facts.d/debian_facts.yaml':
 135                 content => template('debian-org/debian_facts.yaml.erb')
 136         }
 137         file { '/etc/apt/preferences':
 138                 source => 'puppet:///modules/debian-org/apt.preferences',
 139         }
 140         file { '/etc/apt/trusted-keys.d/':
 141                 ensure => directory,
 142                 purge  => true,
 143         }
 144         file { '/etc/apt/apt.conf.d/local-compression':
 145                 source => 'puppet:///modules/debian-org/apt.conf.d/local-compression',
 146         }
 147         file { '/etc/apt/apt.conf.d/local-recommends':
 148                 source => 'puppet:///modules/debian-org/apt.conf.d/local-recommends',
 149         }
 150         file { '/etc/apt/apt.conf.d/local-pdiffs':
 151                 source => 'puppet:///modules/debian-org/apt.conf.d/local-pdiffs',
 152         }
 153         file { '/etc/timezone':
 154                 source => 'puppet:///modules/debian-org/timezone',
 155                 notify => Exec['dpkg-reconfigure tzdata -pcritical -fnoninteractive'],
 156         }
 157         file { '/etc/puppet/puppet.conf':
 158                 content => template('debian-org/puppet.conf.erb'),
 159         }
 160         file { '/etc/default/puppet':
 161                 source => 'puppet:///modules/debian-org/puppet.default',
 162         }
 163         file { '/etc/cron.d/dsa-puppet-stuff':
 164                 source => 'puppet:///modules/debian-org/dsa-puppet-stuff.cron',
 165                 require => Package['debian.org'],
 166         }
 167         file { '/etc/ldap/ldap.conf':
 168                 require => Package['debian.org'],
 169                 source => 'puppet:///modules/debian-org/ldap.conf',
 170         }
 171         file { '/etc/pam.d/common-session':
 172                 require => Package['debian.org'],
 173                 content => template('debian-org/pam.common-session.erb'),
 174         }
 175         file { '/etc/pam.d/common-session-noninteractive':
 176                 require => Package['debian.org'],
 177                 content => template('debian-org/pam.common-session-noninteractive.erb'),
 178         }
 179         file { '/etc/rc.local':
 180                 mode   => '0755',
 181                 source => 'puppet:///modules/debian-org/rc.local',
 182                 notify => Exec['rc.local start'],
 183         }
 184         file { '/etc/dsa':
 185                 ensure => directory,
 186                 mode   => '0755',
 187         }
 188         file { '/etc/dsa/cron.ignore.dsa-puppet-stuff':
 189                 source  => 'puppet:///modules/debian-org/dsa-puppet-stuff.cron.ignore',
 190                 require => Package['debian.org']
 191         }
 192
 193         # set mmap_min_addr to 4096 to mitigate
 194         # Linux NULL-pointer dereference exploits
 195         site::sysctl { 'mmap_min_addr':
 196                 key   => 'vm.mmap_min_addr',
 197                 value => '4096',
 198         }
 199         site::alternative { 'editor':
 200                 linkto => '/usr/bin/vim.basic',
 201         }
 202         site::alternative { 'view':
 203                 linkto => '/usr/bin/vim.basic',
 204         }
 205         mailalias { 'samhain-reports':
 206                 ensure => present,
 207                 recipient => $debianadmin,
 208                 require => Package['debian.org']
 209         }
 210
 211         exec { 'apt-get update':
 212                 path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 213                 refreshonly => true,
 214         }
 215
 216         exec { 'dpkg-reconfigure tzdata -pcritical -fnoninteractive':
 217                 path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 218                 refreshonly => true
 219         }
 220         exec { 'puppetmaster restart':
 221                 path        => '/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin',
 222                 refreshonly => true
 223         }
 224         exec { 'rc.local start':
 225                 path        => '/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin',
 226                 refreshonly => true
 227         }
 228         exec { 'init q':
 229                 refreshonly => true
 230         }
 231 }