modules/apache2/manifests/init.pp

   1 # = Class: apache2
   2 #
   3 # Standard apache config debian.org hosts
   4 #
   5 # == Sample Usage:
   6 #
   7 #   include apache2
   8 #
   9 class apache2 {
  10         package { 'apache2':
  11                 ensure => installed,
  12         }
  13
  14         service { 'apache2':
  15                 ensure  => running,
  16                 require => Package['apache2'],
  17         }
  18
  19         apache2::module { 'info': }
  20         apache2::module { 'status': }
  21         apache2::module { 'headers': }
  22
  23         package { 'libapache2-mod-macro':
  24                 ensure => installed
  25         }
  26
  27         apache2::module { 'macro':
  28                 require => Package['libapache2-mod-macro']
  29         }
  30
  31         apache2::site { '00-default':
  32                 site     => 'default-debian.org',
  33                 content  => template('apache2/default-debian.org.erb'),
  34         }
  35
  36         apache2::site { '000-default':
  37                 ensure => absent,
  38         }
  39
  40         apache2::config { 'serve-cgi-bin':
  41                 ensure => absent,
  42         }
  43
  44         apache2::config { 'ressource-limits':
  45                 ensure => absent,
  46         }
  47
  48         if has_role('udd') {
  49                 $memlimit = 512 * 1024 * 1024
  50         } else {
  51                 $memlimit = 192 * 1024 * 1024
  52         }
  53
  54         apache2::config { 'resource-limits':
  55                 content => template('apache2/resource-limits.erb'),
  56         }
  57
  58         apache2::config { 'security':
  59                 source => 'puppet:///modules/apache2/security',
  60         }
  61
  62         apache2::config { 'logformat-privacy':
  63                 source => 'puppet:///modules/apache2/logformat-privacy',
  64         }
  65
  66         apache2::config { 'local-serverinfo':
  67                 source => 'puppet:///modules/apache2/local-serverinfo',
  68         }
  69
  70         apache2::config { 'server-status':
  71                 source => 'puppet:///modules/apache2/server-status',
  72         }
  73
  74         apache2::config { 'puppet-ssl-macros':
  75                 source => 'puppet:///modules/apache2/puppet-ssl-macros',
  76         }
  77
  78         apache2::config { 'puppet-config':
  79                 content => template('apache2/puppet-config.erb'),
  80         }
  81
  82         apache2::config { 'pratchett':
  83                 source => 'puppet:///modules/apache2/pratchett',
  84         }
  85
  86         if $::lsbmajdistrelease > 7 {
  87                 file { '/etc/apache2/mods-available/mpm_worker.conf':
  88                         content => template('apache2/mpm_worker.erb'),
  89                 }
  90         }
  91
  92         file { '/etc/apache2/sites-available/common-ssl.inc':
  93                 ensure => absent,
  94         }
  95
  96         file { '/etc/logrotate.d/apache2':
  97                 source => 'puppet:///modules/apache2/apache2.logrotate',
  98         }
  99
 100         file { [ '/srv/www', '/srv/www/default.debian.org', '/srv/www/default.debian.org/htdocs' ]:
 101                 ensure  => directory,
 102                 mode    => '0755',
 103         }
 104
 105         file { '/srv/www/default.debian.org/htdocs/index.html':
 106                 content => template('apache2/default-index.html'),
 107         }
 108
 109         file { '/var/log/apache2/.nobackup':
 110                 mode    => '0644',
 111                 content => '',
 112         }
 113
 114         munin::check { 'apache_accesses': }
 115         munin::check { 'apache_processes': }
 116         munin::check { 'apache_volume': }
 117         munin::check { 'apache_servers': }
 118         munin::check { 'ps_apache2':
 119                 script => 'ps_',
 120         }
 121
 122         if $::hostname in [beach,buxtehude,picconi,pkgmirror-1and1] {
 123                 include apache2::dynamic
 124         } else {
 125                 @ferm::rule { 'dsa-http':
 126                         prio        => '23',
 127                         description => 'Allow web access',
 128                         rule        => '&SERVICE(tcp, (http https))'
 129                 }
 130         }
 131
 132         @ferm::rule { 'dsa-http-v6':
 133                 domain          => '(ip6)',
 134                 prio            => '23',
 135                 description     => 'Allow web access',
 136                 rule            => '&SERVICE(tcp, (http https))'
 137         }
 138 }