modules/apache2/manifests/init.pp

   1 # = Class: apache2
   2 #
   3 # Standard apache config debian.org hosts
   4 #
   5 # == Sample Usage:
   6 #
   7 #   include apache2
   8 #
   9 class apache2 {
  10         package { 'apache2':
  11                 ensure => installed,
  12         }
  13
  14         service { 'apache2':
  15                 ensure  => running,
  16                 require => Package['apache2'],
  17         }
  18
  19         apache2::module { 'info': }
  20         apache2::module { 'status': }
  21         apache2::module { 'headers': }
  22
  23         package { 'libapache2-mod-macro':
  24                 ensure => installed
  25         }
  26
  27         apache2::module { 'macro':
  28                 require => Package['libapache2-mod-macro']
  29         }
  30
  31         apache2::site { '00-default':
  32                 site     => 'default-debian.org',
  33                 content  => template('apache2/default-debian.org.erb'),
  34         }
  35
  36         apache2::site { '000-default':
  37                 ensure => absent,
  38         }
  39
  40         apache2::config { 'serve-cgi-bin':
  41                 ensure => absent,
  42         }
  43
  44         apache2::config { 'ressource-limits':
  45                 ensure => absent,
  46         }
  47
  48         if has_role('buildd_master') {
  49                 $memlimit = 192 * 1024 * 1024
  50         } elsif has_role('buildd_ports_master') {
  51                 $memlimit = 192 * 1024 * 1024
  52         } elsif has_role('nagiosmaster') {
  53                 $memlimit = 96 * 1024 * 1024
  54         } elsif has_role('packagesqamaster') {
  55                 $memlimit = 192 * 1024 * 1024
  56         } elsif has_role('nm') {
  57                 $memlimit = 96 * 1024 * 1024
  58         } elsif has_role('udd') {
  59                 $memlimit = 512 * 1024 * 1024
  60         } elsif has_role('soo') {
  61                 $memlimit = 192 * 1024 * 1024
  62         } else {
  63                 $memlimit = 64 * 1024 * 1024
  64         }
  65
  66         apache2::config { 'resource-limits':
  67                 content => template('apache2/resource-limits.erb'),
  68         }
  69
  70         apache2::config { 'security':
  71                 source => 'puppet:///modules/apache2/security',
  72         }
  73
  74         apache2::config { 'logformat-privacy':
  75                 source => 'puppet:///modules/apache2/logformat-privacy',
  76         }
  77
  78         apache2::config { 'local-serverinfo':
  79                 source => 'puppet:///modules/apache2/local-serverinfo',
  80         }
  81
  82         apache2::config { 'server-status':
  83                 source => 'puppet:///modules/apache2/server-status',
  84         }
  85
  86         apache2::config { 'puppet-ssl-macros':
  87                 source => 'puppet:///modules/apache2/puppet-ssl-macros',
  88         }
  89
  90         apache2::config { 'puppet-config':
  91                 content => template('apache2/puppet-config.erb'),
  92         }
  93
  94         apache2::config { 'pratchett':
  95                 source => 'puppet:///modules/apache2/pratchett',
  96         }
  97
  98         if $::lsbmajdistrelease > 7 {
  99                 file { '/etc/apache2/mods-available/mpm_worker.conf':
 100                         content => template('apache2/mpm_worker.erb'),
 101                 }
 102         }
 103
 104         file { '/etc/apache2/sites-available/common-ssl.inc':
 105                 ensure => absent,
 106         }
 107
 108         file { '/etc/logrotate.d/apache2':
 109                 source => 'puppet:///modules/apache2/apache2.logrotate',
 110         }
 111
 112         file { [ '/srv/www', '/srv/www/default.debian.org', '/srv/www/default.debian.org/htdocs' ]:
 113                 ensure  => directory,
 114                 mode    => '0755',
 115         }
 116
 117         file { '/srv/www/default.debian.org/htdocs/index.html':
 118                 content => template('apache2/default-index.html'),
 119         }
 120
 121         file { '/var/log/apache2/.nobackup':
 122                 mode    => '0644',
 123                 content => '',
 124         }
 125
 126         munin::check { 'apache_accesses': }
 127         munin::check { 'apache_processes': }
 128         munin::check { 'apache_volume': }
 129         munin::check { 'apache_servers': }
 130         munin::check { 'ps_apache2':
 131                 script => 'ps_',
 132         }
 133
 134         if $::hostname in [beach,buxtehude,picconi,pkgmirror-1and1] {
 135                 include apache2::dynamic
 136         } else {
 137                 @ferm::rule { 'dsa-http':
 138                         prio        => '23',
 139                         description => 'Allow web access',
 140                         rule        => '&SERVICE(tcp, (http https))'
 141                 }
 142         }
 143
 144         @ferm::rule { 'dsa-http-v6':
 145                 domain          => '(ip6)',
 146                 prio            => '23',
 147                 description     => 'Allow web access',
 148                 rule            => '&SERVICE(tcp, (http https))'
 149         }
 150 }