dh_shlibdeps

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_shlibdeps - calculate shared library dependancies
   6
   7 =cut
   8
   9 use strict;
  10 use Cwd;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15   dh_shlibdeps [debhelper options] [-ldirectory] [-Xitem] [-- params]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_shlibdeps is a debhelper program that is responsible for calculating
  20 shared library dependancies for packages.
  21
  22 This program is merely a wrapper around L<dpkg-shlibdeps(1)> that calls it
  23 once for each package listed in the control file, passing it
  24 a list of ELF executables and shared libraries it has found.
  25
  26 =head1 OPTIONS
  27
  28 =over 4
  29
  30 =item B<-u>I<params>, B<--dpkg-shlibdeps-params=>I<params>
  31
  32 =item B<--> I<params>
  33
  34 Pass "params" to L<dpkg-shlibdeps(1)>.
  35
  36 =item B<-X>I<item>, B<--exclude=>I<item>
  37
  38 Exclude files that contain "item" anywhere in their filename from being
  39 passed to dpkg-shlibdeps. This will make their dependancies be ignored.
  40 This may be useful in some situations, but use it with caution. This option
  41 may be used more than once to exclude more than one thing.
  42
  43 =item B<-l>I<directory>
  44
  45 Before dpkg-shlibdeps is run, LD_LIBRARY_PATH will be set to the specified
  46 directory. This is useful for multi-binary packages where a library
  47 is built in one package and another package contains binaries linked
  48 against said library. Relative paths will be made absolute for the
  49 benefit of dpkg-shlibdeps.
  50
  51 =back
  52
  53 =cut
  54
  55 init();
  56
  57 foreach my $package (@{$dh{DOPACKAGES}}) {
  58         my $tmp=tmpdir($package);
  59         my $ext=pkgext($package);
  60
  61         my @filelist;
  62         my $ff;
  63
  64         # Generate a list of ELF binaries in the package, ignoring any
  65         # we were told to exclude.
  66         my $find_options='';
  67         if (defined($dh{EXCLUDE_FIND}) && $dh{EXCLUDE_FIND} ne '') {
  68                 $find_options="! \\( $dh{EXCLUDE_FIND} \\)";
  69         }
  70         foreach my $file (split(/\n/,`find $tmp -type f \\( -perm +111 -or -name "*.so*" \\) $find_options`)) {
  71                 # TODO: this is slow, optimize. Ie, file can run once on multiple files..
  72                 $ff=`file "$file"`;
  73                 if ($ff=~m/ELF/ && $ff!~/statically linked/) {
  74                         push @filelist,$file;
  75                 }
  76         }
  77
  78         if (@filelist) {
  79                 if ($dh{L_PARAMS}) {
  80                         # Force the path absolute.
  81                         unless ($dh{L_PARAMS}=~m:^/:) {
  82                                 $dh{L_PARAMS}=getcwd()."/$dh{L_PARAMS}";
  83                         }
  84                         $ENV{'LD_LIBRARY_PATH'}=$dh{L_PARAMS};
  85                         verbose_print("LD_LIBRARY_PATH=$dh{L_PARAMS} \\");
  86                 }
  87                 doit("dpkg-shlibdeps","-Tdebian/${ext}substvars",@{$dh{U_PARAMS}},'-dDepends',@filelist);
  88         }
  89 }
  90
  91 =head1 SEE ALSO
  92
  93 L<debhelper(1)>
  94
  95 This program is a part of debhelper.
  96
  97 =head1 AUTHOR
  98
  99 Joey Hess <joeyh@debian.org>
 100
 101 =cut