dh_shlibdeps

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_shlibdeps - calculate shared library dependencies
   6
   7 =cut
   8
   9 use strict;
  10 use Cwd;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_shlibdeps> [S<I<debhelper options>>] [B<-L>I<package>] [B<-l>I<directory>] [B<-X>I<item>] [S<B<--> I<params>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_shlibdeps is a debhelper program that is responsible for calculating
  20 shared library dependencies for packages.
  21
  22 This program is merely a wrapper around L<dpkg-shlibdeps(1)> that calls it
  23 once for each package listed in the control file, passing it
  24 a list of ELF executables and shared libraries it has found.
  25
  26 =head1 OPTIONS
  27
  28 =over 4
  29
  30 =item B<-u>I<params>, B<--dpkg-shlibdeps-params=>I<params>
  31
  32 =item B<--> I<params>
  33
  34 Pass "params" to L<dpkg-shlibdeps(1)>.
  35
  36 =item B<-X>I<item>, B<--exclude=>I<item>
  37
  38 Exclude files that contain "item" anywhere in their filename from being
  39 passed to dpkg-shlibdeps. This will make their dependencies be ignored.
  40 This may be useful in some situations, but use it with caution. This option
  41 may be used more than once to exclude more than one thing.
  42
  43 =item B<-l>I<directory>[:directory:directory:..]
  44
  45 With recent versions of dpkg-shlibdeps, this option is generally not
  46 needed.
  47
  48 Before dpkg-shlibdeps is run, LD_LIBRARY_PATH will have added to it the
  49 specified directory (or directories -- separate with colons). With recent
  50 versions of dpkg-shlibdeps, this is mostly only useful for packages that
  51 build multiple flavors of the same library, or other situations where
  52 the library is installed into a directory not on the regular library search
  53 path.
  54
  55 =item B<-L>I<package>, B<--libpackage=>I<package>
  56
  57 With recent versions of dpkg-shlibdeps, this option is generally not
  58 needed.
  59
  60 Tell dpkg-shlibdeps to use the shlibs file automatically generated by
  61 dh_makeshlibs for the named package instead of the shlibs.local file.
  62
  63 =back
  64
  65 =head1 EXAMPLES
  66
  67 Suppose that your source package produces libfoo1, libfoo-dev, and
  68 libfoo-bin binary packages. libfoo-bin links against libfoo1, and should
  69 depend on it. In your rules file, first run dh_makeshlibs, then dh_shlibdeps:
  70
  71         dh_makeshlibs
  72         dh_shlibdeps
  73
  74 This will have the effect of generating automatically a shlibs file for
  75 libfoo1, and using that file and the libfoo1 library in the
  76 debian/libfoo1/usr/lib directory to calculate shared library dependency
  77 information.
  78
  79 =cut
  80
  81 init();
  82
  83 if ($dh{L_PARAMS}) {
  84         my @paths=();
  85         # Add to existing paths, if set.
  86         push @paths, $ENV{'LD_LIBRARY_PATH'}
  87                 if exists $ENV{'LD_LIBRARY_PATH'};
  88         foreach (split(/:/, $dh{L_PARAMS})) {
  89                 # Force the path absolute.
  90                 if (m:^/:) {
  91                         push @paths, $_;
  92                 }
  93                 else {
  94                         push @paths, "/$_";
  95                 }
  96         }
  97         $dh{L_PARAMS}=join(':', @paths);
  98 }
  99
 100 foreach my $package (@{$dh{DOPACKAGES}}) {
 101         my $tmp=tmpdir($package);
 102         my $ext=pkgext($package);
 103
 104         my @filelist;
 105         my $ff;
 106
 107         # Generate a list of ELF binaries in the package, ignoring any
 108         # we were told to exclude.
 109         my $find_options='';
 110         if (defined($dh{EXCLUDE_FIND}) && $dh{EXCLUDE_FIND} ne '') {
 111                 $find_options="! \\( $dh{EXCLUDE_FIND} \\)";
 112         }
 113         foreach my $file (split(/\n/,`find $tmp -path $tmp/usr/lib/debug -prune -or -type f \\( -perm +111 -or -name "*.so*" \\) $find_options -print`)) {
 114                 # TODO this is slow, optimize. Ie, file can run once on
 115                 # multiple files..
 116                 $ff=`file "$file"`;
 117                 if ($ff=~m/ELF/ && $ff!~/statically linked/) {
 118                         push @filelist,$file;
 119                 }
 120         }
 121
 122         if (@filelist) {
 123                 my @opts;
 124                 if (defined $dh{LIBPACKAGE} && length $dh{LIBPACKAGE}) {
 125                         @opts=("-L".tmpdir($dh{LIBPACKAGE}."/DEBIAN/shlibs"));
 126                 }
 127
 128                 push @opts, "-tudeb" if is_udeb($package);
 129
 130                 my $ld_library_path_orig=$ENV{LD_LIBRARY_PATH};
 131                 if ($dh{L_PARAMS}) {
 132                         $ENV{LD_LIBRARY_PATH}=$dh{L_PARAMS};
 133                         verbose_print("LD_LIBRARY_PATH=$dh{L_PARAMS}");
 134                 }
 135
 136                 doit("dpkg-shlibdeps","-Tdebian/${ext}substvars",
 137                         @opts,@{$dh{U_PARAMS}},@filelist);
 138
 139                 if ($dh{L_PARAMS}) {
 140                         if (defined $ld_library_path_orig) {
 141                                 $ENV{LD_LIBRARY_PATH}=$ld_library_path_orig;
 142                         }
 143                         else {
 144                                 delete $ENV{LD_LIBRARY_PATH};
 145                         }
 146                 }
 147         }
 148 }
 149
 150 =head1 SEE ALSO
 151
 152 L<debhelper(7)>, L<dpkg-shlibdeps(1)>
 153
 154 This program is a part of debhelper.
 155
 156 =head1 AUTHOR
 157
 158 Joey Hess <joeyh@debian.org>
 159
 160 =cut