3rdparty/modules/rabbitmq/manifests/install/rabbitmqadmin.pp

   1 #
   2 class rabbitmq::install::rabbitmqadmin {
   3
   4   if($rabbitmq::ssl) {
   5     $management_port = $rabbitmq::ssl_management_port
   6   }
   7   else {
   8     $management_port = $rabbitmq::management_port
   9   }
  10
  11   $default_user = $rabbitmq::default_user
  12   $default_pass = $rabbitmq::default_pass
  13   $protocol = $rabbitmq::ssl ? { false => 'http', default => 'https' }
  14
  15   staging::file { 'rabbitmqadmin':
  16     target      => "${rabbitmq::rabbitmq_home}/rabbitmqadmin",
  17     source      => "${protocol}://${default_user}:${default_pass}@localhost:${management_port}/cli/rabbitmqadmin",
  18     curl_option => '-k --noproxy localhost --retry 30 --retry-delay 6',
  19     timeout     => '180',
  20     wget_option => '--no-proxy',
  21     require     => [
  22       Class['rabbitmq::service'],
  23       Rabbitmq_plugin['rabbitmq_management']
  24     ],
  25   }
  26
  27   file { '/usr/local/bin/rabbitmqadmin':
  28     owner   => 'root',
  29     group   => '0',
  30     source  => "${rabbitmq::rabbitmq_home}/rabbitmqadmin",
  31     mode    => '0755',
  32     require => Staging::File['rabbitmqadmin'],
  33   }
  34
  35 }