dh_installinit

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_installinit - install init scripts into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_installinit> [S<I<debhelper options>>] [B<--name=>I<name>] [B<-n>] [B<-r>] [B<-d>] [S<B<--> I<params>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_installinit is a debhelper program that is responsible for installing
  19 init scripts and associated defaults files into package build directories.
  20
  21 It also automatically generates the postinst and postrm and prerm commands
  22 needed to set up the symlinks in /etc/rc*.d/ and to start and stop the init
  23 scripts.
  24
  25 If a file named debian/package.init exists, then it is installed into
  26 etc/init.d/package in the package build directory, with "package" replaced
  27 by the package name.
  28
  29 If a file named debian/package.default exists, then it is installed into
  30 etc/default/package in the package build directory, with "package" replaced
  31 by the package name.
  32
  33 =head1 OPTIONS
  34
  35 =over 4
  36
  37 =item B<-n>, B<--noscripts>
  38
  39 Do not modify postinst/postrm/prerm scripts.
  40
  41 =item B<-r>, B<--no-restart-on-upgrade>
  42
  43 Do not restart init script on upgrade.
  44
  45 =item B<--no-start>
  46
  47 Do not start the init script on install or upgrade, or stop it on removal.
  48 Only call update-rc.d. Useful for rcS scripts.
  49
  50 =item B<-d>, B<--remove-d>
  51
  52 Remove trailing "d" from the name of the package, and use the result for the
  53 filename the init script is installed as in etc/init.d/ , and the default file
  54 is installed as in etc/default/ . This may be useful for daemons with names
  55 ending in "d". (Note: this takes precedence over the --init-script parameter
  56 described below.)
  57
  58 =item B<-u>I<params> B<--update-rcd-params=>I<params>
  59
  60 =item B<--> I<params>
  61
  62 Pass "params" to L<update-rc.d(8)>. If not specified, "defaults" will be
  63 passed to L<update-rc.d(8)>.
  64
  65 =item B<--name=>I<name>
  66
  67 Install the init script (and default file) using the filename I<name>
  68 instead of the default filename, which is the package name. When this
  69 parameter is used, dh_installinit looks for and installs files named
  70 debian/package.name.init and debian/package.name.default, instead of the
  71 usual debian/package.init and debian/package.default.
  72
  73 =item B<--init-script=>I<scriptname>
  74
  75 Use "scriptname" as the filename the init script is installed as in
  76 etc/init.d/ (and also use it as the filename for the defaults file, if it
  77 is installed). If you use this parameter, dh_installinit will look to see
  78 if a file in the debian/ directory exists that looks like
  79 "package.scriptname" and if so will install it as the init script in
  80 preference to the files it normally installs.
  81
  82 This parameter is deprecated, use the --name parameter instead.
  83
  84 =item B<--error-handler=>I<function>
  85
  86 Call the named shell function if running the init script fails. The
  87 function should be provided in the prerm and postinst scripts, before the
  88 #DEBHELPER# token.
  89
  90 =back
  91
  92 =head1 NOTES
  93
  94 Note that this command is not idempotent. "dh_clean -k" should be called
  95 between invocations of this command. Otherwise, it may cause multiple
  96 instances of the same text to be added to maintainer scripts.
  97
  98 =cut
  99
 100 init();
 101
 102 foreach my $package (@{$dh{DOPACKAGES}}) {
 103         my $tmp=tmpdir($package);
 104
 105         # Figure out what filename to install it as.
 106         my $script;
 107         if (defined $dh{NAME}) {
 108                 $script=$dh{NAME};
 109         }
 110         elsif ($dh{D_FLAG}) {
 111                 # -d on the command line sets D_FLAG. We will
 112                 # remove a trailing 'd' from the package name and
 113                 # use that as the name.
 114                 $script=$package;
 115                 if ($script=~m/(.*)d$/) {
 116                         $script=$1;
 117                 }
 118                 else {
 119                         warning("\"$package\" has no final d' in its name, but -d was specified.");
 120                 }
 121         }
 122         elsif ($dh{INIT_SCRIPT}) {
 123                 $script=$dh{INIT_SCRIPT};
 124         }
 125         else {
 126                 $script=$package;
 127         }
 128
 129         my $init=pkgfile($package,$script) || pkgfile($package,"init") ||
 130               pkgfile($package,"init.d");
 131         my $default=pkgfile($package,'default');
 132
 133         if ($default ne '') {
 134                 if (! -d "$tmp/etc/default") {
 135                         doit("install","-d","$tmp/etc/default");
 136                 }
 137                 doit("install","-p","-m644",$default,"$tmp/etc/default/$script");
 138         }
 139
 140         if ($init ne '') {
 141                 if (! -d "$tmp/etc/init.d") {
 142                         doit("install","-d","$tmp/etc/init.d");
 143                 }
 144
 145                 doit("install","-p","-m755",$init,"$tmp/etc/init.d/$script");
 146
 147                 # This is set by the -u "foo" command line switch, it's
 148                 # the parameters to pass to update-rc.d. If not set,
 149                 # we have to say "defaults".
 150                 my $params='';
 151                 if (defined($dh{U_PARAMS})) {
 152                         $params=join(' ',@{$dh{U_PARAMS}});
 153                 }
 154                 if ($params eq '') {
 155                         $params="defaults";
 156                 }
 157
 158                 if (! $dh{NOSCRIPTS}) {
 159                         if (! $dh{NO_START}) {
 160                                 # update-rc.d, and start script
 161                                 autoscript($package,"postinst", "postinst-init",
 162                                         "s/#SCRIPT#/$script/;s/#INITPARMS#/$params/;s/#ERROR_HANDLER#/$dh{ERROR_HANDLER}/");
 163
 164                                 if ($dh{R_FLAG}) {
 165                                         # stops script only on remove
 166                                         autoscript($package,"prerm","prerm-init-norestart",
 167                                                 "s/#SCRIPT#/$script/;s/#INITPARMS#/$params/;s/#ERROR_HANDLER#/$dh{ERROR_HANDLER}/");
 168                                 }
 169                                 else {
 170                                         # always stops script
 171                                         autoscript($package,"prerm","prerm-init",
 172                                                 "s/#SCRIPT#/$script/;s/#INITPARMS#/$params/;s/#ERROR_HANDLER#/$dh{ERROR_HANDLER}/");
 173                                 }
 174                         }
 175                         else {
 176                                 # just update-rc.d
 177                                 autoscript($package,"postinst", "postinst-init-nostart",
 178                                         "s/#SCRIPT#/$script/;s/#INITPARMS#/$params/;s/#ERROR_HANDLER#/$dh{ERROR_HANDLER}/");
 179                         }
 180
 181                         # removes rc.d links
 182                         autoscript($package,"postrm","postrm-init",
 183                                 "s/#SCRIPT#/$script/;s/#INITPARMS#/$params/;s/#ERROR_HANDLER#/$dh{ERROR_HANDLER}/");
 184                 }
 185         }
 186 }
 187
 188 =head1 SEE ALSO
 189
 190 L<debhelper(7)>
 191
 192 This program is a part of debhelper.
 193
 194 =head1 AUTHOR
 195
 196 Joey Hess <joeyh@debian.org>
 197
 198 =cut