dh_makeshlibs

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_makeshlibs - automatically create shlibs file and call dpkg-gensymbols
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_makeshlibs> [S<I<debhelper options>>] [B<-m>I<major>] [B<-V>I<[dependencies]>] [B<-n>] [B<-X>I<item>] [S<B<--> I<params>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_makeshlibs is a debhelper program that automatically scans for shared
  19 libraries, and generates a shlibs file for the libraries it finds.
  20
  21 It also adds a call to ldconfig in the postinst and postrm scripts (in
  22 V3 mode and above only) to any packages in which it finds shared libraries.
  23
  24 If a L<dpkg-gensymbols(1)> symbol file is found in debian/package.symbols
  25 (or debian/package.symbols.arch), dpkg-gensymbols will be called
  26 to process and install the symbols file.
  27
  28 =head1 OPTIONS
  29
  30 =over 4
  31
  32 =item B<-m>I<major>, B<--major=>I<major>
  33
  34 Instead of trying to guess the major number of the library with objdump,
  35 use the major number specified after the -m parameter. This is much less
  36 useful than it used to be, back in the bad old days when this program
  37 looked at library filenames rather than using objdump.
  38
  39 =item B<-V>, B<-V>I<dependencies>
  40
  41 =item B<--version-info>, B<--version-info=>I<dependencies>
  42
  43 By default, the shlibs file generated by this program does not make packages
  44 depend on any particular version of the package containing the shared
  45 library. It may be necessary for you to add some version dependancy
  46 information to the shlibs file. If -V is specified with no dependency
  47 information, the current upstream version of the package is plugged into a
  48 dependency that looks like "packagename (>= packageversion)". Note that in
  49 debhelper compatibility levels before v4, the debian part of the package
  50 version number is also included. If -V is specified with parameters, the
  51 parameters can be used to specify the exact dependency information needed
  52 (be sure to include the package name).
  53
  54 Beware of using -V without any parameters; this is a conservative setting
  55 that always ensures that other packages' shared library dependencies are at
  56 least as tight as they need to be (unless your library is prone to changing
  57 ABI without updating the upstream version number), so that if the
  58 maintainer screws up then they won't break. The flip side is that packages
  59 might end up with dependencies that are too tight and so find it harder to
  60 be upgraded.
  61
  62 =item B<-n>, B<--noscripts>
  63
  64 Do not modify postinst/postrm scripts.
  65
  66 =item B<-X>I<item>, B<--exclude=>I<item>
  67
  68 Exclude files that contain "item" anywhere in their filename or directory
  69 from being treated as shared libraries.
  70
  71 =item B<--add-udeb=>I<udeb>
  72
  73 Create an additional line for udebs in the shlibs file and use "udeb" as the
  74 package name for udebs to depend on instead of the regular library package.
  75
  76 =item B<--> I<params>
  77
  78 Pass "params" to L<dpkg-gensymbols(1)>.
  79
  80 =back
  81
  82 =head1 EXAMPLES
  83
  84 =over 4
  85
  86 =item dh_makeshlibs
  87
  88 Assuming this is a package named libfoobar1, generates a shlibs file that
  89 looks something like:
  90  libfoobar 1 libfoobar1
  91
  92 =item dh_makeshlibs -V
  93
  94 Assuming the current version of the package is 1.1-3, generates a shlibs
  95 file that looks something like:
  96  libfoobar 1 libfoobar1 (>= 1.1)
  97
  98 =item dh_makeshlibs -V 'libfoobar1 (>= 1.0)'
  99
 100 Generates a shlibs file that looks something like:
 101   libfoobar 1 libfoobar1 (>= 1.0)
 102
 103 =back
 104
 105 =cut
 106
 107 init(options => {
 108         "m=s", => \$dh{M_PARAMS},
 109         "major=s" => \$dh{M_PARAMS},
 110         "version-info:s" => \$dh{V_FLAG},
 111 });
 112
 113 foreach my $package (@{$dh{DOPACKAGES}}) {
 114         next if is_udeb($package);
 115
 116         my $tmp=tmpdir($package);
 117
 118         my %seen;
 119         my $need_ldconfig = 0;
 120
 121         doit("rm", "-f", "$tmp/DEBIAN/shlibs");
 122
 123         # So, we look for files or links to existing files with names that
 124         # match "*.so*". Matching *.so.* is not good enough because of
 125         # broken crap like db3. And we only look at real files not
 126         # symlinks, so we don't accidentually add shlibs data to -dev
 127         # packages. This may have a few false positives, which is ok,
 128         # because only if we can get a library name and a major number from
 129         # objdump is anything actually added.
 130         my $exclude='';
 131         my @udeb_lines;
 132         if (defined($dh{EXCLUDE_FIND}) && $dh{EXCLUDE_FIND} ne '') {
 133                 $exclude="! \\( $dh{EXCLUDE_FIND} \\) ";
 134         }
 135         open (FIND, "find $tmp -type f \\( -name '*.so' -or -name '*.so.*' \\) $exclude |");
 136         while (<FIND>) {
 137                 my ($library, $major);
 138                 my $objdump=`objdump -p $_`;
 139                 if ($objdump=~m/\s+SONAME\s+(.+)\.so\.(.+)/) {
 140                         # proper soname format
 141                         $library=$1;
 142                         $major=$2;
 143                 }
 144                 elsif ($objdump=~m/\s+SONAME\s+(.+)-(.+)\.so/) {
 145                         # idiotic crap soname format
 146                         $library=$1;
 147                         $major=$2;
 148                 }
 149
 150                 if (defined($dh{M_PARAMS}) && $dh{M_PARAMS} ne '') {
 151                         $major=$dh{M_PARAMS};
 152                 }
 153
 154                 if (! -d "$tmp/DEBIAN") {
 155                         doit("install","-d","$tmp/DEBIAN");
 156                 }
 157                 my $deps=$package;
 158                 if ($dh{V_FLAG_SET}) {
 159                         if ($dh{V_FLAG} ne '') {
 160                                 $deps=$dh{V_FLAG};
 161                         }
 162                         else {
 163                                 # Call isnative becuase it sets $dh{VERSION}
 164                                 # as a side effect.
 165                                 isnative($package);
 166                                 my $version = $dh{VERSION};
 167                                 # Old compatibility levels include the
 168                                 # debian revision, while new do not.
 169                                 if (! compat(3)) {
 170                                         # Remove debian version, if any.
 171                                         $version =~ s/-[^-]+$//;
 172                                 }
 173                                 $deps="$package (>= $version)";
 174                         }
 175                 }
 176                 if (defined($library) && defined($major) && defined($deps) &&
 177                     $library ne '' && $major ne '' && $deps ne '') {
 178                         $need_ldconfig=1;
 179                         # Prevent duplicate lines from entering the file.
 180                         my $line="$library $major $deps";
 181                         if (! $seen{$line}) {
 182                                 $seen{$line}=1;
 183                                 complex_doit("echo '$line' >>$tmp/DEBIAN/shlibs");
 184                                 if (defined($dh{SHLIBS_UDEB}) && $dh{SHLIBS_UDEB} ne '') {
 185                                         my $udeb_deps = $deps;
 186                                         $udeb_deps =~ s/\Q$package\E/$dh{SHLIBS_UDEB}/e;
 187                                         $line="udeb: "."$library $major $udeb_deps";
 188                                         push @udeb_lines, $line;
 189                                 }
 190                         }
 191                 }
 192         }
 193         close FIND;
 194
 195         # Write udeb: lines last.
 196         foreach (@udeb_lines) {
 197                 complex_doit("echo '$_' >>$tmp/DEBIAN/shlibs");
 198         }
 199
 200         # New as of dh_v3.
 201         if (! compat(2) && ! $dh{NOSCRIPTS} && $need_ldconfig) {
 202                 autoscript($package,"postinst","postinst-makeshlibs");
 203                 autoscript($package,"postrm","postrm-makeshlibs");
 204         }
 205
 206         if (-e "$tmp/DEBIAN/shlibs") {
 207                 doit("chmod",644,"$tmp/DEBIAN/shlibs");
 208                 doit("chown","0:0","$tmp/DEBIAN/shlibs");
 209         }
 210
 211         # dpkg-gensymbols files
 212         my $symbols=pkgfile($package, "symbols");
 213         if (-e $symbols) {
 214                 # -I is used rather than using dpkg-gensymbols
 215                 # own search for symbols files, since that search
 216                 # is not 100% compatible with debhelper. (For example,
 217                 # this supports --ignore being used.)
 218                 doit("dpkg-gensymbols", "-p$package", "-I$symbols",
 219                         "-P$tmp", @{$dh{U_PARAMS}});
 220                 if (-s "$tmp/DEBIAN/symbols" == 0) {
 221                         doit("rm", "-f", "$tmp/DEBIAN/symbols");
 222                 }
 223         }
 224 }
 225
 226 =head1 SEE ALSO
 227
 228 L<debhelper(7)>
 229
 230 This program is a part of debhelper.
 231
 232 =head1 AUTHOR
 233
 234 Joey Hess <joeyh@debian.org>
 235
 236 =cut