dh_installman

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_installman - install man pages into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_installman> [S<I<debhelper options>>] [S<I<manpage ...>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_installman is a debhelper program that handles installing
  20 man pages into the correct locations in package build directories. You tell
  21 it what man pages go in your packages, and it figures out where to
  22 install them based on the section field in their .TH line. If you have a
  23 properly formatted .TH line, your man page will be installed into the right
  24 directory, with the right name (this includes proper handling of pages
  25 with a subsection, like "3perl", which are placed in man3, and given an
  26 extension of ".3perl"). If your .TH line is incorrect or missing, the program
  27 may guess wrong based on the file extension.
  28
  29 It also supports translated man pages, by looking for extensions
  30 like .ll.8 and .ll_LL.8, or by use of the --language switch.
  31
  32 If dh_installman seems to install a man page into the wrong section or with
  33 the wrong extension, this is because the man page has the wrong section
  34 listed in its .TH line. Edit the man page and correct the section, and
  35 dh_installman will follow suit.  See L<man(7)> for details about the .TH
  36 section. If dh_installman seems to install a man page into a directory
  37 like /usr/share/man/pl/man1/, that is because your program has a
  38 name like "foo.pl", and dh_installman assumes that means it is translated
  39 into Polish. Use --language=C to avoid this.
  40
  41 dh_installman will use man to guess the character encoding of each manual
  42 page and convert it to UTF-8. If the guesswork fails for some reason, you
  43 can override it using an encoding declaration. See L<manconv(1)> for
  44 details.
  45
  46 Any man page filenames specified as parameters will be installed into the
  47 first package dh_installman is told to act on. By default, this is the
  48 first binary package in debian/control, but if you use -p, -i, or -a flags,
  49 it will be the first package specified by those flags.
  50
  51 Files named debian/package.manpages can list other man pages to be
  52 installed.
  53
  54 After the man page installation step, dh_installman will check to see if
  55 any of the man pages in the temporary directories of any of the packages it
  56 is acting on contain ".so" links. If so, it changes them to symlinks.
  57
  58 =head1 OPTIONS
  59
  60 =over 4
  61
  62 =item B<-A>, B<--all>
  63
  64 Install all files specified by command line parameters in ALL packages
  65 acted on.
  66
  67 =item B<--language>=ll
  68
  69 Use this to specify that the man pages being acted on are written in the
  70 specified language.
  71
  72 =item I<manpage ...>
  73
  74 Install these man pages into the first package acted on. (Or in all
  75 packages if -A is specified).
  76
  77 =back
  78
  79 =head1 NOTES
  80
  81 An older version of this program, L<dh_installmanpages(1)>, is still used
  82 by some packages, and so is still included in debhelper.
  83 It is, however, deprecated, due to its counterintuitive and inconsistent
  84 interface. Use this program instead.
  85
  86 =cut
  87
  88 init();
  89
  90 my @sofiles;
  91 my @sodests;
  92
  93 foreach my $package (@{$dh{DOPACKAGES}}) {
  94         next if is_udeb($package);
  95
  96         my $tmp=tmpdir($package);
  97         my $file=pkgfile($package,"manpages");
  98         my @manpages;
  99
 100         if ($file) {
 101                 @manpages=filearray($file, ".");
 102         }
 103
 104         if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
 105                 push @manpages, @ARGV;
 106         }
 107
 108         foreach my $page (@manpages) {
 109                 my $basename=basename($page);
 110
 111                 # Support compressed pages.
 112                 my $gz='';
 113                 if ($basename=~m/(.*)(\.gz)/) {
 114                         $basename=$1;
 115                         $gz=$2;
 116                 }
 117
 118                 my $section;
 119                 # See if there is a .TH entry in the man page. If so,
 120                 # we'll pull the section field from that.
 121                 if ($gz) {
 122                         open (IN, "zcat $page|") or die "$page: $!";
 123                 }
 124                 else {
 125                         open (IN, $page) or die "$page: $!";
 126                 }
 127                 while (<IN>) {
 128                         if (/^\.TH\s+\S+\s+"?(\d+[^"\s]*)"?/) {
 129                                 $section=$1;
 130                                 last;
 131                         }
 132                 }
 133                 # Failing that, we can try to get it from the filename.
 134                 if (! $section) {
 135                         ($section)=$basename=~m/.*\.([1-9]\S*)/;
 136                 }
 137
 138                 # Now get the numeric component of the section.
 139                 my ($realsection)=$section=~m/^(\d)/ if defined $section;
 140
 141                 # If there is no numeric section, bail.
 142                 if (! $realsection) {
 143                         error("Could not determine section for $page");
 144                 }
 145
 146                 # Get the man page's name -- everything up to the last dot.
 147                 my ($instname)=$basename=~m/^(.*)\./;
 148
 149                 my $destdir="$tmp/usr/share/man/man$realsection/";
 150                 my $langcode;
 151                 if (! defined $dh{LANGUAGE} || ! exists $dh{LANGUAGE}) {
 152                         # Translated man pages are typically specified by adding the
 153                         # language code to the filename, so detect that and
 154                         # redirect to appropriate directory, stripping the code.
 155                         ($langcode)=$basename=~m/.*\.([a-z][a-z](?:_[A-Z][A-Z])?)\.(?:[1-9]|man)/;
 156                 }
 157                 elsif ($dh{LANGUAGE} ne 'C') {
 158                         $langcode=$dh{LANGUAGE};
 159                 }
 160
 161                 if (defined $langcode && $langcode ne '') {
 162                         # Strip the language code from the instname.
 163                         $instname=~s/\.$langcode$//;
 164                 }
 165
 166                 if (defined $langcode && $langcode ne '') {
 167                         $destdir="$tmp/usr/share/man/$langcode/man$realsection/";
 168                 }
 169                 $destdir=~tr:/:/:s; # just for looks
 170                 my $instpage="$destdir/$instname.$section";
 171
 172                 next if -l $instpage;
 173                 next if compat(5) && -e $instpage;
 174
 175                 if (! -d $destdir) {
 176                         doit "install","-d",$destdir;
 177                 }
 178                 if ($gz) {
 179                         complex_doit "zcat \Q$page\E > \Q$instpage\E";
 180                 }
 181                 else {
 182                         doit "install","-p","-m644",$page,$instpage;
 183                 }
 184                 complex_doit "man --recode UTF-8 \Q$instpage\E > \Q$instpage.new\E";
 185                 doit "chmod",644,"$instpage.new";
 186                 doit "mv","-f","$instpage.new",$instpage;
 187         }
 188
 189         # Now the .so conversion.
 190         @sofiles=@sodests=();
 191         foreach my $dir (qw{usr/share/man usr/X11R6/man}) {
 192                 if (-e "$tmp/$dir") {
 193                         find(\&find_so_man, "$tmp/$dir");
 194                 }
 195         }
 196         foreach my $sofile (@sofiles) {
 197                 my $sodest=shift(@sodests);
 198                 doit "rm","-f",$sofile;
 199                 doit "ln","-sf",$sodest,$sofile;
 200         }
 201 }
 202
 203 # Check if a file is a .so man page, for use by File::Find.
 204 sub find_so_man {
 205         # The -s test is becuase a .so file tends to be small. We don't want
 206         # to open every man page. 1024 is arbitrary.
 207         if (! -f $_ || -s $_ > 1024 || -s == 0) {
 208                 return;
 209         }
 210
 211         # Test first line of file for the .so thing.
 212         if (/\.gz$/) {
 213                 open (SOTEST, "zcat $_|") or die "$_: $!";
 214         }
 215         else {
 216                 open (SOTEST,$_) || die "$_: $!";
 217         }
 218         my $l=<SOTEST>;
 219         close SOTEST;
 220
 221         if (! defined $l) {
 222                 error("failed to read $_");
 223         }
 224
 225         if ($l=~m/\.so\s+(.*)\s*/) {
 226                 my $solink=$1;
 227                 # This test is here to prevent links like ... man8/../man8/foo.8
 228                 if (basename($File::Find::dir) eq
 229                     dirname($solink)) {
 230                         $solink=basename($solink);
 231                 }
 232                 else {
 233                         $solink="../$solink";
 234                 }
 235
 236                 push @sofiles,"$File::Find::dir/$_";
 237                 push @sodests,$solink;
 238         }
 239 }
 240
 241 =head1 SEE ALSO
 242
 243 L<debhelper(7)>
 244
 245 This program is a part of debhelper.
 246
 247 =head1 AUTHOR
 248
 249 Joey Hess <joeyh@debian.org>
 250
 251 =cut