dh_shlibdeps

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_shlibdeps - calculate shared library dependencies
   6
   7 =cut
   8
   9 use strict;
  10 use Cwd;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_shlibdeps> [S<I<debhelper options>>] [B<-L>I<package>] [B<-l>I<directory>] [B<-X>I<item>] [S<B<--> I<params>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_shlibdeps is a debhelper program that is responsible for calculating
  20 shared library dependencies for packages.
  21
  22 This program is merely a wrapper around L<dpkg-shlibdeps(1)> that calls it
  23 once for each package listed in the control file, passing it
  24 a list of ELF executables and shared libraries it has found.
  25
  26 =head1 OPTIONS
  27
  28 =over 4
  29
  30 =item B<-u>I<params>, B<--dpkg-shlibdeps-params=>I<params>
  31
  32 =item B<--> I<params>
  33
  34 Pass "params" to L<dpkg-shlibdeps(1)>.
  35
  36 =item B<-X>I<item>, B<--exclude=>I<item>
  37
  38 Exclude files that contain "item" anywhere in their filename from being
  39 passed to dpkg-shlibdeps. This will make their dependencies be ignored.
  40 This may be useful in some situations, but use it with caution. This option
  41 may be used more than once to exclude more than one thing.
  42
  43 =item B<-l>I<directory>[:directory:directory:..]
  44
  45 With recent versions of dpkg-shlibdeps, this option is generally not
  46 needed.
  47
  48 Before dpkg-shlibdeps is run, LD_LIBRARY_PATH will have added to it the
  49 specified directory (or directories -- separate with colons). With recent
  50 versions of dpkg-shlibdeps, this is mostly only useful for packages that
  51 build multiple flavors of the same library, or other situations where
  52 the library is installed into a directory not on the regular library search
  53 path.
  54
  55 =item B<-L>I<package>, B<--libpackage=>I<package>
  56
  57 With recent versions of dpkg-shlibdeps, this option is generally not
  58 needed, unless your package builds multiple flavors of the same library.
  59
  60 It tells dpkg-shlibdeps (via its -S parameter) to look first in the package
  61 build directory for the specified package, when searching for libraries,
  62 symbol files, and shlibs files.
  63
  64 =back
  65
  66 =head1 EXAMPLES
  67
  68 Suppose that your source package produces libfoo1, libfoo-dev, and
  69 libfoo-bin binary packages. libfoo-bin links against libfoo1, and should
  70 depend on it. In your rules file, first run dh_makeshlibs, then dh_shlibdeps:
  71
  72         dh_makeshlibs
  73         dh_shlibdeps
  74
  75 This will have the effect of generating automatically a shlibs file for
  76 libfoo1, and using that file and the libfoo1 library in the
  77 debian/libfoo1/usr/lib directory to calculate shared library dependency
  78 information.
  79
  80 If a libbar1 package is also produced, that is an alternate build of
  81 libfoo, and is installed into /usr/lib/bar/, you can make libfoo-bin depend
  82 on libbar1 as follows:
  83
  84         dh_shlibdeps -Llibbar1 -l/usr/lib/bar
  85
  86 =cut
  87
  88 init();
  89
  90 if ($dh{L_PARAMS}) {
  91         my @paths=();
  92         # Add to existing paths, if set.
  93         push @paths, $ENV{'LD_LIBRARY_PATH'}
  94                 if exists $ENV{'LD_LIBRARY_PATH'};
  95         foreach (split(/:/, $dh{L_PARAMS})) {
  96                 # Force the path absolute.
  97                 if (m:^/:) {
  98                         push @paths, $_;
  99                 }
 100                 else {
 101                         push @paths, "/$_";
 102                 }
 103         }
 104         $dh{L_PARAMS}=join(':', @paths);
 105 }
 106
 107 foreach my $package (@{$dh{DOPACKAGES}}) {
 108         my $tmp=tmpdir($package);
 109         my $ext=pkgext($package);
 110
 111         my @filelist;
 112         my $ff;
 113
 114         # Generate a list of ELF binaries in the package, ignoring any
 115         # we were told to exclude.
 116         my $find_options='';
 117         if (defined($dh{EXCLUDE_FIND}) && $dh{EXCLUDE_FIND} ne '') {
 118                 $find_options="! \\( $dh{EXCLUDE_FIND} \\)";
 119         }
 120         foreach my $file (split(/\n/,`find $tmp -type f \\( -perm +111 -or -name "*.so*" \\) $find_options -print`)) {
 121                 # Prune directories that contain separated debug symbols.
 122                 next if $file=~m!^\Q$tmp\E/usr/lib/debug/(lib|lib64|usr|bin|sbin|opt|dev)/!;
 123                 # TODO this is slow, optimize. Ie, file can run once on
 124                 # multiple files..
 125                 $ff=`file "$file"`;
 126                 if ($ff=~m/ELF/ && $ff!~/statically linked/) {
 127                         push @filelist,$file;
 128                 }
 129         }
 130
 131         if (@filelist) {
 132                 my @opts;
 133                 if (defined $dh{LIBPACKAGE} && length $dh{LIBPACKAGE}) {
 134                         @opts=("-S".tmpdir($dh{LIBPACKAGE}));
 135                 }
 136
 137                 push @opts, "-tudeb" if is_udeb($package);
 138
 139                 my $ld_library_path_orig=$ENV{LD_LIBRARY_PATH};
 140                 if ($dh{L_PARAMS}) {
 141                         $ENV{LD_LIBRARY_PATH}=$dh{L_PARAMS};
 142                         verbose_print("LD_LIBRARY_PATH=$dh{L_PARAMS}");
 143                 }
 144
 145                 doit("dpkg-shlibdeps","-Tdebian/${ext}substvars",
 146                         @opts,@{$dh{U_PARAMS}},@filelist);
 147
 148                 if ($dh{L_PARAMS}) {
 149                         if (defined $ld_library_path_orig) {
 150                                 $ENV{LD_LIBRARY_PATH}=$ld_library_path_orig;
 151                         }
 152                         else {
 153                                 delete $ENV{LD_LIBRARY_PATH};
 154                         }
 155                 }
 156         }
 157 }
 158
 159 =head1 SEE ALSO
 160
 161 L<debhelper(7)>, L<dpkg-shlibdeps(1)>
 162
 163 This program is a part of debhelper.
 164
 165 =head1 AUTHOR
 166
 167 Joey Hess <joeyh@debian.org>
 168
 169 =cut