dh_makeshlibs

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_makeshlibs - automatically create shlibs file
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14   dh_makeshlibs [debhelper options] [-mmajor] [-V[dependancies]] [-n]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_makeshlibs is a debhelper program that automatically scans for shared
  19 libraries, and generates a shlibs file for the libraries it finds.
  20
  21 It also adds a call to ldconfig in the postinst and postrm scripts (in
  22 DH_COMPAT=3 mode and above only).
  23
  24 =head1 OPTIONS
  25
  26 =over 4
  27
  28 =item B<-m>I<major>, B<--major=>I<major>
  29
  30 Instead of trying to guess the major number of the library with objdump,
  31 use the major number specified after the -m parameter. This is much less
  32 useful than it used to be, back in the bad old days when this program
  33 looked at library filenames rather than using objdump.
  34
  35 =item B<-V>, B<-V>I<dependancies>
  36
  37 =item B<--version-info>, B<--version-info=>I<dependancies>
  38
  39 By default, the shlibs file generated by this program does not make packages
  40 depend on any particular version of the package containing the shared
  41 library. It may be necessary for you to add some version dependancy
  42 information to the shlibs file. If -V is specified with no dependancy
  43 information, the current version of the package is plugged into a
  44 dependancy that looks like "packagename (>= packageversion)". If -V is specified with
  45 parameters, the parameters can be used to specify the exact dependancy
  46 information needed (be sure to include the package name).
  47
  48 =item B<-n>, B<--noscripts>
  49
  50 Do not modify postinst/postrm scripts.
  51
  52 =back
  53
  54 =head1 EXAMPLES
  55
  56  dh_makeshlibs
  57
  58 Assuming this is a package named libfoobar1, generates a shlibs file that
  59 looks something like:
  60  libfoobar 1 libfoobar1
  61
  62  dh_makeshlibs -V
  63
  64 Assuming the current version of the package is 1.0-3, generates a shlibs
  65 file that looks something like:
  66  libfoobar 1 libfoobar1 (>= 1.0-3)
  67
  68  dh_makeshlibs -V 'libfoobar1 (>= 1.0)'
  69
  70 Generates a shlibs file that looks something like:
  71   libfoobar 1 libfoobar1 (>= 1.0)
  72
  73 =cut
  74
  75 init();
  76
  77 foreach my $package (@{$dh{DOPACKAGES}}) {
  78         my $tmp=tmpdir($package);
  79
  80         my %seen;
  81         my $need_ldconfig = 0;
  82
  83         doit("rm", "-f", "$tmp/DEBIAN/shlibs");
  84
  85         # So, we look for files or links to existing files with names that
  86         # match "*.so*". Matching *.so.* is not good enough because of
  87         # broken crap like db3. And we only look at real files not
  88         # symlinks, so we don't accidentually add shlibs data to -dev
  89         # packages. This may have a few false positives, which is ok,
  90         # because only if we can get a library name and a major number from
  91         # objdump is anything actually added.
  92         open (FIND, "find $tmp -type f -name '*.so*' |");
  93         while (<FIND>) {
  94                 my ($library, $major);
  95                 my $objdump=`objdump -p $_`;
  96                 if ($objdump=~m/\s+SONAME\s+(.+)\.so\.(.+)/) {
  97                         # proper soname format
  98                         $library=$1;
  99                         $major=$2;
 100                 }
 101                 elsif ($objdump=~m/\s+SONAME\s+(.+)-(.+)\.so/) {
 102                         # idiotic crap soname format
 103                         $library=$1;
 104                         $major=$2;
 105                 }
 106
 107                 if (defined($dh{M_PARAMS}) && $dh{M_PARAMS} ne '') {
 108                         $major=$dh{M_PARAMS};
 109                 }
 110
 111                 if (! -d "$tmp/DEBIAN") {
 112                         doit("install","-d","$tmp/DEBIAN");
 113                 }
 114                 my $deps=$package;
 115                 if ($dh{V_FLAG_SET}) {
 116                         if ($dh{V_FLAG} ne '') {
 117                                 $deps=$dh{V_FLAG};
 118                         }
 119                         else {
 120                                 # Call isnative becuase it sets $dh{VERSION}
 121                                 # as a side effect.
 122                                 isnative($package);
 123                                 $deps="$package (>= $dh{VERSION})";
 124                         }
 125                 }
 126                 if (defined($library) && defined($major) && defined($deps) &&
 127                     $library ne '' && $major ne '' && $deps ne '') {
 128                         $need_ldconfig=1;
 129                         # Prevent duplicate lines from entering the file.
 130                         my $line="$library $major $deps";
 131                         if (! $seen{$line}) {
 132                                 $seen{$line}=1;
 133                                 complex_doit("echo '$line' >>$tmp/DEBIAN/shlibs");
 134                         }
 135                 }
 136         }
 137         close FIND;
 138
 139         # New as of dh_v3.
 140         if (! compat(2) && ! $dh{NOSCRIPTS} && $need_ldconfig) {
 141                 autoscript($package,"postinst","postinst-makeshlibs");
 142                 autoscript($package,"postrm","postrm-makeshlibs");
 143         }
 144
 145         if (-e "$tmp/DEBIAN/shlibs") {
 146                 doit("chmod",644,"$tmp/DEBIAN/shlibs");
 147                 doit("chown","0.0","$tmp/DEBIAN/shlibs");
 148         }
 149 }
 150
 151 =head1 SEE ALSO
 152
 153 L<debhelper(1)>
 154
 155 This program is a part of debhelper.
 156
 157 =head1 AUTHOR
 158
 159 Joey Hess <joeyh@debian.org>
 160
 161 =cut