dh_strip

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_strip - strip executables, shared libraries, and some static libraries
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_strip> [S<I<debhelper options>>] [B<-X>I<item>] [--dbg-package=package] [--keep-debug]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_strip is a debhelper program that is responsible for stripping
  20 executables, shared libraries, and static libraries that are not used for
  21 debugging.
  22
  23 This program examines your package build directories and works out what
  24 to strip on its own. It uses L<file(1)> and file permissions and filenames
  25 to figure out what files are shared libraries (*.so), executable binaries,
  26 and static (lib*.a) and debugging libraries (lib*_g.a, debug/*.so), and
  27 strips each as much as is possible. (Which is not at all for debugging
  28 libraries.) In general it seems to make very good guesses, and will do the
  29 right thing in almost all cases.
  30
  31 Since it is very hard to automatically guess if a file is a
  32 module, and hard to determine how to strip a module, dh_strip does not
  33 currently deal with stripping binary modules such as .o files.
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item B<-X>I<item>, B<--exclude=>I<item>
  40
  41 Exclude files that contain "item" anywhere in their filename from being
  42 stripped. You may use this option multiple times to build up a list of
  43 things to exclude.
  44
  45 =item B<--dbg-package=>I<package>
  46
  47 Causes dh_strip to save debug symbols stripped from the packages it acts on
  48 as independent files in the package build directory of the specified debugging
  49 package.
  50
  51 For example, if your packages are libfoo and foo and you want to include a
  52 foo-dbg package with debugging symbols, use dh_strip --dbg-package=foo-dbg.
  53
  54 Note that this option behaves significantly different in debhelper
  55 compatibility levels 4 and below. Instead of specifying the name of a debug
  56 package to put symbols in, it specifies a package (or packages) which
  57 should have separated debug symbols, and the separated symbols are placed
  58 in packages with "-dbg" added to their name.
  59
  60 =item B<-k>, B<--keep-debug>
  61
  62 Debug symbols will be retained, but split into an independent
  63 file in usr/lib/debug/ in the package build directory. --dbg-package
  64 is easier to use than this option, but this option is more flexible.
  65
  66 =back
  67
  68 =head1 NOTES
  69
  70 If the DEB_BUILD_OPTIONS environment variable contains "nostrip", nothing
  71 will be stripped, in accordance with Debian policy (section 10.1
  72 "Binaries").
  73
  74 =head1 CONFORMS TO
  75
  76 Debian policy, version 3.0.1
  77
  78 =cut
  79
  80 init(options => {
  81         "keep-debug" => \$dh{K_FLAG},
  82 });
  83
  84 # This variable can be used to turn off stripping (see Policy).
  85 if (defined $ENV{DEB_BUILD_OPTIONS} && $ENV{DEB_BUILD_OPTIONS} =~ /nostrip/) {
  86         exit;
  87 }
  88
  89 # I could just use `file $_[0]`, but this is safer
  90 sub get_file_type {
  91         my $file=shift;
  92         open (FILE, '-|') # handle all filenames safely
  93                 || exec('file', $file)
  94                 || die "can't exec file: $!";
  95         my $type=<FILE>;
  96         close FILE;
  97         return $type;
  98 }
  99
 100 # Check if a file is an elf binary, shared library, or static library,
 101 # for use by File::Find. It'll fill the following 3 arrays with anything
 102 # it finds:
 103 my (@shared_libs, @executables, @static_libs);
 104 sub testfile {
 105         return if -l $_ or -d $_; # Skip directories and symlinks always.
 106
 107         # See if we were asked to exclude this file.
 108         # Note that we have to test on the full filename, including directory.
 109         my $fn="$File::Find::dir/$_";
 110         foreach my $f (@{$dh{EXCLUDE}}) {
 111                 return if ($fn=~m/\Q$f\E/);
 112         }
 113
 114         # Is it a debug library in a debug subdir?
 115         return if $fn=~m/debug\/.*\.so/;
 116
 117         # Does its filename look like a shared library?
 118         if (m/.*\.so.*?/) {
 119                 # Ok, do the expensive test.
 120                 my $type=get_file_type($_);
 121                 if ($type=~m/.*ELF.*shared.*/) {
 122                         push @shared_libs, $fn;
 123                         return;
 124                 }
 125         }
 126
 127         # Is it executable? -x isn't good enough, so we need to use stat.
 128         my (undef,undef,$mode,undef)=stat(_);
 129         if ($mode & 0111) {
 130                 # Ok, expensive test.
 131                 my $type=get_file_type($_);
 132                 if ($type=~m/.*ELF.*(executable|shared).*/) {
 133                         push @executables, $fn;
 134                         return;
 135                 }
 136         }
 137
 138         # Is it a static library, and not a debug library?
 139         if (m/lib.*\.a$/ && ! m/.*_g\.a$/) {
 140                 # Is it a binary file, or something else (maybe a liner
 141                 # script on Hurd, for example? I don't use file, because
 142                 # file returns a varity of things on static libraries.
 143                 if (-B $_) {
 144                         push @static_libs, $fn;
 145                         return;
 146                 }
 147         }
 148 }
 149
 150 sub make_debug {
 151         my $file=shift;
 152         my $tmp=shift;
 153         my $desttmp=shift;
 154
 155         # Don't try to copy debug symbols out if the file is already
 156         # stripped.
 157         return unless get_file_type($file) =~ /not stripped/;
 158
 159         my ($base_file)=$file=~/^\Q$tmp\E(.*)/;
 160         my $debug_path=$desttmp."/usr/lib/debug/".$base_file;
 161         my $debug_dir=dirname($debug_path);
 162         if (! -d $debug_dir) {
 163                 doit("install", "-d", $debug_dir);
 164         }
 165         doit("objcopy", "--only-keep-debug", $file, $debug_path);
 166         # No reason for this to be executable.
 167         doit("chmod", 644, $debug_path);
 168         return $debug_path;
 169 }
 170
 171 sub attach_debug {
 172         my $file=shift;
 173         my $debug_path=shift;
 174         doit("objcopy", "--add-gnu-debuglink", $debug_path, $file);
 175 }
 176
 177 foreach my $package (@{$dh{DOPACKAGES}}) {
 178         my $tmp=tmpdir($package);
 179
 180         # Support for keeping the debugging symbols in a detached file.
 181         my $keep_debug=$dh{K_FLAG};
 182         my $debugtmp=$tmp;
 183         if (! compat(4)) {
 184                 if (ref $dh{DEBUGPACKAGES}) {
 185                         $keep_debug=1;
 186                         # Note that it's only an array for the v4 stuff;
 187                         # for v5 only one value is used.
 188                         my $debugpackage=@{$dh{DEBUGPACKAGES}}[0];
 189                         if (! grep { $_ eq $debugpackage } getpackages()) {
 190                                 error("debug package $debugpackage is not listed in the control file");
 191                         }
 192                         $debugtmp=tmpdir($debugpackage);
 193                 }
 194         }
 195         else {
 196                 if (ref $dh{DEBUGPACKAGES} && grep { $_ eq $package } @{$dh{DEBUGPACKAGES}}) {
 197                         $keep_debug=1;
 198                         $debugtmp=tmpdir($package."-dbg");
 199                 }
 200         }
 201
 202         @shared_libs=@executables=@static_libs=();
 203         find(\&testfile,$tmp);
 204
 205         foreach (@shared_libs) {
 206                 my $debug_path = make_debug($_, $tmp, $debugtmp) if $keep_debug;
 207                 # Note that all calls to strip on shared libs
 208                 # *must* inclde the --strip-unneeded.
 209                 doit("strip","--remove-section=.comment",
 210                         "--remove-section=.note","--strip-unneeded",$_);
 211                 attach_debug($_, $debug_path) if defined $debug_path;
 212         }
 213
 214         foreach (@executables) {
 215                 my $debug_path = make_debug($_, $tmp, $debugtmp) if $keep_debug;
 216                 doit("strip","--remove-section=.comment",
 217                         "--remove-section=.note",$_);
 218                 attach_debug($_, $debug_path) if defined $debug_path;
 219         }
 220
 221         foreach (@static_libs) {
 222                 doit("strip","--strip-debug",$_);
 223         }
 224 }
 225
 226 =head1 SEE ALSO
 227
 228 L<debhelper(7)>
 229
 230 This program is a part of debhelper.
 231
 232 =head1 AUTHOR
 233
 234 Joey Hess <joeyh@debian.org>
 235
 236 =cut