dh_installxfonts

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_installxfonts - register X fonts
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_installxfonts> [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_installxfonts is a debhelper program that is responsible for
  19 registering X fonts, so their corresponding fonts.dir, fonts.alias,
  20 and fonts.scale be rebuilt properly at install time.
  21
  22 Before calling this program, you should have installed any X fonts provided
  23 by your package into the appropriate location in the package build
  24 directory, and if you have fonts.alias or fonts.scale files, you should
  25 install them into the correct location under etc/X11/fonts/X11R7 in your
  26 package build directory.
  27
  28 Your package should depend on xfonts-utils so that the
  29 update-fonts-* commands are available. (This program adds that dependency to
  30 ${misc:Depends}.)
  31
  32 This program automatically generates the postinst and postrm commands needed
  33 to register X fonts.  See L<dh_installdeb(1)> for an explanation of how this
  34 works.
  35
  36 =head1 NOTES
  37
  38 See L<update-fonts-alias(8)>, L<update-fonts-scale(8)>, and
  39 L<update-fonts-dir(8)> for more information about X font installation.
  40
  41 See Debian policy, section 11.8.5. for details about doing fonts the Debian
  42 way.
  43
  44 =cut
  45
  46 init();
  47
  48 foreach my $package (@{$dh{DOPACKAGES}}) {
  49         my $tmp=tmpdir($package);
  50
  51         # Find all font directories in the package build directory.
  52         my @fontdirs;
  53         foreach my $parentdir ("$tmp/usr/X11R6/lib/X11/fonts/", "$tmp/usr/share/fonts/X11/") {
  54                 opendir DIR, $parentdir || next;
  55                 @fontdirs = grep { -d "$parentdir/$_" && !/^\./ } (readdir DIR);
  56                 closedir DIR;
  57         }
  58
  59         if (@fontdirs) {
  60                 # Figure out what commands the postinst and postrm will need
  61                 # to call.
  62                 my @cmds;
  63                 foreach my $f (@fontdirs) {
  64                         # This must come before update-fonts-dir.
  65                         push @cmds, "update-fonts-scale --x11r7-layout $f"
  66                                 if -f "$tmp/etc/X11/fonts/X11R7/$f/$package.scale";
  67                         push @cmds, "update-fonts-dir --x11r7-layout $f";
  68                         push @cmds, "update-fonts-alias --x11r7-layout $f"
  69                                 if -f "$tmp/etc/X11/fonts/$f/$package.alias";
  70                 }
  71
  72                 autoscript($package, "postinst", "postinst-xfonts",
  73                         "s:#CMDS#:".join(";", @cmds).":;");
  74                 autoscript($package, "postrm", "postrm-xfonts",
  75                         "s:#CMDS#:".join(";", @cmds).":;");
  76
  77                 addsubstvar($package, "misc:Depends", "xfonts-utils");
  78         }
  79         else {
  80                 # remove
  81                 addsubstvar($package, "misc:Depends", "xfonts-utils", "", 1);
  82         }
  83 }
  84
  85 =head1 SEE ALSO
  86
  87 L<debhelper(7)>
  88
  89 This program is a part of debhelper.
  90
  91 =head1 AUTHOR
  92
  93 Joey Hess <joeyh@debian.org>
  94
  95 =cut