modules/buildd/manifests/init.pp

   1 class buildd ($ensure=present) {
   2
   3         include schroot
   4
   5         package { 'sbuild':
   6                 ensure => installed,
   7                 tag    => extra_repo,
   8         }
   9         package { 'libsbuild-perl':
  10                 ensure => installed,
  11                 tag    => extra_repo,
  12                 before => Package['sbuild']
  13         }
  14
  15         package { 'apt-transport-https':
  16                 ensure => installed,
  17         }
  18         if $ensure == present {
  19                 package { 'dupload':
  20                         ensure => installed,
  21                 }
  22                 file { '/etc/dupload.conf':
  23                         source  => 'puppet:///modules/buildd/dupload.conf',
  24                         require => Package['dupload'],
  25                 }
  26                 site::linux_module { 'dm_snapshot': }
  27                 include ferm::ftp_conntrack
  28         }
  29
  30         site::aptrepo { 'buildd':
  31                 ensure => absent,
  32         }
  33
  34         $suite = $::lsbdistcodename ? {
  35                 squeeze => $::lsbdistcodename,
  36                 wheezy  => $::lsbdistcodename,
  37                 undef   => 'squeeze',
  38                 default => 'wheezy'
  39         }
  40
  41         site::aptrepo { 'buildd.debian.org':
  42                 key        => 'puppet:///modules/buildd/buildd.debian.org.asc',
  43                 url        => 'https://buildd.debian.org/apt/',
  44                 suite      => $suite,
  45                 components => 'main',
  46                 require    => Package['apt-transport-https'],
  47         }
  48
  49         $buildd_prop_ensure = $::hostname ? {
  50                 /^(alkman|barber|brahms|porpora|zandonai)$/ => 'present',
  51                 default => 'absent',
  52         }
  53
  54         site::aptrepo { 'buildd.debian.org-proposed':
  55                 ensure     => $buildd_prop_ensure,
  56                 url        => 'https://buildd.debian.org/apt/',
  57                 suite      => "${suite}-proposed",
  58                 components => 'main',
  59                 require    => Package['apt-transport-https'],
  60         }
  61
  62         # 'bad' extension
  63         file { '/etc/apt/preferences.d/buildd.debian.org':
  64                 ensure => absent,
  65         }
  66         file { '/etc/apt/preferences.d/buildd':
  67                 ensure => absent,
  68         }
  69         file { '/etc/cron.d/dsa-buildd':
  70                 source  => 'puppet:///modules/buildd/cron.d-dsa-buildd',
  71                 require => Package['debian.org']
  72         }
  73
  74         if ($::lsbmajdistrelease >= 7 and $::kernel == 'Linux') {
  75                 package { 'python-psutil':
  76                         ensure => installed,
  77                 }
  78                 file { '/usr/local/sbin/buildd-schroot-aptitude-kill':
  79                         source  => 'puppet:///modules/buildd/buildd-schroot-aptitude-kill',
  80                         mode    => '0555',
  81                 }
  82         } else {
  83                 file { '/usr/local/sbin/buildd-schroot-aptitude-kill':
  84                         source  => 'puppet:///modules/buildd/buildd-schroot-aptitude-kill.squeeze',
  85                         mode    => '0555',
  86                 }
  87         }
  88         file { '/etc/cron.d/puppet-buildd-aptitude':
  89                 content => "*/5 * * * * root /usr/local/sbin/buildd-schroot-aptitude-kill\n",
  90         }
  91 }