dh_strip

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_strip - strip executables, shared libraries, and some static libraries
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_strip> [S<I<debhelper options>>] [B<-X>I<item>] [--dbg-package=package] [--keep-debug]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_strip is a debhelper program that is responsible for stripping
  20 executables, shared libraries, and static libraries that are not used for
  21 debugging.
  22
  23 This program examines your package build directories and works out what
  24 to strip on its own. It uses L<file(1)> and file permissions and filenames
  25 to figure out what files are shared libraries (*.so), executable binaries,
  26 and static (lib*.a) and debugging libraries (lib*_g.a, debug/*.so), and
  27 strips each as much as is possible. (Which is not at all for debugging
  28 libraries.) In general it seems to make very good guesses, and will do the
  29 right thing in almost all cases.
  30
  31 Since it is very hard to automatically guess if a file is a
  32 module, and hard to determine how to strip a module, dh_strip does not
  33 currently deal with stripping binary modules such as .o files.
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item B<-X>I<item>, B<--exclude=>I<item>
  40
  41 Exclude files that contain "item" anywhere in their filename from being
  42 stripped. You may use this option multiple times to build up a list of
  43 things to exclude.
  44
  45 =item B<--dbg-package=>I<package>
  46
  47 Causes dh_strip to save debug symbols stripped from the packages it acts on
  48 as independent files in the package build directory of the specified debugging
  49 package.
  50
  51 For example, if your packages are libfoo and foo and you want to include a
  52 foo-dbg package with debugging symbols, use dh_strip --dbg-package=foo-dbg.
  53
  54 Note that this option behaves significantly different in debhelper
  55 compatibility levels 4 and below. Instead of specifying the name of a debug
  56 package to put symbols in, it specifies a package (or packages) which
  57 should have separated debug symbols, and the separated symbols are placed
  58 in packages with "-dbg" added to their name.
  59
  60 =item B<-k>, B<--keep-debug>
  61
  62 Debug symbols will be retained, but split into an independent
  63 file in usr/lib/debug/ in the package build directory. --dbg-package
  64 is easier to use than this option, but this option is more flexible.
  65
  66 =back
  67
  68 =head1 NOTES
  69
  70 If the DEB_BUILD_OPTIONS environment variable contains "nostrip", nothing
  71 will be stripped, in accordance with Debian policy (section 10.1
  72 "Binaries").
  73
  74 =head1 CONFORMS TO
  75
  76 Debian policy, version 3.0.1
  77
  78 =cut
  79
  80 init();
  81
  82 # This variable can be used to turn off stripping (see Policy).
  83 if (defined $ENV{DEB_BUILD_OPTIONS} && $ENV{DEB_BUILD_OPTIONS} =~ /nostrip/) {
  84         exit;
  85 }
  86
  87 # I could just use `file $_[0]`, but this is safer
  88 sub get_file_type {
  89         my $file=shift;
  90         open (FILE, '-|') # handle all filenames safely
  91                 || exec('file', $file)
  92                 || die "can't exec file: $!";
  93         my $type=<FILE>;
  94         close FILE;
  95         return $type;
  96 }
  97
  98 # Check if a file is an elf binary, shared library, or static library,
  99 # for use by File::Find. It'll fill the following 3 arrays with anything
 100 # it finds:
 101 my (@shared_libs, @executables, @static_libs);
 102 sub testfile {
 103         return if -l $_ or -d $_; # Skip directories and symlinks always.
 104
 105         # See if we were asked to exclude this file.
 106         # Note that we have to test on the full filename, including directory.
 107         my $fn="$File::Find::dir/$_";
 108         foreach my $f (@{$dh{EXCLUDE}}) {
 109                 return if ($fn=~m/\Q$f\E/);
 110         }
 111
 112         # Is it a debug library in a debug subdir?
 113         return if $fn=~m/debug\/.*\.so/;
 114
 115         # Does its filename look like a shared library?
 116         if (m/.*\.so.*?/) {
 117                 # Ok, do the expensive test.
 118                 my $type=get_file_type($_);
 119                 if ($type=~m/.*ELF.*shared.*/) {
 120                         push @shared_libs, $fn;
 121                         return;
 122                 }
 123         }
 124
 125         # Is it executable? -x isn't good enough, so we need to use stat.
 126         my (undef,undef,$mode,undef)=stat(_);
 127         if ($mode & 0111) {
 128                 # Ok, expensive test.
 129                 my $type=get_file_type($_);
 130                 if ($type=~m/.*ELF.*(executable|shared).*/) {
 131                         push @executables, $fn;
 132                         return;
 133                 }
 134         }
 135
 136         # Is it a static library, and not a debug library?
 137         if (m/lib.*\.a$/ && ! m/.*_g\.a$/) {
 138                 # Is it a binary file, or something else (maybe a liner
 139                 # script on Hurd, for example? I don't use file, because
 140                 # file returns a varity of things on static libraries.
 141                 if (-B $_) {
 142                         push @static_libs, $fn;
 143                         return;
 144                 }
 145         }
 146 }
 147
 148 sub make_debug {
 149         my $file=shift;
 150         my $tmp=shift;
 151         my $desttmp=shift;
 152
 153         my ($base_file)=$file=~/^\Q$tmp\E(.*)/;
 154         my $debug_path=$desttmp."/usr/lib/debug/".$base_file;
 155         my $debug_dir=dirname($debug_path);
 156         if (! -d $debug_dir) {
 157                 doit("install", "-d", $debug_dir);
 158         }
 159         if (! -e $debug_path) {
 160                 doit("objcopy", "--only-keep-debug", $file, $debug_path);
 161         }
 162         # No reason for this to be executable.
 163         doit("chmod", 644, $debug_path);
 164         return $debug_path;
 165 }
 166
 167 sub attach_debug {
 168         my $file=shift;
 169         my $debug_path=shift;
 170         doit("objcopy", "--add-gnu-debuglink", $debug_path, $file);
 171 }
 172
 173 foreach my $package (@{$dh{DOPACKAGES}}) {
 174         my $tmp=tmpdir($package);
 175
 176         # Support for keeping the debugging symbols in a detached file.
 177         my $keep_debug=$dh{KEEP_DEBUG};
 178         my $debugtmp=$tmp;
 179         if (! compat(4)) {
 180                 if (ref $dh{DEBUGPACKAGES}) {
 181                         $keep_debug=1;
 182                         # Note that it's only an array for the v4 stuff;
 183                         # for v5 only one value is used.
 184                         $debugtmp=tmpdir(@{$dh{DEBUGPACKAGES}}[0]);
 185                 }
 186         }
 187         else {
 188                 if (ref $dh{DEBUGPACKAGES} && grep { $_ eq $package } @{$dh{DEBUGPACKAGES}}) {
 189                         $keep_debug=1;
 190                         $debugtmp=tmpdir($package."-dbg");
 191                 }
 192         }
 193
 194         @shared_libs=@executables=@static_libs=();
 195         find(\&testfile,$tmp);
 196
 197         foreach (@shared_libs) {
 198                 my $debug_path = make_debug($_, $tmp, $debugtmp) if $keep_debug;
 199                 # Note that all calls to strip on shared libs
 200                 # *must* inclde the --strip-unneeded.
 201                 doit("strip","--remove-section=.comment",
 202                         "--remove-section=.note","--strip-unneeded",$_);
 203                 attach_debug($_, $debug_path) if $keep_debug;
 204         }
 205
 206         foreach (@executables) {
 207                 my $debug_path = make_debug($_, $tmp, $debugtmp) if $keep_debug;
 208                 doit("strip","--remove-section=.comment",
 209                         "--remove-section=.note",$_);
 210                 attach_debug($_, $debug_path) if $keep_debug
 211         }
 212
 213         foreach (@static_libs) {
 214                 doit("strip","--strip-debug",$_);
 215         }
 216 }
 217
 218 =head1 SEE ALSO
 219
 220 L<debhelper(7)>
 221
 222 This program is a part of debhelper.
 223
 224 =head1 AUTHOR
 225
 226 Joey Hess <joeyh@debian.org>
 227
 228 =cut