dh_installman

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_installman - install man pages into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_installman> [S<I<debhelper options>>] [S<I<manpage ...>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_installman is a debhelper program that handles installing
  20 man pages into the correct locations in package build directories. You tell
  21 it what man pages go in your packages, and it figures out where to
  22 install them based on the section field in their .TH line. If you have a
  23 properly formatted .TH line, your man page will be installed into the right
  24 directory, with the right name (this includes proper handling of pages
  25 with a subsection, like "3perl", which are placed in man3, and given an
  26 extension of ".3perl"). If your .TH line is incorrect or missing, the program
  27 may guess wrong based on the file extension.
  28
  29 It also supports translated man pages, by looking for extensions
  30 like .ll.8 and .ll_LL.8
  31
  32 If dh_installman seems to install a man page into the wrong section or with
  33 the wrong extension, this is because the man page has the wrong section
  34 listed in its .TH line. Edit the man page and correct the section, and
  35 dh_installman will follow suit.  See to L<man(7)> for details about the .TH
  36 section. If dh_installman seems to install a man page into a directory
  37 like /usr/share/man/pl/man1/, that is because your program has a
  38 name like "foo.pl", and dh_installman assumes that means it is translated
  39 into Polish. There is currently no support for resolving this ambiguity;
  40 programs in debian should proably not have extensions like that anyway.
  41
  42 Any man page filenames specified as parameters will be installed into the
  43 first package dh_installman is told to act on. By default, this is the
  44 first binary package in debian/control, but if you use -p, -i, or -a flags,
  45 it will be the first package specified by those flags.
  46
  47 Files named debian/package.manpages can list other man pages to be
  48 installed.
  49
  50 After the man page installation step, dh_installman will check to see if
  51 any of the man pages in the temporary directories of any of the packages it
  52 is acting on contain ".so" links. If so, it changes them to symlinks.
  53
  54 =head1 OPTIONS
  55
  56 =over 4
  57
  58 =item B<-A>, B<--all>
  59
  60 Install all files specified by command line parameters in ALL packages
  61 acted on.
  62
  63 =item I<manpage ...>
  64
  65 Install these man pages into the first package acted on. (Or in all
  66 packages if -A is specified).
  67
  68 =back
  69
  70 =head1 NOTES
  71
  72 An older version of this program, L<dh_installmanpages(1)>, is still used
  73 by some packages, and so is still included in debhelper.
  74 It is, however, deprecated, due to its counterintuitive and inconsistent
  75 interface. Use this program instead.
  76
  77 =cut
  78
  79 init();
  80
  81 my @sofiles;
  82 my @sodests;
  83
  84 foreach my $package (@{$dh{DOPACKAGES}}) {
  85         my $tmp=tmpdir($package);
  86         my $file=pkgfile($package,"manpages");
  87         my @manpages;
  88
  89         if ($file) {
  90                 @manpages=filearray($file, ".");
  91         }
  92
  93         if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
  94                 push @manpages, @ARGV;
  95         }
  96
  97         foreach my $page (@manpages) {
  98                 my $basename=basename($page);
  99
 100                 # Support compressed pages.
 101                 my $gz='';
 102                 if ($basename=~m/(.*)(\.gz)/) {
 103                         $basename=$1;
 104                         $gz=$2;
 105                 }
 106
 107                 my $section;
 108                 # See if there is a .TH entry in the man page. If so,
 109                 # we'll pull the section field from that.
 110                 if ($gz) {
 111                         open (IN, "zcat $page|") or die "$page: $!";
 112                 }
 113                 else {
 114                         open (IN, $page) or die "$page: $!";
 115                 }
 116                 while (<IN>) {
 117                         if (/^\.TH\s+\S+\s+"?(\d+[^"\s]*)"?/) {
 118                                 $section=$1;
 119                                 last;
 120                         }
 121                 }
 122                 # Failing that, we can try to get it from the filename.
 123                 if (! $section) {
 124                         ($section)=$basename=~m/.*\.([1-9]\S*)/;
 125                 }
 126
 127                 # Now get the numeric component of the section.
 128                 my ($realsection)=$section=~m/^(\d)/ if defined $section;
 129
 130                 # If there is no numeric section, bail.
 131                 if (! $realsection) {
 132                         error("Could not determine section for $page");
 133                 }
 134
 135                 # Get the man page's name -- everything up to the last dot.
 136                 my ($instname)=$basename=~m/^(.*)\./;
 137
 138                 my $destdir="$tmp/usr/share/man/man$realsection/";
 139                 # Translated man pages are typically specified by adding the
 140                 # language code to the filename, so detect that and
 141                 # redirect to appropriate directory, stripping the code.
 142                 my ($langcode)=$basename=~m/.*\.([a-z][a-z](?:_[A-Z][A-Z])?)\.(?:[1-9]|man)/;
 143                 if (defined $langcode && $langcode ne '') {
 144                         $destdir="$tmp/usr/share/man/$langcode/man$realsection/";
 145                         # Strip the language code from the instname.
 146                         $instname=~s/\.$langcode$//;
 147                 }
 148                 $destdir=~tr:/:/:s; # just for looks
 149
 150                 if (! -e "$destdir/$instname.$section" &&
 151                     ! -l "$destdir/$instname.$section") {
 152                         if (! -d $destdir) {
 153                                 doit "install","-d",$destdir;
 154                         }
 155                         doit "install","-p","-m644",$page,
 156                                 "$destdir$instname.$section$gz";
 157                 }
 158
 159         }
 160
 161         # Now the .so conversion.
 162         @sofiles=@sodests=();
 163         foreach my $dir (qw{usr/share/man usr/X11R6/man}) {
 164                 if (-e "$tmp/$dir") {
 165                         find(\&find_so_man, "$tmp/$dir");
 166                 }
 167         }
 168         foreach my $sofile (@sofiles) {
 169                 my $sodest=shift(@sodests);
 170                 doit "rm","-f",$sofile;
 171                 doit "ln","-sf",$sodest,$sofile;
 172         }
 173 }
 174
 175 # Check if a file is a .so man page, for use by File::Find.
 176 sub find_so_man {
 177         # The -s test is becuase a .so file tends to be small. We don't want
 178         # to open every man page. 1024 is arbitrary.
 179         if (! -f $_ || -s $_ > 1024 || -s == 0) {
 180                 return;
 181         }
 182
 183         # Test first line of file for the .so thing.
 184         open (SOTEST,$_) || die "$_: $!";
 185         my $l=<SOTEST>;
 186         close SOTEST;
 187         if ($l=~m/\.so\s+(.*)/) {
 188                 my $solink=$1;
 189                 # This test is here to prevent links like ... man8/../man8/foo.8
 190                 if (basename($File::Find::dir) eq
 191                     dirname($solink)) {
 192                         $solink=basename($solink);
 193                 }
 194                 else {
 195                         $solink="../$solink";
 196                 }
 197
 198                 push @sofiles,"$File::Find::dir/$_";
 199                 push @sodests,$solink;
 200         }
 201 }
 202
 203 =head1 SEE ALSO
 204
 205 L<debhelper(7)>
 206
 207 This program is a part of debhelper.
 208
 209 =head1 AUTHOR
 210
 211 Joey Hess <joeyh@debian.org>
 212
 213 =cut