dh_python

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_python - calculates python dependencies and adds postinst and prerm python scripts
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_python> [S<I<debhelper options>>] [B<-n>] [B<-V> I<version>] [S<I<module dirs ...>>]
  16
  17 =head1 DESCRIPTION
  18
  19 Note: This program is deprecated. You should use dh_pysupport or
  20 dh_pycentral instead. This program will do nothing if debian/pycompat
  21 exists.
  22
  23 dh_python is a debhelper program that is responsible for generating the
  24 ${python:Depends} substitutions and adding them to substvars files. It
  25 will also add a postinst and a prerm script if required.
  26
  27 The program will look at python scripts and modules in your package, and
  28 will use this information to generate a dependency on python, with the
  29 current major version, or on pythonX.Y if your scripts or modules need a
  30 specific python version. The dependency will be substituted into your
  31 package's control file wherever you place the token "${python:Depends}".
  32
  33 If some modules need to be byte-compiled at install time, appropriate
  34 postinst and prerm scripts will be generated. If already byte-compiled
  35 modules are found, they are removed.
  36
  37 If you use this program, your package should build-depend on python.
  38
  39 =head1 OPTIONS
  40
  41 =over 4
  42
  43 =item I<module dirs>
  44
  45 If your package installs python modules in non-standard directories, you
  46 can make dh_python check those directories by passing their names on the
  47 command line. By default, it will check /usr/lib/site-python,
  48 /usr/lib/$PACKAGE, /usr/share/$PACKAGE, /usr/lib/games/$PACKAGE,
  49 /usr/share/games/$PACKAGE and /usr/lib/python?.?/site-packages.
  50
  51 Note: only /usr/lib/site-python, /usr/lib/python?.?/site-packages and the
  52 extra names on the command line are searched for binary (.so) modules.
  53
  54 =item B<-V> I<version>
  55
  56 If the .py files your package ships are meant to be used by a specific
  57 pythonX.Y version, you can use this option to specify the desired version,
  58 such as 2.3. Do not use if you ship modules in /usr/lib/site-python.
  59
  60 =item B<-n>, B<--noscripts>
  61
  62 Do not modify postinst/postrm scripts.
  63
  64 =back
  65
  66 =head1 CONFORMS TO
  67
  68 Debian policy, version 3.5.7
  69
  70 Python policy, version 0.3.7
  71
  72 =cut
  73
  74 init();
  75
  76 if (-e "debian/pycompat") {
  77         warning("Doing nothing since dh_pycompat exists; dh_pysupport or dh_pycentral should do the work. You can remove dh_python from your rules file.");
  78         exit 0;
  79 }
  80
  81 warning("This program is deprecated, you should use dh_pysupport or dh_pycentral instead.");
  82
  83 my $python = 'python';
  84
  85 # The current python major version
  86 my $python_major;
  87 my $python_version = `$python -V 2>&1`;
  88 if (! defined $python_version || $python_version eq "") {
  89         error("Python is not installed, aborting. (Probably forgot to Build-Depend on python.)");
  90 }
  91 elsif ($python_version =~ m/^Python\s+(\d+)\.(\d+)(\.\d+)*/) {
  92         $python_version = "$1.$2" ;
  93         $python_major = $1 ;
  94 } else {
  95         error("Unable to parse python version out of \"$python_version\".");
  96 }
  97
  98 # The next python version
  99 my $python_nextversion = $python_version + 0.1;
 100 my $python_nextmajor = $python_major + 1;
 101
 102 my @python_allversions = ('1.5','2.1','2.2','2.3','2.4');
 103 foreach (@python_allversions) {
 104         s/^/python/;
 105 }
 106
 107 # Check for -V
 108 my $usepython = "python$python_version";
 109 if($dh{V_FLAG_SET}) {
 110         $usepython = $dh{V_FLAG};
 111         $usepython =~ s/^/python/;
 112         if (! grep { $_ eq $usepython } @python_allversions) {
 113                 error("Unknown python version $dh{V_FLAG}");
 114         }
 115 }
 116
 117 # Cleaning the paths given on the command line
 118 foreach (@ARGV) {
 119         s#/$##;
 120         s#^/##;
 121 }
 122
 123 # dependency types
 124 use constant PROGRAM   => 1;
 125 use constant PY_MODULE => 2;
 126 use constant PY_MODULE_NONSTANDARD => 4;
 127 use constant SO_MODULE => 8;
 128 use constant SO_MODULE_NONSTANDARD => 16;
 129
 130 foreach my $package (@{$dh{DOPACKAGES}}) {
 131         my $tmp = tmpdir($package);
 132
 133         delsubstvar($package, "python:Depends");
 134
 135         my @dirs = ("usr/lib/site-python", "usr/lib/$package", "usr/share/$package", "usr/lib/games/$package", "usr/share/games/$package", @ARGV );
 136         my @dirs_so = ("usr/lib/site-python", @ARGV );
 137
 138         my $dep_on_python = 0;
 139         my $strong_dep = 0;
 140         my $look_for_pythonXY = 1;
 141
 142         # First, the case of python-foo and pythonX.Y-foo
 143         if ($package =~ /^python-/) {
 144                 $dep_on_python = 1;
 145                 $strong_dep = 1;
 146                 my $pack = $package;
 147                 $pack =~ s/^python/python$python_version/;
 148                 if (grep { "$_" eq "$pack" } getpackages()) {
 149                         addsubstvar($package, "python:Depends", $pack);
 150                 }
 151         }
 152         if ($package !~ /^python[0-9].[0-9]-/) {
 153                 push @dirs, "usr/lib/$usepython/site-packages";
 154                 push @dirs_so, "usr/lib/$usepython/site-packages";
 155                 $look_for_pythonXY = 0;
 156         }
 157
 158         @dirs = grep -d, map "$tmp/$_", @dirs;
 159         @dirs_so = grep -d, map "$tmp/$_", @dirs_so;
 160
 161         my $deps = 0;
 162         my %verdeps = ();
 163         foreach (@python_allversions) {
 164                 $verdeps{$_} = 0;
 165         }
 166
 167         # Find scripts
 168         find sub {
 169                 return unless -f and (-x or /\.py$/);
 170                 local *F;
 171                 return unless open F, $_;
 172                 if (read F, local $_, 32 and m%^#!\s*/usr/bin/(env\s+)?(python(\d+\.\d+)?)\s%) {
 173                         if ( "python" eq $2 ) {
 174                                 $deps |= PROGRAM;
 175                         } elsif(defined $verdeps{$2}) {
 176                                 $verdeps{$2} |= PROGRAM;
 177                         }
 178                 }
 179                 close F;
 180         }, $tmp;
 181
 182         # Look for python modules
 183         my $dirlist="";
 184         if (@dirs) {
 185                 foreach my $curdir (@dirs) {
 186                         my $has_module = 0;
 187                         $curdir =~ s%^$tmp/%%;
 188                         find sub {
 189                                 return unless -f;
 190                                 if (/\.py$/) {
 191                                         $has_module = 1;
 192                                         doit(("rm","-f",$_."c",$_."o"));
 193                                 }
 194                         }, "$tmp/$curdir" ;
 195                         if ($has_module) {
 196                                 if ($dh{V_FLAG_SET}) {
 197                                         $verdeps{$usepython} |= PY_MODULE_NONSTANDARD;
 198                                 } else {
 199                                         $deps |= PY_MODULE;
 200                                 }
 201                                 $dirlist="$dirlist /$curdir";
 202                         }
 203                 }
 204         }
 205         if (@dirs_so) {
 206                 foreach my $curdir (@dirs_so) {
 207                         my $has_module = 0;
 208                         $curdir =~ s%^$tmp/%%;
 209                         find sub {
 210                                 return unless -f;
 211                                 $has_module = 1 if /\.so$/;
 212                         }, "$tmp/$curdir" ;
 213                         if ($has_module) {
 214                                 if ($dh{V_FLAG_SET}) {
 215                                         $verdeps{$usepython} |= SO_MODULE_NONSTANDARD;
 216                                 }
 217                                 else {
 218                                         $deps |= SO_MODULE;
 219                                 }
 220                         }
 221                 }
 222         }
 223
 224         # Dependencies on current python
 225         $dep_on_python = 1 if $deps;
 226         $strong_dep = 1 if($deps & (PY_MODULE|SO_MODULE));
 227
 228         if ($dep_on_python) {
 229                 addsubstvar($package, "python:Depends", $python, ">= $python_version");
 230                 if ($strong_dep) {
 231                         addsubstvar($package, "python:Depends", $python, "<< $python_nextversion");
 232                 } else {
 233                         addsubstvar($package, "python:Depends", $python, "<< $python_nextmajor");
 234                 }
 235         }
 236
 237         my $need_prerm = 0;
 238
 239         # Look for specific pythonX.Y modules
 240         foreach my $pyver (@python_allversions) {
 241                 my $pydir="/usr/lib/$pyver/site-packages";
 242                 if ($look_for_pythonXY) {
 243                         if (grep -d,"$tmp$pydir") {
 244                                 find sub {
 245                                         return unless -f;
 246                                         if (/\.py$/) {
 247                                                 $verdeps{$pyver} |= PY_MODULE;
 248                                                 doit(("rm","-f",$_."c",$_."o"));
 249                                         }
 250                                         $verdeps{$pyver} |= SO_MODULE if /\.so$/;
 251                                 }, "$tmp$pydir";
 252                         }
 253                 }
 254
 255                 # Go for the dependencies
 256                 addsubstvar($package, "python:Depends", $pyver) if $verdeps{$pyver};
 257
 258                 # And now, the postinst and prerm stuff
 259                 if ($pyver eq "$usepython") {
 260                         if ($verdeps{$pyver} & PY_MODULE) {
 261                                 $pydir = $pydir.$dirlist;
 262                         } else {
 263                                 $pydir = $dirlist;
 264                         }
 265                         $verdeps{$pyver} |= PY_MODULE if($deps & PY_MODULE);
 266                 }
 267                 if ($verdeps{$pyver} & (PY_MODULE|PY_MODULE_NONSTANDARD) && ! $dh{NOSCRIPTS}) {
 268                         autoscript($package,"postinst","postinst-python","s%#PYVER#%$pyver%;s%#DIRLIST#%$pydir%");
 269                         $need_prerm = 1;
 270                 }
 271         }
 272         if ($need_prerm && ! $dh{NOSCRIPTS}) {
 273                 autoscript($package,"prerm","prerm-python","s%#PACKAGE#%$package%");
 274         }
 275 }
 276
 277 =head1 SEE ALSO
 278
 279 L<debhelper(7)>
 280
 281 This program is a part of debhelper.
 282
 283 =head1 AUTHOR
 284
 285 Josselin Mouette <joss@debian.org>
 286
 287 most ideas stolen from Brendan O'Dea <bod@debian.org>
 288
 289 =cut